Lemaitre_Tolman.ipynb

Kernel: SageMath 10.0.rc3

Lemaître-Tolman solutions

This Jupyter/SageMath notebook is relative to the lectures Geometry and physics of black holes.

The computations make use of tools developed through the SageManifolds project.

version()

'SageMath version 10.0.rc3, Release Date: 2023-05-12'

First we set up the notebook to display mathematical objects using LaTeX rendering:

%display latex

Spacetime

We declare the spacetime manifold $M$:

M = Manifold(4, 'M', structure='Lorentzian')
print(M)

4-dimensional Lorentzian manifold M

and declare the chart of Lemaître synchronous coordinates on it:

X.<t,x,th,ph> = M.chart(r't:\tau x:(0,+oo):\chi th:(0,pi):\theta ph:(0,2*pi):\phi')
X

$\displaystyle \left(M,({\tau}, {\chi}, {\theta}, {\phi})\right)$

The most general metric tensor, assuming spherical symmetry and synchronous coordinates:

g = M.metric()
a = function('a')
r = function('r')
g[0,0] = -1
g[1,1] = a(t,x)^2
g[2,2] = r(t,x)^2
g[3,3] = (r(t,x)*sin(th))^2
g.display()

$\displaystyle g = -\mathrm{d} {\tau}\otimes \mathrm{d} {\tau} + a\left({\tau}, {\chi}\right)^{2} \mathrm{d} {\chi}\otimes \mathrm{d} {\chi} + r\left({\tau}, {\chi}\right)^{2} \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + r\left({\tau}, {\chi}\right)^{2} \sin\left({\theta}\right)^{2} \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}$

Einstein equation

The cosmological constant:

Lamb = var('Lamb', latex_name=r'\Lambda')
Lamb

$\displaystyle {\Lambda}$

The Ricci tensor:

Ric = g.ricci()
print(Ric)

Field of symmetric bilinear forms Ric(g) on the 4-dimensional Lorentzian manifold M

Ric.display()

$\displaystyle \mathrm{Ric}\left(g\right) = \left( -\frac{r\left({\tau}, {\chi}\right) \frac{\partial^2\,a}{\partial {\tau} ^ 2} + 2 \, a\left({\tau}, {\chi}\right) \frac{\partial^2\,r}{\partial {\tau} ^ 2}}{a\left({\tau}, {\chi}\right) r\left({\tau}, {\chi}\right)} \right) \mathrm{d} {\tau}\otimes \mathrm{d} {\tau} -\frac{2 \, {\left(a\left({\tau}, {\chi}\right) \frac{\partial^2\,r}{\partial {\tau}\partial {\chi}} - \frac{\partial\,a}{\partial {\tau}} \frac{\partial\,r}{\partial {\chi}}\right)}}{a\left({\tau}, {\chi}\right) r\left({\tau}, {\chi}\right)} \mathrm{d} {\tau}\otimes \mathrm{d} {\chi} -\frac{2 \, {\left(a\left({\tau}, {\chi}\right) \frac{\partial^2\,r}{\partial {\tau}\partial {\chi}} - \frac{\partial\,a}{\partial {\tau}} \frac{\partial\,r}{\partial {\chi}}\right)}}{a\left({\tau}, {\chi}\right) r\left({\tau}, {\chi}\right)} \mathrm{d} {\chi}\otimes \mathrm{d} {\tau} + \left( \frac{a\left({\tau}, {\chi}\right)^{2} r\left({\tau}, {\chi}\right) \frac{\partial^2\,a}{\partial {\tau} ^ 2} + 2 \, a\left({\tau}, {\chi}\right)^{2} \frac{\partial\,a}{\partial {\tau}} \frac{\partial\,r}{\partial {\tau}} + 2 \, \frac{\partial\,a}{\partial {\chi}} \frac{\partial\,r}{\partial {\chi}} - 2 \, a\left({\tau}, {\chi}\right) \frac{\partial^2\,r}{\partial {\chi} ^ 2}}{a\left({\tau}, {\chi}\right) r\left({\tau}, {\chi}\right)} \right) \mathrm{d} {\chi}\otimes \mathrm{d} {\chi} + \left( \frac{a\left({\tau}, {\chi}\right)^{2} r\left({\tau}, {\chi}\right) \frac{\partial\,a}{\partial {\tau}} \frac{\partial\,r}{\partial {\tau}} + a\left({\tau}, {\chi}\right)^{3} \frac{\partial\,r}{\partial {\tau}}^{2} + a\left({\tau}, {\chi}\right)^{3} r\left({\tau}, {\chi}\right) \frac{\partial^2\,r}{\partial {\tau} ^ 2} + a\left({\tau}, {\chi}\right)^{3} + r\left({\tau}, {\chi}\right) \frac{\partial\,a}{\partial {\chi}} \frac{\partial\,r}{\partial {\chi}} - a\left({\tau}, {\chi}\right) \frac{\partial\,r}{\partial {\chi}}^{2} - a\left({\tau}, {\chi}\right) r\left({\tau}, {\chi}\right) \frac{\partial^2\,r}{\partial {\chi} ^ 2}}{a\left({\tau}, {\chi}\right)^{3}} \right) \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \frac{{\left(a\left({\tau}, {\chi}\right)^{2} r\left({\tau}, {\chi}\right) \frac{\partial\,a}{\partial {\tau}} \frac{\partial\,r}{\partial {\tau}} + a\left({\tau}, {\chi}\right)^{3} \frac{\partial\,r}{\partial {\tau}}^{2} + a\left({\tau}, {\chi}\right)^{3} r\left({\tau}, {\chi}\right) \frac{\partial^2\,r}{\partial {\tau} ^ 2} + a\left({\tau}, {\chi}\right)^{3} + r\left({\tau}, {\chi}\right) \frac{\partial\,a}{\partial {\chi}} \frac{\partial\,r}{\partial {\chi}} - a\left({\tau}, {\chi}\right) \frac{\partial\,r}{\partial {\chi}}^{2} - a\left({\tau}, {\chi}\right) r\left({\tau}, {\chi}\right) \frac{\partial^2\,r}{\partial {\chi} ^ 2}\right)} \sin\left({\theta}\right)^{2}}{a\left({\tau}, {\chi}\right)^{3}} \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}$

