Kerr-AdS-5D-asymptotic_b_0.ipynb

Kernel: SageMath 9.3

Asymptotic 5D Kerr-AdS metric with b=0 in light-cone coordinates

This SageMath notebook is relative to the article Heavy quarks in rotating plasma via holography by Anastasia A. Golubtsova, Eric Gourgoulhon and Marina K. Usova, arXiv:2107.11672.

The involved differential geometry computations are based on tools developed through the SageManifolds project.

version()

'SageMath version 9.3, Release Date: 2021-05-09'

%display latex

Parallelism().set(nproc=8)

M = Manifold(5, 'M', r'\mathcal{M}', structure='Lorentzian', metric_name='G')
print(M)

5-dimensional Lorentzian manifold M

Asymptotically AdS coordinates

AdSc.<T,y,Th,Ph,Ps> = M.chart(r'T y:(0,+oo) Th:(0,pi/2):\Theta Ph:(0,2*pi):\Phi Ps:(0,2*pi):\Psi')
AdSc

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\left(\mathcal{M},(T, y, {\Theta}, {\Phi}, {\Psi})\right)$$

var('m a b', domain='real')

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\left(m, a, b\right)$$

b = 0  # assumed in Sec. 5

keep_Delta = True  # change to False to provide explicit expression for Delta

if keep_Delta:
    Delta = var('Delta', latex_name=r'\Delta', domain='real')
else:
    Delta = 1 - a^2*sin(Th)^2 - b^2*cos(Th)^2

G = M.metric()
G[0,0] = - (1 + y^2) + 2*m/(Delta^3*y^2)
G[0,3] = -2*a*m*sin(Th)^2/(Delta^3*y^2)
G[0,4] = -2*b*m*cos(Th)^2/(Delta^3*y^2)
G[1,1] = 1/(1 + y^2 - 2*m/(Delta^2*y^2))
G[2,2] = y^2
G[3,3] = y^2*sin(Th)^2 + 2*a^2*m*sin(Th)^4/(Delta^3*y^2)
G[3,4] = 2*a*b*m*sin(Th)^2*cos(Th)^2/(Delta^3*y^2)
G[4,4] = y^2*cos(Th)^2 + 2*b^2*m*cos(Th)^4/(Delta^3*y^2)

Check of Eq. (5.38):

G.display()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}G = \left( -y^{2} + \frac{2 \, m}{{\Delta}^{3} y^{2}} - 1 \right) \mathrm{d} T\otimes \mathrm{d} T -\frac{2 \, a m \sin\left({\Theta}\right)^{2}}{{\Delta}^{3} y^{2}} \mathrm{d} T\otimes \mathrm{d} {\Phi} + \left( \frac{1}{y^{2} - \frac{2 \, m}{{\Delta}^{2} y^{2}} + 1} \right) \mathrm{d} y\otimes \mathrm{d} y + y^{2} \mathrm{d} {\Theta}\otimes \mathrm{d} {\Theta} -\frac{2 \, a m \sin\left({\Theta}\right)^{2}}{{\Delta}^{3} y^{2}} \mathrm{d} {\Phi}\otimes \mathrm{d} T + \left( y^{2} \sin\left({\Theta}\right)^{2} + \frac{2 \, a^{2} m \sin\left({\Theta}\right)^{4}}{{\Delta}^{3} y^{2}} \right) \mathrm{d} {\Phi}\otimes \mathrm{d} {\Phi} + y^{2} \cos\left({\Theta}\right)^{2} \mathrm{d} {\Psi}\otimes \mathrm{d} {\Psi}$$

