Reissner_Nordstrom_monopole.ipynb

Kernel: SageMath 10.0.beta2

Reissner-Nordström black hole with a magnetic monopole

version()

'SageMath version 10.0.beta2, Release Date: 2023-02-23'

%display latex

Spacetime manifold

We declare the Lorentzian manifold $M$ and the ingoing null Eddington-Finkelstein coordinates $(v,r,\theta,\phi)$ as a chart on $M$:

M = Manifold(4, 'M', structure='Lorentzian')
X.<v,r,th,ph> = M.chart(r'v r:(0,+oo) th:(0,pi):\theta ph:(0,2*pi):\phi')
X

$\displaystyle \left(M,(v, r, {\theta}, {\phi})\right)$

We shall use the ingoing null Eddington-Finkelstein coordinates for they are regular on the black hole event horizon.

Metric tensor

We introduce the parameters $m$, $q$ and $p$, where $m$ is the ADM (= Komar) mass and $q$ and $p$ are related to the electric charge $Q$ and the magnetic charge $P$ via $$q = \sqrt{\frac{\mu_0}{4\pi}} Q \quad\mbox{and}\quad p = \sqrt{\frac{\mu_0}{4\pi}} P$$ We are using SI units and in the following we set $\mu_0 = 1$ (in addition to $c=1$ and $G=1$).

m = var('m')  
q = var('q')
p = var('p')
assume(m>0)
assume(m^2 - q^2 - p^2 >= 0)

g = M.metric()
g[0,0] = - (1 - 2*m/r + (q^2 + p^2)/r^2)
g[0,1] = 1
g[2,2] = r^2
g[3,3] = r^2*sin(th)^2
g.display()

$\displaystyle g = \left( \frac{2 \, m}{r} - \frac{p^{2} + q^{2}}{r^{2}} - 1 \right) \mathrm{d} v\otimes \mathrm{d} v +\mathrm{d} v\otimes \mathrm{d} r +\mathrm{d} r\otimes \mathrm{d} v + r^{2} \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + r^{2} \sin\left({\theta}\right)^{2} \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}$

The event horizon $\mathscr{H}$ is located at $r=r_H$, with $r_H = m + \sqrt{m^2 - q^2 - p^2}$:

rH = m + sqrt(m^2 - q^2 - p^2)

A generic point on $\mathscr{H}$:

pH = M((v, rH, th, ph))
print(pH)

Point on the 4-dimensional Lorentzian manifold M

X(pH)

$\displaystyle \left(v, m + \sqrt{m^{2} - p^{2} - q^{2}}, {\theta}, {\phi}\right)$

Ricci tensor

Ric = g.ricci()
Ric.display()

$\displaystyle \mathrm{Ric}\left(g\right) = \left( \frac{p^{4} + 2 \, p^{2} q^{2} + q^{4} + {\left(p^{2} + q^{2}\right)} r^{2} - 2 \, {\left(m p^{2} + m q^{2}\right)} r}{r^{6}} \right) \mathrm{d} v\otimes \mathrm{d} v + \left( -\frac{p^{2} + q^{2}}{r^{4}} \right) \mathrm{d} v\otimes \mathrm{d} r + \left( -\frac{p^{2} + q^{2}}{r^{4}} \right) \mathrm{d} r\otimes \mathrm{d} v + \left( \frac{p^{2} + q^{2}}{r^{2}} \right) \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \frac{{\left(p^{2} + q^{2}\right)} \sin\left({\theta}\right)^{2}}{r^{2}} \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}$

Ric.apply_map(factor)
Ric[:]

$\displaystyle \left(\begin{array}{rrrr} \frac{{\left(p^{2} + q^{2} - 2 \, m r + r^{2}\right)} {\left(p^{2} + q^{2}\right)}}{r^{6}} & -\frac{p^{2} + q^{2}}{r^{4}} & 0 & 0 \\ -\frac{p^{2} + q^{2}}{r^{4}} & 0 & 0 & 0 \\ 0 & 0 & \frac{p^{2} + q^{2}}{r^{2}} & 0 \\ 0 & 0 & 0 & \frac{{\left(p^{2} + q^{2}\right)} \sin\left({\theta}\right)^{2}}{r^{2}} \end{array}\right)$