The Einstein tensor:

G = Ric - 1/2*g.ricci_scalar() * g
G.set_name('G')
print(G)

Field of symmetric bilinear forms G on the 4-dimensional Lorentzian manifold M

G.display_comp()

$\displaystyle \begin{array}{lcl} G_{ \, {\tau} \, {\tau} }^{ \phantom{\, {\tau}}\phantom{\, {\tau}} } & = & \frac{2 \, a\left({\tau}, {\chi}\right)^{2} r\left({\tau}, {\chi}\right) \frac{\partial\,a}{\partial {\tau}} \frac{\partial\,r}{\partial {\tau}} + a\left({\tau}, {\chi}\right)^{3} \frac{\partial\,r}{\partial {\tau}}^{2} + a\left({\tau}, {\chi}\right)^{3} + 2 \, r\left({\tau}, {\chi}\right) \frac{\partial\,a}{\partial {\chi}} \frac{\partial\,r}{\partial {\chi}} - a\left({\tau}, {\chi}\right) \frac{\partial\,r}{\partial {\chi}}^{2} - 2 \, a\left({\tau}, {\chi}\right) r\left({\tau}, {\chi}\right) \frac{\partial^2\,r}{\partial {\chi} ^ 2}}{a\left({\tau}, {\chi}\right)^{3} r\left({\tau}, {\chi}\right)^{2}} \\ G_{ \, {\tau} \, {\chi} }^{ \phantom{\, {\tau}}\phantom{\, {\chi}} } & = & -\frac{2 \, {\left(a\left({\tau}, {\chi}\right) \frac{\partial^2\,r}{\partial {\tau}\partial {\chi}} - \frac{\partial\,a}{\partial {\tau}} \frac{\partial\,r}{\partial {\chi}}\right)}}{a\left({\tau}, {\chi}\right) r\left({\tau}, {\chi}\right)} \\ G_{ \, {\chi} \, {\tau} }^{ \phantom{\, {\chi}}\phantom{\, {\tau}} } & = & -\frac{2 \, {\left(a\left({\tau}, {\chi}\right) \frac{\partial^2\,r}{\partial {\tau}\partial {\chi}} - \frac{\partial\,a}{\partial {\tau}} \frac{\partial\,r}{\partial {\chi}}\right)}}{a\left({\tau}, {\chi}\right) r\left({\tau}, {\chi}\right)} \\ G_{ \, {\chi} \, {\chi} }^{ \phantom{\, {\chi}}\phantom{\, {\chi}} } & = & -\frac{a\left({\tau}, {\chi}\right)^{2} \left(\frac{\partial\,r}{\partial {\tau}}\right)^{2} + 2 \, a\left({\tau}, {\chi}\right)^{2} r\left({\tau}, {\chi}\right) \frac{\partial^2\,r}{\partial {\tau} ^ 2} + a\left({\tau}, {\chi}\right)^{2} - \left(\frac{\partial\,r}{\partial {\chi}}\right)^{2}}{r\left({\tau}, {\chi}\right)^{2}} \\ G_{ \, {\theta} \, {\theta} }^{ \phantom{\, {\theta}}\phantom{\, {\theta}} } & = & -\frac{a\left({\tau}, {\chi}\right)^{2} r\left({\tau}, {\chi}\right)^{2} \frac{\partial^2\,a}{\partial {\tau} ^ 2} + a\left({\tau}, {\chi}\right)^{2} r\left({\tau}, {\chi}\right) \frac{\partial\,a}{\partial {\tau}} \frac{\partial\,r}{\partial {\tau}} + a\left({\tau}, {\chi}\right)^{3} r\left({\tau}, {\chi}\right) \frac{\partial^2\,r}{\partial {\tau} ^ 2} + r\left({\tau}, {\chi}\right) \frac{\partial\,a}{\partial {\chi}} \frac{\partial\,r}{\partial {\chi}} - a\left({\tau}, {\chi}\right) r\left({\tau}, {\chi}\right) \frac{\partial^2\,r}{\partial {\chi} ^ 2}}{a\left({\tau}, {\chi}\right)^{3}} \\ G_{ \, {\phi} \, {\phi} }^{ \phantom{\, {\phi}}\phantom{\, {\phi}} } & = & -\frac{{\left(a\left({\tau}, {\chi}\right)^{2} r\left({\tau}, {\chi}\right)^{2} \frac{\partial^2\,a}{\partial {\tau} ^ 2} + a\left({\tau}, {\chi}\right)^{2} r\left({\tau}, {\chi}\right) \frac{\partial\,a}{\partial {\tau}} \frac{\partial\,r}{\partial {\tau}} + a\left({\tau}, {\chi}\right)^{3} r\left({\tau}, {\chi}\right) \frac{\partial^2\,r}{\partial {\tau} ^ 2} + r\left({\tau}, {\chi}\right) \frac{\partial\,a}{\partial {\chi}} \frac{\partial\,r}{\partial {\chi}} - a\left({\tau}, {\chi}\right) r\left({\tau}, {\chi}\right) \frac{\partial^2\,r}{\partial {\chi} ^ 2}\right)} \sin\left({\theta}\right)^{2}}{a\left({\tau}, {\chi}\right)^{3}} \end{array}$

