Parametric Surfaces Solutions.sagews

Solutions: Parametric Exercises

1. The top half of a hemisphere of radius 3.

Easiest is probably to use polar (or something equivalent):

var("r, t")
parametric_plot3d((r*cos(t), r*sin(t), sqrt(9 - r^2)), (r, 0, 3), (t, 0, 2*pi))

(r, t)

3D rendering not yet implemented

But, there's no reason why we couldn't let the $x$-coordinates range between $\pm 3$, while the $y$ coordinates need to go between $\pm \sqrt{9 - x^2}$:

var("u, v")
parametric_plot3d((u, v*sqrt(9-u^2), sqrt(9-u^2-(v^2*(9-u^2)))), (u, -3, 3), (v, -1, 1))

(u, v)

3D rendering not yet implemented

(In short, there are many parametric representations of the same surface.)

2. The surface $z = x + 2 y$ over the region where $0 \leq y \leq x^2$, $0 \leq x \leq 1$. Then see if you can add the sides to make a picture of the region under consideration when computing [ \int_0^1 \int_0^{x^2} x + 2 y , dy , dx ] from section 15.3.

Solution:

var("u, v")
regtop = parametric_plot3d((u, v*u^2, (u + 2*v*u^2)), (u, 0, 1), (v, 0, 1), color="darkgreen")
regfront = parametric_plot3d((1, u, v*(1+2*u)), (u, 0, 1), (v, 0, 1), color="olive")
regleft = parametric_plot3d((u, 0, v*(u+0)), (u, 0, 1), (v, 0, 1), color="olivedrab")
regback = parametric_plot3d((u, u^2, v*(u + 2*u^2)), (u, 0, 1), (v, 0, 1), color="green")
regtop + regfront + regleft + regback

(u, v)

3D rendering not yet implemented

3. The region trapped between $z = x^2 + 3 y^2$ and $z = 8 - x^2 - y^2$, which we found the volume of in section 15.10.

Solution: Start by finding the intersection of these curves. We have [ x^2 + 3 y^2 = 8 - x^2 - y^2 ] which gives the ellipse in the $xy$ plane [ \frac{x^2}{4} + \frac{y^2}{2} = 1 ] We can parametrize these with $x = 2 \cos(\theta)$ and $y = \sqrt{2} \sin(\theta)$, so our top and bottom should look like this:

var("r, t")
solidtop = parametric_plot3d((2*r*cos(t), sqrt(2)*r*sin(t), 8 - (2*r*cos(t))^2 - (sqrt(2)*r*sin(t))^2), (r, 0, 1), (t, 0, 2*pi), color="tan")
solidbot = parametric_plot3d((2*r*cos(t), sqrt(2)*r*sin(t), (2*r*cos(t))^2 +3*(sqrt(2)*r*sin(t))^2), (r, 0, 1), (t, 0, 2*pi), color="coral")
solidtop+solidbot

(r, t)

3D rendering not yet implemented

4. On Test 3, problem 1(c) asked you to find the region being integrated over for [ \int_{x=0}^3 \int_{y=0}^{9-x^2} \int_{z = 0}^{3-x} f(x, y, z) , dz , dy , dx ] (It was choice (G) of the options presented, and is shown below.)

Solution:

var("u, v")
testgtop = parametric_plot3d((u, v*(9-u^2), (3-u)), (u, 0, 3), (v, 0, 1))
testgfront = parametric_plot3d((u, 9-u^2, v*(3-u)), (u, 0, 3), (v, 0, 1), color="teal")
testgback = parametric_plot3d((0, u, v), (u, 0, 9), (v, 0, 3), color="steelblue")  # Of course, you can't see this side on the test...
testgleft = parametric_plot3d((u, 0, v*(3-u)), (u, 0, 3), (v, 0, 1), color="navy") # Or this side either!
testgtop + testgfront + testgback + testgleft

(u, v)

3D rendering not yet implemented

In fact, I've left bottoms off of all of these, but they would not be hard to add if you wished.

︠7335ff35-2832-4317-a0f6-bfd107bbb4e3︠
︠3ab9f9ec-e0ad-4cf6-aec2-e32802ac4b1e︠