The Ricci scalar vanishes indentically:

R = g.ricci_scalar()
R.display()

$\displaystyle \begin{array}{llcl} \mathrm{r}\left(g\right):& M & \longrightarrow & \mathbb{R} \\ & \left(v, r, {\theta}, {\phi}\right) & \longmapsto & 0 \end{array}$

Einstein tensor

G = Ric - R/2*g
G.set_name('G')
G.display()

$\displaystyle G = \frac{{\left(p^{2} + q^{2} - 2 \, m r + r^{2}\right)} {\left(p^{2} + q^{2}\right)}}{r^{6}} \mathrm{d} v\otimes \mathrm{d} v + \left( -\frac{p^{2} + q^{2}}{r^{4}} \right) \mathrm{d} v\otimes \mathrm{d} r + \left( -\frac{p^{2} + q^{2}}{r^{4}} \right) \mathrm{d} r\otimes \mathrm{d} v + \left( \frac{p^{2} + q^{2}}{r^{2}} \right) \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \frac{{\left(p^{2} + q^{2}\right)} \sin\left({\theta}\right)^{2}}{r^{2}} \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}$

Electromagnetic field

To form the electromagnetic field 2-form $F$, we shall need the 1-forms $\mathrm{d}v$, $\mathrm{d}r$, $\mathrm{d}\theta$, and $\mathrm{d}\phi$. We get them from the coframe associated to the coordinate chart X:

X.coframe()

$\displaystyle \left(M, \left(\mathrm{d} v,\mathrm{d} r,\mathrm{d} {\theta},\mathrm{d} {\phi}\right)\right)$

dv, dr, dth, dph = X.coframe()[:]

dv.display()

$\displaystyle \mathrm{d} v = \mathrm{d} v$

print(dv)

1-form dv on the 4-dimensional Lorentzian manifold M

We can then write the electromagnetic field in terms of wedge products as:

F = 1/sqrt(4*pi) * (- q/r^2*dv.wedge(dr) + p*sin(th)*dth.wedge(dph) )
F.set_name('F')
F.display()

$\displaystyle F = -\frac{q}{2 \, \sqrt{\pi} r^{2}} \mathrm{d} v\wedge \mathrm{d} r + \frac{p \sin\left({\theta}\right)}{2 \, \sqrt{\pi}} \mathrm{d} {\theta}\wedge \mathrm{d} {\phi}$

print(F)

2-form F on the 4-dimensional Lorentzian manifold M

F[:]

$\displaystyle \left(\begin{array}{rrrr} 0 & -\frac{q}{2 \, \sqrt{\pi} r^{2}} & 0 & 0 \\ \frac{q}{2 \, \sqrt{\pi} r^{2}} & 0 & 0 & 0 \\ 0 & 0 & 0 & \frac{p \sin\left({\theta}\right)}{2 \, \sqrt{\pi}} \\ 0 & 0 & -\frac{p \sin\left({\theta}\right)}{2 \, \sqrt{\pi}} & 0 \end{array}\right)$

star_F = F.hodge_dual(g)
star_F.display()

$\displaystyle \star F = \frac{p}{2 \, \sqrt{\pi} r^{2}} \mathrm{d} v\wedge \mathrm{d} r + \frac{q \sin\left({\theta}\right)}{2 \, \sqrt{\pi}} \mathrm{d} {\theta}\wedge \mathrm{d} {\phi}$

star_F[:]

$\displaystyle \left(\begin{array}{rrrr} 0 & \frac{p}{2 \, \sqrt{\pi} r^{2}} & 0 & 0 \\ -\frac{p}{2 \, \sqrt{\pi} r^{2}} & 0 & 0 & 0 \\ 0 & 0 & 0 & \frac{q \sin\left({\theta}\right)}{2 \, \sqrt{\pi}} \\ 0 & 0 & -\frac{q \sin\left({\theta}\right)}{2 \, \sqrt{\pi}} & 0 \end{array}\right)$

Maxwell equations

Let us check that $F$ obeys the source-free Maxwell equations:

diff(F).display()

$\displaystyle \mathrm{d}F = 0$

diff(star_F).display()