Dust matter model

Let us consider a pressureless fluid ("dust"). Moreover, we assume that the coordinates $(\tau,\chi,\theta,\phi)$ are comoving, i.e. that the fluid 4-velocity is equal to $\partial_\tau$:

u = M.vector_field('u')
u[0] = 1
u.display()

$\displaystyle u = \frac{\partial}{\partial {\tau} }$

Since $(\tau,\chi,\theta,\chi)$ are synchronous, the above does define a unit timelike vector:

g(u,u).display()

$\displaystyle \begin{array}{llcl} g\left(u,u\right):& M & \longrightarrow & \mathbb{R} \\ & \left({\tau}, {\chi}, {\theta}, {\phi}\right) & \longmapsto & -1 \end{array}$

Let us check that $u$ is a geodesic vector field:

nabla = g.connection()
acc = u['^b']*nabla(u)['^a_b']
acc.display()

$\displaystyle 0$

The 1-form associated to the fluid 4-velocity by metric duality:

u_form = u.down(g)
print(u_form)

1-form on the 4-dimensional Lorentzian manifold M

u_form.display()

$\displaystyle -\mathrm{d} {\tau}$

The pressureless energy-momentum tensor:

rho = function('rho')
T = rho(t,x)*(u_form * u_form)
T.set_name('T')
print(T)

Field of symmetric bilinear forms T on the 4-dimensional Lorentzian manifold M

T.display()

$\displaystyle T = \rho\left({\tau}, {\chi}\right) \mathrm{d} {\tau}\otimes \mathrm{d} {\tau}$

The Einstein equation:

E = G + Lamb*g - 8*pi*T 
E.set_name('E')
print(E)

Field of symmetric bilinear forms E on the 4-dimensional Lorentzian manifold M

E.display_comp()

$\displaystyle \begin{array}{lcl} E_{ \, {\tau} \, {\tau} }^{ \phantom{\, {\tau}}\phantom{\, {\tau}} } & = & -\frac{8 \, \pi a\left({\tau}, {\chi}\right)^{3} r\left({\tau}, {\chi}\right)^{2} \rho\left({\tau}, {\chi}\right) + {\Lambda} a\left({\tau}, {\chi}\right)^{3} r\left({\tau}, {\chi}\right)^{2} - 2 \, a\left({\tau}, {\chi}\right)^{2} r\left({\tau}, {\chi}\right) \frac{\partial\,a}{\partial {\tau}} \frac{\partial\,r}{\partial {\tau}} - a\left({\tau}, {\chi}\right)^{3} \frac{\partial\,r}{\partial {\tau}}^{2} - a\left({\tau}, {\chi}\right)^{3} - 2 \, r\left({\tau}, {\chi}\right) \frac{\partial\,a}{\partial {\chi}} \frac{\partial\,r}{\partial {\chi}} + a\left({\tau}, {\chi}\right) \frac{\partial\,r}{\partial {\chi}}^{2} + 2 \, a\left({\tau}, {\chi}\right) r\left({\tau}, {\chi}\right) \frac{\partial^2\,r}{\partial {\chi} ^ 2}}{a\left({\tau}, {\chi}\right)^{3} r\left({\tau}, {\chi}\right)^{2}} \\ E_{ \, {\tau} \, {\chi} }^{ \phantom{\, {\tau}}\phantom{\, {\chi}} } & = & -\frac{2 \, {\left(a\left({\tau}, {\chi}\right) \frac{\partial^2\,r}{\partial {\tau}\partial {\chi}} - \frac{\partial\,a}{\partial {\tau}} \frac{\partial\,r}{\partial {\chi}}\right)}}{a\left({\tau}, {\chi}\right) r\left({\tau}, {\chi}\right)} \\ E_{ \, {\chi} \, {\tau} }^{ \phantom{\, {\chi}}\phantom{\, {\tau}} } & = & -\frac{2 \, {\left(a\left({\tau}, {\chi}\right) \frac{\partial^2\,r}{\partial {\tau}\partial {\chi}} - \frac{\partial\,a}{\partial {\tau}} \frac{\partial\,r}{\partial {\chi}}\right)}}{a\left({\tau}, {\chi}\right) r\left({\tau}, {\chi}\right)} \\ E_{ \, {\chi} \, {\chi} }^{ \phantom{\, {\chi}}\phantom{\, {\chi}} } & = & \frac{{\Lambda} a\left({\tau}, {\chi}\right)^{2} r\left({\tau}, {\chi}\right)^{2} - a\left({\tau}, {\chi}\right)^{2} \left(\frac{\partial\,r}{\partial {\tau}}\right)^{2} - 2 \, a\left({\tau}, {\chi}\right)^{2} r\left({\tau}, {\chi}\right) \frac{\partial^2\,r}{\partial {\tau} ^ 2} - a\left({\tau}, {\chi}\right)^{2} + \left(\frac{\partial\,r}{\partial {\chi}}\right)^{2}}{r\left({\tau}, {\chi}\right)^{2}} \\ E_{ \, {\theta} \, {\theta} }^{ \phantom{\, {\theta}}\phantom{\, {\theta}} } & = & \frac{{\Lambda} a\left({\tau}, {\chi}\right)^{3} r\left({\tau}, {\chi}\right)^{2} - a\left({\tau}, {\chi}\right)^{2} r\left({\tau}, {\chi}\right)^{2} \frac{\partial^2\,a}{\partial {\tau} ^ 2} - a\left({\tau}, {\chi}\right)^{2} r\left({\tau}, {\chi}\right) \frac{\partial\,a}{\partial {\tau}} \frac{\partial\,r}{\partial {\tau}} - a\left({\tau}, {\chi}\right)^{3} r\left({\tau}, {\chi}\right) \frac{\partial^2\,r}{\partial {\tau} ^ 2} - r\left({\tau}, {\chi}\right) \frac{\partial\,a}{\partial {\chi}} \frac{\partial\,r}{\partial {\chi}} + a\left({\tau}, {\chi}\right) r\left({\tau}, {\chi}\right) \frac{\partial^2\,r}{\partial {\chi} ^ 2}}{a\left({\tau}, {\chi}\right)^{3}} \\ E_{ \, {\phi} \, {\phi} }^{ \phantom{\, {\phi}}\phantom{\, {\phi}} } & = & \frac{{\left({\Lambda} a\left({\tau}, {\chi}\right)^{3} r\left({\tau}, {\chi}\right)^{2} - a\left({\tau}, {\chi}\right)^{2} r\left({\tau}, {\chi}\right)^{2} \frac{\partial^2\,a}{\partial {\tau} ^ 2} - a\left({\tau}, {\chi}\right)^{2} r\left({\tau}, {\chi}\right) \frac{\partial\,a}{\partial {\tau}} \frac{\partial\,r}{\partial {\tau}} - a\left({\tau}, {\chi}\right)^{3} r\left({\tau}, {\chi}\right) \frac{\partial^2\,r}{\partial {\tau} ^ 2} - r\left({\tau}, {\chi}\right) \frac{\partial\,a}{\partial {\chi}} \frac{\partial\,r}{\partial {\chi}} + a\left({\tau}, {\chi}\right) r\left({\tau}, {\chi}\right) \frac{\partial^2\,r}{\partial {\chi} ^ 2}\right)} \sin\left({\theta}\right)^{2}}{a\left({\tau}, {\chi}\right)^{3}} \end{array}$

