Black branes in Lifshitz-like spacetimes

This Jupyter/SageMath worksheet implements some computations of the article

• I. Ya. Aref'eva, A. A. Golubtsova & E. Gourgoulhon: Analytic black branes in Lifshitz-like backgrounds and thermalization, arXiv:1601.06046

These computations are based on SageManifolds (v0.9)

The worksheet file (ipynb format) can be downloaded from here.

Content

1. Five-dimensional Lifschitz-like spacetime
2. Black brane solution

First we set up the notebook to display mathematical objects using LaTeX formatting:

%display latex

1. Five-dimensional Lifshitz-like spacetime

Let us declare the spacetime $M$ as a 5-dimensional manifold:

M = Manifold(5, 'M')
print M

5-dimensional differentiable manifold M

We introduce a first coordinate system on $M$:

X0.<t,x,y1,y2,R> = M.chart(r't x y1:y_1 y2:y_2 R:\tilde{r}:(0,+oo)')
X0

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(M,(t, x, {y_1}, {y_2}, {\tilde{r}})\right)$$

Let us consider the following Lifshitz-symmetric metric, parametrized by some real number $\nu$:

g = M.lorentzian_metric('g')
var('nu', latex_name=r'\nu', domain='real')
g[0,0] = -R^(2*nu)
g[1,1] = R^(2*nu)
g[2,2] = R^2
g[3,3] = R^2
g[4,4] = 1/R^2
g.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}g = -{\tilde{r}}^{2 \, {\nu}} \mathrm{d} t\otimes \mathrm{d} t + {\tilde{r}}^{2 \, {\nu}} \mathrm{d} x\otimes \mathrm{d} x + {\tilde{r}}^{2} \mathrm{d} {y_1}\otimes \mathrm{d} {y_1} + {\tilde{r}}^{2} \mathrm{d} {y_2}\otimes \mathrm{d} {y_2} + \frac{1}{{\tilde{r}}^{2}} \mathrm{d} {\tilde{r}}\otimes \mathrm{d} {\tilde{r}}$$

A matrix view of the metric components:

g[:]

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(\begin{array}{rrrrr} -{\tilde{r}}^{2 \, {\nu}} & 0 & 0 & 0 & 0 \\ 0 & {\tilde{r}}^{2 \, {\nu}} & 0 & 0 & 0 \\ 0 & 0 & {\tilde{r}}^{2} & 0 & 0 \\ 0 & 0 & 0 & {\tilde{r}}^{2} & 0 \\ 0 & 0 & 0 & 0 & \frac{1}{{\tilde{r}}^{2}} \end{array}\right)$$

This metric is invariant under the Lifshitz scaling $$ (t,x,y_1,y_2,\tilde r) \longmapsto \left(\lambda^\nu t, \lambda^\nu x, \lambda y_1, \lambda y_2, \frac{\tilde r}{\lambda} \right)$$

• If $\nu=1$ the scaling is isotropic and we recognize the metric of $\mathrm{AdS}_5$ in Poincaré coordinates ($M$ is then the Poincaré patch of $\mathrm{AdS}_5$)
• If $\nu\not=1$, the scaling is anisotropic

Let us introduce a second coordinate system on $M$:

X.<t,x,y1,y2,r> = M.chart('t x y1:y_1 y2:y_2 r')
X

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(M,(t, x, {y_1}, {y_2}, r)\right)$$

and relate it to the previous one by the transformation $r=\ln\tilde r$:

X0_to_X = X0.transition_map(X, [t, x, y1, y2, ln(R)])
X0_to_X.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left\{\begin{array}{lcl} t & = & t \\ x & = & x \\ {y_1} & = & {y_1} \\ {y_2} & = & {y_2} \\ r & = & \log\left({\tilde{r}}\right) \end{array}\right.$$

The inverse coordinate transition is computed by means of the method inverse():

X_to_X0 = X0_to_X.inverse()
X_to_X0.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left\{\begin{array}{lcl} t & = & t \\ x & = & x \\ {y_1} & = & {y_1} \\ {y_2} & = & {y_2} \\ {\tilde{r}} & = & e^{r} \end{array}\right.$$

At this stage, the manifold's atlas defined by the user is

M.atlas()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left[\left(M,(t, x, {y_1}, {y_2}, {\tilde{r}})\right), \left(M,(t, x, {y_1}, {y_2}, r)\right)\right]$$

and the list of defined vector frames defined is

M.frames()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left[\left(M, \left(\frac{\partial}{\partial t },\frac{\partial}{\partial x },\frac{\partial}{\partial {y_1} },\frac{\partial}{\partial {y_2} },\frac{\partial}{\partial {\tilde{r}} }\right)\right), \left(M, \left(\frac{\partial}{\partial t },\frac{\partial}{\partial x },\frac{\partial}{\partial {y_1} },\frac{\partial}{\partial {y_2} },\frac{\partial}{\partial r }\right)\right)\right]$$

The expression of the metric in terms of the new coordinates is

g.display(X.frame(), X)

$$\newcommand{\Bold}[1]{\mathbf{#1}}g = -e^{\left(2 \, {\nu} r\right)} \mathrm{d} t\otimes \mathrm{d} t + e^{\left(2 \, {\nu} r\right)} \mathrm{d} x\otimes \mathrm{d} x + e^{\left(2 \, r\right)} \mathrm{d} {y_1}\otimes \mathrm{d} {y_1} + e^{\left(2 \, r\right)} \mathrm{d} {y_2}\otimes \mathrm{d} {y_2} +\mathrm{d} r\otimes \mathrm{d} r$$

or, in matrix view:

g[X.frame(),:,X]

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(\begin{array}{rrrrr} -e^{\left(2 \, {\nu} r\right)} & 0 & 0 & 0 & 0 \\ 0 & e^{\left(2 \, {\nu} r\right)} & 0 & 0 & 0 \\ 0 & 0 & e^{\left(2 \, r\right)} & 0 & 0 \\ 0 & 0 & 0 & e^{\left(2 \, r\right)} & 0 \\ 0 & 0 & 0 & 0 & 1 \end{array}\right)$$

To access to a particular component, we have to specify (i) the frame w.r.t. which it is defined and (ii) the coordinates in which the component is expressed:

g[X.frame(),0,0,X]

$$\newcommand{\Bold}[1]{\mathbf{#1}}-e^{\left(2 \, {\nu} r\right)}$$

g[X.frame(),0,0]  # the default chart is used

$$\newcommand{\Bold}[1]{\mathbf{#1}}-{\tilde{r}}^{2 \, {\nu}}$$

From now on, let us consider the coordinates $X = (t,x,y_1,y_2,r)$ as the default ones on the manifold $M$:

M.set_default_chart(X)
M.set_default_frame(X.frame())

Then

g.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}g = -e^{\left(2 \, {\nu} r\right)} \mathrm{d} t\otimes \mathrm{d} t + e^{\left(2 \, {\nu} r\right)} \mathrm{d} x\otimes \mathrm{d} x + e^{\left(2 \, r\right)} \mathrm{d} {y_1}\otimes \mathrm{d} {y_1} + e^{\left(2 \, r\right)} \mathrm{d} {y_2}\otimes \mathrm{d} {y_2} +\mathrm{d} r\otimes \mathrm{d} r$$

g[:]

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(\begin{array}{rrrrr} -e^{\left(2 \, {\nu} r\right)} & 0 & 0 & 0 & 0 \\ 0 & e^{\left(2 \, {\nu} r\right)} & 0 & 0 & 0 \\ 0 & 0 & e^{\left(2 \, r\right)} & 0 & 0 \\ 0 & 0 & 0 & e^{\left(2 \, r\right)} & 0 \\ 0 & 0 & 0 & 0 & 1 \end{array}\right)$$

g[0,0]

$$\newcommand{\Bold}[1]{\mathbf{#1}}-e^{\left(2 \, {\nu} r\right)}$$

g.display_comp()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{lcl} g_{ \, t \, t }^{ \phantom{\, t}\phantom{\, t} } & = & -e^{\left(2 \, {\nu} r\right)} \\ g_{ \, x \, x }^{ \phantom{\, x}\phantom{\, x} } & = & e^{\left(2 \, {\nu} r\right)} \\ g_{ \, {y_1} \, {y_1} }^{ \phantom{\, {y_1}}\phantom{\, {y_1}} } & = & e^{\left(2 \, r\right)} \\ g_{ \, {y_2} \, {y_2} }^{ \phantom{\, {y_2}}\phantom{\, {y_2}} } & = & e^{\left(2 \, r\right)} \\ g_{ \, r \, r }^{ \phantom{\, r}\phantom{\, r} } & = & 1 \end{array}$$

Curvature

The Riemann tensor is

Riem = g.riemann()
print Riem

Tensor field Riem(g) of type (1,3) on the 5-dimensional differentiable manifold M

Riem.display_comp(only_nonredundant=True)

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{lcl} \mathrm{Riem}\left(g\right)_{ \phantom{\, t} \, x \, t \, x }^{ \, t \phantom{\, x} \phantom{\, t} \phantom{\, x} } & = & -{\nu}^{2} e^{\left(2 \, {\nu} r\right)} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, t} \, {y_1} \, t \, {y_1} }^{ \, t \phantom{\, {y_1}} \phantom{\, t} \phantom{\, {y_1}} } & = & -{\nu} e^{\left(2 \, r\right)} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, t} \, {y_2} \, t \, {y_2} }^{ \, t \phantom{\, {y_2}} \phantom{\, t} \phantom{\, {y_2}} } & = & -{\nu} e^{\left(2 \, r\right)} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, t} \, r \, t \, r }^{ \, t \phantom{\, r} \phantom{\, t} \phantom{\, r} } & = & -{\nu}^{2} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, x} \, t \, t \, x }^{ \, x \phantom{\, t} \phantom{\, t} \phantom{\, x} } & = & -{\nu}^{2} e^{\left(2 \, {\nu} r\right)} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, x} \, {y_1} \, x \, {y_1} }^{ \, x \phantom{\, {y_1}} \phantom{\, x} \phantom{\, {y_1}} } & = & -{\nu} e^{\left(2 \, r\right)} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, x} \, {y_2} \, x \, {y_2} }^{ \, x \phantom{\, {y_2}} \phantom{\, x} \phantom{\, {y_2}} } & = & -{\nu} e^{\left(2 \, r\right)} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, x} \, r \, x \, r }^{ \, x \phantom{\, r} \phantom{\, x} \phantom{\, r} } & = & -{\nu}^{2} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, {y_1}} \, t \, t \, {y_1} }^{ \, {y_1} \phantom{\, t} \phantom{\, t} \phantom{\, {y_1}} } & = & -{\nu} e^{\left(2 \, {\nu} r\right)} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, {y_1}} \, x \, x \, {y_1} }^{ \, {y_1} \phantom{\, x} \phantom{\, x} \phantom{\, {y_1}} } & = & {\nu} e^{\left(2 \, {\nu} r\right)} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, {y_1}} \, {y_2} \, {y_1} \, {y_2} }^{ \, {y_1} \phantom{\, {y_2}} \phantom{\, {y_1}} \phantom{\, {y_2}} } & = & -e^{\left(2 \, r\right)} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, {y_1}} \, r \, {y_1} \, r }^{ \, {y_1} \phantom{\, r} \phantom{\, {y_1}} \phantom{\, r} } & = & -1 \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, {y_2}} \, t \, t \, {y_2} }^{ \, {y_2} \phantom{\, t} \phantom{\, t} \phantom{\, {y_2}} } & = & -{\nu} e^{\left(2 \, {\nu} r\right)} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, {y_2}} \, x \, x \, {y_2} }^{ \, {y_2} \phantom{\, x} \phantom{\, x} \phantom{\, {y_2}} } & = & {\nu} e^{\left(2 \, {\nu} r\right)} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, {y_2}} \, {y_1} \, {y_1} \, {y_2} }^{ \, {y_2} \phantom{\, {y_1}} \phantom{\, {y_1}} \phantom{\, {y_2}} } & = & e^{\left(2 \, r\right)} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, {y_2}} \, r \, {y_2} \, r }^{ \, {y_2} \phantom{\, r} \phantom{\, {y_2}} \phantom{\, r} } & = & -1 \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, r} \, t \, t \, r }^{ \, r \phantom{\, t} \phantom{\, t} \phantom{\, r} } & = & -{\nu}^{2} e^{\left(2 \, {\nu} r\right)} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, r} \, x \, x \, r }^{ \, r \phantom{\, x} \phantom{\, x} \phantom{\, r} } & = & {\nu}^{2} e^{\left(2 \, {\nu} r\right)} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, r} \, {y_1} \, {y_1} \, r }^{ \, r \phantom{\, {y_1}} \phantom{\, {y_1}} \phantom{\, r} } & = & e^{\left(2 \, r\right)} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, r} \, {y_2} \, {y_2} \, r }^{ \, r \phantom{\, {y_2}} \phantom{\, {y_2}} \phantom{\, r} } & = & e^{\left(2 \, r\right)} \end{array}$$

The Ricci tensor:

Ric = g.ricci()
print Ric

Field of symmetric bilinear forms Ric(g) on the 5-dimensional differentiable manifold M

Ric.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{Ric}\left(g\right) = 2 \, {\left({\nu}^{2} + {\nu}\right)} e^{\left(2 \, {\nu} r\right)} \mathrm{d} t\otimes \mathrm{d} t -2 \, {\left({\nu}^{2} + {\nu}\right)} e^{\left(2 \, {\nu} r\right)} \mathrm{d} x\otimes \mathrm{d} x -2 \, {\left({\nu} + 1\right)} e^{\left(2 \, r\right)} \mathrm{d} {y_1}\otimes \mathrm{d} {y_1} -2 \, {\left({\nu} + 1\right)} e^{\left(2 \, r\right)} \mathrm{d} {y_2}\otimes \mathrm{d} {y_2} + \left( -2 \, {\nu}^{2} - 2 \right) \mathrm{d} r\otimes \mathrm{d} r$$