$\displaystyle \mathrm{d}\star F = 0$

An equivalent check is the vanishing of the divergences $\nabla_a F^a_{\ \, b}$ and $\nabla_a \star F^a_{\ \, b}$ :

nabla = g.connection()

div_F = nabla(F.up(g, 0)).trace(0, 2)
div_F.display()

$\displaystyle 0$

div_star_F = nabla(star_F.up(g, 0)).trace(0, 2)
div_star_F.display()

$\displaystyle 0$

Energy-momentum tensor of the electromagnetic field

To evaluate the energy-momentum tensor, we need the scalar $F_{ab}F^{ab}$, which we compute as follows:

Fuu = F.up(g)
F2 = F['_ab']*Fuu['^ab']
print(F2)

Scalar field on the 4-dimensional Lorentzian manifold M

F2.display()

$\displaystyle \begin{array}{llcl} & M & \longrightarrow & \mathbb{R} \\ & \left(v, r, {\theta}, {\phi}\right) & \longmapsto & \frac{p^{2} - q^{2}}{2 \, \pi r^{4}} \end{array}$

F2.expr()

$\displaystyle \frac{p^{2} - q^{2}}{2 \, \pi r^{4}}$

The type-(1,1) tensor $F^a_{\ \, b}$:

Fud = F.up(g, 0)
Fud.apply_map(factor)
Fud[:]

$\displaystyle \left(\begin{array}{rrrr} \frac{q}{2 \, \sqrt{\pi} r^{2}} & 0 & 0 & 0 \\ \frac{{\left(p^{2} + q^{2} - 2 \, m r + r^{2}\right)} q}{2 \, \sqrt{\pi} r^{4}} & -\frac{q}{2 \, \sqrt{\pi} r^{2}} & 0 & 0 \\ 0 & 0 & 0 & \frac{p \sin\left({\theta}\right)}{2 \, \sqrt{\pi} r^{2}} \\ 0 & 0 & -\frac{p}{2 \, \sqrt{\pi} r^{2} \sin\left({\theta}\right)} & 0 \end{array}\right)$

The energy-momentum tensor of the electromagnetic field:

T = F['_k.']*Fud['^k_.'] - 1/4*F2 * g
T.apply_map(factor)
T.display()

$\displaystyle \frac{{\left(p^{2} + q^{2} - 2 \, m r + r^{2}\right)} {\left(p^{2} + q^{2}\right)}}{8 \, \pi r^{6}} \mathrm{d} v\otimes \mathrm{d} v + \left( -\frac{p^{2} + q^{2}}{8 \, \pi r^{4}} \right) \mathrm{d} v\otimes \mathrm{d} r + \left( -\frac{p^{2} + q^{2}}{8 \, \pi r^{4}} \right) \mathrm{d} r\otimes \mathrm{d} v + \left( \frac{p^{2} + q^{2}}{8 \, \pi r^{2}} \right) \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \frac{{\left(p^{2} + q^{2}\right)} \sin\left({\theta}\right)^{2}}{8 \, \pi r^{2}} \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}$

T[:]

$\displaystyle \left(\begin{array}{rrrr} \frac{{\left(p^{2} + q^{2} - 2 \, m r + r^{2}\right)} {\left(p^{2} + q^{2}\right)}}{8 \, \pi r^{6}} & -\frac{p^{2} + q^{2}}{8 \, \pi r^{4}} & 0 & 0 \\ -\frac{p^{2} + q^{2}}{8 \, \pi r^{4}} & 0 & 0 & 0 \\ 0 & 0 & \frac{p^{2} + q^{2}}{8 \, \pi r^{2}} & 0 \\ 0 & 0 & 0 & \frac{{\left(p^{2} + q^{2}\right)} \sin\left({\theta}\right)^{2}}{8 \, \pi r^{2}} \end{array}\right)$

Check of the Einstein equation

G == 8*pi*T

$\displaystyle \mathrm{True}$

Pseudo-electric field $E$ and pseudo-magnetic field $B$

The stationary Killing vector field $\xi$:

xi = M.vector_field(1, 0, 0, 0, name='xi', latex_name=r'\xi')
xi.display()

$\displaystyle \xi = \frac{\partial}{\partial v }$