Solving the Einstein equation

$\tau\chi$ component

Let us first consider the $01 = \tau\chi$ component of the Einstein equation:

E[0,1]

$\displaystyle -\frac{2 \, {\left(a\left({\tau}, {\chi}\right) \frac{\partial^2\,r}{\partial {\tau}\partial {\chi}} - \frac{\partial\,a}{\partial {\tau}} \frac{\partial\,r}{\partial {\chi}}\right)}}{a\left({\tau}, {\chi}\right) r\left({\tau}, {\chi}\right)}$

A slight rearrangement of the equation:

eq = E[0,1]*r(t,x)/(-2*a(t,x)) 
eq

$\displaystyle \frac{a\left({\tau}, {\chi}\right) \frac{\partial^2\,r}{\partial {\tau}\partial {\chi}} - \frac{\partial\,a}{\partial {\tau}} \frac{\partial\,r}{\partial {\chi}}}{a\left({\tau}, {\chi}\right)^{2}}$

We see that this equation is equivalent to $$\frac{\partial}{\partial\tau} \left( \frac{1}{a}\frac{\partial r}{\partial\chi} \right) = 0$$ since

drdx = diff(r(t,x), x)
eq - diff(drdx/a(t,x), t)

$\displaystyle 0$

Hence there exists a function of $\chi$ only, $f(\chi)$ say, such that $\frac{1}{a}\frac{\partial r}{\partial\chi} = f(\chi)$. We disregard the case $f(\chi)=0$, which would imply $\frac{\partial r}{\partial\chi}=0$ and would lead to the so-called Datt model (1938). Accordingly, we may write $$a(\tau,\chi) = \frac{1}{f(\chi)}\frac{\partial r}{\partial\chi}$$ Let us call af this expression of $a$:

f = function('f')
af(t,x) = drdx / f(x)
af(t,x)

$\displaystyle \frac{\frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right)}{f\left({\chi}\right)}$

We check that if we substitute $a$ by af in the $\tau\chi$ component of the Einstein equation, we get identically zero:

E[0,1].expr().substitute_function(a, af)

$\displaystyle 0$

NB: expr() returns a Sage symbolic expression from the coordinate function E[0,1], so that we may apply substitute_function

Hence the first Lemaitre-Tolman equation is

LT1 = a(t,x) == af(t,x)
LT1

$\displaystyle a\left({\tau}, {\chi}\right) = \frac{\frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right)}{f\left({\chi}\right)}$

$\chi\chi$ component

The $11 = \chi\chi$ component of Einstein equation is

E[1,1]