G.display_comp(only_nonredundant=True)

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{lcl} G_{ \, T \, T }^{ \phantom{\, T}\phantom{\, T} } & = & -y^{2} + \frac{2 \, m}{{\Delta}^{3} y^{2}} - 1 \\ G_{ \, T \, {\Phi} }^{ \phantom{\, T}\phantom{\, {\Phi}} } & = & -\frac{2 \, a m \sin\left({\Theta}\right)^{2}}{{\Delta}^{3} y^{2}} \\ G_{ \, y \, y }^{ \phantom{\, y}\phantom{\, y} } & = & \frac{1}{y^{2} - \frac{2 \, m}{{\Delta}^{2} y^{2}} + 1} \\ G_{ \, {\Theta} \, {\Theta} }^{ \phantom{\, {\Theta}}\phantom{\, {\Theta}} } & = & y^{2} \\ G_{ \, {\Phi} \, {\Phi} }^{ \phantom{\, {\Phi}}\phantom{\, {\Phi}} } & = & y^{2} \sin\left({\Theta}\right)^{2} + \frac{2 \, a^{2} m \sin\left({\Theta}\right)^{4}}{{\Delta}^{3} y^{2}} \\ G_{ \, {\Psi} \, {\Psi} }^{ \phantom{\, {\Psi}}\phantom{\, {\Psi}} } & = & y^{2} \cos\left({\Theta}\right)^{2} \end{array}$$

Light cone coordinates

LC.<xp,xm,y,Th,Ps> = M.chart(r'xp:x^+ xm:x^- y:(0,+oo) Th:(0,pi/2):\Theta Ps:(0,2*pi):\Psi')
LC

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\left(\mathcal{M},({x^+}, {x^-}, y, {\Theta}, {\Psi})\right)$$

The transformation from AdS coordinates to light cone coordinates is defined by Eq. (5.40) of the paper:

AdSc_to_LC = AdSc.transition_map(LC, [T - a*Ph, T + a*Ph, y, Th, Ps])
AdSc_to_LC.display()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\left\{\begin{array}{lcl} {x^+} & = & -{\Phi} a + T \\ {x^-} & = & {\Phi} a + T \\ y & = & y \\ {\Theta} & = & {\Theta} \\ {\Psi} & = & {\Psi} \end{array}\right.$$

AdSc_to_LC.inverse().display()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\left\{\begin{array}{lcl} T & = & \frac{1}{2} \, {x^-} + \frac{1}{2} \, {x^+} \\ y & = & y \\ {\Theta} & = & {\Theta} \\ {\Phi} & = & \frac{{x^-} - {x^+}}{2 \, a} \\ {\Psi} & = & {\Psi} \end{array}\right.$$

G.display(LC)

$$\renewcommand{\Bold}[1]{\mathbf{#1}}G = \left( -\frac{{\Delta}^{3} a^{2} y^{2} + {\left({\Delta}^{3} a^{2} - {\Delta}^{3} \sin\left({\Theta}\right)^{2}\right)} y^{4} - 2 \, {\left(\sin\left({\Theta}\right)^{4} + 2 \, \sin\left({\Theta}\right)^{2} + 1\right)} a^{2} m}{4 \, {\Delta}^{3} a^{2} y^{2}} \right) \mathrm{d} {x^+}\otimes \mathrm{d} {x^+} + \left( -\frac{{\Delta}^{3} a^{2} y^{2} + {\left({\Delta}^{3} a^{2} + {\Delta}^{3} \sin\left({\Theta}\right)^{2}\right)} y^{4} + 2 \, {\left(\sin\left({\Theta}\right)^{4} - 1\right)} a^{2} m}{4 \, {\Delta}^{3} a^{2} y^{2}} \right) \mathrm{d} {x^+}\otimes \mathrm{d} {x^-} + \left( -\frac{{\Delta}^{3} a^{2} y^{2} + {\left({\Delta}^{3} a^{2} + {\Delta}^{3} \sin\left({\Theta}\right)^{2}\right)} y^{4} + 2 \, {\left(\sin\left({\Theta}\right)^{4} - 1\right)} a^{2} m}{4 \, {\Delta}^{3} a^{2} y^{2}} \right) \mathrm{d} {x^-}\otimes \mathrm{d} {x^+} + \left( -\frac{{\Delta}^{3} a^{2} y^{2} - 2 \, a^{2} m \cos\left({\Theta}\right)^{4} + {\left({\Delta}^{3} a^{2} + {\Delta}^{3} \cos\left({\Theta}\right)^{2} - {\Delta}^{3}\right)} y^{4}}{4 \, {\Delta}^{3} a^{2} y^{2}} \right) \mathrm{d} {x^-}\otimes \mathrm{d} {x^-} + \left( \frac{{\Delta}^{2} y^{2}}{{\Delta}^{2} y^{4} + {\Delta}^{2} y^{2} - 2 \, m} \right) \mathrm{d} y\otimes \mathrm{d} y + y^{2} \mathrm{d} {\Theta}\otimes \mathrm{d} {\Theta} + y^{2} \cos\left({\Theta}\right)^{2} \mathrm{d} {\Psi}\otimes \mathrm{d} {\Psi}$$

G.display_comp(chart=LC, only_nonredundant=True)

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{lcl} G_{ \, {x^+} \, {x^+} }^{ \phantom{\, {x^+}}\phantom{\, {x^+}} } & = & -\frac{{\Delta}^{3} a^{2} y^{2} + {\left({\Delta}^{3} a^{2} - {\Delta}^{3} \sin\left({\Theta}\right)^{2}\right)} y^{4} - 2 \, {\left(\sin\left({\Theta}\right)^{4} + 2 \, \sin\left({\Theta}\right)^{2} + 1\right)} a^{2} m}{4 \, {\Delta}^{3} a^{2} y^{2}} \\ G_{ \, {x^+} \, {x^-} }^{ \phantom{\, {x^+}}\phantom{\, {x^-}} } & = & -\frac{{\Delta}^{3} a^{2} y^{2} + {\left({\Delta}^{3} a^{2} + {\Delta}^{3} \sin\left({\Theta}\right)^{2}\right)} y^{4} + 2 \, {\left(\sin\left({\Theta}\right)^{4} - 1\right)} a^{2} m}{4 \, {\Delta}^{3} a^{2} y^{2}} \\ G_{ \, {x^-} \, {x^-} }^{ \phantom{\, {x^-}}\phantom{\, {x^-}} } & = & -\frac{{\Delta}^{3} a^{2} y^{2} - 2 \, a^{2} m \cos\left({\Theta}\right)^{4} + {\left({\Delta}^{3} a^{2} + {\Delta}^{3} \cos\left({\Theta}\right)^{2} - {\Delta}^{3}\right)} y^{4}}{4 \, {\Delta}^{3} a^{2} y^{2}} \\ G_{ \, y \, y }^{ \phantom{\, y}\phantom{\, y} } & = & \frac{{\Delta}^{2} y^{2}}{{\Delta}^{2} y^{4} + {\Delta}^{2} y^{2} - 2 \, m} \\ G_{ \, {\Theta} \, {\Theta} }^{ \phantom{\, {\Theta}}\phantom{\, {\Theta}} } & = & y^{2} \\ G_{ \, {\Psi} \, {\Psi} }^{ \phantom{\, {\Psi}}\phantom{\, {\Psi}} } & = & y^{2} \cos\left({\Theta}\right)^{2} \end{array}$$

M.set_default_chart(LC)
M.set_default_frame(LC.frame())

Check of Eq. (5.41)

G.apply_map(expand, keep_other_components=True)
G.display()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}G = \left( -\frac{1}{4} \, y^{2} + \frac{y^{2} \sin\left({\Theta}\right)^{2}}{4 \, a^{2}} + \frac{m \sin\left({\Theta}\right)^{4}}{2 \, {\Delta}^{3} y^{2}} + \frac{m \sin\left({\Theta}\right)^{2}}{{\Delta}^{3} y^{2}} + \frac{m}{2 \, {\Delta}^{3} y^{2}} - \frac{1}{4} \right) \mathrm{d} {x^+}\otimes \mathrm{d} {x^+} + \left( -\frac{1}{4} \, y^{2} - \frac{y^{2} \sin\left({\Theta}\right)^{2}}{4 \, a^{2}} - \frac{m \sin\left({\Theta}\right)^{4}}{2 \, {\Delta}^{3} y^{2}} + \frac{m}{2 \, {\Delta}^{3} y^{2}} - \frac{1}{4} \right) \mathrm{d} {x^+}\otimes \mathrm{d} {x^-} + \left( -\frac{1}{4} \, y^{2} - \frac{y^{2} \sin\left({\Theta}\right)^{2}}{4 \, a^{2}} - \frac{m \sin\left({\Theta}\right)^{4}}{2 \, {\Delta}^{3} y^{2}} + \frac{m}{2 \, {\Delta}^{3} y^{2}} - \frac{1}{4} \right) \mathrm{d} {x^-}\otimes \mathrm{d} {x^+} + \left( -\frac{1}{4} \, y^{2} - \frac{y^{2} \cos\left({\Theta}\right)^{2}}{4 \, a^{2}} + \frac{y^{2}}{4 \, a^{2}} + \frac{m \cos\left({\Theta}\right)^{4}}{2 \, {\Delta}^{3} y^{2}} - \frac{1}{4} \right) \mathrm{d} {x^-}\otimes \mathrm{d} {x^-} + \left( \frac{{\Delta}^{2} y^{2}}{{\Delta}^{2} y^{4} + {\Delta}^{2} y^{2} - 2 \, m} \right) \mathrm{d} y\otimes \mathrm{d} y + y^{2} \mathrm{d} {\Theta}\otimes \mathrm{d} {\Theta} + y^{2} \cos\left({\Theta}\right)^{2} \mathrm{d} {\Psi}\otimes \mathrm{d} {\Psi}$$

G.display_comp()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{lcl} G_{ \, {x^+} \, {x^+} }^{ \phantom{\, {x^+}}\phantom{\, {x^+}} } & = & -\frac{1}{4} \, y^{2} + \frac{y^{2} \sin\left({\Theta}\right)^{2}}{4 \, a^{2}} + \frac{m \sin\left({\Theta}\right)^{4}}{2 \, {\Delta}^{3} y^{2}} + \frac{m \sin\left({\Theta}\right)^{2}}{{\Delta}^{3} y^{2}} + \frac{m}{2 \, {\Delta}^{3} y^{2}} - \frac{1}{4} \\ G_{ \, {x^+} \, {x^-} }^{ \phantom{\, {x^+}}\phantom{\, {x^-}} } & = & -\frac{1}{4} \, y^{2} - \frac{y^{2} \sin\left({\Theta}\right)^{2}}{4 \, a^{2}} - \frac{m \sin\left({\Theta}\right)^{4}}{2 \, {\Delta}^{3} y^{2}} + \frac{m}{2 \, {\Delta}^{3} y^{2}} - \frac{1}{4} \\ G_{ \, {x^-} \, {x^+} }^{ \phantom{\, {x^-}}\phantom{\, {x^+}} } & = & -\frac{1}{4} \, y^{2} - \frac{y^{2} \sin\left({\Theta}\right)^{2}}{4 \, a^{2}} - \frac{m \sin\left({\Theta}\right)^{4}}{2 \, {\Delta}^{3} y^{2}} + \frac{m}{2 \, {\Delta}^{3} y^{2}} - \frac{1}{4} \\ G_{ \, {x^-} \, {x^-} }^{ \phantom{\, {x^-}}\phantom{\, {x^-}} } & = & -\frac{1}{4} \, y^{2} - \frac{y^{2} \cos\left({\Theta}\right)^{2}}{4 \, a^{2}} + \frac{y^{2}}{4 \, a^{2}} + \frac{m \cos\left({\Theta}\right)^{4}}{2 \, {\Delta}^{3} y^{2}} - \frac{1}{4} \\ G_{ \, y \, y }^{ \phantom{\, y}\phantom{\, y} } & = & \frac{{\Delta}^{2} y^{2}}{{\Delta}^{2} y^{4} + {\Delta}^{2} y^{2} - 2 \, m} \\ G_{ \, {\Theta} \, {\Theta} }^{ \phantom{\, {\Theta}}\phantom{\, {\Theta}} } & = & y^{2} \\ G_{ \, {\Psi} \, {\Psi} }^{ \phantom{\, {\Psi}}\phantom{\, {\Psi}} } & = & y^{2} \cos\left({\Theta}\right)^{2} \end{array}$$

The above components fully agree with Eq. (5.41).