2804.sagews

function d=dependence(T)
i=size(T,"r")
for var=1:i
d(1,var)=sum(T(var,:))
end
endfunction

function f=influence(T)
j=size(T,"c")
for var=1:j
f(1,var)=sum(T(:,var))
end
endfunction

function [T,d,f] = micmac(D,k)
  if (typeof(D)=="polynomial") then
    time=input("Introduzca el tiempo ")
    T1=D^k
    C=coeff(T1)
    n=size(T1,"c")
    T=C(:,time*n+1:(time+1)*n)
  else  
    T=D^k
  end
  d=dependence(T)
  f=influence(T)
endfunction

function En=normal(n)
  for col=1:n
    for ren=1:n
      En(ren,col)=1/n
    end      
  end
endfunction

function [T,d,f] = pagerank(A,p)
  j=size(A,"c")

  if (typeof(A)=='polynomial') then
   error('El metodo PageRank no puede usarse en una matriz polinomial') 
  else
    for var=1:j
      out(1,var)=sum(A(:,var))
    end

    for fil=1:j
      for col=1:j
        if (A(fil,col)~=0) then
          D(fil,col)=1/out(1,col)*A(fil,col)
        else
          D(fil,col)=0
        end
      end
    end

    cero=zeros(j,j)
    verdad=and(D==cero,"r")

    for ind=1:j
      if (verdad(1,ind)==%T) then
        Dbar(1:j,ind)=1/j
      else
        Dbar(1:j,ind)=D(1:j,ind)
      end
    end

    En=normal(j)

    T=(p*Dbar+(1-p)*En)^20
    d=dependence(T)
    d=(1/j)*d
    f=influence(T)
  end

endfunction

function [E] = polyexpm(D)
E=eye(size(D,"c"),size(D,"c"))
  for n=1:100
    E=E+D^n/factorial(n)
  end
endfunction

function [T,d,f]=pwp(D,lambda)
  j=size(D,"r")
  flag=typeof(D)

  if (flag=='polynomial') then
    time=input("Introduzca el tiempo ")
    T1=(polyexpm(lambda*D)-eye(j,j))/(exp(lambda)-1)
    C=coeff(T1)
    n=size(T1,"c")
    T=C(:,time*n+1:(time+1)*n)
  else
    T=(expm(lambda*D)-eye(j,j))/(exp(lambda)-1)
  end

  d=dependence(T)
  f=influence(T)
endfunction