$\displaystyle \frac{{\Lambda} a\left({\tau}, {\chi}\right)^{2} r\left({\tau}, {\chi}\right)^{2} - a\left({\tau}, {\chi}\right)^{2} \left(\frac{\partial\,r}{\partial {\tau}}\right)^{2} - 2 \, a\left({\tau}, {\chi}\right)^{2} r\left({\tau}, {\chi}\right) \frac{\partial^2\,r}{\partial {\tau} ^ 2} - a\left({\tau}, {\chi}\right)^{2} + \left(\frac{\partial\,r}{\partial {\chi}}\right)^{2}}{r\left({\tau}, {\chi}\right)^{2}}$

It is equivalent to

eq = (- E[1,1] * r(t,x)^2).expr() == 0
eq

$\displaystyle -{\Lambda} a\left({\tau}, {\chi}\right)^{2} r\left({\tau}, {\chi}\right)^{2} + a\left({\tau}, {\chi}\right)^{2} \frac{\partial}{\partial {\tau}}r\left({\tau}, {\chi}\right)^{2} + 2 \, a\left({\tau}, {\chi}\right)^{2} r\left({\tau}, {\chi}\right) \frac{\partial^{2}}{(\partial {\tau})^{2}}r\left({\tau}, {\chi}\right) + a\left({\tau}, {\chi}\right)^{2} - \frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right)^{2} = 0$

Let us substitute for $a(\tau,\chi)$ the value found above when solving the $\tau\chi$ component:

eq1 = eq.substitute_function(a, af)
eq1

$\displaystyle -\frac{{\Lambda} r\left({\tau}, {\chi}\right)^{2} \frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right)^{2}}{f\left({\chi}\right)^{2}} + \frac{\frac{\partial}{\partial {\tau}}r\left({\tau}, {\chi}\right)^{2} \frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right)^{2}}{f\left({\chi}\right)^{2}} + \frac{2 \, r\left({\tau}, {\chi}\right) \frac{\partial^{2}}{(\partial {\tau})^{2}}r\left({\tau}, {\chi}\right) \frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right)^{2}}{f\left({\chi}\right)^{2}} - \frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right)^{2} + \frac{\frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right)^{2}}{f\left({\chi}\right)^{2}} = 0$

Some slight rearrangement and simplification:

eq2 = (eq1 * f(x)^2 / diff(r(t,x), x)^2).simplify_full()
eq2

$\displaystyle -{\Lambda} r\left({\tau}, {\chi}\right)^{2} - f\left({\chi}\right)^{2} + \frac{\partial}{\partial {\tau}}r\left({\tau}, {\chi}\right)^{2} + 2 \, r\left({\tau}, {\chi}\right) \frac{\partial^{2}}{(\partial {\tau})^{2}}r\left({\tau}, {\chi}\right) + 1 = 0$

eq3 = (eq2 * diff(r(t,x),t)).simplify_full()
eq3

$\displaystyle -f\left({\chi}\right)^{2} \frac{\partial}{\partial {\tau}}r\left({\tau}, {\chi}\right) + \frac{\partial}{\partial {\tau}}r\left({\tau}, {\chi}\right)^{3} + 2 \, r\left({\tau}, {\chi}\right) \frac{\partial}{\partial {\tau}}r\left({\tau}, {\chi}\right) \frac{\partial^{2}}{(\partial {\tau})^{2}}r\left({\tau}, {\chi}\right) - {\left({\Lambda} r\left({\tau}, {\chi}\right)^{2} - 1\right)} \frac{\partial}{\partial {\tau}}r\left({\tau}, {\chi}\right) = 0$

We notice that the left-hand side of this equation is nothing but the partial derivative w.r.t. $\tau$ of the following quantity:

A = (diff(r(t,x),t)^2 + 1 - f(x)^2 - (Lamb/3)*r(t,x)^2) * r(t,x) 
A

$\displaystyle -\frac{1}{3} \, {\left({\Lambda} r\left({\tau}, {\chi}\right)^{2} + 3 \, f\left({\chi}\right)^{2} - 3 \, \frac{\partial}{\partial {\tau}}r\left({\tau}, {\chi}\right)^{2} - 3\right)} r\left({\tau}, {\chi}\right)$

bool(eq3.lhs() == diff(A, t))

$\displaystyle \mathrm{True}$

Hence eq3 tells that $A$ is independent of $\tau$, i.e. is a function of $\chi$ only, which we call $2 m(\chi)$:

m = function('m')
eq4 = A - 2*m(x) == 0
eq4

$\displaystyle -\frac{1}{3} \, {\left({\Lambda} r\left({\tau}, {\chi}\right)^{2} + 3 \, f\left({\chi}\right)^{2} - 3 \, \frac{\partial}{\partial {\tau}}r\left({\tau}, {\chi}\right)^{2} - 3\right)} r\left({\tau}, {\chi}\right) - 2 \, m\left({\chi}\right) = 0$

Let us solve extract $(\partial r/\partial\tau)^2$ from this equation:

drdt2_sol = solve(eq4, diff(r(t,x),t)^2)
drdt2_sol

$\displaystyle \left[\frac{\partial}{\partial {\tau}}r\left({\tau}, {\chi}\right)^{2} = \frac{{\Lambda} r\left({\tau}, {\chi}\right)^{3} + 3 \, f\left({\chi}\right)^{2} r\left({\tau}, {\chi}\right) + 6 \, m\left({\chi}\right) - 3 \, r\left({\tau}, {\chi}\right)}{3 \, r\left({\tau}, {\chi}\right)}\right]$