$\xi$ is null on $\mathscr{H}$:

g(xi,xi)(pH)

$\displaystyle 0$

The pseudo-electric field 1-form is defined by $E := F(.,\xi)$. It would be the electric field measured by the observer of 4-velocity $\xi$ if $\xi$ would be a unit timelike vector, which it is not, except for $r\to +\infty$.

E = F.contract(xi)
E.set_name('E')
E.display()

$\displaystyle E = \frac{q}{2 \, \sqrt{\pi} r^{2}} \mathrm{d} r$

$E$ is a closed 1-form:

diff(E).display()

$\displaystyle \mathrm{d}E = 0$

$E$ is actually an exact 1-form:

Phi = M.scalar_field(1/sqrt(4*pi) * q/r, name='Phi', 
                     latex_name=r'\Phi')
Phi.display()

$\displaystyle \begin{array}{llcl} \Phi:& M & \longrightarrow & \mathbb{R} \\ & \left(v, r, {\theta}, {\phi}\right) & \longmapsto & \frac{q}{2 \, \sqrt{\pi} r} \end{array}$

E == - diff(Phi)

$\displaystyle \mathrm{True}$

The vector field $\vec{E}$ associated to $E$ by metric duality:

vE = E.up(g)
vE.set_name('vE', latex_name = r'\vec{E}')
vE.display()

$\displaystyle \vec{E} = \frac{q}{2 \, \sqrt{\pi} r^{2}} \frac{\partial}{\partial v } + \left( \frac{p^{2} q + q^{3} - 2 \, m q r + q r^{2}}{2 \, \sqrt{\pi} r^{4}} \right) \frac{\partial}{\partial r }$

We note that $\vec{E}$ is collinear to $\xi$ on the event horizon $\mathscr{H}$:

vE.at(pH).display()

$\displaystyle \vec{E} = \frac{q}{2 \, {\left(2 \, \sqrt{\pi} \sqrt{m^{2} - p^{2} - q^{2}} m + \sqrt{\pi} {\left(2 \, m^{2} - p^{2} - q^{2}\right)}\right)}} \frac{\partial}{\partial v }$

g(vE,vE)(pH)

$\displaystyle 0$

The pseudo-magnetic field 1-form is defined by $B := \star F(\xi,.)$; as for $E$ it fails to be a genuine magnetic field because $\xi$ is not a unit timelike vector.

B = xi.contract(star_F)
B.set_name('B')
B.display()

$\displaystyle B = \frac{p}{2 \, \sqrt{\pi} r^{2}} \mathrm{d} r$

We note that $B$ is collinear to $E$ and that it is a closed 1-form as well:

diff(B).display()

$\displaystyle \mathrm{d}B = 0$

As $E$, $B$ is actually an exact 1-form:

Psi = M.scalar_field(1/sqrt(4*pi) * p/r, name='Psi', 
                     latex_name=r'\Psi')
Psi.display()

$\displaystyle \begin{array}{llcl} \Psi:& M & \longrightarrow & \mathbb{R} \\ & \left(v, r, {\theta}, {\phi}\right) & \longmapsto & \frac{p}{2 \, \sqrt{\pi} r} \end{array}$

B == - diff(Psi)

$\displaystyle \mathrm{True}$

The vector field $\vec{B}$ associated to $B$ by metric duality:

vB = B.up(g)
vB.set_name('vB', latex_name = r'\vec{B}')
vB.display()

$\displaystyle \vec{B} = \frac{p}{2 \, \sqrt{\pi} r^{2}} \frac{\partial}{\partial v } + \left( \frac{p^{3} + p q^{2} - 2 \, m p r + p r^{2}}{2 \, \sqrt{\pi} r^{4}} \right) \frac{\partial}{\partial r }$

vB.at(pH).display()

$\displaystyle \vec{B} = \frac{p}{2 \, {\left(2 \, \sqrt{\pi} \sqrt{m^{2} - p^{2} - q^{2}} m + \sqrt{\pi} {\left(2 \, m^{2} - p^{2} - q^{2}\right)}\right)}} \frac{\partial}{\partial v }$

Electromagnetic potential $A$