Ric.display_comp()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{lcl} \mathrm{Ric}\left(g\right)_{ \, t \, t }^{ \phantom{\, t}\phantom{\, t} } & = & 2 \, {\left({\nu}^{2} + {\nu}\right)} e^{\left(2 \, {\nu} r\right)} \\ \mathrm{Ric}\left(g\right)_{ \, x \, x }^{ \phantom{\, x}\phantom{\, x} } & = & -2 \, {\left({\nu}^{2} + {\nu}\right)} e^{\left(2 \, {\nu} r\right)} \\ \mathrm{Ric}\left(g\right)_{ \, {y_1} \, {y_1} }^{ \phantom{\, {y_1}}\phantom{\, {y_1}} } & = & -2 \, {\left({\nu} + 1\right)} e^{\left(2 \, r\right)} \\ \mathrm{Ric}\left(g\right)_{ \, {y_2} \, {y_2} }^{ \phantom{\, {y_2}}\phantom{\, {y_2}} } & = & -2 \, {\left({\nu} + 1\right)} e^{\left(2 \, r\right)} \\ \mathrm{Ric}\left(g\right)_{ \, r \, r }^{ \phantom{\, r}\phantom{\, r} } & = & -2 \, {\nu}^{2} - 2 \end{array}$$

The Ricci scalar:

Rscal = g.ricci_scalar()
print Rscal

Scalar field r(g) on the 5-dimensional differentiable manifold M

Rscal.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} \mathrm{r}\left(g\right):& M & \longrightarrow & \mathbb{R} \\ & \left(t, x, {y_1}, {y_2}, {\tilde{r}}\right) & \longmapsto & -6 \, {\nu}^{2} - 8 \, {\nu} - 6 \\ & \left(t, x, {y_1}, {y_2}, r\right) & \longmapsto & -6 \, {\nu}^{2} - 8 \, {\nu} - 6 \end{array}$$

We note that the Ricci scalar is constant.

Source model

Let us consider a model based on the following action, involving a dilaton scalar field $\phi$ and a Maxwell 2-form $F$:

$$ S = \int \left( R(g) + \Lambda - \frac{1}{2} \nabla_m \phi \nabla^m \phi - \frac{1}{4} e^{\lambda\phi} F_{mn} F^{mn} \right) \sqrt{-g} \, \mathrm{d}^5 x \qquad\qquad \mbox{(1)}$$

where $R(g)$ is the Ricci scalar of metric $g$, $\Lambda$ is the cosmological constant and $\lambda$ is the dilatonic coupling constant.

The dilaton scalar field

We consider the following ansatz for the dilaton scalar field $\phi$: $$ \phi = \frac{1}{\lambda} \left( 4 r + \ln\mu \right),$$ where $\mu$ is a constant.

var('mu', latex_name=r'\mu', domain='real')
var('lamb', latex_name=r'\lambda', domain='real')
phi = M.scalar_field({X: (4*r + ln(mu))/lamb}, 
                     name='phi', latex_name=r'\phi')
phi.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} \phi:& M & \longrightarrow & \mathbb{R} \\ & \left(t, x, {y_1}, {y_2}, {\tilde{r}}\right) & \longmapsto & \frac{4 \, \log\left({\tilde{r}}\right) + \log\left({\mu}\right)}{{\lambda}} \\ & \left(t, x, {y_1}, {y_2}, r\right) & \longmapsto & \frac{4 \, r + \log\left({\mu}\right)}{{\lambda}} \end{array}$$

The 1-form $\mathrm{d}\phi$ is

dphi = phi.differential()
print dphi

1-form dphi on the 5-dimensional differentiable manifold M

dphi.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{d}\phi = \frac{4}{{\lambda}} \mathrm{d} r$$

dphi[:]  # all the components in the default frame

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left[0, 0, 0, 0, \frac{4}{{\lambda}}\right]$$

The 2-form field

We consider the following ansatz for $F$: $$ F = \frac{1}{2} q \, \mathrm{d}y_1\wedge \mathrm{d}y_2, $$ where $q$ is a constant.

Let us first get the 1-forms $\mathrm{d}y_1$ and $\mathrm{d}y_2$:

X.coframe()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(M, \left(\mathrm{d} t,\mathrm{d} x,\mathrm{d} {y_1},\mathrm{d} {y_2},\mathrm{d} r\right)\right)$$

dy1 = X.coframe()[2]
dy2 = X.coframe()[3]
print dy1
print dy2
dy1, dy2

1-form dy1 on the 5-dimensional differentiable manifold M
1-form dy2 on the 5-dimensional differentiable manifold M

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(\mathrm{d} {y_1}, \mathrm{d} {y_2}\right)$$

Then we can form $F$ according to the above ansatz:

var('q', domain='real')
F = q/2 * dy1.wedge(dy2)
F.set_name('F')
print F
F.display()

2-form F on the 5-dimensional differentiable manifold M