We thus obtain the second Lemaitre-Tolman equation:

LT2 = drdt2_sol[0].expand()
LT2

$\displaystyle \frac{\partial}{\partial {\tau}}r\left({\tau}, {\chi}\right)^{2} = \frac{1}{3} \, {\Lambda} r\left({\tau}, {\chi}\right)^{2} + f\left({\chi}\right)^{2} + \frac{2 \, m\left({\chi}\right)}{r\left({\tau}, {\chi}\right)} - 1$

drdt2 = LT2.rhs()
drdt2

$\displaystyle \frac{1}{3} \, {\Lambda} r\left({\tau}, {\chi}\right)^{2} + f\left({\chi}\right)^{2} + \frac{2 \, m\left({\chi}\right)}{r\left({\tau}, {\chi}\right)} - 1$

$\tau\tau$ component

The $00 = \tau\tau$ component of Einstein equation is

E[0,0]

$\displaystyle -\frac{8 \, \pi a\left({\tau}, {\chi}\right)^{3} r\left({\tau}, {\chi}\right)^{2} \rho\left({\tau}, {\chi}\right) + {\Lambda} a\left({\tau}, {\chi}\right)^{3} r\left({\tau}, {\chi}\right)^{2} - 2 \, a\left({\tau}, {\chi}\right)^{2} r\left({\tau}, {\chi}\right) \frac{\partial\,a}{\partial {\tau}} \frac{\partial\,r}{\partial {\tau}} - a\left({\tau}, {\chi}\right)^{3} \frac{\partial\,r}{\partial {\tau}}^{2} - a\left({\tau}, {\chi}\right)^{3} - 2 \, r\left({\tau}, {\chi}\right) \frac{\partial\,a}{\partial {\chi}} \frac{\partial\,r}{\partial {\chi}} + a\left({\tau}, {\chi}\right) \frac{\partial\,r}{\partial {\chi}}^{2} + 2 \, a\left({\tau}, {\chi}\right) r\left({\tau}, {\chi}\right) \frac{\partial^2\,r}{\partial {\chi} ^ 2}}{a\left({\tau}, {\chi}\right)^{3} r\left({\tau}, {\chi}\right)^{2}}$

It is equivalent to

eq = (- E[0,0] * a(t,x)^3 * r(t,x)^2).expr() == 0
eq

$\displaystyle 8 \, \pi a\left({\tau}, {\chi}\right)^{3} r\left({\tau}, {\chi}\right)^{2} \rho\left({\tau}, {\chi}\right) + {\Lambda} a\left({\tau}, {\chi}\right)^{3} r\left({\tau}, {\chi}\right)^{2} - 2 \, a\left({\tau}, {\chi}\right)^{2} r\left({\tau}, {\chi}\right) \frac{\partial}{\partial {\tau}}a\left({\tau}, {\chi}\right) \frac{\partial}{\partial {\tau}}r\left({\tau}, {\chi}\right) - a\left({\tau}, {\chi}\right)^{3} \frac{\partial}{\partial {\tau}}r\left({\tau}, {\chi}\right)^{2} - a\left({\tau}, {\chi}\right)^{3} - 2 \, r\left({\tau}, {\chi}\right) \frac{\partial}{\partial {\chi}}a\left({\tau}, {\chi}\right) \frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right) + a\left({\tau}, {\chi}\right) \frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right)^{2} + 2 \, a\left({\tau}, {\chi}\right) r\left({\tau}, {\chi}\right) \frac{\partial^{2}}{(\partial {\chi})^{2}}r\left({\tau}, {\chi}\right) = 0$

As above, we substitute for $a(\tau,\chi)$ the value found when solving the $\tau\chi$ component:

eq1 = eq.substitute_function(a, af)
eq1

$\displaystyle \frac{8 \, \pi r\left({\tau}, {\chi}\right)^{2} \rho\left({\tau}, {\chi}\right) \frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right)^{3}}{f\left({\chi}\right)^{3}} + 2 \, {\left(\frac{\frac{\partial}{\partial {\chi}}f\left({\chi}\right) \frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right)}{f\left({\chi}\right)^{2}} - \frac{\frac{\partial^{2}}{(\partial {\chi})^{2}}r\left({\tau}, {\chi}\right)}{f\left({\chi}\right)}\right)} r\left({\tau}, {\chi}\right) \frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right) + \frac{{\Lambda} r\left({\tau}, {\chi}\right)^{2} \frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right)^{3}}{f\left({\chi}\right)^{3}} - \frac{2 \, r\left({\tau}, {\chi}\right) \frac{\partial}{\partial {\tau}}r\left({\tau}, {\chi}\right) \frac{\partial^{2}}{\partial {\tau}\partial {\chi}}r\left({\tau}, {\chi}\right) \frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right)^{2}}{f\left({\chi}\right)^{3}} + \frac{\frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right)^{3}}{f\left({\chi}\right)} - \frac{\frac{\partial}{\partial {\tau}}r\left({\tau}, {\chi}\right)^{2} \frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right)^{3}}{f\left({\chi}\right)^{3}} + \frac{2 \, r\left({\tau}, {\chi}\right) \frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right) \frac{\partial^{2}}{(\partial {\chi})^{2}}r\left({\tau}, {\chi}\right)}{f\left({\chi}\right)} - \frac{\frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right)^{3}}{f\left({\chi}\right)^{3}} = 0$

