Black branes in Lifshitz-like wraped backgrounds

This Jupyter/SageMath worksheet implements some computations of the article

• I. Ya. Aref'eva, A. A. Golubtsova & E. Gourgoulhon: ??, in preparation

These computations are based on SageManifolds (v0.9)

The worksheet file (ipynb format) can be downloaded from ??.

First we set up the notebook to display mathematical objects using LaTeX formatting:

%display latex

Metric

Let us declare the spacetime $M$ as a 5-dimensional manifold:

M = Manifold(5, 'M')
print M

5-dimensional differentiable manifold M

We introduce a the Poincaré-type coordinate system on $M$:

X.<t,x,y1,y2,z> = M.chart(r't x y1:y_1 y2:y_2 z:(0,+oo)')
X

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(M,(t, x, {y_1}, {y_2}, z)\right)$$

Let us consider the following Lifshitz-symmetric metric, parametrized by some real numbers $\nu$ and $c$, and the blackening function $f(z)$:

g = M.lorentzian_metric('g')
var('nu', latex_name=r'\nu', domain='real')
var('c', domain='real')
ff = function('f')(z)
b(z) = exp(c*z^2/2)
# b(z)=1 ## for checks
g[0,0] = - b(z)*ff/z^2
g[1,1] = b(z)/z^2
g[2,2] = b(z)*z^(-2/nu)
g[3,3] = b(z)*z^(-2/nu)
g[4,4] = b(z)/z^2/ff
g.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}g = -\frac{e^{\left(\frac{1}{2} \, c z^{2}\right)} f\left(z\right)}{z^{2}} \mathrm{d} t\otimes \mathrm{d} t + \frac{e^{\left(\frac{1}{2} \, c z^{2}\right)}}{z^{2}} \mathrm{d} x\otimes \mathrm{d} x + \left( z^{-\frac{2}{{\nu}}} e^{\left(\frac{1}{2} \, c z^{2}\right)} \right) \mathrm{d} {y_1}\otimes \mathrm{d} {y_1} + \left( z^{-\frac{2}{{\nu}}} e^{\left(\frac{1}{2} \, c z^{2}\right)} \right) \mathrm{d} {y_2}\otimes \mathrm{d} {y_2} + \frac{e^{\left(\frac{1}{2} \, c z^{2}\right)}}{z^{2} f\left(z\right)} \mathrm{d} z\otimes \mathrm{d} z$$

A matrix view of the metric components:

g[:]

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(\begin{array}{rrrrr} -\frac{e^{\left(\frac{1}{2} \, c z^{2}\right)} f\left(z\right)}{z^{2}} & 0 & 0 & 0 & 0 \\ 0 & \frac{e^{\left(\frac{1}{2} \, c z^{2}\right)}}{z^{2}} & 0 & 0 & 0 \\ 0 & 0 & z^{-\frac{2}{{\nu}}} e^{\left(\frac{1}{2} \, c z^{2}\right)} & 0 & 0 \\ 0 & 0 & 0 & z^{-\frac{2}{{\nu}}} e^{\left(\frac{1}{2} \, c z^{2}\right)} & 0 \\ 0 & 0 & 0 & 0 & \frac{e^{\left(\frac{1}{2} \, c z^{2}\right)}}{z^{2} f\left(z\right)} \end{array}\right)$$

g.display_comp()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{lcl} g_{ \, t \, t }^{ \phantom{\, t } \phantom{\, t } } & = & -\frac{e^{\left(\frac{1}{2} \, c z^{2}\right)} f\left(z\right)}{z^{2}} \\ g_{ \, x \, x }^{ \phantom{\, x } \phantom{\, x } } & = & \frac{e^{\left(\frac{1}{2} \, c z^{2}\right)}}{z^{2}} \\ g_{ \, {y_1} \, {y_1} }^{ \phantom{\, {y_1} } \phantom{\, {y_1} } } & = & z^{-\frac{2}{{\nu}}} e^{\left(\frac{1}{2} \, c z^{2}\right)} \\ g_{ \, {y_2} \, {y_2} }^{ \phantom{\, {y_2} } \phantom{\, {y_2} } } & = & z^{-\frac{2}{{\nu}}} e^{\left(\frac{1}{2} \, c z^{2}\right)} \\ g_{ \, z \, z }^{ \phantom{\, z } \phantom{\, z } } & = & \frac{e^{\left(\frac{1}{2} \, c z^{2}\right)}}{z^{2} f\left(z\right)} \end{array}$$

Curvature

The Riemann tensor is

Riem = g.riemann()
print Riem

Tensor field Riem(g) of type (1,3) on the 5-dimensional differentiable manifold M

#Riem.display_comp(only_nonredundant=True)
Riem[0,1,0,1]