$$\newcommand{\Bold}[1]{\mathbf{#1}}F = \frac{1}{2} \, q \mathrm{d} {y_1}\wedge \mathrm{d} {y_2}$$

By construction, the 2-form $F$ is closed (since $q$ is constant):

print(F.exterior_derivative())

3-form dF on the 5-dimensional differentiable manifold M

F.exterior_derivative().display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{d}F = 0$$

Let us evaluate the square $F_{mn} F^{mn}$ of $F$:

Fu = F.up(g)
print Fu
Fu.display()

Tensor field of type (2,0) on the 5-dimensional differentiable manifold M

$$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{2} \, q e^{\left(-4 \, r\right)} \frac{\partial}{\partial {y_1} }\otimes \frac{\partial}{\partial {y_2} } -\frac{1}{2} \, q e^{\left(-4 \, r\right)} \frac{\partial}{\partial {y_2} }\otimes \frac{\partial}{\partial {y_1} }$$

F2 = F['_{mn}']*Fu['^{mn}']  # using LaTeX notations to denote contraction
print F2
F2.display()

Scalar field on the 5-dimensional differentiable manifold M

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} & M & \longrightarrow & \mathbb{R} \\ & \left(t, x, {y_1}, {y_2}, {\tilde{r}}\right) & \longmapsto & \frac{q^{2}}{2 \, {\tilde{r}}^{4}} \\ & \left(t, x, {y_1}, {y_2}, r\right) & \longmapsto & \frac{1}{2} \, q^{2} e^{\left(-4 \, r\right)} \end{array}$$

We shall also need the tensor $\mathcal{F}_{mn} := F_{mp} F_n^{\ \, p}$:

FF = F['_mp'] * F.up(g,1)['^p_n']
print FF
FF.display()

Tensor field of type (0,2) on the 5-dimensional differentiable manifold M

$$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{4} \, q^{2} e^{\left(-2 \, r\right)} \mathrm{d} {y_1}\otimes \mathrm{d} {y_1} + \frac{1}{4} \, q^{2} e^{\left(-2 \, r\right)} \mathrm{d} {y_2}\otimes \mathrm{d} {y_2}$$

The tensor field $\mathcal{F}$ is symmetric:

FF == FF.symmetrize()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{True}$$

Therefore, from now on, we set

FF = FF.symmetrize()

Einstein equation

Let us first introduce the cosmological constant:

var('Lamb', latex_name=r'\Lambda', domain='real')

$$\newcommand{\Bold}[1]{\mathbf{#1}}{\Lambda}$$

From the action (1), the field equation for the metric $g$ is $$ R_{mn} + \frac{\Lambda}{3} \, g - \frac{1}{2}\partial_m\phi \partial_n\phi -\frac{1}{2} e^{\lambda\phi} F_{mp} F^{\ \, p}_n + \frac{1}{12} e^{\lambda\phi} F_{rs} F^{rs} \, g_{mn} = 0 $$ We write it as

EE == 0

with EE defined by

EE = Ric + Lamb/3*g - 1/2* (dphi*dphi) -  1/2*exp(lamb*phi)*FF \
     + 1/12*exp(lamb*phi)*F2*g
EE.set_name('E')
print EE

Field of symmetric bilinear forms E on the 5-dimensional differentiable manifold M

EE.display_comp(only_nonredundant=True)

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{lcl} E_{ \, t \, t }^{ \phantom{\, t}\phantom{\, t} } & = & -\frac{1}{24} \, {\left({\mu} q^{2} - 48 \, {\nu}^{2} + 8 \, {\Lambda} - 48 \, {\nu}\right)} e^{\left(2 \, {\nu} r\right)} \\ E_{ \, x \, x }^{ \phantom{\, x}\phantom{\, x} } & = & \frac{1}{24} \, {\left({\mu} q^{2} - 48 \, {\nu}^{2} + 8 \, {\Lambda} - 48 \, {\nu}\right)} e^{\left(2 \, {\nu} r\right)} \\ E_{ \, {y_1} \, {y_1} }^{ \phantom{\, {y_1}}\phantom{\, {y_1}} } & = & -\frac{1}{12} \, {\left({\mu} q^{2} - 4 \, {\Lambda} + 24 \, {\nu} + 24\right)} e^{\left(2 \, r\right)} \\ E_{ \, {y_2} \, {y_2} }^{ \phantom{\, {y_2}}\phantom{\, {y_2}} } & = & -\frac{1}{12} \, {\left({\mu} q^{2} - 4 \, {\Lambda} + 24 \, {\nu} + 24\right)} e^{\left(2 \, r\right)} \\ E_{ \, r \, r }^{ \phantom{\, r}\phantom{\, r} } & = & \frac{{\lambda}^{2} {\mu} q^{2} - 48 \, {\lambda}^{2} {\nu}^{2} + 8 \, {\left({\Lambda} - 6\right)} {\lambda}^{2} - 192}{24 \, {\lambda}^{2}} \end{array}$$

We note that EE==0 leads to only 3 independent equations:

eq1 = (EE[0,0]/exp(2*nu*r)).expr()
eq1

$$\newcommand{\Bold}[1]{\mathbf{#1}}-\frac{1}{24} \, {\mu} q^{2} + 2 \, {\nu}^{2} - \frac{1}{3} \, {\Lambda} + 2 \, {\nu}$$

eq2 = (EE[2,2]/exp(2*r)).expr()
eq2

$$\newcommand{\Bold}[1]{\mathbf{#1}}-\frac{1}{12} \, {\mu} q^{2} + \frac{1}{3} \, {\Lambda} - 2 \, {\nu} - 2$$

eq3 = EE[4,4].expr().expand()
eq3

$$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{24} \, {\mu} q^{2} - 2 \, {\nu}^{2} + \frac{1}{3} \, {\Lambda} - \frac{8}{{\lambda}^{2}} - 2$$

Dilaton field equation

First we evaluate $\nabla_m \nabla^m \phi$:

nab = g.connection()
print nab
nab

Levi-Civita connection nabla_g associated with the Lorentzian metric g on the 5-dimensional differentiable manifold M

$$\newcommand{\Bold}[1]{\mathbf{#1}}\nabla_{g}$$

box_phi = nab(nab(phi).up(g)).trace()
print box_phi
box_phi.display()

Scalar field on the 5-dimensional differentiable manifold M

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} & M & \longrightarrow & \mathbb{R} \\ & \left(t, x, {y_1}, {y_2}, {\tilde{r}}\right) & \longmapsto & \frac{8 \, {\left({\nu} + 1\right)}}{{\lambda}} \\ & \left(t, x, {y_1}, {y_2}, r\right) & \longmapsto & \frac{8 \, {\left({\nu} + 1\right)}}{{\lambda}} \end{array}$$

From the action (1), the field equation for $\phi$ is $$ \nabla_m \nabla^m \phi = \frac{\lambda}{4} e^{\lambda\phi} F_{mn} F^{mn}$$ We write it as

DE == 0

with DE defined by

DE = box_phi - lamb/4*exp(lamb*phi) * F2
print DE

Scalar field on the 5-dimensional differentiable manifold M

DE.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} & M & \longrightarrow & \mathbb{R} \\ & \left(t, x, {y_1}, {y_2}, {\tilde{r}}\right) & \longmapsto & -\frac{{\lambda}^{2} {\mu} q^{2} - 64 \, {\nu} - 64}{8 \, {\lambda}} \\ & \left(t, x, {y_1}, {y_2}, r\right) & \longmapsto & -\frac{{\lambda}^{2} {\mu} q^{2} - 64 \, {\nu} - 64}{8 \, {\lambda}} \end{array}$$

Hence the dilaton field equation provides a fourth equation:

eq4 = DE.expr().expand()
eq4

$$\newcommand{\Bold}[1]{\mathbf{#1}}-\frac{1}{8} \, {\lambda} {\mu} q^{2} + \frac{8 \, {\nu}}{{\lambda}} + \frac{8}{{\lambda}}$$

Maxwell equation

From the action (1), the field equation for $F$ is $$ \nabla_m \left( e^{\lambda\phi} F^{mn} \right)= 0 $$ We write it as

ME == 0

with ME defined by

ME = nab(exp(lamb*phi)*Fu).trace(0,2)
print ME
ME.display()

Vector field on the 5-dimensional differentiable manifold M

$$\newcommand{\Bold}[1]{\mathbf{#1}}0$$

We get identically zero; indeed the tensor $\nabla_p (e^{\lambda\phi} F^{mn})$ has a vanishing trace, as we can check:

nab(exp(lamb*phi)*Fu).display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}{\mu} q \frac{\partial}{\partial {y_1} }\otimes \frac{\partial}{\partial {y_2} }\otimes \mathrm{d} r -\frac{1}{2} \, {\mu} q e^{\left(2 \, r\right)} \frac{\partial}{\partial {y_1} }\otimes \frac{\partial}{\partial r }\otimes \mathrm{d} {y_2} -{\mu} q \frac{\partial}{\partial {y_2} }\otimes \frac{\partial}{\partial {y_1} }\otimes \mathrm{d} r + \frac{1}{2} \, {\mu} q e^{\left(2 \, r\right)} \frac{\partial}{\partial {y_2} }\otimes \frac{\partial}{\partial r }\otimes \mathrm{d} {y_1} + \frac{1}{2} \, {\mu} q e^{\left(2 \, r\right)} \frac{\partial}{\partial r }\otimes \frac{\partial}{\partial {y_1} }\otimes \mathrm{d} {y_2} -\frac{1}{2} \, {\mu} q e^{\left(2 \, r\right)} \frac{\partial}{\partial r }\otimes \frac{\partial}{\partial {y_2} }\otimes \mathrm{d} {y_1}$$

Summary

We have 4 equations involving the constants $\lambda$, $\mu$, $\nu$, $q$ and $\Lambda$:

eq1 == 0

$$\newcommand{\Bold}[1]{\mathbf{#1}}-\frac{1}{24} \, {\mu} q^{2} + 2 \, {\nu}^{2} - \frac{1}{3} \, {\Lambda} + 2 \, {\nu} = 0$$

eq2 == 0

$$\newcommand{\Bold}[1]{\mathbf{#1}}-\frac{1}{12} \, {\mu} q^{2} + \frac{1}{3} \, {\Lambda} - 2 \, {\nu} - 2 = 0$$

eq3 == 0

$$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{24} \, {\mu} q^{2} - 2 \, {\nu}^{2} + \frac{1}{3} \, {\Lambda} - \frac{8}{{\lambda}^{2}} - 2 = 0$$

eq4 == 0

$$\newcommand{\Bold}[1]{\mathbf{#1}}-\frac{1}{8} \, {\lambda} {\mu} q^{2} + \frac{8 \, {\nu}}{{\lambda}} + \frac{8}{{\lambda}} = 0$$

Solution for $\nu=1$ ($\mathrm{AdS}_5$)

eqs = [eq1, eq2, eq3, eq4]
neqs = [eq.subs(nu=1) for eq in eqs]

[eq == 0 for eq in neqs]

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left[-\frac{1}{24} \, {\mu} q^{2} - \frac{1}{3} \, {\Lambda} + 4 = 0, -\frac{1}{12} \, {\mu} q^{2} + \frac{1}{3} \, {\Lambda} - 4 = 0, \frac{1}{24} \, {\mu} q^{2} + \frac{1}{3} \, {\Lambda} - \frac{8}{{\lambda}^{2}} - 4 = 0, -\frac{1}{8} \, {\lambda} {\mu} q^{2} + \frac{16}{{\lambda}} = 0\right]$$

solve([eq == 0 for eq in neqs], lamb, mu, Lamb, q)

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left[\right]$$

Hence there is no solution for $\mathrm{AdS}_5$ with the above ansatz.

Solution for $\nu = 2$

neqs = [eq.subs(nu=2) for eq in eqs]
[eq == 0 for eq in neqs]

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left[-\frac{1}{24} \, {\mu} q^{2} - \frac{1}{3} \, {\Lambda} + 12 = 0, -\frac{1}{12} \, {\mu} q^{2} + \frac{1}{3} \, {\Lambda} - 6 = 0, \frac{1}{24} \, {\mu} q^{2} + \frac{1}{3} \, {\Lambda} - \frac{8}{{\lambda}^{2}} - 10 = 0, -\frac{1}{8} \, {\lambda} {\mu} q^{2} + \frac{24}{{\lambda}} = 0\right]$$

solve([eq == 0 for eq in neqs], lamb, mu, Lamb, q)

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left[\left[{\lambda} = 2, {\mu} = \frac{48}{r_{1}^{2}}, {\Lambda} = 30, q = r_{1}\right], \left[{\lambda} = \left(-2\right), {\mu} = \frac{48}{r_{2}^{2}}, {\Lambda} = 30, q = r_{2}\right]\right]$$

Hence there are two families of solutions, each famility being parametrized by e.g. $q$. Indeed, in the above writing, $r_1$ and $r_2$ stand for arbitrary parameters (nothing to do with the coordinate $r$).

Solution for $\nu = 4$

neqs = [eq.subs(nu=4) for eq in eqs]
[eq == 0 for eq in neqs]

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left[-\frac{1}{24} \, {\mu} q^{2} - \frac{1}{3} \, {\Lambda} + 40 = 0, -\frac{1}{12} \, {\mu} q^{2} + \frac{1}{3} \, {\Lambda} - 10 = 0, \frac{1}{24} \, {\mu} q^{2} + \frac{1}{3} \, {\Lambda} - \frac{8}{{\lambda}^{2}} - 34 = 0, -\frac{1}{8} \, {\lambda} {\mu} q^{2} + \frac{40}{{\lambda}} = 0\right]$$

solve([eq == 0 for eq in neqs], lamb, mu, Lamb, q)

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left[\left[{\lambda} = \frac{2}{3} \, \sqrt{3}, {\mu} = \frac{240}{r_{3}^{2}}, {\Lambda} = 90, q = r_{3}\right], \left[{\lambda} = -\frac{2}{3} \, \sqrt{3}, {\mu} = \frac{240}{r_{4}^{2}}, {\Lambda} = 90, q = r_{4}\right]\right]$$

Hence there are two families of solutions, each family being parametrized by e.g. $q$. Note that, as above, $r_i$, with $i$ an integer, stands for an arbitrary parameter (nothing to do with the coordinate $r$).

2. Black brane solution

We add a blackening factor $f(r)$ to the metric; i.e. we declare a new metric $g$ according to

g = M.lorentzian_metric('g')
ff = function('f')(r)
g[0,0] = -ff*exp(2*nu*r)
g[1,1] = exp(2*nu*r)
g[2,2] = exp(2*r)
g[3,3] = exp(2*r)
g[4,4] = 1/ff
g.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}g = -e^{\left(2 \, {\nu} r\right)} f\left(r\right) \mathrm{d} t\otimes \mathrm{d} t + e^{\left(2 \, {\nu} r\right)} \mathrm{d} x\otimes \mathrm{d} x + e^{\left(2 \, r\right)} \mathrm{d} {y_1}\otimes \mathrm{d} {y_1} + e^{\left(2 \, r\right)} \mathrm{d} {y_2}\otimes \mathrm{d} {y_2} + \frac{1}{f\left(r\right)} \mathrm{d} r\otimes \mathrm{d} r$$

The Ricci tensor of $g$ is

Ric = g.ricci()
print Ric

Field of symmetric bilinear forms Ric(g) on the 5-dimensional differentiable manifold M

Ric.display_comp()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{lcl} \mathrm{Ric}\left(g\right)_{ \, t \, t }^{ \phantom{\, t}\phantom{\, t} } & = & 2 \, {\left({\nu}^{2} + {\nu}\right)} e^{\left(2 \, {\nu} r\right)} f\left(r\right)^{2} + {\left(2 \, {\nu} + 1\right)} e^{\left(2 \, {\nu} r\right)} f\left(r\right) \frac{\partial\,f}{\partial r} + \frac{1}{2} \, e^{\left(2 \, {\nu} r\right)} f\left(r\right) \frac{\partial^2\,f}{\partial r ^ 2} \\ \mathrm{Ric}\left(g\right)_{ \, x \, x }^{ \phantom{\, x}\phantom{\, x} } & = & -2 \, {\left({\nu}^{2} + {\nu}\right)} e^{\left(2 \, {\nu} r\right)} f\left(r\right) - {\nu} e^{\left(2 \, {\nu} r\right)} \frac{\partial\,f}{\partial r} \\ \mathrm{Ric}\left(g\right)_{ \, {y_1} \, {y_1} }^{ \phantom{\, {y_1}}\phantom{\, {y_1}} } & = & -2 \, {\left({\nu} + 1\right)} e^{\left(2 \, r\right)} f\left(r\right) - e^{\left(2 \, r\right)} \frac{\partial\,f}{\partial r} \\ \mathrm{Ric}\left(g\right)_{ \, {y_2} \, {y_2} }^{ \phantom{\, {y_2}}\phantom{\, {y_2}} } & = & -2 \, {\left({\nu} + 1\right)} e^{\left(2 \, r\right)} f\left(r\right) - e^{\left(2 \, r\right)} \frac{\partial\,f}{\partial r} \\ \mathrm{Ric}\left(g\right)_{ \, r \, r }^{ \phantom{\, r}\phantom{\, r} } & = & -\frac{4 \, {\left({\nu}^{2} + 1\right)} f\left(r\right) + 2 \, {\left(2 \, {\nu} + 1\right)} \frac{\partial\,f}{\partial r} + \frac{\partial^2\,f}{\partial r ^ 2}}{2 \, f\left(r\right)} \end{array}$$

By construction, the 2-form $F$ does not depend on $g$; hence there is no need to reevaluate it:

F.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}F = \frac{1}{2} \, q \mathrm{d} {y_1}\wedge \mathrm{d} {y_2}$$

On the contrary, we need to reevaluate its metric dual, in order to compute $F^2 := F_{mn} F^{mn}$:

Fu = F.up(g)
print Fu
Fu.display()

Tensor field of type (2,0) on the 5-dimensional differentiable manifold M

$$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{2} \, q e^{\left(-4 \, r\right)} \frac{\partial}{\partial {y_1} }\otimes \frac{\partial}{\partial {y_2} } -\frac{1}{2} \, q e^{\left(-4 \, r\right)} \frac{\partial}{\partial {y_2} }\otimes \frac{\partial}{\partial {y_1} }$$

F2 = F['_{mn}']*Fu['^{mn}']  # using LaTeX notations to denote contraction
print F2
F2.display()

Scalar field on the 5-dimensional differentiable manifold M

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} & M & \longrightarrow & \mathbb{R} \\ & \left(t, x, {y_1}, {y_2}, {\tilde{r}}\right) & \longmapsto & \frac{q^{2}}{2 \, {\tilde{r}}^{4}} \\ & \left(t, x, {y_1}, {y_2}, r\right) & \longmapsto & \frac{1}{2} \, q^{2} e^{\left(-4 \, r\right)} \end{array}$$

Simlarly, we need to reevaluate $\mathcal{F}_{mn} := F_{mp} F_n^{\ \, p}$:

FF = F['_mp'] * F.up(g,1)['^p_n']
print FF
FF.display()

Tensor field of type (0,2) on the 5-dimensional differentiable manifold M

$$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{4} \, q^{2} e^{\left(-2 \, r\right)} \mathrm{d} {y_1}\otimes \mathrm{d} {y_1} + \frac{1}{4} \, q^{2} e^{\left(-2 \, r\right)} \mathrm{d} {y_2}\otimes \mathrm{d} {y_2}$$

FF == FF.symmetrize()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{True}$$

FF = FF.symmetrize()

The new Einstein equation is

EE = Ric + Lamb/3*g - 1/2* (dphi*dphi) -  1/2*exp(lamb*phi)*FF \
     + 1/12*exp(lamb*phi)*F2*g
EE.set_name('E')
print EE

Field of symmetric bilinear forms E on the 5-dimensional differentiable manifold M

EE.display_comp(only_nonredundant=True)

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{lcl} E_{ \, t \, t }^{ \phantom{\, t}\phantom{\, t} } & = & 2 \, {\left({\nu}^{2} + {\nu}\right)} e^{\left(2 \, {\nu} r\right)} f\left(r\right)^{2} + {\left(2 \, {\nu} + 1\right)} e^{\left(2 \, {\nu} r\right)} f\left(r\right) \frac{\partial\,f}{\partial r} - \frac{1}{24} \, {\left({\mu} q^{2} + 8 \, {\Lambda}\right)} e^{\left(2 \, {\nu} r\right)} f\left(r\right) + \frac{1}{2} \, e^{\left(2 \, {\nu} r\right)} f\left(r\right) \frac{\partial^2\,f}{\partial r ^ 2} \\ E_{ \, x \, x }^{ \phantom{\, x}\phantom{\, x} } & = & -2 \, {\left({\nu}^{2} + {\nu}\right)} e^{\left(2 \, {\nu} r\right)} f\left(r\right) - {\nu} e^{\left(2 \, {\nu} r\right)} \frac{\partial\,f}{\partial r} + \frac{1}{24} \, {\left({\mu} q^{2} + 8 \, {\Lambda}\right)} e^{\left(2 \, {\nu} r\right)} \\ E_{ \, {y_1} \, {y_1} }^{ \phantom{\, {y_1}}\phantom{\, {y_1}} } & = & -2 \, {\left({\nu} + 1\right)} e^{\left(2 \, r\right)} f\left(r\right) - \frac{1}{12} \, {\left({\mu} q^{2} - 4 \, {\Lambda}\right)} e^{\left(2 \, r\right)} - e^{\left(2 \, r\right)} \frac{\partial\,f}{\partial r} \\ E_{ \, {y_2} \, {y_2} }^{ \phantom{\, {y_2}}\phantom{\, {y_2}} } & = & -2 \, {\left({\nu} + 1\right)} e^{\left(2 \, r\right)} f\left(r\right) - \frac{1}{12} \, {\left({\mu} q^{2} - 4 \, {\Lambda}\right)} e^{\left(2 \, r\right)} - e^{\left(2 \, r\right)} \frac{\partial\,f}{\partial r} \\ E_{ \, r \, r }^{ \phantom{\, r}\phantom{\, r} } & = & \frac{{\lambda}^{2} {\mu} q^{2} + 8 \, {\Lambda} {\lambda}^{2} - 12 \, {\lambda}^{2} \frac{\partial^2\,f}{\partial r ^ 2} - 48 \, {\left({\lambda}^{2} {\nu}^{2} + {\lambda}^{2} + 4\right)} f\left(r\right) - 24 \, {\left(2 \, {\lambda}^{2} {\nu} + {\lambda}^{2}\right)} \frac{\partial\,f}{\partial r}}{24 \, {\lambda}^{2} f\left(r\right)} \end{array}$$

EE[2,2] == EE[3,3]

$$\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{True}$$

There are 4 independent components:

eq0 = EE[0,0]/exp(2*nu*r)
eq0

$$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{24} \, {\left(48 \, {\left({\nu}^{2} + {\nu}\right)} e^{\left(2 \, {\nu} r\right)} f\left(r\right)^{2} + 24 \, {\left(2 \, {\nu} + 1\right)} e^{\left(2 \, {\nu} r\right)} f\left(r\right) \frac{\partial\,f}{\partial r} - {\left({\mu} q^{2} + 8 \, {\Lambda}\right)} e^{\left(2 \, {\nu} r\right)} f\left(r\right) + 12 \, e^{\left(2 \, {\nu} r\right)} f\left(r\right) \frac{\partial^2\,f}{\partial r ^ 2}\right)} e^{\left(-2 \, {\nu} r\right)}$$

eq1 = EE[1,1]/exp(2*nu*r)
eq1

$$\newcommand{\Bold}[1]{\mathbf{#1}}-\frac{1}{24} \, {\left(48 \, {\left({\nu}^{2} + {\nu}\right)} e^{\left(2 \, {\nu} r\right)} f\left(r\right) + 24 \, {\nu} e^{\left(2 \, {\nu} r\right)} \frac{\partial\,f}{\partial r} - {\left({\mu} q^{2} + 8 \, {\Lambda}\right)} e^{\left(2 \, {\nu} r\right)}\right)} e^{\left(-2 \, {\nu} r\right)}$$

eq2 = EE[2,2]/exp(2*r)
eq2

$$\newcommand{\Bold}[1]{\mathbf{#1}}-\frac{1}{12} \, {\left(24 \, {\left({\nu} + 1\right)} e^{\left(2 \, r\right)} f\left(r\right) + {\left({\mu} q^{2} - 4 \, {\Lambda}\right)} e^{\left(2 \, r\right)} + 12 \, e^{\left(2 \, r\right)} \frac{\partial\,f}{\partial r}\right)} e^{\left(-2 \, r\right)}$$

eq3 = EE[4,4]*lamb^2*f(r)
eq3

$$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{24} \, {\lambda}^{2} {\mu} q^{2} + \frac{1}{3} \, {\Lambda} {\lambda}^{2} - \frac{1}{2} \, {\lambda}^{2} \frac{\partial^2\,f}{\partial r ^ 2} - 2 \, {\left({\lambda}^{2} {\nu}^{2} + {\lambda}^{2} + 4\right)} f\left(r\right) - {\left(2 \, {\lambda}^{2} {\nu} + {\lambda}^{2}\right)} \frac{\partial\,f}{\partial r}$$

The dilaton field equation becomes

nab = g.connection()
box_phi = nab(nab(phi).up(g)).trace()
print box_phi
box_phi.display()

Scalar field on the 5-dimensional differentiable manifold M

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} & M & \longrightarrow & \mathbb{R} \\ & \left(t, x, {y_1}, {y_2}, {\tilde{r}}\right) & \longmapsto & \frac{4 \, {\left(2 \, {\left({\nu} + 1\right)} f\left(\log\left({\tilde{r}}\right)\right) + \frac{\partial\,f}{\partial \left( \log\left({\tilde{r}}\right) \right)}\right)}}{{\lambda}} \\ & \left(t, x, {y_1}, {y_2}, r\right) & \longmapsto & \frac{4 \, {\left(2 \, {\left({\nu} + 1\right)} f\left(r\right) + \frac{\partial\,f}{\partial r}\right)}}{{\lambda}} \end{array}$$

DE = box_phi - lamb/4*exp(lamb*phi) * F2
DE.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} & M & \longrightarrow & \mathbb{R} \\ & \left(t, x, {y_1}, {y_2}, {\tilde{r}}\right) & \longmapsto & -\frac{{\lambda}^{2} {\mu} q^{2} - 64 \, {\left({\nu} + 1\right)} f\left(\log\left({\tilde{r}}\right)\right) - 32 \, \frac{\partial\,f}{\partial \left( \log\left({\tilde{r}}\right) \right)}}{8 \, {\lambda}} \\ & \left(t, x, {y_1}, {y_2}, r\right) & \longmapsto & -\frac{{\lambda}^{2} {\mu} q^{2} - 64 \, {\left({\nu} + 1\right)} f\left(r\right) - 32 \, \frac{\partial\,f}{\partial r}}{8 \, {\lambda}} \end{array}$$

eq4 = DE.coord_function()*lamb
eq4

$$\newcommand{\Bold}[1]{\mathbf{#1}}-\frac{1}{8} \, {\lambda}^{2} {\mu} q^{2} + 8 \, {\left({\nu} + 1\right)} f\left(r\right) + 4 \, \frac{\partial\,f}{\partial r}$$

The Maxwell equation is still identically satisfied:

ME = nab(exp(lamb*phi)*Fu).trace(0,2)
print ME
ME.display()

Vector field on the 5-dimensional differentiable manifold M

$$\newcommand{\Bold}[1]{\mathbf{#1}}0$$

The solution

The Einstein equation + the dilaton field equation yields a system of 5 equations (eq0, eq1, eq2, eq3, eq4).

Let us show that a solution is obtained for $\nu=2$ and $\nu=4$ with the following specific form of the blackening function:

$$ f(r) = 1 - m e^{-(2\nu +2)r}, $$

where $m$ is a constant.

To this aim, we declare

var('m', domain='real')
fm(r) = 1 - m*exp(-(2*nu+2)*r)
fm

$$\newcommand{\Bold}[1]{\mathbf{#1}}r \ {\mapsto}\ -m e^{\left(-2 \, {\left({\nu} + 1\right)} r\right)} + 1$$

and substitute this function for $f(r)$ in all the equations:

eq0m = eq0.expr().substitute_function(f, fm).simplify_full()
eq0m

$$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{24} \, {\left(m {\mu} q^{2} - 48 \, m {\nu}^{2} + 8 \, {\Lambda} m - 48 \, m {\nu} - {\left({\mu} q^{2} - 48 \, {\nu}^{2} + 8 \, {\Lambda} - 48 \, {\nu}\right)} e^{\left(2 \, {\nu} r + 2 \, r\right)}\right)} e^{\left(-2 \, {\nu} r - 2 \, r\right)}$$

eq0m = (eq0m * exp(2*nu*r+2*r)).simplify_full()
eq0m

$$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{24} \, m {\mu} q^{2} - 2 \, m {\nu}^{2} + \frac{1}{3} \, {\Lambda} m - 2 \, m {\nu} - \frac{1}{24} \, {\left({\mu} q^{2} - 48 \, {\nu}^{2} + 8 \, {\Lambda} - 48 \, {\nu}\right)} e^{\left(2 \, {\nu} r + 2 \, r\right)}$$

eq1m = eq1.expr().substitute_function(f, fm).simplify_full()
eq1m

$$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{24} \, {\mu} q^{2} - 2 \, {\nu}^{2} + \frac{1}{3} \, {\Lambda} - 2 \, {\nu}$$

eq2m = eq2.expr().substitute_function(f, fm).simplify_full()
eq2m

$$\newcommand{\Bold}[1]{\mathbf{#1}}-\frac{1}{12} \, {\mu} q^{2} + \frac{1}{3} \, {\Lambda} - 2 \, {\nu} - 2$$

eq3m = eq3.expr().substitute_function(f, fm).simplify_full()
eq3m

$$\newcommand{\Bold}[1]{\mathbf{#1}}-\frac{1}{24} \, {\left(48 \, {\lambda}^{2} m {\nu} - 48 \, {\left({\lambda}^{2} + 4\right)} m - {\left({\lambda}^{2} {\mu} q^{2} - 48 \, {\lambda}^{2} {\nu}^{2} + 8 \, {\left({\Lambda} - 6\right)} {\lambda}^{2} - 192\right)} e^{\left(2 \, {\nu} r + 2 \, r\right)}\right)} e^{\left(-2 \, {\nu} r - 2 \, r\right)}$$

eq3m = (eq3m * exp(2*nu*r+2*r)).simplify_full()
eq3m

$$\newcommand{\Bold}[1]{\mathbf{#1}}-2 \, {\lambda}^{2} m {\nu} + 2 \, {\left({\lambda}^{2} + 4\right)} m + \frac{1}{24} \, {\left({\lambda}^{2} {\mu} q^{2} - 48 \, {\lambda}^{2} {\nu}^{2} + 8 \, {\left({\Lambda} - 6\right)} {\lambda}^{2} - 192\right)} e^{\left(2 \, {\nu} r + 2 \, r\right)}$$

eq4m = eq4.expr().substitute_function(f, fm).simplify_full()
eq4m

$$\newcommand{\Bold}[1]{\mathbf{#1}}-\frac{1}{8} \, {\lambda}^{2} {\mu} q^{2} + 8 \, {\nu} + 8$$

eqs = [eq0m, eq1m, eq2m, eq3m, eq4m]

Solution for $\nu = 2$

neqs = [eq.subs(nu=2).simplify_full() for eq in eqs]
[eq == 0 for eq in neqs]

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left[\frac{1}{24} \, m {\mu} q^{2} + \frac{1}{3} \, {\left({\Lambda} - 36\right)} m - \frac{1}{24} \, {\left({\mu} q^{2} + 8 \, {\Lambda} - 288\right)} e^{\left(6 \, r\right)} = 0, \frac{1}{24} \, {\mu} q^{2} + \frac{1}{3} \, {\Lambda} - 12 = 0, -\frac{1}{12} \, {\mu} q^{2} + \frac{1}{3} \, {\Lambda} - 6 = 0, -2 \, {\left({\lambda}^{2} - 4\right)} m + \frac{1}{24} \, {\left({\lambda}^{2} {\mu} q^{2} + 8 \, {\left({\Lambda} - 30\right)} {\lambda}^{2} - 192\right)} e^{\left(6 \, r\right)} = 0, -\frac{1}{8} \, {\lambda}^{2} {\mu} q^{2} + 24 = 0\right]$$

solve([eq == 0 for eq in neqs], lamb, mu, Lamb, q, m, r)

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left[\left[{\lambda} = 2, {\mu} = \frac{48}{r_{5}^{2}}, {\Lambda} = 30, q = r_{5}, m = r_{6}, r = r_{7}\right], \left[{\lambda} = \left(-2\right), {\mu} = \frac{48}{r_{8}^{2}}, {\Lambda} = 30, q = r_{8}, m = r_{9}, r = r_{10}\right]\right]$$

In the above solutions, $r_i$, with $i$ an integer, stands for an arbitrary parameter.
We recover the same solution for $\lambda$, $\Lambda$ and $\mu q^2$ as in Sec. 1 (i.e. without any black brane). The value of $m$ can be chosen arbitraly. The solution of Sec. 1 corresponds to $m=0$.

Solution for $\nu=4$

neqs = [eq.subs(nu=4).simplify_full() for eq in eqs]
[eq == 0 for eq in neqs]

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left[\frac{1}{24} \, m {\mu} q^{2} + \frac{1}{3} \, {\left({\Lambda} - 120\right)} m - \frac{1}{24} \, {\left({\mu} q^{2} + 8 \, {\Lambda} - 960\right)} e^{\left(10 \, r\right)} = 0, \frac{1}{24} \, {\mu} q^{2} + \frac{1}{3} \, {\Lambda} - 40 = 0, -\frac{1}{12} \, {\mu} q^{2} + \frac{1}{3} \, {\Lambda} - 10 = 0, -2 \, {\left(3 \, {\lambda}^{2} - 4\right)} m + \frac{1}{24} \, {\left({\lambda}^{2} {\mu} q^{2} + 8 \, {\left({\Lambda} - 102\right)} {\lambda}^{2} - 192\right)} e^{\left(10 \, r\right)} = 0, -\frac{1}{8} \, {\lambda}^{2} {\mu} q^{2} + 40 = 0\right]$$

solve([eq == 0 for eq in neqs], lamb, mu, Lamb, q, m, r)

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left[\left[{\lambda} = \frac{2}{3} \, \sqrt{3}, {\mu} = \frac{240}{r_{11}^{2}}, {\Lambda} = 90, q = r_{11}, m = r_{12}, r = r_{13}\right], \left[{\lambda} = -\frac{2}{3} \, \sqrt{3}, {\mu} = \frac{240}{r_{14}^{2}}, {\Lambda} = 90, q = r_{14}, m = r_{15}, r = r_{16}\right]\right]$$

In the above solutions, $r_i$, with $i$ an integer, stands for an arbitrary parameter.
We recover the same solution for $\lambda$, $\Lambda$ and $\mu q^2$ as in Sec. 1 (i.e. without any black brane). The value of $m$ can be chosen arbitraly. The solution of Sec. 1 corresponds to $m=0$.