eq2 = (eq1 * f(x)^3).simplify_full()
eq2

$\displaystyle 2 \, f\left({\chi}\right) r\left({\tau}, {\chi}\right) \frac{\partial}{\partial {\chi}}f\left({\chi}\right) \frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right)^{2} - 2 \, r\left({\tau}, {\chi}\right) \frac{\partial}{\partial {\tau}}r\left({\tau}, {\chi}\right) \frac{\partial^{2}}{\partial {\tau}\partial {\chi}}r\left({\tau}, {\chi}\right) \frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right)^{2} + f\left({\chi}\right)^{2} \frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right)^{3} + {\left(8 \, \pi r\left({\tau}, {\chi}\right)^{2} \rho\left({\tau}, {\chi}\right) + {\Lambda} r\left({\tau}, {\chi}\right)^{2} - \frac{\partial}{\partial {\tau}}r\left({\tau}, {\chi}\right)^{2} - 1\right)} \frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right)^{3} = 0$

Let us substitute for $\partial r/\partial \tau$ the positive square root of the value of $(\partial r/\partial \tau)^2$ found when solving the $\chi\chi$ component:

drdt = sqrt(drdt2)
drdt

$\displaystyle \sqrt{\frac{1}{3} \, {\Lambda} r\left({\tau}, {\chi}\right)^{2} + f\left({\chi}\right)^{2} + \frac{2 \, m\left({\chi}\right)}{r\left({\tau}, {\chi}\right)} - 1}$

eq3 = eq2.subs({diff(r(t,x),t): drdt, diff(r(t,x),t,x): diff(drdt, x)}).simplify_full()
eq3

$\displaystyle 8 \, \pi r\left({\tau}, {\chi}\right)^{2} \rho\left({\tau}, {\chi}\right) \frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right)^{3} - 2 \, \frac{\partial}{\partial {\chi}}m\left({\chi}\right) \frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right)^{2} = 0$

If we use the negative square root of $(\partial r/\partial \tau)^2$ instead, we get the same result:

drdt = - sqrt(drdt2)
drdt

$\displaystyle -\sqrt{\frac{1}{3} \, {\Lambda} r\left({\tau}, {\chi}\right)^{2} + f\left({\chi}\right)^{2} + \frac{2 \, m\left({\chi}\right)}{r\left({\tau}, {\chi}\right)} - 1}$

eq3_minus = eq2.subs({diff(r(t,x),t): drdt, diff(r(t,x),t,x): diff(drdt, x)}).simplify_full()
eq3_minus

$\displaystyle 8 \, \pi r\left({\tau}, {\chi}\right)^{2} \rho\left({\tau}, {\chi}\right) \frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right)^{3} - 2 \, \frac{\partial}{\partial {\chi}}m\left({\chi}\right) \frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right)^{2} = 0$

eq3_minus == eq3

$\displaystyle \mathrm{True}$

Thus we continue with eq3 and rearrange it to get the third Lemaitre-Tolman equation:

eq4 = (eq3 / (2*diff(r(t,x),x)^2)).simplify_full()
eq4

$\displaystyle 4 \, \pi r\left({\tau}, {\chi}\right)^{2} \rho\left({\tau}, {\chi}\right) \frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right) - \frac{\partial}{\partial {\chi}}m\left({\chi}\right) = 0$

dmdx_sol = solve(eq4, diff(m(x),x))
dmdx_sol

$\displaystyle \left[\frac{\partial}{\partial {\chi}}m\left({\chi}\right) = 4 \, \pi r\left({\tau}, {\chi}\right)^{2} \rho\left({\tau}, {\chi}\right) \frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right)\right]$

LT3 = dmdx_sol[0]
LT3

$\displaystyle \frac{\partial}{\partial {\chi}}m\left({\chi}\right) = 4 \, \pi r\left({\tau}, {\chi}\right)^{2} \rho\left({\tau}, {\chi}\right) \frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right)$

$\theta\theta$ and $\phi\phi$ components

First we notice that the $\theta\theta$ and $\phi\phi$ components of the Einstein equation are equivalent:

E[3,3] == E[2,2] * sin(th)^2

$\displaystyle \mathrm{True}$

Let us thus consider only the $22 = \theta\theta$ component:

E[2,2]

$\displaystyle \frac{{\Lambda} a\left({\tau}, {\chi}\right)^{3} r\left({\tau}, {\chi}\right)^{2} - a\left({\tau}, {\chi}\right)^{2} r\left({\tau}, {\chi}\right)^{2} \frac{\partial^2\,a}{\partial {\tau} ^ 2} - a\left({\tau}, {\chi}\right)^{2} r\left({\tau}, {\chi}\right) \frac{\partial\,a}{\partial {\tau}} \frac{\partial\,r}{\partial {\tau}} - a\left({\tau}, {\chi}\right)^{3} r\left({\tau}, {\chi}\right) \frac{\partial^2\,r}{\partial {\tau} ^ 2} - r\left({\tau}, {\chi}\right) \frac{\partial\,a}{\partial {\chi}} \frac{\partial\,r}{\partial {\chi}} + a\left({\tau}, {\chi}\right) r\left({\tau}, {\chi}\right) \frac{\partial^2\,r}{\partial {\chi} ^ 2}}{a\left({\tau}, {\chi}\right)^{3}}$

