1402-Plotting Planar Curves.sagews

Plotting Planar Curves

In MATH 161 you worked a great deal with scalar functions of one variable $y = f(x)$.  There is a straightforward method for plotting the graph of such a function.  We illustrate this for the "sinc" function (that is, $sin(x)/x$) below.

var('x')
f(x) = sin(x)/x
plot(f(x), (x, -6*pi, 6*pi))

Plotting planar curves using parametrization

Another way to plot this same curve is using the parametric_plot() command, whose syntax is only mildly different than the plot() command in the previous cell.

var('x')
parametric_plot((x, sin(x)/x), (x, -6*pi, 6*pi))

The idea for a (planar) parametric curve is that there is a single parameter which runs through some interval of numbers and, as it does so, $x$ and $y$ both change.  In the above cell, $x$ itself was the parameter.  It is equally valid to use $y$ as the parameter.  But parametric curves become even more useful when we introduce a third variable, say $t$, as the parameter.  Both variables ($x$ and $y$) become dependent upon the parameter.  We do not have to give any explicit relationship between $x$ and $y$ and, indeed, the relation between them may not be a function at all.  The cell below employs this technique in order to produce a plot of the unit circle.

var('t')
x(t) = cos(t)
y(t) = sin(t)       # Note we are not using any formula of the form y = f(x)
parametric_plot((x(t), y(t)), (t, -pi, pi), aspect_ratio=1)

The parameter $t$ in the previous cell ran through the interval $[-\pi, \pi]$ in producing this curve.  Any interval of length $2\pi$ would have produced the same curve.  A shorter interval would have yielded only a partial circle, while a longer interval would have yielded a curve that wraps over onto itself.

No doubt, if you own a graphing calculator, what we have done thus far may be duplicated on it using the calculators parametric mode for graphing.

Parametric Curves in 3D

There is nothing particularly difficult about plotting curves in 3-dimensional space, once we are familiar with parametric curves in two dimensions.  There is still only one parameter which roams through some interval of values.  The only difference (besides the slight change in the name of the command) is that we need to express how the third ($z$) coordinate relies on that parameter.  The parametric equations

   $x(t) = cos(t)$,         $y(t) = 2 sin(t)$,         $z(t) = t / 5$,

describe a helical coil in space, as the next cell demonstrates.

parametric_plot3d((cos(t), 2*sin(t), t/5), (t, 0, 25), aspect_ratio=[1,1,1])

Parametrized Surfaces

Up to this point we have been plotting parametrized curves.  For such curves, the parameter runs through some interval $I$ of numbers, and the parameter functions $x(t)$, $y(t)$, $z(t)$ describe how that interval is morphed into some space curve.

We may now ask, what if there are two parameters -- call them $u$ and $v$ -- and $x$, $y$, $z$ each depend on both of these parameters?  We get a rich collection of examples when we consider the conversions between rectangular, cylindrical and spherical coordinates.  For instance, the equations describing the conversion between spherical coordinates $(\rho, \phi, \theta)$ and rectangular coordinates $(x,y,z)$ are

     $x = \rho\sin\phi\cos\theta$,         $y = \rho\sin\phi\sin\theta$,        $z = \rho\cos\phi$.

Spherical coordinates with $\rho$ fixed (so $\phi$ and $\theta$ are parameters)

If we fix the value of $\rho$ at 1, and allow $\phi$ to roam in the interval $[0, \pi]$, $\theta$ in $[-\pi, \pi]$, the result should be a sphere of radius 1.  The next cell (in which we use $u$ and $v$ in place of $\phi$ and $\theta$) illustrates this.

var('u v')
parametric_plot3d((sin(u)*cos(v), sin(u)*sin(v), cos(u)), (u,0,pi), (v,-pi,pi))

By changing to a smaller interval for $\phi$ or $\theta$, you can get various parts of this same sphere.  Changing the value of $\rho$ to 2 has a predictable effect on the radius.  These ideas are illustrated next.

var('u v')
r = 2
parametric_plot3d((r*sin(u)*cos(v), r*sin(u)*sin(v), r*cos(u)), (u,0,pi/2), (v,-pi,0), aspect_ratio=[1,1,1])

