2017-10-02-043718.sagews

t1,t2,t3,t4,p,q=var('t1,t2,t3,t4,p,q')
m = matrix(SR,[[t1^4+p*t1^2,t1^3+q*t1^2,t1,1],
               [t2^4+p*t2^2,t2^3+q*t2^2,t2,1],
               [t3^4+p*t3^2,t3^3+q*t3^2,t3,1],
               [t4^4+p*t4^2,t4^3+q*t4^2,t4,1]])
(m.determinant().factor()/((t1-t2)*(t1-t3)*(t1-t4)*(t2-t3)*(t2-t4)*(t3-t4))).show()

$\displaystyle q t_{1} + q t_{2} + t_{1} t_{2} + q t_{3} + t_{1} t_{3} + t_{2} t_{3} + q t_{4} + t_{1} t_{4} + t_{2} t_{4} + t_{3} t_{4} - p$

p,q,r=var('p,q,r')
m = matrix(SR,[[2,0,0,1],
               [0,1,0,r],
               [0,0,2,r^2],
               [p,q,r,0]])
(m.determinant()/(-2)).show()

$\displaystyle r^{3} + 2 \, q r + p$

t1,t2,t3,t4,p,q,r=var('t1,t2,t3,t4,p,q,r')
m = matrix(SR,[[t1^4+p*t1,t1^3-q*t1,t1^2+r*t1,1],
               [t2^4+p*t2,t2^3-q*t2,t2^2+r*t2,1],
               [t3^4+p*t3,t3^3-q*t3,t3^2+r*t3,1],
               [t4^4+p*t4,t4^3-q*t4,t4^2+r*t4,1]])
(m.determinant().factor()/((t1-t2)*(t1-t3)*(t1-t4)*(t2-t3)*(t2-t4)*(t3-t4))).show()

$\displaystyle r t_{1} t_{2} + r t_{1} t_{3} + r t_{2} t_{3} + t_{1} t_{2} t_{3} + r t_{1} t_{4} + r t_{2} t_{4} + t_{1} t_{2} t_{4} + r t_{3} t_{4} + t_{1} t_{3} t_{4} + t_{2} t_{3} t_{4} + q t_{1} + q t_{2} + q t_{3} + q t_{4} + p$

p,q,r,s=var('p,q,r,s')
#a14,a23,a24,a33,a34,a44
m = matrix(SR,[[1,1,0,0,0,0],
               [2*s,0,2,1,0,0],
               [0,r,s,0,1,0],
               [0,2*q,0,2*r,2*s,1],
               [p,0,q,0,r,s],
               [2*p*s,2*q*r,2*q*s,r^2,2*r*s,s^2]])
(m.determinant().factor()/2).show()

$\displaystyle {\left(r^{3} - 2 \, q r s + p s^{2} - q^{2} + p r\right)} {\left(s^{2} + r\right)}$

p,q,r,s=var('p,q,r,s')
#a13,a22,a24,a33,a34,a44
m = matrix(SR,[[2,1,0,0,0,0],
               [2*r,0,2,1,0,0],
               [0,q,s,0,1,0],
               [2*p,0,0,2*r,2*s,1],
               [0,0,q,0,r,s],
               [2*p*r,q^2,2*q*s,r^2,2*r*s,s^2]])
(m.determinant().factor()/2).show()

$\displaystyle {\left(r^{3} - 2 \, q r s + p s^{2} - q^{2} + p r\right)} {\left(r s + q\right)}$

t1,t2,t3,t4,p,q,r,s=var('t1,t2,t3,t4,p,q,r,s')
m = matrix(SR,[[t1^4-p,t1^3+q,t1^2-r,t1+s],
               [t2^4-p,t2^3+q,t2^2-r,t2+s],
               [t3^4-p,t3^3+q,t3^2-r,t3+s],
               [t4^4-p,t4^3+q,t4^2-r,t4+s]])