It is equivalent to

eq = (- E[2,2] * a(t,x)^3).expr() == 0
eq

$\displaystyle -{\Lambda} a\left({\tau}, {\chi}\right)^{3} r\left({\tau}, {\chi}\right)^{2} + a\left({\tau}, {\chi}\right)^{2} r\left({\tau}, {\chi}\right)^{2} \frac{\partial^{2}}{(\partial {\tau})^{2}}a\left({\tau}, {\chi}\right) + a\left({\tau}, {\chi}\right)^{2} r\left({\tau}, {\chi}\right) \frac{\partial}{\partial {\tau}}a\left({\tau}, {\chi}\right) \frac{\partial}{\partial {\tau}}r\left({\tau}, {\chi}\right) + a\left({\tau}, {\chi}\right)^{3} r\left({\tau}, {\chi}\right) \frac{\partial^{2}}{(\partial {\tau})^{2}}r\left({\tau}, {\chi}\right) + r\left({\tau}, {\chi}\right) \frac{\partial}{\partial {\chi}}a\left({\tau}, {\chi}\right) \frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right) - a\left({\tau}, {\chi}\right) r\left({\tau}, {\chi}\right) \frac{\partial^{2}}{(\partial {\chi})^{2}}r\left({\tau}, {\chi}\right) = 0$

We substitute for $a(\tau,\chi)$ the value found when solving the $\tau\chi$ component:

eq1 = eq.substitute_function(a, af).simplify_full()
eq1

$\displaystyle -\frac{f\left({\chi}\right) r\left({\tau}, {\chi}\right) \frac{\partial}{\partial {\chi}}f\left({\chi}\right) \frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right)^{2} + {\left({\Lambda} r\left({\tau}, {\chi}\right)^{2} - r\left({\tau}, {\chi}\right) \frac{\partial^{2}}{(\partial {\tau})^{2}}r\left({\tau}, {\chi}\right)\right)} \frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right)^{3} - {\left(r\left({\tau}, {\chi}\right)^{2} \frac{\partial^{3}}{(\partial {\tau})^{2}\partial {\chi}}r\left({\tau}, {\chi}\right) + r\left({\tau}, {\chi}\right) \frac{\partial}{\partial {\tau}}r\left({\tau}, {\chi}\right) \frac{\partial^{2}}{\partial {\tau}\partial {\chi}}r\left({\tau}, {\chi}\right)\right)} \frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right)^{2}}{f\left({\chi}\right)^{3}} = 0$

eq2 = (eq1 * f(x)^3).simplify_full()
eq2

$\displaystyle -f\left({\chi}\right) r\left({\tau}, {\chi}\right) \frac{\partial}{\partial {\chi}}f\left({\chi}\right) \frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right)^{2} - {\left({\Lambda} r\left({\tau}, {\chi}\right)^{2} - r\left({\tau}, {\chi}\right) \frac{\partial^{2}}{(\partial {\tau})^{2}}r\left({\tau}, {\chi}\right)\right)} \frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right)^{3} + {\left(r\left({\tau}, {\chi}\right)^{2} \frac{\partial^{3}}{(\partial {\tau})^{2}\partial {\chi}}r\left({\tau}, {\chi}\right) + r\left({\tau}, {\chi}\right) \frac{\partial}{\partial {\tau}}r\left({\tau}, {\chi}\right) \frac{\partial^{2}}{\partial {\tau}\partial {\chi}}r\left({\tau}, {\chi}\right)\right)} \frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right)^{2} = 0$

Then we substitute for $\partial r/\partial\tau$ the value obtained when solving the $\tau\tau$ component:

eq3 = eq2.subs({diff(r(t,x),t,t,x): diff(drdt,t,x), diff(r(t,x),t,t): diff(drdt,t)}).simplify_full()
eq4 = eq3.subs({diff(r(t,x),t): drdt, diff(r(t,x),t,x): diff(drdt,x)}).simplify_full()
eq4

$\displaystyle 0 = 0$

We conclude that the $\theta\theta$ component of Einstein equation does not add any independent equation.

Summary

Let us collect the three independent equations obtained from the Einstein equation, constituting the Lemaître-Tolman system:

for eq in [LT1, LT2, LT3]:
    show(eq)

$\displaystyle a\left({\tau}, {\chi}\right) = \frac{\frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right)}{f\left({\chi}\right)}$

$\displaystyle \frac{\partial}{\partial {\tau}}r\left({\tau}, {\chi}\right)^{2} = \frac{1}{3} \, {\Lambda} r\left({\tau}, {\chi}\right)^{2} + f\left({\chi}\right)^{2} + \frac{2 \, m\left({\chi}\right)}{r\left({\tau}, {\chi}\right)} - 1$

$\displaystyle \frac{\partial}{\partial {\chi}}m\left({\chi}\right) = 4 \, \pi r\left({\tau}, {\chi}\right)^{2} \rho\left({\tau}, {\chi}\right) \frac{\partial}{\partial {\chi}}r\left({\tau}, {\chi}\right)$

The first equation is the unnumbered one just above Eq. (8.1) in Lemaître's article L'univers en expansion, Annales de la Société Scientifique de Bruxelles A 53, 51 (1933), translated in English in Gen. Relativ. Gravit. 29, 641 (1997). The second equation is Eq. (8.2) in Lemaître's article, while the third one is Eq. (8.3).