Spherical coordinates with $\phi$ fixed

If, on the other hand, we fix the value of some other one of the spherical coordinates -- say, $\phi$ -- and let $\rho$ and $\theta$ roam through intervals, the resulting surface changes.  In the next cell, we fix $\rho = \pi/6$, and let $\rho$ roam through the interval $[2, 10]$, $\theta$ through $[0, 2\pi]$.  (Recall that $\sin(\pi/6) = 1/2$ and $\cos(\pi/6) = \sqrt 3/2$.  These values have been used below.)

var('r v')
parametric_plot((r*cos(v)/2, r*sin(v)/2, r*sqrt(3)/2), (r,2,10), (v,0,2*pi))

Cylindrical coordinates with $r$ fixed

As with spherical coordinates, there are three cylindrical coordinates $(r, \theta, z)$. If we fix the value of any one of them while letting the other two roam through intervals of the real line, the result is a parametrized surface. The transformations from cylindrical to rectangular coordinates are

     $x = r\cos\theta$        and        $y = r\sin\theta$.

(The $z$-coordinate is the same in both.) In the cell below, we fix the value of $r$ at 2, and allow $\theta$ to roam in $[0, 3\pi/2]$, $z$ in $[0,5]$, resulting in a portion of a right circular cylinder.

var('u v')
parametric_plot3d((2*cos(u), 2*sin(u), v), (u,0,3*pi/2), (v,0,5))

You should play around with these methods for employing spherical and cylindrical coordinates to produce different types of surfaces until you feel quite comfortable with them.  In particular, you should explore what happens when you fix the value of $\theta$ in spherical coordinates and use $\rho$, $\phi$ as parameters in various intervals.  You should also explore cylindrical coordinates further, fixing $z$ (i.e., $r$ and $\theta$ are the parameters) and then $\theta$.

Other surfaces

Finally, you should not walk away from this lesson thinking the only value parametrized surfaces arise from spherical and cylindrical coordinates.  Here are a couple more interesting examples that have nothing to do with either.

Torus:

var('u v t')
a = 3    # distance from z-axis to circle at center of tube
b = 2    # radius of

torus = parametric_plot3d(((a+b*cos(u))*cos(v), (a+b*cos(u))*sin(v), b*sin(u)), \
    (u,0,2*pi), (v,0,2*pi), aspect_ratio=[1,1,1], opacity=.5)
    
# extra stuff to explain the role of 'a' and 'b'
innerCircle = parametric_plot((a*cos(t), a*sin(t), 0), (t,-pi,pi), \
    color='red', thickness=2)
radii = line([(0,0,0),(a,0,0)], color='red', thickness=2)
radii += line([(a,0,0),(a+b*sqrt(2)/2,0,b*sqrt(2)/2)], color='red', thickness=2)
radii += line([(a,0,0),(a+b*sqrt(2)/2,0,-b*sqrt(2)/2)], color='red', thickness=2)
labels = text3d('a', (a/2, 0, .3), color='red')
labels += text3d('b', (a+b*sqrt(2)/4,0,b*sqrt(2)/4+.4), color='red')
labels += text3d('b', (a+b*sqrt(2)/4,0,-b*sqrt(2)/4-.4), color='red')
show(torus + innerCircle + radii + labels)

Surface of rotation

Next, we take an initial curve in the $xy$-plane, and rotate it around the $x$-axis to produce a surface of rotation.  The initial curve is $y = 1 + |\cos x|$, for $x$ in the interval $[0, 4\pi]$.

var('x u v')
r(x) = 1 + abs(cos(x))
# first plot the curve itself in the xy-plane
plot(r(x), (x,0,4*pi)).show()
parametric_plot3d((u, r(u)*cos(v), r(u)*sin(v)), (u,0,4*pi), (v,-pi,pi))

Mobius band

This is an interesting type of surface, as it is non-orientable.  Said another way, it has just one side.  You can actually make one of these out of a strip of paper and tape or glue.

var('u v')
parametric_plot3d(((1+v*cos(u/2))*cos(u), (1+v*cos(u/2))*sin(u), v*sin(u/2)), \
    (u,0,2*pi), (v,-.8,.8), aspect_ratio=[1,1,1])