(m.determinant().factor()/((t1-t2)*(t1-t3)*(t1-t4)*(t2-t3)*(t2-t4)*(t3-t4))).show()

$\displaystyle s t_{1} t_{2} t_{3} + s t_{1} t_{2} t_{4} + s t_{1} t_{3} t_{4} + s t_{2} t_{3} t_{4} + t_{1} t_{2} t_{3} t_{4} + r t_{1} t_{2} + r t_{1} t_{3} + r t_{2} t_{3} + r t_{1} t_{4} + r t_{2} t_{4} + r t_{3} t_{4} + q t_{1} + q t_{2} + q t_{3} + q t_{4} + p$

p,q,r,s=var('p,q,r,s')
#a13,a14,a24,a33,a34,a44
m = matrix(SR,[[-2*r,2*s,2,1,0,0],
               [-2*q,r,s,0,1,0],
               [-2*p,-2*q,0,-2*r,2*s,1],
               [0,-p,q,0,-r,s],
               [2*(p*r-q^2),-2*(p*s-q*r),2*q*s,r^2,-2*r*s,s^2]])
minors = m.minors(5)
for i in minors:
    i.factor().show()

$\displaystyle 4 \, {\left(r^{3} - 2 \, q r s + p s^{2} + q^{2} - p r\right)} {\left(q^{2} - p r\right)}$

$\displaystyle -2 \, {\left(r^{3} - 2 \, q r s + p s^{2} + q^{2} - p r\right)} {\left(q r - p s\right)}$

$\displaystyle 4 \, {\left(r^{3} - 2 \, q r s + p s^{2} + q^{2} - p r\right)} {\left(q s - p\right)}$

$\displaystyle -2 \, {\left(r^{3} - 2 \, q r s + p s^{2} + q^{2} - p r\right)} {\left(r^{2} - 2 \, q s + p\right)}$

$\displaystyle -2 \, {\left(r^{3} - 2 \, q r s + p s^{2} + q^{2} - p r\right)} {\left(r s - q\right)}$

$\displaystyle 2 \, {\left(r^{3} - 2 \, q r s + p s^{2} + q^{2} - p r\right)} {\left(s^{2} - r\right)}$

R.<p,q,r,s,b,d> = PolynomialRing(QQ,6)
I = R * [r - s*(b+d) + b*d, q - s*(b^2+b*d+d^2) + b*d*(b+d), p - s*(b^3+b^2*d+b*d^2+d^3) + b*d*(b^2+b*d+d^2)]
I.elimination_ideal([b,d])

Ideal (r^3 - 2*q*r*s + p*s^2 + q^2 - p*r) of Multivariate Polynomial Ring in p, q, r, s, b, d over Rational Field

# rational space quartic with coordinates of degrees 4,3,2,1
t,t1,t2,t3,t4=var('t,t1,t2,t3,t4')
p, q, r, s = var('p,q,r,s')
p1 = t^4 - p
p2 = t^3 + q
p3 = t^2 - r
p4 = t + s
# q(x) describes the space quartic as x varies
q(x) = [p1.substitute(t==x), p2.substitute(t==x), p3.substitute(t==x), p4.substitute(t==x)]
# 4 distinct points t1, t2, t3, t4 are coplanar iff the following matrix is singular
m = matrix(SR,[q(t1), q(t2), q(t3), q(t4)])
F=(m.determinant().factor())/((t1-t2)*(t1-t3)*(t1-t4)*(t2-t3)*(t2-t4)*(t3-t4))
print("The symmetric expression F is")
F.show()
print("Solve F=0 for t4 and set it equal to f")
f=solve(F,t4)[0].rhs(); f.show()
print("Quotient of the partial derivatives of f with respect to t2 and t3:")
g = (f.diff(t2)/f.diff(t3)).simplify_full(); g.show()
print("The above expression should be independent of t1, so take the partial derivative wrt t1, take the numerator of that and factorize:")
h = g.diff(t1).numerator().factor(); h.show()
print("Since t1, t2, t3 are arbitrary in some small ball, the first and last factors are non-zero generically, and we obtain that the catalecticant vanishes.")
g.diff(t1).denominator().factor().show()