Since $F$ obeys the source-free Maxwell equation $\mathrm{d}F = 0$, we may introduce locally a 1-form $A$ such that $F = \mathrm{d}A$. However, unless $p=0$, $A$ cannot be a globally regular 1-form, as we shall discuss below.

A = - 1/sqrt(4*pi) * (q/r * dv + p*cos(th)*dph )
A.set_name('A')
A.display()

$\displaystyle A = -\frac{q}{2 \, \sqrt{\pi} r} \mathrm{d} v -\frac{p \cos\left({\theta}\right)}{2 \, \sqrt{\pi}} \mathrm{d} {\phi}$

diff(A).display()

$\displaystyle \mathrm{d}A = -\frac{q}{2 \, \sqrt{\pi} r^{2}} \mathrm{d} v\wedge \mathrm{d} r + \frac{p \sin\left({\theta}\right)}{2 \, \sqrt{\pi}} \mathrm{d} {\theta}\wedge \mathrm{d} {\phi}$

F == diff(A)

$\displaystyle \mathrm{True}$

We have actually $\Phi = - \langle A, \xi \rangle$:

Phi == - A(xi)

$\displaystyle \mathrm{True}$

The 1-form $$\Omega = \Phi F + \frac{1}{2} \, \underline{\xi} \wedge (A\cdot F)$$ which appears in the proof of the generalized Smarr formula without magnetic monopole:

AF = A['_b']*Fud['^b_a']
AF.display()

$\displaystyle -\frac{q^{2}}{4 \, \pi r^{3}} \mathrm{d} v + \frac{p^{2} \cos\left({\theta}\right)}{4 \, \pi r^{2} \sin\left({\theta}\right)} \mathrm{d} {\theta}$

xif = xi.down(g)
xif.display()

$\displaystyle \left( \frac{2 \, m}{r} - \frac{p^{2} + q^{2}}{r^{2}} - 1 \right) \mathrm{d} v +\mathrm{d} r$

Omega = Phi*F + 1/2*xif.wedge(AF)
Omega.set_name('Omega', latex_name=r'\Omega')
Omega.apply_map(factor)
Omega.display()

$\displaystyle \Omega = -\frac{q^{2}}{8 \, \pi r^{3}} \mathrm{d} v\wedge \mathrm{d} r -\frac{{\left(p^{2} + q^{2} - 2 \, m r + r^{2}\right)} p^{2} \cos\left({\theta}\right)}{8 \, \pi r^{4} \sin\left({\theta}\right)} \mathrm{d} v\wedge \mathrm{d} {\theta} + \frac{p^{2} \cos\left({\theta}\right)}{8 \, \pi r^{2} \sin\left({\theta}\right)} \mathrm{d} r\wedge \mathrm{d} {\theta} + \frac{p q \sin\left({\theta}\right)}{4 \, \pi r} \mathrm{d} {\theta}\wedge \mathrm{d} {\phi}$

div_Omega = nabla(Omega).up(g, 2).trace(0, 2)
div_Omega.apply_map(factor)
div_Omega.display()

$\displaystyle \frac{{\left(p^{2} + q^{2} - 2 \, m r + r^{2}\right)} {\left(p^{2} + q^{2}\right)}}{8 \, \pi r^{6}} \mathrm{d} v + \left( -\frac{p^{2} + q^{2}}{8 \, \pi r^{4}} \right) \mathrm{d} r$

T.contract(xi) == div_Omega

$\displaystyle \mathrm{True}$

Regularity of the fields $F$, $A$, $\Omega$, $\Phi$ and $\Psi$

To assess the regularity of the fields on the axis $\theta=0$ or $\pi$, we introduce a Cartesian-like coordinate system:

Y.<v,x,y,z> = M.chart()
Y

$\displaystyle \left(M,(v, x, y, z)\right)$

X_to_Y = X.transition_map(Y, (v, 
                              r*sin(th)*cos(ph),  
                              r*sin(th)*sin(ph),
                              r*cos(th)))
X_to_Y.display()