$$\newcommand{\Bold}[1]{\mathbf{#1}}-\frac{{\left(c^{2} z^{4} - 4 \, c z^{2} + 4\right)} f\left(z\right) + {\left(c z^{3} - 2 \, z\right)} \frac{\partial\,f}{\partial z}}{4 \, z^{2}}$$

The Ricci tensor:

Ric = g.ricci()
print Ric

Field of symmetric bilinear forms Ric(g) on the 5-dimensional differentiable manifold M

Ric.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{Ric}\left(g\right) = \left( \frac{2 \, {\nu} z^{2} f\left(z\right) \frac{\partial^2\,f}{\partial z^2} + {\left(3 \, c^{2} {\nu} z^{4} - 2 \, {\left(3 \, c {\nu} + 2 \, c\right)} z^{2} + 8 \, {\nu} + 8\right)} f\left(z\right)^{2} + {\left(5 \, c {\nu} z^{3} - 2 \, {\left(3 \, {\nu} + 2\right)} z\right)} f\left(z\right) \frac{\partial\,f}{\partial z}}{4 \, {\nu} z^{2}} \right) \mathrm{d} t\otimes \mathrm{d} t + \left( -\frac{{\left(3 \, c^{2} {\nu} z^{4} - 2 \, {\left(3 \, c {\nu} + 2 \, c\right)} z^{2} + 8 \, {\nu} + 8\right)} f\left(z\right) + 2 \, {\left(c {\nu} z^{3} - 2 \, {\nu} z\right)} \frac{\partial\,f}{\partial z}}{4 \, {\nu} z^{2}} \right) \mathrm{d} x\otimes \mathrm{d} x + \left( -\frac{{\left({\left(3 \, c^{2} {\nu}^{2} z^{4} - 10 \, c {\nu} z^{2} + 8 \, {\nu} + 8\right)} f\left(z\right) + 2 \, {\left(c {\nu}^{2} z^{3} - 2 \, {\nu} z\right)} \frac{\partial\,f}{\partial z}\right)} z^{-\frac{2}{{\nu}}}}{4 \, {\nu}^{2}} \right) \mathrm{d} {y_1}\otimes \mathrm{d} {y_1} + \left( -\frac{{\left({\left(3 \, c^{2} {\nu}^{2} z^{4} - 10 \, c {\nu} z^{2} + 8 \, {\nu} + 8\right)} f\left(z\right) + 2 \, {\left(c {\nu}^{2} z^{3} - 2 \, {\nu} z\right)} \frac{\partial\,f}{\partial z}\right)} z^{-\frac{2}{{\nu}}}}{4 \, {\nu}^{2}} \right) \mathrm{d} {y_2}\otimes \mathrm{d} {y_2} + \left( -\frac{2 \, {\nu}^{2} z^{2} \frac{\partial^2\,f}{\partial z^2} + 4 \, {\left({\left(3 \, c {\nu}^{2} - c {\nu}\right)} z^{2} + 2 \, {\nu}^{2} + 2\right)} f\left(z\right) + {\left(5 \, c {\nu}^{2} z^{3} - 2 \, {\left(3 \, {\nu}^{2} + 2 \, {\nu}\right)} z\right)} \frac{\partial\,f}{\partial z}}{4 \, {\nu}^{2} z^{2} f\left(z\right)} \right) \mathrm{d} z\otimes \mathrm{d} z$$

Ric.display_comp()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{lcl} \mathrm{Ric}\left(g\right)_{ \, t \, t }^{ \phantom{\, t } \phantom{\, t } } & = & \frac{2 \, {\nu} z^{2} f\left(z\right) \frac{\partial^2\,f}{\partial z^2} + {\left(3 \, c^{2} {\nu} z^{4} - 2 \, {\left(3 \, c {\nu} + 2 \, c\right)} z^{2} + 8 \, {\nu} + 8\right)} f\left(z\right)^{2} + {\left(5 \, c {\nu} z^{3} - 2 \, {\left(3 \, {\nu} + 2\right)} z\right)} f\left(z\right) \frac{\partial\,f}{\partial z}}{4 \, {\nu} z^{2}} \\ \mathrm{Ric}\left(g\right)_{ \, x \, x }^{ \phantom{\, x } \phantom{\, x } } & = & -\frac{{\left(3 \, c^{2} {\nu} z^{4} - 2 \, {\left(3 \, c {\nu} + 2 \, c\right)} z^{2} + 8 \, {\nu} + 8\right)} f\left(z\right) + 2 \, {\left(c {\nu} z^{3} - 2 \, {\nu} z\right)} \frac{\partial\,f}{\partial z}}{4 \, {\nu} z^{2}} \\ \mathrm{Ric}\left(g\right)_{ \, {y_1} \, {y_1} }^{ \phantom{\, {y_1} } \phantom{\, {y_1} } } & = & -\frac{{\left({\left(3 \, c^{2} {\nu}^{2} z^{4} - 10 \, c {\nu} z^{2} + 8 \, {\nu} + 8\right)} f\left(z\right) + 2 \, {\left(c {\nu}^{2} z^{3} - 2 \, {\nu} z\right)} \frac{\partial\,f}{\partial z}\right)} z^{-\frac{2}{{\nu}}}}{4 \, {\nu}^{2}} \\ \mathrm{Ric}\left(g\right)_{ \, {y_2} \, {y_2} }^{ \phantom{\, {y_2} } \phantom{\, {y_2} } } & = & -\frac{{\left({\left(3 \, c^{2} {\nu}^{2} z^{4} - 10 \, c {\nu} z^{2} + 8 \, {\nu} + 8\right)} f\left(z\right) + 2 \, {\left(c {\nu}^{2} z^{3} - 2 \, {\nu} z\right)} \frac{\partial\,f}{\partial z}\right)} z^{-\frac{2}{{\nu}}}}{4 \, {\nu}^{2}} \\ \mathrm{Ric}\left(g\right)_{ \, z \, z }^{ \phantom{\, z } \phantom{\, z } } & = & -\frac{2 \, {\nu}^{2} z^{2} \frac{\partial^2\,f}{\partial z^2} + 4 \, {\left({\left(3 \, c {\nu}^{2} - c {\nu}\right)} z^{2} + 2 \, {\nu}^{2} + 2\right)} f\left(z\right) + {\left(5 \, c {\nu}^{2} z^{3} - 2 \, {\left(3 \, {\nu}^{2} + 2 \, {\nu}\right)} z\right)} \frac{\partial\,f}{\partial z}}{4 \, {\nu}^{2} z^{2} f\left(z\right)} \end{array}$$

The Ricci scalar:

Rscal = g.ricci_scalar()
print Rscal

Scalar field r(g) on the 5-dimensional differentiable manifold M

Rscal.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} \mathrm{r}\left(g\right):& M & \longrightarrow & \mathbb{R} \\ & \left(t, x, {y_1}, {y_2}, z\right) & \longmapsto & -\frac{{\left({\nu}^{2} z^{2} \frac{\partial^2\,f}{\partial z^2} + {\left(3 \, c^{2} {\nu}^{2} z^{4} - 8 \, c {\nu} z^{2} + 6 \, {\nu}^{2} + 8 \, {\nu} + 6\right)} f\left(z\right) + 4 \, {\left(c {\nu}^{2} z^{3} - {\left({\nu}^{2} + {\nu}\right)} z\right)} \frac{\partial\,f}{\partial z}\right)} e^{\left(-\frac{1}{2} \, c z^{2}\right)}}{{\nu}^{2}} \end{array}$$

Source model

Let us consider a model based on the following action, involving a dilaton scalar field $\phi$ and a Maxwell 2-form $F$:

$$ S = \int \left( R(g) + \Lambda - \frac{1}{2} \nabla_m \phi \nabla^m \phi - \frac{1}{4} e^{\lambda\phi} F_{mn} F^{mn} \right) \sqrt{-g} \, \mathrm{d}^5 x \qquad\qquad \mbox{(1)}$$

where $R(g)$ is the Ricci scalar of metric $g$, $\Lambda$ is the cosmological constant and $\lambda$ is the dilatonic coupling constant.

The dilaton scalar field

We consider the following ansatz for the dilaton scalar field $\phi$: $$ \phi = \frac{1}{\lambda} \left( \ln\mu - \frac{4}{\nu}\ln z\right),$$ where $\mu$ is a constant.

var('mu', latex_name=r'\mu', domain='real')
var('lamb', latex_name=r'\lambda', domain='real')
phi = M.scalar_field({X: (ln(mu) - 4/nu*ln(z))/lamb}, 
                     name='phi', latex_name=r'\phi')
phi.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} \phi:& M & \longrightarrow & \mathbb{R} \\ & \left(t, x, {y_1}, {y_2}, z\right) & \longmapsto & -\frac{\frac{4 \, \log\left(z\right)}{{\nu}} - \log\left({\mu}\right)}{{\lambda}} \end{array}$$