The symmetric expression F is

$\displaystyle s t_{1} t_{2} t_{3} + s t_{1} t_{2} t_{4} + s t_{1} t_{3} t_{4} + s t_{2} t_{3} t_{4} + t_{1} t_{2} t_{3} t_{4} + r t_{1} t_{2} + r t_{1} t_{3} + r t_{2} t_{3} + r t_{1} t_{4} + r t_{2} t_{4} + r t_{3} t_{4} + q t_{1} + q t_{2} + q t_{3} + q t_{4} + p$

Solve F=0 for t4 and set it equal to f

$\displaystyle -\frac{q t_{1} + {\left(r t_{1} + q\right)} t_{2} + {\left(r t_{1} + {\left(s t_{1} + r\right)} t_{2} + q\right)} t_{3} + p}{r t_{1} + {\left(s t_{1} + r\right)} t_{2} + {\left(s t_{1} + {\left(s + t_{1}\right)} t_{2} + r\right)} t_{3} + q}$

Quotient of the partial derivatives of f with respect to t2 and t3:

$\displaystyle \frac{{\left(r^{2} - q s\right)} t_{1}^{2} + {\left({\left(s^{2} - r\right)} t_{1}^{2} + r^{2} - q s + {\left(r s - q\right)} t_{1}\right)} t_{3}^{2} + q^{2} - p r + {\left(q r - p s\right)} t_{1} + {\left({\left(r s - q\right)} t_{1}^{2} + q r - p s + {\left(r^{2} - p\right)} t_{1}\right)} t_{3}}{{\left(r^{2} - q s\right)} t_{1}^{2} + {\left({\left(s^{2} - r\right)} t_{1}^{2} + r^{2} - q s + {\left(r s - q\right)} t_{1}\right)} t_{2}^{2} + q^{2} - p r + {\left(q r - p s\right)} t_{1} + {\left({\left(r s - q\right)} t_{1}^{2} + q r - p s + {\left(r^{2} - p\right)} t_{1}\right)} t_{2}}$

The above expression should be independent of t1, so take the partial derivative wrt t1, take the numerator of that and factorize:

$\displaystyle {\left(s t_{1}^{2} t_{2} + s t_{1}^{2} t_{3} + 2 \, s t_{1} t_{2} t_{3} + t_{1}^{2} t_{2} t_{3} + r t_{1}^{2} + 2 \, r t_{1} t_{2} + 2 \, r t_{1} t_{3} + r t_{2} t_{3} + 2 \, q t_{1} + q t_{2} + q t_{3} + p\right)} {\left(r^{3} - 2 \, q r s + p s^{2} + q^{2} - p r\right)} {\left(t_{2} - t_{3}\right)}$

Since t1, t2, t3 are arbitrary in some small ball, the first and last factors are non-zero generically, and we obtain that the catalecticant vanishes.

$\displaystyle {\left(s^{2} t_{1}^{2} t_{2}^{2} + r s t_{1}^{2} t_{2} + r s t_{1} t_{2}^{2} - r t_{1}^{2} t_{2}^{2} + r^{2} t_{1}^{2} - q s t_{1}^{2} + r^{2} t_{1} t_{2} - q t_{1}^{2} t_{2} + r^{2} t_{2}^{2} - q s t_{2}^{2} - q t_{1} t_{2}^{2} + q r t_{1} - p s t_{1} + q r t_{2} - p s t_{2} - p t_{1} t_{2} + q^{2} - p r\right)}^{2}$

R.<p,q,r,s,b,d> = PolynomialRing(QQ,6)
I = R * [b*d, b*d*(b+d), 1 + b*d*(b^2+b*d+d^2)]
I.elimination_ideal([b,d])

Ideal (1) of Multivariate Polynomial Ring in p, q, r, s, b, d over Rational Field