$\displaystyle \left\{\begin{array}{lcl} v & = & v \\ x & = & r \cos\left({\phi}\right) \sin\left({\theta}\right) \\ y & = & r \sin\left({\phi}\right) \sin\left({\theta}\right) \\ z & = & r \cos\left({\theta}\right) \end{array}\right.$

X_to_Y.set_inverse(v, sqrt(x^2 + y^2 + z^2), atan2(sqrt(x^2+y^2),z), atan2(y, x))

Check of the inverse coordinate transformation:
  v == v  *passed*
  r == r  *passed*
  th == arctan2(r*sin(th), r*cos(th))  **failed**
  ph == arctan2(r*sin(ph)*sin(th), r*cos(ph)*sin(th))  **failed**
  v == v  *passed*
  x == x  *passed*
  y == y  *passed*
  z == z  *passed*
NB: a failed report can reflect a mere lack of simplification.

X_to_Y.inverse().display()

$\displaystyle \left\{\begin{array}{lcl} v & = & v \\ r & = & \sqrt{x^{2} + y^{2} + z^{2}} \\ {\theta} & = & \arctan\left(\sqrt{x^{2} + y^{2}}, z\right) \\ {\phi} & = & \arctan\left(y, x\right) \end{array}\right.$

$F$ is perfectly regular in all the region $r>0$:

F.display(Y)

$\displaystyle F = -\frac{q x}{2 \, \sqrt{\pi} {\left(x^{2} + y^{2} + z^{2}\right)}^{\frac{3}{2}}} \mathrm{d} v\wedge \mathrm{d} x -\frac{q y}{2 \, \sqrt{\pi} {\left(x^{2} + y^{2} + z^{2}\right)}^{\frac{3}{2}}} \mathrm{d} v\wedge \mathrm{d} y -\frac{q z}{2 \, \sqrt{\pi} {\left(x^{2} + y^{2} + z^{2}\right)}^{\frac{3}{2}}} \mathrm{d} v\wedge \mathrm{d} z + \left( \frac{\sqrt{x^{2} + y^{2} + z^{2}} p z}{2 \, \sqrt{\pi} {\left(x^{4} + 2 \, x^{2} y^{2} + y^{4} + z^{4} + 2 \, {\left(x^{2} + y^{2}\right)} z^{2}\right)}} \right) \mathrm{d} x\wedge \mathrm{d} y -\frac{p y}{2 \, \sqrt{\pi} {\left(x^{2} + y^{2} + z^{2}\right)}^{\frac{3}{2}}} \mathrm{d} x\wedge \mathrm{d} z + \frac{p x}{2 \, \sqrt{\pi} {\left(x^{2} + y^{2} + z^{2}\right)}^{\frac{3}{2}}} \mathrm{d} y\wedge \mathrm{d} z$

F.apply_map(factor, frame=Y.frame(), chart=Y, keep_other_components=True)
F.display(Y)

$\displaystyle F = -\frac{q x}{2 \, \sqrt{\pi} {\left(x^{2} + y^{2} + z^{2}\right)}^{\frac{3}{2}}} \mathrm{d} v\wedge \mathrm{d} x -\frac{q y}{2 \, \sqrt{\pi} {\left(x^{2} + y^{2} + z^{2}\right)}^{\frac{3}{2}}} \mathrm{d} v\wedge \mathrm{d} y -\frac{q z}{2 \, \sqrt{\pi} {\left(x^{2} + y^{2} + z^{2}\right)}^{\frac{3}{2}}} \mathrm{d} v\wedge \mathrm{d} z + \frac{p z}{2 \, \sqrt{\pi} {\left(x^{2} + y^{2} + z^{2}\right)}^{\frac{3}{2}}} \mathrm{d} x\wedge \mathrm{d} y -\frac{p y}{2 \, \sqrt{\pi} {\left(x^{2} + y^{2} + z^{2}\right)}^{\frac{3}{2}}} \mathrm{d} x\wedge \mathrm{d} z + \frac{p x}{2 \, \sqrt{\pi} {\left(x^{2} + y^{2} + z^{2}\right)}^{\frac{3}{2}}} \mathrm{d} y\wedge \mathrm{d} z$

while $A$ is singular on the axis $\theta=0$ or $\pi$ $\iff$ $x^2 + y^2 = 0$ if $p\neq 0$:

A.display(Y)

$\displaystyle A = \left( -\frac{q}{2 \, \sqrt{\pi} \sqrt{x^{2} + y^{2} + z^{2}}} \right) \mathrm{d} v + \left( \frac{p y z}{2 \, \sqrt{\pi} \sqrt{x^{2} + y^{2} + z^{2}} {\left(x^{2} + y^{2}\right)}} \right) \mathrm{d} x + \left( -\frac{p x z}{2 \, \sqrt{\pi} \sqrt{x^{2} + y^{2} + z^{2}} {\left(x^{2} + y^{2}\right)}} \right) \mathrm{d} y$

$\Omega$ is singular there as well:

Omega.apply_map(factor, frame=Y.frame(), chart=Y, keep_other_components=True)
Omega.display(Y)

$\displaystyle \Omega = -\frac{{\left(q^{2} x^{4} + 2 \, q^{2} x^{2} y^{2} + q^{2} y^{4} + p^{4} z^{2} + p^{2} q^{2} z^{2} + p^{2} x^{2} z^{2} + q^{2} x^{2} z^{2} + p^{2} y^{2} z^{2} + q^{2} y^{2} z^{2} + p^{2} z^{4} - 2 \, \sqrt{x^{2} + y^{2} + z^{2}} m p^{2} z^{2}\right)} x}{8 \, \pi {\left(x^{2} + y^{2} + z^{2}\right)}^{3} {\left(x^{2} + y^{2}\right)}} \mathrm{d} v\wedge \mathrm{d} x -\frac{{\left(q^{2} x^{4} + 2 \, q^{2} x^{2} y^{2} + q^{2} y^{4} + p^{4} z^{2} + p^{2} q^{2} z^{2} + p^{2} x^{2} z^{2} + q^{2} x^{2} z^{2} + p^{2} y^{2} z^{2} + q^{2} y^{2} z^{2} + p^{2} z^{4} - 2 \, \sqrt{x^{2} + y^{2} + z^{2}} m p^{2} z^{2}\right)} y}{8 \, \pi {\left(x^{2} + y^{2} + z^{2}\right)}^{3} {\left(x^{2} + y^{2}\right)}} \mathrm{d} v\wedge \mathrm{d} y + \frac{{\left(p^{4} + p^{2} q^{2} + p^{2} x^{2} - q^{2} x^{2} + p^{2} y^{2} - q^{2} y^{2} + p^{2} z^{2} - q^{2} z^{2} - 2 \, \sqrt{x^{2} + y^{2} + z^{2}} m p^{2}\right)} z}{8 \, \pi {\left(x^{2} + y^{2} + z^{2}\right)}^{3}} \mathrm{d} v\wedge \mathrm{d} z + \frac{p q z}{4 \, \pi {\left(x^{2} + y^{2} + z^{2}\right)}^{2}} \mathrm{d} x\wedge \mathrm{d} y -\frac{{\left(p x^{3} z + p x y^{2} z + p x z^{3} + 2 \, \sqrt{x^{2} + y^{2} + z^{2}} q x^{2} y + 2 \, \sqrt{x^{2} + y^{2} + z^{2}} q y^{3}\right)} p}{8 \, \pi {\left(x^{2} + y^{2} + z^{2}\right)}^{\frac{5}{2}} {\left(x^{2} + y^{2}\right)}} \mathrm{d} x\wedge \mathrm{d} z -\frac{{\left(p x^{2} y z + p y^{3} z + p y z^{3} - 2 \, \sqrt{x^{2} + y^{2} + z^{2}} q x^{3} - 2 \, \sqrt{x^{2} + y^{2} + z^{2}} q x y^{2}\right)} p}{8 \, \pi {\left(x^{2} + y^{2} + z^{2}\right)}^{\frac{5}{2}} {\left(x^{2} + y^{2}\right)}} \mathrm{d} y\wedge \mathrm{d} z$

The scalar potentials $\Phi$ and $\Psi$ are regular in all the region $r>0$:

Phi.expr(Y)

$\displaystyle \frac{q}{2 \, \sqrt{\pi} \sqrt{x^{2} + y^{2} + z^{2}}}$

Psi.expr(Y)

$\displaystyle \frac{p}{2 \, \sqrt{\pi} \sqrt{x^{2} + y^{2} + z^{2}}}$