The 1-form $\mathrm{d}\phi$ is

dphi = phi.differential()
print dphi

1-form dphi on the 5-dimensional differentiable manifold M

dphi.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{d}\phi = -\frac{4}{{\lambda} {\nu} z} \mathrm{d} z$$

dphi[:]  # all the components in the default frame

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left[0, 0, 0, 0, -\frac{4}{{\lambda} {\nu} z}\right]$$

The 2-form field

We consider the following ansatz for $F$: $$ F = \frac{1}{2} q \, \mathrm{d}y_1\wedge \mathrm{d}y_2, $$ where $q$ is a constant.

Let us first get the 1-forms $\mathrm{d}y_1$ and $\mathrm{d}y_2$:

X.coframe()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(M ,\left(\mathrm{d} t,\mathrm{d} x,\mathrm{d} {y_1},\mathrm{d} {y_2},\mathrm{d} z\right)\right)$$

dy1 = X.coframe()[2]
dy2 = X.coframe()[3]
print dy1
print dy2
dy1, dy2

1-form dy1 on the 5-dimensional differentiable manifold M
1-form dy2 on the 5-dimensional differentiable manifold M

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(\mathrm{d} {y_1}, \mathrm{d} {y_2}\right)$$

Then we can form $F$ according to the above ansatz:

var('q', domain='real')
F = q/2 * dy1.wedge(dy2)
F.set_name('F')
print F
F.display()

2-form F on the 5-dimensional differentiable manifold M

