Kerr_ZAMO_frame.ipynb

Kernel: SageMath 9.2.beta14

ZAMO frame in Kerr spacetime

This Jupyter/SageMath notebook is relative to the lectures Geometry and physics of black holes.

The corresponding tools have been developed within the SageManifolds project.

NB: a version of SageMath at least equal to 9.1 is required to run this notebook:

version()

'SageMath version 9.2.beta13, Release Date: 2020-09-21'

First we set up the notebook to display mathematical objects using LaTeX rendering:

%display latex

We ask for running tensor computations in parallel on 8 threads:

Parallelism().set(nproc=8)

Spacetime manifold

We declare the Kerr spacetime (or more precisely the part of it covered by Boyer-Lindquist coordinates) as a 4-dimensional Lorentzian manifold $\mathcal{M}$:

M = Manifold(4, 'M', latex_name=r'\mathcal{M}', structure='Lorentzian')
print(M)

4-dimensional Lorentzian manifold M

We then introduce the standard Boyer-Lindquist coordinates as a chart BL (for Boyer-Lindquist) on $\mathcal{M}$, via the method chart(), the argument of which is a string (delimited by r"..." because of the backslash symbols) expressing the coordinates names, their ranges (the default is $(-\infty,+\infty)$) and their LaTeX symbols:

BL.<t,r,th,ph> = M.chart(r"t r th:(0,pi):\theta ph:(0,2*pi):\phi") 
print(BL); BL

Chart (M, (t, r, th, ph))

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\left(\mathcal{M},(t, r, {\theta}, {\phi})\right)$$

BL[0], BL[1]

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\left(t, r\right)$$

Metric tensor

The 2 parameters $m$ and $a$ of the Kerr spacetime are declared as symbolic variables:

var('m, a', domain='real')

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\left(m, a\right)$$

We get the (yet undefined) spacetime metric:

g = M.metric()

The metric is set by its components in the coordinate frame associated with Boyer-Lindquist coordinates, which is the current manifold's default frame:

rho2 = r^2 + (a*cos(th))^2
Delta = r^2 -2*m*r + a^2
g[0,0] = -(1-2*m*r/rho2)
g[0,3] = -2*a*m*r*sin(th)^2/rho2
g[1,1], g[2,2] = rho2/Delta, rho2
g[3,3] = (r^2+a^2+2*m*r*(a*sin(th))^2/rho2)*sin(th)^2
g.display()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}g = \left( \frac{2 \, m r}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} - 1 \right) \mathrm{d} t\otimes \mathrm{d} t + \left( -\frac{2 \, a m r \sin\left({\theta}\right)^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \right) \mathrm{d} t\otimes \mathrm{d} {\phi} + \left( \frac{a^{2} \cos\left({\theta}\right)^{2} + r^{2}}{a^{2} - 2 \, m r + r^{2}} \right) \mathrm{d} r\otimes \mathrm{d} r + \left( a^{2} \cos\left({\theta}\right)^{2} + r^{2} \right) \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \left( -\frac{2 \, a m r \sin\left({\theta}\right)^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \right) \mathrm{d} {\phi}\otimes \mathrm{d} t + {\left(\frac{2 \, a^{2} m r \sin\left({\theta}\right)^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} + a^{2} + r^{2}\right)} \sin\left({\theta}\right)^{2} \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}$$

A matrix view of the components with respect to the manifold's default vector frame:

g[:]

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\left(\begin{array}{rrrr} \frac{2 \, m r}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} - 1 & 0 & 0 & -\frac{2 \, a m r \sin\left({\theta}\right)^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \\ 0 & \frac{a^{2} \cos\left({\theta}\right)^{2} + r^{2}}{a^{2} - 2 \, m r + r^{2}} & 0 & 0 \\ 0 & 0 & a^{2} \cos\left({\theta}\right)^{2} + r^{2} & 0 \\ -\frac{2 \, a m r \sin\left({\theta}\right)^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} & 0 & 0 & {\left(\frac{2 \, a^{2} m r \sin\left({\theta}\right)^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} + a^{2} + r^{2}\right)} \sin\left({\theta}\right)^{2} \end{array}\right)$$

The list of the non-vanishing components:

g.display_comp()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{lcl} g_{ \, t \, t }^{ \phantom{\, t}\phantom{\, t} } & = & \frac{2 \, m r}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} - 1 \\ g_{ \, t \, {\phi} }^{ \phantom{\, t}\phantom{\, {\phi}} } & = & -\frac{2 \, a m r \sin\left({\theta}\right)^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \\ g_{ \, r \, r }^{ \phantom{\, r}\phantom{\, r} } & = & \frac{a^{2} \cos\left({\theta}\right)^{2} + r^{2}}{a^{2} - 2 \, m r + r^{2}} \\ g_{ \, {\theta} \, {\theta} }^{ \phantom{\, {\theta}}\phantom{\, {\theta}} } & = & a^{2} \cos\left({\theta}\right)^{2} + r^{2} \\ g_{ \, {\phi} \, t }^{ \phantom{\, {\phi}}\phantom{\, t} } & = & -\frac{2 \, a m r \sin\left({\theta}\right)^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \\ g_{ \, {\phi} \, {\phi} }^{ \phantom{\, {\phi}}\phantom{\, {\phi}} } & = & {\left(\frac{2 \, a^{2} m r \sin\left({\theta}\right)^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} + a^{2} + r^{2}\right)} \sin\left({\theta}\right)^{2} \end{array}$$

ZAMO frame

The default vector frame on the spacetime manifold is the coordinate basis associated with Boyer-Lindquist coordinates:

M.default_frame() is BL.frame()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\mathrm{True}$$

BL.frame()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\left(\mathcal{M}, \left(\frac{\partial}{\partial t },\frac{\partial}{\partial r },\frac{\partial}{\partial {\theta} },\frac{\partial}{\partial {\phi} }\right)\right)$$

The ZAMO 4-velocity is defined by its components w.r.t. the Boyer-Lindquist frame:

e0 = M.vector_field(name='e0', latex_name=r'e_0')
rho = sqrt(rho2)
e0[0] = sqrt(rho2*(r^2 + a^2) + 2*a^2*m*r*sin(th)^2)/(rho*sqrt(Delta))
e0[3] = 2*a*m*r/(rho*sqrt(Delta*(rho2*(r^2 + a^2) + 2*a^2*m*r*sin(th)^2)))
e0.display()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}e_0 = \left( \frac{\sqrt{2 \, a^{2} m r \sin\left({\theta}\right)^{2} + {\left(a^{2} \cos\left({\theta}\right)^{2} + r^{2}\right)} {\left(a^{2} + r^{2}\right)}}}{\sqrt{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \sqrt{a^{2} - 2 \, m r + r^{2}}} \right) \frac{\partial}{\partial t } + \left( \frac{2 \, a m r}{\sqrt{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \sqrt{{\left(2 \, a^{2} m r \sin\left({\theta}\right)^{2} + {\left(a^{2} \cos\left({\theta}\right)^{2} + r^{2}\right)} {\left(a^{2} + r^{2}\right)}\right)} {\left(a^{2} - 2 \, m r + r^{2}\right)}}} \right) \frac{\partial}{\partial {\phi} }$$

We check that is a unit timelike vector:

g(e0, e0).expr()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-1$$

and that it is future-directed, by computing its scalar product with the global null vector $k$, which generates the ingoing principal null geodesics:

k = M.vector_field([(r^2 + a^2)/Delta, -1, 0, a/Delta],
                   name='k')
k.display()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}k = \left( \frac{a^{2} + r^{2}}{a^{2} - 2 \, m r + r^{2}} \right) \frac{\partial}{\partial t } -\frac{\partial}{\partial r } + \left( \frac{a}{a^{2} - 2 \, m r + r^{2}} \right) \frac{\partial}{\partial {\phi} }$$

g(k, e0).expr().factor()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-\frac{\sqrt{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} {\left(a^{2} + r^{2}\right)}}{\sqrt{2 \, a^{2} m r + a^{2} r^{2} + r^{4} + {\left(a^{4} - 2 \, a^{2} m r + a^{2} r^{2}\right)} \cos\left({\theta}\right)^{2}} \sqrt{a^{2} - 2 \, m r + r^{2}}}$$

The spacelike vectors of the ZAMO frame:

e1 = M.vector_field([0, sqrt(Delta)/rho, 0, 0],
                    name='e1', latex_name=r'e_1')
e1.display()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}e_1 = \left( \frac{\sqrt{a^{2} - 2 \, m r + r^{2}}}{\sqrt{a^{2} \cos\left({\theta}\right)^{2} + r^{2}}} \right) \frac{\partial}{\partial r }$$

e2 = M.vector_field([0, 0, 1/rho, 0],
                    name='e2', latex_name=r'e_2')
e2.display()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}e_2 = \left( \frac{1}{\sqrt{a^{2} \cos\left({\theta}\right)^{2} + r^{2}}} \right) \frac{\partial}{\partial {\theta} }$$

e3 = M.vector_field(name='e3', latex_name=r'e_3')
e3[3] = rho/(sin(th)*sqrt(rho^2*(r^2 + a^2) +  2*a^2*m*r*sin(th)^2))
e3.display()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}e_3 = \left( \frac{\sqrt{a^{2} \cos\left({\theta}\right)^{2} + r^{2}}}{\sqrt{2 \, a^{2} m r \sin\left({\theta}\right)^{2} + {\left(a^{2} \cos\left({\theta}\right)^{2} + r^{2}\right)} {\left(a^{2} + r^{2}\right)}} \sin\left({\theta}\right)} \right) \frac{\partial}{\partial {\phi} }$$

ZF = M.vector_frame('e', [e0, e1, e2, e3])
ZF

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\left(\mathcal{M}, \left(e_{0},e_{1},e_{2},e_{3}\right)\right)$$

for v in ZF:
    show(v.display())

$$\renewcommand{\Bold}[1]{\mathbf{#1}}e_{0} = \left( \frac{\sqrt{2 \, a^{2} m r \sin\left({\theta}\right)^{2} + {\left(a^{2} \cos\left({\theta}\right)^{2} + r^{2}\right)} {\left(a^{2} + r^{2}\right)}}}{\sqrt{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \sqrt{a^{2} - 2 \, m r + r^{2}}} \right) \frac{\partial}{\partial t } + \left( \frac{2 \, a m r}{\sqrt{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \sqrt{{\left(2 \, a^{2} m r \sin\left({\theta}\right)^{2} + {\left(a^{2} \cos\left({\theta}\right)^{2} + r^{2}\right)} {\left(a^{2} + r^{2}\right)}\right)} {\left(a^{2} - 2 \, m r + r^{2}\right)}}} \right) \frac{\partial}{\partial {\phi} }$$

$$\renewcommand{\Bold}[1]{\mathbf{#1}}e_{1} = \left( \frac{\sqrt{a^{2} - 2 \, m r + r^{2}}}{\sqrt{a^{2} \cos\left({\theta}\right)^{2} + r^{2}}} \right) \frac{\partial}{\partial r }$$

$$\renewcommand{\Bold}[1]{\mathbf{#1}}e_{2} = \left( \frac{1}{\sqrt{a^{2} \cos\left({\theta}\right)^{2} + r^{2}}} \right) \frac{\partial}{\partial {\theta} }$$

$$\renewcommand{\Bold}[1]{\mathbf{#1}}e_{3} = \left( \frac{\sqrt{a^{2} \cos\left({\theta}\right)^{2} + r^{2}}}{\sqrt{2 \, a^{2} m r \sin\left({\theta}\right)^{2} + {\left(a^{2} \cos\left({\theta}\right)^{2} + r^{2}\right)} {\left(a^{2} + r^{2}\right)}} \sin\left({\theta}\right)} \right) \frac{\partial}{\partial {\phi} }$$

Check that the ZAMO frame is orthonormal:

matrix([[g(u, v).expr() for v in ZF] for u in ZF])  

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\left(\begin{array}{rrrr} -1 & 0 & 0 & 0 \\ 0 & 1 & 0 & 0 \\ 0 & 0 & 1 & 0 \\ 0 & 0 & 0 & 1 \end{array}\right)$$

The ZAMO coframe

for f in ZF.coframe():
    show(f.display())

$$\renewcommand{\Bold}[1]{\mathbf{#1}}e^{0} = \left( \frac{\sqrt{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \sqrt{a^{2} - 2 \, m r + r^{2}}}{\sqrt{2 \, a^{2} m r \sin\left({\theta}\right)^{2} + a^{2} r^{2} + r^{4} + {\left(a^{4} + a^{2} r^{2}\right)} \cos\left({\theta}\right)^{2}}} \right) \mathrm{d} t$$

$$\renewcommand{\Bold}[1]{\mathbf{#1}}e^{1} = \left( \frac{\sqrt{a^{2} \cos\left({\theta}\right)^{2} + r^{2}}}{\sqrt{a^{2} - 2 \, m r + r^{2}}} \right) \mathrm{d} r$$

$$\renewcommand{\Bold}[1]{\mathbf{#1}}e^{2} = \left( \sqrt{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \right) \mathrm{d} {\theta}$$

$$\renewcommand{\Bold}[1]{\mathbf{#1}}e^{3} = \left( -\frac{2 \, a m r \sin\left({\theta}\right)}{\sqrt{2 \, a^{2} m r + a^{2} r^{2} + r^{4} + {\left(a^{4} - 2 \, a^{2} m r + a^{2} r^{2}\right)} \cos\left({\theta}\right)^{2}} \sqrt{a^{2} \cos\left({\theta}\right)^{2} + r^{2}}} \right) \mathrm{d} t + \left( \frac{\sqrt{2 \, a^{2} m r \sin\left({\theta}\right)^{2} + a^{2} r^{2} + r^{4} + {\left(a^{4} + a^{2} r^{2}\right)} \cos\left({\theta}\right)^{2}} \sin\left({\theta}\right)}{\sqrt{a^{2} \cos\left({\theta}\right)^{2} + r^{2}}} \right) \mathrm{d} {\phi}$$

4-acceleration of the ZAMO observer

nabla = g.connection()
print(nabla)

Levi-Civita connection nabla_g associated with the Lorentzian metric g on the 4-dimensional Lorentzian manifold M

A = nabla(e0).contract(e0)  # use A to avoid any confusion with the Kerr parameter a
A.set_name('a')
print(A)

Vector field a on the 4-dimensional Lorentzian manifold M

A.apply_map(factor)  # factor the components for a better display
A.display()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}a = -\frac{{\left(a^{6} \cos\left({\theta}\right)^{2} + 2 \, a^{4} r^{2} \cos\left({\theta}\right)^{2} - 4 \, a^{2} m r^{3} \cos\left({\theta}\right)^{2} + a^{2} r^{4} \cos\left({\theta}\right)^{2} - a^{4} r^{2} + 4 \, a^{2} m r^{3} - 2 \, a^{2} r^{4} - r^{6}\right)} m}{{\left(a^{4} \cos\left({\theta}\right)^{2} - 2 \, a^{2} m r \cos\left({\theta}\right)^{2} + a^{2} r^{2} \cos\left({\theta}\right)^{2} + 2 \, a^{2} m r + a^{2} r^{2} + r^{4}\right)} {\left(a^{2} \cos\left({\theta}\right)^{2} + r^{2}\right)}^{2}} \frac{\partial}{\partial r } -\frac{2 \, {\left(a^{2} + r^{2}\right)} a^{2} m r \cos\left({\theta}\right) \sin\left({\theta}\right)}{{\left(a^{4} \cos\left({\theta}\right)^{2} - 2 \, a^{2} m r \cos\left({\theta}\right)^{2} + a^{2} r^{2} \cos\left({\theta}\right)^{2} + 2 \, a^{2} m r + a^{2} r^{2} + r^{4}\right)} {\left(a^{2} \cos\left({\theta}\right)^{2} + r^{2}\right)}^{2}} \frac{\partial}{\partial {\theta} }$$

Display in the ZAMO frame:

A.apply_map(factor, frame=ZF, keep_other_components=True)
A.display(ZF)

$$\renewcommand{\Bold}[1]{\mathbf{#1}}a = \left( -\frac{{\left(a^{6} \cos\left({\theta}\right)^{2} + 2 \, a^{4} r^{2} \cos\left({\theta}\right)^{2} - 4 \, a^{2} m r^{3} \cos\left({\theta}\right)^{2} + a^{2} r^{4} \cos\left({\theta}\right)^{2} - a^{4} r^{2} + 4 \, a^{2} m r^{3} - 2 \, a^{2} r^{4} - r^{6}\right)} m}{{\left(a^{4} \cos\left({\theta}\right)^{2} - 2 \, a^{2} m r \cos\left({\theta}\right)^{2} + a^{2} r^{2} \cos\left({\theta}\right)^{2} + 2 \, a^{2} m r + a^{2} r^{2} + r^{4}\right)} {\left(a^{2} \cos\left({\theta}\right)^{2} + r^{2}\right)}^{\frac{3}{2}} \sqrt{a^{2} - 2 \, m r + r^{2}}} \right) e_{1} -\frac{2 \, {\left(a^{2} + r^{2}\right)} a^{2} m r \cos\left({\theta}\right) \sin\left({\theta}\right)}{{\left(a^{4} \cos\left({\theta}\right)^{2} - 2 \, a^{2} m r \cos\left({\theta}\right)^{2} + a^{2} r^{2} \cos\left({\theta}\right)^{2} + 2 \, a^{2} m r + a^{2} r^{2} + r^{4}\right)} {\left(a^{2} \cos\left({\theta}\right)^{2} + r^{2}\right)}^{\frac{3}{2}}} e_{2}$$

A.display_comp(ZF, only_nonzero=False)

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{lcl} a_{\phantom{\, 0}}^{\,0} & = & 0 \\ a_{\phantom{\, 1}}^{\,1} & = & -\frac{{\left(a^{6} \cos\left({\theta}\right)^{2} + 2 \, a^{4} r^{2} \cos\left({\theta}\right)^{2} - 4 \, a^{2} m r^{3} \cos\left({\theta}\right)^{2} + a^{2} r^{4} \cos\left({\theta}\right)^{2} - a^{4} r^{2} + 4 \, a^{2} m r^{3} - 2 \, a^{2} r^{4} - r^{6}\right)} m}{{\left(a^{4} \cos\left({\theta}\right)^{2} - 2 \, a^{2} m r \cos\left({\theta}\right)^{2} + a^{2} r^{2} \cos\left({\theta}\right)^{2} + 2 \, a^{2} m r + a^{2} r^{2} + r^{4}\right)} {\left(a^{2} \cos\left({\theta}\right)^{2} + r^{2}\right)}^{\frac{3}{2}} \sqrt{a^{2} - 2 \, m r + r^{2}}} \\ a_{\phantom{\, 2}}^{\,2} & = & -\frac{2 \, {\left(a^{2} + r^{2}\right)} a^{2} m r \cos\left({\theta}\right) \sin\left({\theta}\right)}{{\left(a^{4} \cos\left({\theta}\right)^{2} - 2 \, a^{2} m r \cos\left({\theta}\right)^{2} + a^{2} r^{2} \cos\left({\theta}\right)^{2} + 2 \, a^{2} m r + a^{2} r^{2} + r^{4}\right)} {\left(a^{2} \cos\left({\theta}\right)^{2} + r^{2}\right)}^{\frac{3}{2}}} \\ a_{\phantom{\, 3}}^{\,3} & = & 0 \end{array}$$

a1_num = A[ZF, 1].expr().numerator()
a1_num

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-{\left(a^{6} \cos\left({\theta}\right)^{2} + 2 \, a^{4} r^{2} \cos\left({\theta}\right)^{2} - 4 \, a^{2} m r^{3} \cos\left({\theta}\right)^{2} + a^{2} r^{4} \cos\left({\theta}\right)^{2} - a^{4} r^{2} + 4 \, a^{2} m r^{3} - 2 \, a^{2} r^{4} - r^{6}\right)} m$$

We check the agreement with Eq. (70) of O. Semerak, Gen. Relat. Grav. 25, 1041 (1993):

bool(a1_num == m*(rho2*(r^4 - a^4) + 2*Delta*(r*a*sin(th))^2))

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\mathrm{True}$$

4-rotation of the ZAMO frame

We define the rotation operator as $$\Omega_{\rm rot}(v) = \nabla_{e_0} v - \Omega_{\rm FW}(v)$$ where $$\Omega_{\rm FW}(v) := (a\cdot v) e_0 - (e_0\cdot v) a$$ is the Fermi-Walker operator:

def rotation_operator(v):
    return nabla(v).contract(e0) - g(A, v)*e0 + g(e0, v)*A

Let us evaluate $\Omega_{\rm rot}(e_1)$:

De1 = rotation_operator(e1)
De1.display()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\left( \frac{2 \, a^{6} m^{2} r^{3} + 3 \, a^{4} m r^{6} - 2 \, a^{2} m^{2} r^{7} + 3 \, a^{2} m r^{8} + m r^{10} + {\left(a^{6} m - 8 \, a^{4} m^{3}\right)} r^{4} - {\left(a^{10} m - 2 \, a^{8} m^{2} r + 3 \, a^{8} m r^{2} - 8 \, a^{6} m^{2} r^{3} - 6 \, a^{4} m^{2} r^{5} + a^{4} m r^{6} + {\left(3 \, a^{6} m + 8 \, a^{4} m^{3}\right)} r^{4}\right)} \cos\left({\theta}\right)^{4} - 2 \, {\left(a^{8} m^{2} r + 5 \, a^{6} m^{2} r^{3} - 8 \, a^{4} m^{3} r^{4} + 3 \, a^{4} m^{2} r^{5} - a^{2} m^{2} r^{7}\right)} \cos\left({\theta}\right)^{2} + {\left(a^{6} m + a^{4} m r^{2} - a^{2} m r^{4} - m r^{6} - {\left(a^{6} m + 2 \, a^{4} m r^{2} - 4 \, a^{2} m^{2} r^{3} + a^{2} m r^{4}\right)} \sin\left({\theta}\right)^{2}\right)} \sqrt{a^{4} + 2 \, a^{2} r^{2} + r^{4} - {\left(a^{4} - 2 \, a^{2} m r + a^{2} r^{2}\right)} \sin\left({\theta}\right)^{2}} \sqrt{2 \, a^{2} m r + a^{2} r^{2} + r^{4} + {\left(a^{4} - 2 \, a^{2} m r + a^{2} r^{2}\right)} \cos\left({\theta}\right)^{2}}}{{\left(2 \, a^{4} m r^{5} + 2 \, a^{2} r^{8} - 2 \, m r^{9} + r^{10} + {\left(a^{4} - 4 \, a^{2} m^{2}\right)} r^{6} + {\left(a^{10} - 4 \, a^{8} m r - 4 \, a^{6} m r^{3} + a^{6} r^{4} + 2 \, {\left(a^{8} + 2 \, a^{6} m^{2}\right)} r^{2}\right)} \cos\left({\theta}\right)^{6} + {\left(2 \, a^{8} m r - 8 \, a^{6} m r^{3} - 10 \, a^{4} m r^{5} + 3 \, a^{4} r^{6} + 2 \, {\left(3 \, a^{6} + 4 \, a^{4} m^{2}\right)} r^{4} + {\left(3 \, a^{8} - 4 \, a^{6} m^{2}\right)} r^{2}\right)} \cos\left({\theta}\right)^{4} + {\left(4 \, a^{6} m r^{3} - 4 \, a^{4} m r^{5} - 8 \, a^{2} m r^{7} + 3 \, a^{2} r^{8} + 2 \, {\left(3 \, a^{4} + 2 \, a^{2} m^{2}\right)} r^{6} + {\left(3 \, a^{6} - 8 \, a^{4} m^{2}\right)} r^{4}\right)} \cos\left({\theta}\right)^{2}\right)} \sqrt{2 \, a^{2} m r + a^{2} r^{2} + r^{4} + {\left(a^{4} - 2 \, a^{2} m r + a^{2} r^{2}\right)} \cos\left({\theta}\right)^{2}}} \right) \frac{\partial}{\partial t } + \left( \frac{{\left(a^{3} m r^{2} + 3 \, a m r^{4} - {\left(a^{5} m - a^{3} m r^{2}\right)} \cos\left({\theta}\right)^{2}\right)} \sqrt{2 \, a^{2} m r + a^{2} r^{2} + r^{4} + {\left(a^{4} - 2 \, a^{2} m r + a^{2} r^{2}\right)} \cos\left({\theta}\right)^{2}}}{4 \, a^{4} m^{2} r^{4} + 4 \, a^{4} m r^{5} + a^{4} r^{6} + 4 \, a^{2} m r^{7} + 2 \, a^{2} r^{8} + r^{10} + {\left(a^{10} - 4 \, a^{8} m r - 4 \, a^{6} m r^{3} + a^{6} r^{4} + 2 \, {\left(a^{8} + 2 \, a^{6} m^{2}\right)} r^{2}\right)} \cos\left({\theta}\right)^{6} + {\left(4 \, a^{8} m r - 4 \, a^{6} m r^{3} - 8 \, a^{4} m r^{5} + 3 \, a^{4} r^{6} + 2 \, {\left(3 \, a^{6} + 2 \, a^{4} m^{2}\right)} r^{4} + {\left(3 \, a^{8} - 8 \, a^{6} m^{2}\right)} r^{2}\right)} \cos\left({\theta}\right)^{4} + {\left(4 \, a^{6} m^{2} r^{2} + 8 \, a^{6} m r^{3} + 4 \, a^{4} m r^{5} + 6 \, a^{4} r^{6} - 4 \, a^{2} m r^{7} + 3 \, a^{2} r^{8} + {\left(3 \, a^{6} - 8 \, a^{4} m^{2}\right)} r^{4}\right)} \cos\left({\theta}\right)^{2}} \right) \frac{\partial}{\partial {\phi} }$$

The output clearly requires some simplification. In particular, the component along $\partial/\partial t$ should be zero. We perform some trigonometric simplication on the components thanks to the method apply_map:

De1.apply_map(lambda x: x.trig_reduce())
De1.apply_map(lambda x: x.simplify_trig())
De1.apply_map(factor)
De1.display()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\left( \frac{{\left(a^{4} \cos\left({\theta}\right)^{2} - a^{2} r^{2} \cos\left({\theta}\right)^{2} - a^{2} r^{2} - 3 \, r^{4}\right)} \sqrt{2 \, a^{2} m r + a^{2} r^{2} + r^{4} + {\left(a^{4} - 2 \, a^{2} m r + a^{2} r^{2}\right)} \cos\left({\theta}\right)^{2}} a m}{{\left(a^{4} \sin\left({\theta}\right)^{2} - 2 \, a^{2} m r \sin\left({\theta}\right)^{2} + a^{2} r^{2} \sin\left({\theta}\right)^{2} - a^{4} - 2 \, a^{2} r^{2} - r^{4}\right)}^{2} {\left(a^{2} \sin\left({\theta}\right)^{2} - a^{2} - r^{2}\right)}} \right) \frac{\partial}{\partial {\phi} }$$

De1.display(ZF)

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\left( \frac{{\left(a^{3} m r^{2} + 3 \, a m r^{4} - {\left(a^{5} m - a^{3} m r^{2}\right)} \cos\left({\theta}\right)^{2}\right)} \sin\left({\theta}\right)}{{\left(2 \, a^{2} m r^{3} + a^{2} r^{4} + r^{6} + {\left(a^{6} - 2 \, a^{4} m r + a^{4} r^{2}\right)} \cos\left({\theta}\right)^{4} + 2 \, {\left(a^{4} m r + a^{4} r^{2} - a^{2} m r^{3} + a^{2} r^{4}\right)} \cos\left({\theta}\right)^{2}\right)} \sqrt{a^{2} \cos\left({\theta}\right)^{2} + r^{2}}} \right) e_{3}$$

De1.apply_map(factor, frame=ZF, keep_other_components=True)
De1.display(ZF)

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-\frac{{\left(a^{4} \cos\left({\theta}\right)^{2} - a^{2} r^{2} \cos\left({\theta}\right)^{2} - a^{2} r^{2} - 3 \, r^{4}\right)} a m \sin\left({\theta}\right)}{{\left(a^{4} \cos\left({\theta}\right)^{2} - 2 \, a^{2} m r \cos\left({\theta}\right)^{2} + a^{2} r^{2} \cos\left({\theta}\right)^{2} + 2 \, a^{2} m r + a^{2} r^{2} + r^{4}\right)} {\left(a^{2} \cos\left({\theta}\right)^{2} + r^{2}\right)}^{\frac{3}{2}}} e_{3}$$

Let us now evaluate $\Omega_{\rm rot}(e_2)$:

De2 = rotation_operator(e2)
De2.apply_map(lambda x: x.trig_reduce())
De2.apply_map(lambda x: x.simplify_trig())
De2.apply_map(factor)
De2.apply_map(lambda x: x.trig_reduce(), frame=ZF, keep_other_components=True)
De2.apply_map(lambda x: x.simplify_trig(), frame=ZF, keep_other_components=True)
De2.apply_map(factor, frame=ZF, keep_other_components=True)
De2.display(ZF)

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\left( -\frac{2 \, \sqrt{a^{2} - 2 \, m r + r^{2}} a^{3} m r \cos\left({\theta}\right) \sin\left({\theta}\right)^{2}}{{\left(a^{4} \sin\left({\theta}\right)^{2} - 2 \, a^{2} m r \sin\left({\theta}\right)^{2} + a^{2} r^{2} \sin\left({\theta}\right)^{2} - a^{4} - 2 \, a^{2} r^{2} - r^{4}\right)} {\left(a^{2} \sin\left({\theta}\right)^{2} - a^{2} - r^{2}\right)} \sqrt{-a^{2} \sin\left({\theta}\right)^{2} + a^{2} + r^{2}}} \right) e_{3}$$

and finally $\Omega_{\rm rot}(e_3)$:

De3 = rotation_operator(e3)
De3.apply_map(factor, frame=ZF, keep_other_components=True)
De3.display(ZF)

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{{\left(a^{4} \cos\left({\theta}\right)^{2} - a^{2} r^{2} \cos\left({\theta}\right)^{2} - a^{2} r^{2} - 3 \, r^{4}\right)} a m \sin\left({\theta}\right)}{{\left(a^{4} \cos\left({\theta}\right)^{2} - 2 \, a^{2} m r \cos\left({\theta}\right)^{2} + a^{2} r^{2} \cos\left({\theta}\right)^{2} + 2 \, a^{2} m r + a^{2} r^{2} + r^{4}\right)} {\left(a^{2} \cos\left({\theta}\right)^{2} + r^{2}\right)}^{\frac{3}{2}}} e_{1} + \left( \frac{2 \, \sqrt{a^{2} - 2 \, m r + r^{2}} a^{3} m r \cos\left({\theta}\right) \sin\left({\theta}\right)^{2}}{{\left(a^{4} \cos\left({\theta}\right)^{2} - 2 \, a^{2} m r \cos\left({\theta}\right)^{2} + a^{2} r^{2} \cos\left({\theta}\right)^{2} + 2 \, a^{2} m r + a^{2} r^{2} + r^{4}\right)} {\left(a^{2} \cos\left({\theta}\right)^{2} + r^{2}\right)}^{\frac{3}{2}}} \right) e_{2}$$

In the orthonormal frame $(e_1, e_2, e_3)$ of the ZAMO's rest space, the matrix of the operator $\Omega_{\rm rot}$ must be of the type $$\left( \begin{array}{ccc} 0 & - \omega^3 & \omega^2 \\ \omega^3 & 0 & -\omega^1 \\ - \omega^2 & \omega^1 & 0 \end{array} \right),$$ where the $\omega^i$'s are the components on the 4-rotation vector: $$\omega = \omega^i e_i$$

From the above expressions of the $\Omega_{\rm rot}(e_i)$'s, we get immediately $\omega^3 = 0$ and we check that

De1[ZF, 3] == - De3[ZF, 1]

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\mathrm{True}$$

De2[ZF, 3] == - De3[ZF, 2]

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\mathrm{True}$$

Therefore, we get the 4-rotation vector $\omega$ as

omega = - De3[ZF, 2]*e1 + De3[ZF, 1]*e2
omega.set_name('omega', latex_name=r'\omega')
omega.apply_map(factor)
omega.apply_map(factor, frame=ZF, keep_other_components=True)
omega.display(ZF)

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\omega = \left( -\frac{2 \, \sqrt{a^{2} - 2 \, m r + r^{2}} a^{3} m r \cos\left({\theta}\right) \sin\left({\theta}\right)^{2}}{{\left(a^{4} \cos\left({\theta}\right)^{2} - 2 \, a^{2} m r \cos\left({\theta}\right)^{2} + a^{2} r^{2} \cos\left({\theta}\right)^{2} + 2 \, a^{2} m r + a^{2} r^{2} + r^{4}\right)} {\left(a^{2} \cos\left({\theta}\right)^{2} + r^{2}\right)}^{\frac{3}{2}}} \right) e_{1} + \frac{{\left(a^{4} \cos\left({\theta}\right)^{2} - a^{2} r^{2} \cos\left({\theta}\right)^{2} - a^{2} r^{2} - 3 \, r^{4}\right)} a m \sin\left({\theta}\right)}{{\left(a^{4} \cos\left({\theta}\right)^{2} - 2 \, a^{2} m r \cos\left({\theta}\right)^{2} + a^{2} r^{2} \cos\left({\theta}\right)^{2} + 2 \, a^{2} m r + a^{2} r^{2} + r^{4}\right)} {\left(a^{2} \cos\left({\theta}\right)^{2} + r^{2}\right)}^{\frac{3}{2}}} e_{2}$$

omega.display()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\omega = -\frac{2 \, {\left(a^{2} - 2 \, m r + r^{2}\right)} a^{3} m r \cos\left({\theta}\right) \sin\left({\theta}\right)^{2}}{{\left(a^{4} \cos\left({\theta}\right)^{2} - 2 \, a^{2} m r \cos\left({\theta}\right)^{2} + a^{2} r^{2} \cos\left({\theta}\right)^{2} + 2 \, a^{2} m r + a^{2} r^{2} + r^{4}\right)} {\left(a^{2} \cos\left({\theta}\right)^{2} + r^{2}\right)}^{2}} \frac{\partial}{\partial r } + \frac{{\left(a^{4} \cos\left({\theta}\right)^{2} - a^{2} r^{2} \cos\left({\theta}\right)^{2} - a^{2} r^{2} - 3 \, r^{4}\right)} a m \sin\left({\theta}\right)}{{\left(a^{4} \cos\left({\theta}\right)^{2} - 2 \, a^{2} m r \cos\left({\theta}\right)^{2} + a^{2} r^{2} \cos\left({\theta}\right)^{2} + 2 \, a^{2} m r + a^{2} r^{2} + r^{4}\right)} {\left(a^{2} \cos\left({\theta}\right)^{2} + r^{2}\right)}^{2}} \frac{\partial}{\partial {\theta} }$$

As a check, we note that the above formula agrees with that given by Eqs. (73)-(74) of O. Semerak, Gen. Relat. Grav. 25, 1041 (1993).