$$\newcommand{\Bold}[1]{\mathbf{#1}}F = \frac{1}{2} \, q \mathrm{d} {y_1}\wedge \mathrm{d} {y_2}$$

By construction, the 2-form $F$ is closed (since $q$ is constant):

print xder(F)

3-form dF on the 5-dimensional differentiable manifold M

xder(F).display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{d}F = 0$$

Let us evaluate the square $F_{mn} F^{mn}$ of $F$:

Fu = F.up(g)
print Fu
Fu.display()

Tensor field of type (2,0) on the 5-dimensional differentiable manifold M

$$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{2} \, q z^{\frac{4}{{\nu}}} e^{\left(-c z^{2}\right)} \frac{\partial}{\partial {y_1} }\otimes \frac{\partial}{\partial {y_2} } -\frac{1}{2} \, q z^{\frac{4}{{\nu}}} e^{\left(-c z^{2}\right)} \frac{\partial}{\partial {y_2} }\otimes \frac{\partial}{\partial {y_1} }$$

F2 = F['_{mn}']*Fu['^{mn}']  # using LaTeX notations to denote contraction
print F2
F2.display()

Scalar field on the 5-dimensional differentiable manifold M

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} & M & \longrightarrow & \mathbb{R} \\ & \left(t, x, {y_1}, {y_2}, z\right) & \longmapsto & \frac{1}{2} \, q^{2} z^{\frac{4}{{\nu}}} e^{\left(-c z^{2}\right)} \end{array}$$

We shall also need the tensor $\mathcal{F}_{mn} := F_{mp} F_n^{\ \, p}$:

FF = F['_mp'] * F.up(g,1)['^p_n']
print FF
FF.display()

Tensor field of type (0,2) on the 5-dimensional differentiable manifold M

$$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{4} \, q^{2} z^{\frac{2}{{\nu}}} e^{\left(-\frac{1}{2} \, c z^{2}\right)} \mathrm{d} {y_1}\otimes \mathrm{d} {y_1} + \frac{1}{4} \, q^{2} z^{\frac{2}{{\nu}}} e^{\left(-\frac{1}{2} \, c z^{2}\right)} \mathrm{d} {y_2}\otimes \mathrm{d} {y_2}$$

The tensor field $\mathcal{F}$ is symmetric:

FF == FF.symmetrize()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{True}$$

Therefore, from now on, we set

FF = FF.symmetrize()

Einstein equation

Let us first introduce the cosmological constant:

var('Lamb', latex_name=r'\Lambda', domain='real')

$$\newcommand{\Bold}[1]{\mathbf{#1}}{\Lambda}$$

From the action (1), the field equation for the metric $g$ is $$ R_{mn} + \frac{\Lambda}{3} \, g - \frac{1}{2}\partial_m\phi \partial_n\phi -\frac{1}{2} e^{\lambda\phi} F_{mp} F^{\ \, p}_n + \frac{1}{12} e^{\lambda\phi} F_{rs} F^{rs} \, g_{mn} = 0 $$ We write it as

EE == 0

with EE defined by

EE = Ric + Lamb/3*g - 1/2* (dphi*dphi) -  1/2*exp(lamb*phi)*FF \
     + 1/12*exp(lamb*phi)*F2*g
EE.set_name('E')
print EE

Field of symmetric bilinear forms E on the 5-dimensional differentiable manifold M

EE.display_comp(only_nonredundant=True)

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{lcl} E_{ \, t \, t }^{ \phantom{\, t } \phantom{\, t } } & = & \frac{{\left(12 \, {\nu} z^{2} e^{\left(\frac{1}{2} \, c z^{2}\right)} f\left(z\right) \frac{\partial^2\,f}{\partial z^2} + 6 \, {\left(3 \, c^{2} {\nu} z^{4} - 2 \, {\left(3 \, c {\nu} + 2 \, c\right)} z^{2} + 8 \, {\nu} + 8\right)} e^{\left(\frac{1}{2} \, c z^{2}\right)} f\left(z\right)^{2} + 6 \, {\left(5 \, c {\nu} z^{3} - 2 \, {\left(3 \, {\nu} + 2\right)} z\right)} e^{\left(\frac{1}{2} \, c z^{2}\right)} f\left(z\right) \frac{\partial\,f}{\partial z} - {\left({\mu} {\nu} q^{2} + 8 \, {\Lambda} {\nu} e^{\left(c z^{2}\right)}\right)} f\left(z\right)\right)} e^{\left(-\frac{1}{2} \, c z^{2}\right)}}{24 \, {\nu} z^{2}} \\ E_{ \, x \, x }^{ \phantom{\, x } \phantom{\, x } } & = & \frac{{\left({\mu} {\nu} q^{2} + 8 \, {\Lambda} {\nu} e^{\left(c z^{2}\right)} - 6 \, {\left(3 \, c^{2} {\nu} z^{4} - 2 \, {\left(3 \, c {\nu} + 2 \, c\right)} z^{2} + 8 \, {\nu} + 8\right)} e^{\left(\frac{1}{2} \, c z^{2}\right)} f\left(z\right) - 12 \, {\left(c {\nu} z^{3} - 2 \, {\nu} z\right)} e^{\left(\frac{1}{2} \, c z^{2}\right)} \frac{\partial\,f}{\partial z}\right)} e^{\left(-\frac{1}{2} \, c z^{2}\right)}}{24 \, {\nu} z^{2}} \\ E_{ \, {y_1} \, {y_1} }^{ \phantom{\, {y_1} } \phantom{\, {y_1} } } & = & -\frac{{\left({\mu} {\nu}^{2} q^{2} - 4 \, {\Lambda} {\nu}^{2} e^{\left(c z^{2}\right)} + 3 \, {\left(3 \, c^{2} {\nu}^{2} z^{4} - 10 \, c {\nu} z^{2} + 8 \, {\nu} + 8\right)} e^{\left(\frac{1}{2} \, c z^{2}\right)} f\left(z\right) + 6 \, {\left(c {\nu}^{2} z^{3} - 2 \, {\nu} z\right)} e^{\left(\frac{1}{2} \, c z^{2}\right)} \frac{\partial\,f}{\partial z}\right)} z^{-\frac{2}{{\nu}}} e^{\left(-\frac{1}{2} \, c z^{2}\right)}}{12 \, {\nu}^{2}} \\ E_{ \, {y_2} \, {y_2} }^{ \phantom{\, {y_2} } \phantom{\, {y_2} } } & = & -\frac{{\left({\mu} {\nu}^{2} q^{2} - 4 \, {\Lambda} {\nu}^{2} e^{\left(c z^{2}\right)} + 3 \, {\left(3 \, c^{2} {\nu}^{2} z^{4} - 10 \, c {\nu} z^{2} + 8 \, {\nu} + 8\right)} e^{\left(\frac{1}{2} \, c z^{2}\right)} f\left(z\right) + 6 \, {\left(c {\nu}^{2} z^{3} - 2 \, {\nu} z\right)} e^{\left(\frac{1}{2} \, c z^{2}\right)} \frac{\partial\,f}{\partial z}\right)} z^{-\frac{2}{{\nu}}} e^{\left(-\frac{1}{2} \, c z^{2}\right)}}{12 \, {\nu}^{2}} \\ E_{ \, z \, z }^{ \phantom{\, z } \phantom{\, z } } & = & -\frac{{\left(12 \, {\lambda}^{2} {\nu}^{2} z^{2} e^{\left(\frac{1}{2} \, c z^{2}\right)} \frac{\partial^2\,f}{\partial z^2} - {\lambda}^{2} {\mu} {\nu}^{2} q^{2} - 8 \, {\Lambda} {\lambda}^{2} {\nu}^{2} e^{\left(c z^{2}\right)} + 24 \, {\left(2 \, {\lambda}^{2} {\nu}^{2} + {\left(3 \, c {\lambda}^{2} {\nu}^{2} - c {\lambda}^{2} {\nu}\right)} z^{2} + 2 \, {\lambda}^{2} + 8\right)} e^{\left(\frac{1}{2} \, c z^{2}\right)} f\left(z\right) + 6 \, {\left(5 \, c {\lambda}^{2} {\nu}^{2} z^{3} - 2 \, {\left(3 \, {\lambda}^{2} {\nu}^{2} + 2 \, {\lambda}^{2} {\nu}\right)} z\right)} e^{\left(\frac{1}{2} \, c z^{2}\right)} \frac{\partial\,f}{\partial z}\right)} e^{\left(-\frac{1}{2} \, c z^{2}\right)}}{24 \, {\lambda}^{2} {\nu}^{2} z^{2} f\left(z\right)} \end{array}$$

We note that EE==0 leads to 4 independent equations:

eq1 = EE[0,0]*24*nu*z^2/f(z)*exp(c*z^2/2)
eq1

$$\newcommand{\Bold}[1]{\mathbf{#1}}12 \, {\nu} z^{2} e^{\left(\frac{1}{2} \, c z^{2}\right)} \frac{\partial^2\,f}{\partial z^2} - {\mu} {\nu} q^{2} - 8 \, {\Lambda} {\nu} e^{\left(c z^{2}\right)} + 6 \, {\left(3 \, c^{2} {\nu} z^{4} - 2 \, {\left(3 \, c {\nu} + 2 \, c\right)} z^{2} + 8 \, {\nu} + 8\right)} e^{\left(\frac{1}{2} \, c z^{2}\right)} f\left(z\right) + 6 \, {\left(5 \, c {\nu} z^{3} - 2 \, {\left(3 \, {\nu} + 2\right)} z\right)} e^{\left(\frac{1}{2} \, c z^{2}\right)} \frac{\partial\,f}{\partial z}$$

eq2 = EE[1,1]*24*nu*z^2*exp(c*z^2/2)
eq2

$$\newcommand{\Bold}[1]{\mathbf{#1}}{\mu} {\nu} q^{2} + 8 \, {\Lambda} {\nu} e^{\left(c z^{2}\right)} - 6 \, {\left(3 \, c^{2} {\nu} z^{4} - 2 \, {\left(3 \, c {\nu} + 2 \, c\right)} z^{2} + 8 \, {\nu} + 8\right)} e^{\left(\frac{1}{2} \, c z^{2}\right)} f\left(z\right) - 12 \, {\left(c {\nu} z^{3} - 2 \, {\nu} z\right)} e^{\left(\frac{1}{2} \, c z^{2}\right)} \frac{\partial\,f}{\partial z}$$

eq3 = EE[2,2]*12*nu^2*z^(2/nu)*exp(c*z^2/2)
eq3

$$\newcommand{\Bold}[1]{\mathbf{#1}}-{\mu} {\nu}^{2} q^{2} + 4 \, {\Lambda} {\nu}^{2} e^{\left(c z^{2}\right)} - 3 \, {\left(3 \, c^{2} {\nu}^{2} z^{4} - 10 \, c {\nu} z^{2} + 8 \, {\nu} + 8\right)} e^{\left(\frac{1}{2} \, c z^{2}\right)} f\left(z\right) - 6 \, {\left(c {\nu}^{2} z^{3} - 2 \, {\nu} z\right)} e^{\left(\frac{1}{2} \, c z^{2}\right)} \frac{\partial\,f}{\partial z}$$

eq4 = EE[4,4]*2*lamb^2*nu^2*z^2*f(z)*exp(c*z^2/2)
eq4

$$\newcommand{\Bold}[1]{\mathbf{#1}}-{\lambda}^{2} {\nu}^{2} z^{2} e^{\left(\frac{1}{2} \, c z^{2}\right)} \frac{\partial^2\,f}{\partial z^2} + \frac{1}{12} \, {\lambda}^{2} {\mu} {\nu}^{2} q^{2} + \frac{2}{3} \, {\Lambda} {\lambda}^{2} {\nu}^{2} e^{\left(c z^{2}\right)} - 2 \, {\left(2 \, {\lambda}^{2} {\nu}^{2} + {\left(3 \, c {\lambda}^{2} {\nu}^{2} - c {\lambda}^{2} {\nu}\right)} z^{2} + 2 \, {\lambda}^{2} + 8\right)} e^{\left(\frac{1}{2} \, c z^{2}\right)} f\left(z\right) - \frac{1}{2} \, {\left(5 \, c {\lambda}^{2} {\nu}^{2} z^{3} - 2 \, {\left(3 \, {\lambda}^{2} {\nu}^{2} + 2 \, {\lambda}^{2} {\nu}\right)} z\right)} e^{\left(\frac{1}{2} \, c z^{2}\right)} \frac{\partial\,f}{\partial z}$$

Dilaton field equation

First we evaluate $\nabla_m \nabla^m \phi$:

nab = g.connection()
print nab
nab

Levi-Civita connection nabla_g associated with the Lorentzian metric g on the 5-dimensional differentiable manifold M

$$\newcommand{\Bold}[1]{\mathbf{#1}}\nabla_{g}$$

box_phi = nab(nab(phi).up(g)).trace()
print box_phi
box_phi.display()

Scalar field on the 5-dimensional differentiable manifold M

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} & M & \longrightarrow & \mathbb{R} \\ & \left(t, x, {y_1}, {y_2}, z\right) & \longmapsto & -\frac{2 \, {\left(2 \, {\nu} z \frac{\partial\,f}{\partial z} + {\left(3 \, c {\nu} z^{2} - 4 \, {\nu} - 4\right)} f\left(z\right)\right)} e^{\left(-\frac{1}{2} \, c z^{2}\right)}}{{\lambda} {\nu}^{2}} \end{array}$$

From the action (1), the field equation for $\phi$ is $$ \nabla_m \nabla^m \phi = \frac{\lambda}{4} e^{\lambda\phi} F_{mn} F^{mn}$$ We write it as

DE == 0

with DE defined by

DE = box_phi - lamb/4*exp(lamb*phi) * F2
print DE

Scalar field on the 5-dimensional differentiable manifold M

DE.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} & M & \longrightarrow & \mathbb{R} \\ & \left(t, x, {y_1}, {y_2}, z\right) & \longmapsto & -\frac{{\left({\lambda}^{2} {\mu} {\nu}^{2} q^{2} + 32 \, {\nu} z e^{\left(\frac{1}{2} \, c z^{2}\right)} \frac{\partial\,f}{\partial z} + 16 \, {\left(3 \, c {\nu} z^{2} - 4 \, {\nu} - 4\right)} e^{\left(\frac{1}{2} \, c z^{2}\right)} f\left(z\right)\right)} e^{\left(-c z^{2}\right)}}{8 \, {\lambda} {\nu}^{2}} \end{array}$$

Hence the dilaton field equation provides a fifth equation:

eq5 = DE.coord_function()*lamb*nu^2*exp(c*z^2)/2
eq5

$$\newcommand{\Bold}[1]{\mathbf{#1}}-\frac{1}{16} \, {\lambda}^{2} {\mu} {\nu}^{2} q^{2} - 2 \, {\nu} z e^{\left(\frac{1}{2} \, c z^{2}\right)} \frac{\partial\,f}{\partial z} - {\left(3 \, c {\nu} z^{2} - 4 \, {\nu} - 4\right)} e^{\left(\frac{1}{2} \, c z^{2}\right)} f\left(z\right)$$

Maxwell equation

From the action (1), the field equation for $F$ is $$ \nabla_m \left( e^{\lambda\phi} F^{mn} \right)= 0 $$ We write it as

ME == 0

with ME defined by

ME = nab(exp(lamb*phi)*Fu).trace(0,2)
print ME
ME.display()

Vector field on the 5-dimensional differentiable manifold M

$$\newcommand{\Bold}[1]{\mathbf{#1}}0$$

We get identically zero; hence the Maxwell equation do not provide any further equation.

The solution

The Einstein equation + the dilaton field equation yields a system of 5 equations (eq1, eq2, eq3, eq4, eq5).

Let us show that a solution is obtained for $\nu=2$ and $\nu=4$ with the following specific form of the blackening function:

$$ f(z) = 1 - m z^{2/\nu+2}, $$

where $m$ is a constant.

To this aim, we declare

var('m', domain='real')
fm(z) = 1 - m*z^(2/nu+2)
fm

$$\newcommand{\Bold}[1]{\mathbf{#1}}z \ {\mapsto}\ -m z^{\frac{2}{{\nu}} + 2} + 1$$

and substitute this function for $f(z)$ in all the equations:

eq1m = eq1.expr().substitute_function(f, fm).simplify_full()
eq1m

$$\newcommand{\Bold}[1]{\mathbf{#1}}-{\mu} {\nu} q^{2} - 8 \, {\Lambda} {\nu} e^{\left(c z^{2}\right)} + 6 \, {\left(3 \, c^{2} {\nu} z^{4} - 2 \, {\left(3 \, c {\nu} + 2 \, c\right)} z^{2} - {\left(3 \, c^{2} m {\nu} z^{6} + 2 \, {\left(2 \, c m {\nu} + 3 \, c m\right)} z^{4}\right)} z^{\frac{2}{{\nu}}} + 8 \, {\nu} + 8\right)} e^{\left(\frac{1}{2} \, c z^{2}\right)}$$

eq2m = eq2.expr().substitute_function(f, fm).simplify_full()
eq2m

$$\newcommand{\Bold}[1]{\mathbf{#1}}{\mu} {\nu} q^{2} + 8 \, {\Lambda} {\nu} e^{\left(c z^{2}\right)} - 6 \, {\left(3 \, c^{2} {\nu} z^{4} - 2 \, {\left(3 \, c {\nu} + 2 \, c\right)} z^{2} - {\left(3 \, c^{2} m {\nu} z^{6} - 2 \, c m {\nu} z^{4}\right)} z^{\frac{2}{{\nu}}} + 8 \, {\nu} + 8\right)} e^{\left(\frac{1}{2} \, c z^{2}\right)}$$

eq3m = eq3.expr().substitute_function(f, fm).simplify_full()
eq3m

$$\newcommand{\Bold}[1]{\mathbf{#1}}-{\mu} {\nu}^{2} q^{2} + 4 \, {\Lambda} {\nu}^{2} e^{\left(c z^{2}\right)} - 3 \, {\left(3 \, c^{2} {\nu}^{2} z^{4} - 10 \, c {\nu} z^{2} - {\left(3 \, c^{2} m {\nu}^{2} z^{6} + 2 \, {\left(2 \, c m {\nu}^{2} - 3 \, c m {\nu}\right)} z^{4}\right)} z^{\frac{2}{{\nu}}} + 8 \, {\nu} + 8\right)} e^{\left(\frac{1}{2} \, c z^{2}\right)}$$

eq4m = eq4.expr().substitute_function(f, fm).simplify_full()
eq4m

$$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{12} \, {\lambda}^{2} {\mu} {\nu}^{2} q^{2} + \frac{2}{3} \, {\Lambda} {\lambda}^{2} {\nu}^{2} e^{\left(c z^{2}\right)} - {\left(4 \, {\lambda}^{2} {\nu}^{2} + 2 \, {\left(3 \, c {\lambda}^{2} {\nu}^{2} - c {\lambda}^{2} {\nu}\right)} z^{2} + 4 \, {\lambda}^{2} - {\left({\left(11 \, c {\lambda}^{2} m {\nu}^{2} + 3 \, c {\lambda}^{2} m {\nu}\right)} z^{4} - 4 \, {\left({\lambda}^{2} m {\nu} - {\left({\lambda}^{2} + 4\right)} m\right)} z^{2}\right)} z^{\frac{2}{{\nu}}} + 16\right)} e^{\left(\frac{1}{2} \, c z^{2}\right)}$$

eq5m = eq5.expr().substitute_function(f, fm).simplify_full()
eq5m

$$\newcommand{\Bold}[1]{\mathbf{#1}}-\frac{1}{16} \, {\lambda}^{2} {\mu} {\nu}^{2} q^{2} + {\left(3 \, c m {\nu} z^{\frac{2}{{\nu}} + 4} - 3 \, c {\nu} z^{2} + 4 \, {\nu} + 4\right)} e^{\left(\frac{1}{2} \, c z^{2}\right)}$$

eqs = [eq1m, eq2m, eq3m, eq4m, eq5m]

Solution for $\nu = 2$

neqs = [eq.subs(nu=2).simplify_full() for eq in eqs]
[eq == 0 for eq in neqs]

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left[-2 \, {\mu} q^{2} - 16 \, {\Lambda} e^{\left(c z^{2}\right)} - 12 \, {\left(3 \, c^{2} m z^{7} + 7 \, c m z^{5} - 3 \, c^{2} z^{4} + 8 \, c z^{2} - 12\right)} e^{\left(\frac{1}{2} \, c z^{2}\right)} = 0, 2 \, {\mu} q^{2} + 16 \, {\Lambda} e^{\left(c z^{2}\right)} + 12 \, {\left(3 \, c^{2} m z^{7} - 2 \, c m z^{5} - 3 \, c^{2} z^{4} + 8 \, c z^{2} - 12\right)} e^{\left(\frac{1}{2} \, c z^{2}\right)} = 0, -4 \, {\mu} q^{2} + 16 \, {\Lambda} e^{\left(c z^{2}\right)} + 12 \, {\left(3 \, c^{2} m z^{7} + c m z^{5} - 3 \, c^{2} z^{4} + 5 \, c z^{2} - 6\right)} e^{\left(\frac{1}{2} \, c z^{2}\right)} = 0, \frac{1}{3} \, {\lambda}^{2} {\mu} q^{2} + \frac{8}{3} \, {\Lambda} {\lambda}^{2} e^{\left(c z^{2}\right)} + 2 \, {\left(25 \, c {\lambda}^{2} m z^{5} - 10 \, c {\lambda}^{2} z^{2} - 2 \, {\left({\lambda}^{2} - 4\right)} m z^{3} - 10 \, {\lambda}^{2} - 8\right)} e^{\left(\frac{1}{2} \, c z^{2}\right)} = 0, -\frac{1}{4} \, {\lambda}^{2} {\mu} q^{2} + 6 \, {\left(c m z^{5} - c z^{2} + 2\right)} e^{\left(\frac{1}{2} \, c z^{2}\right)} = 0\right]$$

solve([eq == 0 for eq in neqs], lamb, mu, Lamb, q, m, c)

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left[\left[{\lambda} = \left(-2\right), {\mu} = \frac{12}{r_{1}^{2}}, {\Lambda} = \left(\frac{15}{2}\right), q = r_{1}, m = r_{2}, c = 0\right], \left[{\lambda} = 2, {\mu} = \frac{12}{r_{3}^{2}}, {\Lambda} = \left(\frac{15}{2}\right), q = r_{3}, m = r_{4}, c = 0\right], \left[{\lambda} = 2, {\mu} = -\frac{24 \, e^{3}}{r_{5}^{2}}, {\Lambda} = 57 \, e^{\left(-3\right)}, q = r_{5}, m = 0, c = \frac{6}{z^{2}}\right], \left[{\lambda} = \left(-2\right), {\mu} = -\frac{24 \, e^{3}}{r_{6}^{2}}, {\Lambda} = 57 \, e^{\left(-3\right)}, q = r_{6}, m = 0, c = \frac{6}{z^{2}}\right], \left[{\lambda} = \frac{2}{11} i \, \sqrt{11}, {\mu} = 0, {\Lambda} = 6 \, e^{\left(-1\right)}, q = r_{7}, m = 0, c = \frac{2}{z^{2}}\right], \left[{\lambda} = -\frac{2}{11} i \, \sqrt{11}, {\mu} = 0, {\Lambda} = 6 \, e^{\left(-1\right)}, q = r_{8}, m = 0, c = \frac{2}{z^{2}}\right], \left[{\lambda} = \frac{2}{11} i \, \sqrt{11}, {\mu} = r_{9}, {\Lambda} = 6 \, e^{\left(-1\right)}, q = 0, m = 0, c = \frac{2}{z^{2}}\right], \left[{\lambda} = -\frac{2}{11} i \, \sqrt{11}, {\mu} = r_{10}, {\Lambda} = 6 \, e^{\left(-1\right)}, q = 0, m = 0, c = \frac{2}{z^{2}}\right]\right]$$

In the above solutions, $r_i$, with $i$ an integer, stands for an arbitrary parameter.

The solutions for $c=0$ are those already obtained for $b(z)=1$. But there are no solution with $c\not = 0$ and $c={\rm const}$.

Solution for $\nu=4$

neqs = [eq.subs(nu=4).simplify_full() for eq in eqs]
[eq == 0 for eq in neqs]

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left[-4 \, {\mu} q^{2} - 12 \, {\left(6 \, c^{2} m z^{6} + 11 \, c m z^{4}\right)} \sqrt{z} e^{\left(\frac{1}{2} \, c z^{2}\right)} - 32 \, {\Lambda} e^{\left(c z^{2}\right)} + 24 \, {\left(3 \, c^{2} z^{4} - 7 \, c z^{2} + 10\right)} e^{\left(\frac{1}{2} \, c z^{2}\right)} = 0, 4 \, {\mu} q^{2} + 24 \, {\left(3 \, c^{2} m z^{6} - 2 \, c m z^{4}\right)} \sqrt{z} e^{\left(\frac{1}{2} \, c z^{2}\right)} + 32 \, {\Lambda} e^{\left(c z^{2}\right)} - 24 \, {\left(3 \, c^{2} z^{4} - 7 \, c z^{2} + 10\right)} e^{\left(\frac{1}{2} \, c z^{2}\right)} = 0, -16 \, {\mu} q^{2} + 24 \, {\left(6 \, c^{2} m z^{6} + 5 \, c m z^{4}\right)} \sqrt{z} e^{\left(\frac{1}{2} \, c z^{2}\right)} + 64 \, {\Lambda} e^{\left(c z^{2}\right)} - 24 \, {\left(6 \, c^{2} z^{4} - 5 \, c z^{2} + 5\right)} e^{\left(\frac{1}{2} \, c z^{2}\right)} = 0, \frac{4}{3} \, {\lambda}^{2} {\mu} q^{2} + \frac{32}{3} \, {\Lambda} {\lambda}^{2} e^{\left(c z^{2}\right)} + 4 \, {\left(47 \, c {\lambda}^{2} m z^{4} - {\left(3 \, {\lambda}^{2} - 4\right)} m z^{2}\right)} \sqrt{z} e^{\left(\frac{1}{2} \, c z^{2}\right)} - 4 \, {\left(22 \, c {\lambda}^{2} z^{2} + 17 \, {\lambda}^{2} + 4\right)} e^{\left(\frac{1}{2} \, c z^{2}\right)} = 0, 12 \, c m z^{\frac{9}{2}} e^{\left(\frac{1}{2} \, c z^{2}\right)} - {\lambda}^{2} {\mu} q^{2} - 4 \, {\left(3 \, c z^{2} - 5\right)} e^{\left(\frac{1}{2} \, c z^{2}\right)} = 0\right]$$

solve([eq == 0 for eq in neqs], lamb, mu, Lamb, q, m, c)

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left[\left[{\lambda} = -\frac{2}{3} \, \sqrt{3}, {\mu} = \frac{15}{r_{11}^{2}}, {\Lambda} = \left(\frac{45}{8}\right), q = r_{11}, m = r_{12}, c = 0\right], \left[{\lambda} = \frac{2}{3} \, \sqrt{3}, {\mu} = \frac{15}{r_{13}^{2}}, {\Lambda} = \left(\frac{45}{8}\right), q = r_{13}, m = r_{14}, c = 0\right], \left[{\lambda} = \frac{2}{3} \, \sqrt{3}, {\mu} = -\frac{39 \, e^{3}}{r_{15}^{2}}, {\Lambda} = \frac{495}{8} \, e^{\left(-3\right)}, q = r_{15}, m = 0, c = \frac{6}{z^{2}}\right], \left[{\lambda} = -\frac{2}{3} \, \sqrt{3}, {\mu} = -\frac{39 \, e^{3}}{r_{16}^{2}}, {\Lambda} = \frac{495}{8} \, e^{\left(-3\right)}, q = r_{16}, m = 0, c = \frac{6}{z^{2}}\right], \left[{\lambda} = \frac{2}{11} i \, \sqrt{3}, {\mu} = 0, {\Lambda} = 5 \, e^{\left(-\frac{5}{6}\right)}, q = r_{17}, m = 0, c = \frac{5}{3 \, z^{2}}\right], \left[{\lambda} = -\frac{2}{11} i \, \sqrt{3}, {\mu} = 0, {\Lambda} = 5 \, e^{\left(-\frac{5}{6}\right)}, q = r_{18}, m = 0, c = \frac{5}{3 \, z^{2}}\right], \left[{\lambda} = \frac{2}{11} i \, \sqrt{3}, {\mu} = r_{19}, {\Lambda} = 5 \, e^{\left(-\frac{5}{6}\right)}, q = 0, m = 0, c = \frac{5}{3 \, z^{2}}\right], \left[{\lambda} = -\frac{2}{11} i \, \sqrt{3}, {\mu} = r_{20}, {\Lambda} = 5 \, e^{\left(-\frac{5}{6}\right)}, q = 0, m = 0, c = \frac{5}{3 \, z^{2}}\right]\right]$$

In the above solutions, $r_i$, with $i$ an integer, stands for an arbitrary parameter.

The solutions for $c=0$ are those already obtained for $b(z)=1$. But there are no solution with $c\not = 0$ and $c={\rm const}$.