Las ecuaciones paramétricas del movimiento de una partícula de 2 kg son:
$$
\left.\begin{array}{r}x=t^3\\y=t^2+2\\z=t\end{array}\right\}
$$
Calcula:
var('t')
# -------- DATOS (en unidades del SI) --------
# Ecuaciones paramétricas del movimiento
x(t) = t^3
y(t) = t^2 + 2
z(t) = t
# Masa m de la partícula
m = 2
# Instantes t1 y t2 considerados
t1 = 1
t2 = 3
# Punto (x0, y0, z0) respecto al que se calcula el momento
x0 = 0
y0 = 0
z0 = 0
# Ecuaciones de la posición, velocidad y aceleración en función del tiempo
r = vector((x(t), y(t), z(t)))
v = r.derivative(t)
a = r.derivative(t, 2)
# Salida por pantalla
show("Vector de posicion en funcion del tiempo (m):")
show(r)
show("Velocidad en funcion del tiempo (m/s):")
show(v)
show("Aceleracion en funcion del tiempo (m/s^2):")
show(a)
De acuerdo con la segunda ley de Newton: $$\Sigma\vec{F}=m·\vec{a}$$ siendo:
Ejercicio
Halla la fuerza que produce el movimiento de la partícula.
# Fuerza en función del tiempo
F = m*a
# Salida por pantalla
show("Fuerza en funcion del tiempo (N):")
show(F)
Ejercicio
Halla la fuerza en el instante $t_1$.
# Fuerza en el instante t1
F1 = F(t=t1)
# Salida por pantalla
show("Fuerza en el instante t = %.2f s (en N):" % t1)
show(F1)
El momento lineal $\vec{p}$ de una partícula de masa $m$ que se mueve con una velocidad $\vec{v}$ es: $$ \vec{p}=m·\vec{v} $$
Ejercicio
Halla el momento lineal de la partícula en función del tiempo.
# Momento lineal en función del tiempo
p = m*v
# Salida por pantalla
show("Momento lineal en funcion del tiempo (kg m/s):")
show(p)
Ejercicio
Calcula el momento lineal de la partícula en el instante $t_1$ y en el instante $t_2$.
# Momento lineal en el instante t1
p1 = p(t=t1)
# Momento lineal en el instante t2
p2 = p(t=t2)
# Salida por pantalla
show("Momento lineal en el instante t = %.2f s (en kg m/s):" % t1)
show(p1)
show("Momento lineal en el instante t = %.2f s (en kg m/s):" % t2)
show(p2)
Ejercicio
¿Cuánto ha variado el momento lineal de la partícula entre los instantes $t_1$ y $t_2$?
# Variación del momento lineal entre t1 y t2
delta_p = p2 - p1
# Salida por pantalla
show("Variacion del momento lineal entre los instantes t = %.2f s y t = %.2f s (kg m/s):" % (t1, t2))
show(delta_p)
El impulso $\vec{I}$ de una fuerza $\vec{F}$ en el intervalo de tiempo $(t_1,t_2)$ se define como:
$$ \vec{I}=\int_{t_1}^{t_2}\vec{F}dt $$
Si la fuerza es constante la expresión anterior se reduce a:
$$ \vec{I}=\vec{F}\Delta t $$
donde $\Delta t = t_2-t_1$.
Ejercicio
Calcula el impulso que la fuerza $\vec{F}$ le comunica a la partícula cuando está actuando desde el instante $t_1$ hasta el instante $t_2$.
# Impulso de F entre t1 y t2
impulso12 = F.integrate(t, t1, t2)
# Salida por pantalla
show("Impulso entre los instantes t = %.2f s y t = %.2f s (en N s):" % (t1, t2))
show(impulso12)
El impulso de una fuerza es igual a la variación del momento lineal que experimenta el cuerpo sobre el que está actuando la fuerza:
$$ \vec{I}=\Delta\vec{p} \;\Rightarrow\; \vec{I}=\vec{p}_2-\vec{p}_1$$
Ejercicio
Utiliza los resultados obtenidos en los ejercicios anteriores para comprobar esta igualdad.
El momento $\vec M$ de una fuerza $\vec F$ con respecto a un punto $O$ se define como el producto vectorial de $\overrightarrow{OP}$ por $\vec F$, donde $\overrightarrow {OP}$ es el vector de origen el punto $O$ y extremo el punto $P$ de aplicación de $\vec F$:
$$ \vec M=\overrightarrow{OP}\times\vec F $$
Para calcular el vector $\vec{r}$ se restan las coordenadas de $P(x,y,x)$ menos las coordenadas de $O(x_0,y_0,z_0)$:
$$ \overrightarrow{OP}=(x-x_0,y-y_0,z-z_0) $$
Si el momento se calcula con respecto al origen de coordenadas, entonces $\overrightarrow{OP}=\vec{r}$, donde $\vec{r}$ es el vector de posición de la partícula. En consecuencia:
$$ \vec M=\vec{r}\times\vec F $$
El momento de una fuerza mide la tendencia de dicha fuerza a causar una rotación alrededor de un eje que pasa por O.
# Punto O respecto al que se calcula el momento: O(x0, y0, z0)
puntoO = vector((x0, y0, z0))
# Punto P de aplicación de la fuerza: P(x, y, z)
puntoP = vector((x(t), y(t), z(t)))
# Vector OP = P - O
OP = puntoP - puntoO
# Momento: M = OP x F
M = OP.cross_product(F)
# Salida por pantalla
show("Momento de la fuerza con respecto al punto (%.2f, %.2f, %.2f) (N m):" % (x0,y0,z0))
show(M.simplify_full())
El trabajo que realiza la fuerza $\vec{F}$ al desplazar una partícula entre las posiciones $A$ y $B$ es:
$$ W_A^B=\int_A^B\vec{F}\;d\vec{r} $$
Teniendo en cuenta que $$ \vec{v}=\frac{d\vec{r}}{dt} \;\Rightarrow\; d\vec{r}=\vec{v}\;dt $$ entonces el trabajo también se puede calcular como: $$ W_A^B=\int_A^B\vec{F}\;d\vec{r}=\int_A^B\vec{F}·\vec{v}\;dt $$
Si la fuerza es constante, entonces: $$ W_{A\rightarrow B}=\vec{F}·(\vec{r}_B - \vec{r}_A) = \vec{F}·\Delta\vec{r} $$
# Producto de la fuerza y la velocidad
productoFv = F.dot_product(v)
# Trabajo entre t1 y t2
trabajo12 = integrate(productoFv, t, t1, t2)
# Salida por pantalla
show("Trabajo que realiza la fuerza entre t = %.2f s y t = %.2f s:" % (t1, t2))
show("%.2f J" % trabajo12)
La energía cinética de una partícula de masa $m$ que se mueve a una velocidad $v$ es: $$ E_c = \frac12 m v^2 $$
Ejercicio
Calcula la energía cinética de la partícula en los instantes $t_1$ y $t_2$.
# Módulo de la velocidad
modulo_v = v.norm()
# Energia cinética
Ec = 0.5*m*modulo_v^2
# Energia cinética en t1
Ec1 = Ec(t=t1)
# Energia cinética en t2
Ec2 = Ec(t=t2)
# Salida por pantalla
show("Energia cinetica en t = %.2f s: %.2f J" % (t1, Ec1))
show("Energia cinetica en t = %.2f s: %.2f J" % (t2, Ec2))
Ejercicio
¿Cuánto ha variado la energía cinética de la partícula entre los instantes $t_1$ y $t_2$?
# Variación de la energía cinética
delta_Ec = Ec2 - Ec1
# Salida por pantalla
show("Variacion de la energia cinetica entre t = %.2f s y t = %.2f s:" % (t1, t2))
show("%.2f J" % delta_Ec)
El trabajo de la fuerza resultante que actúa sobre un cuerpo se emplea en variar su energía cinética:
$$ W= \Delta E_c $$
Ejercicio
Utiliza los resultados obtenidos en los ejercicios anteriores para comprobar este teorema.
La potencia media $P_m$ de una fuerza se define como el trabajo realizado por la fuerza dividido por el tiempo empleado en realizar dicho trabajo: $$ P_m = \frac{W_A^B}{\Delta t}$$
Ejercicio
Calcula la potencia media desarrollada por la fuerza entre los instantes $t_1$ y $t_2$.
# Intervalo de tiempo
delta_t = t2 - t1
# Potencia media
Pm = trabajo12 / delta_t
# Salida por pantalla
show("Potencia media entre t = %.2f s y t = %.2f s:" % (t1, t2))
show("%.2f W" % Pm)
La potencia instántanea es el límite de la potencia media cuando $\Delta t$ tiende a cero:
$$ P=\lim_{\Delta t\rightarrow0}P_m=\lim_{\Delta t\rightarrow0}\;\frac{W_A^B}{\Delta t}$$
Es decir:
$$ P=\frac{dW}{dt} $$
Teniendo en cuenta que $dW=\vec{F}\;d\vec{r}$, y que $\vec{v}=\frac{d\vec r}{dt}$, entonces la potencia instantánea se puede calcular de la siguiente manera:
$$ P = \frac{dW}{dt} = \frac{\vec{F}\;d\vec{r}}{dt} = \vec{F}\;\vec{v} $$
Ejercicio
Calcula la potencia en el instante $t_1$.
# El producto F·v ya fue calculado anteriormente y se llama "productoFv"
# Potencia en función del tiempo
Pot = productoFv
# Potencia en t1
Pot1 = Pot(t=t1)
# Salida por pantalla
show("Potencia instantanea en funcion del tiempo (en W):")
show(Pot)
show("Potencia en t = %.2f s:" % t1)
show("%.2f W" % Pot1)
El momento angular $\vec{L}$ de una partícula con respecto a un punto es el momento con respecto a dicho punto del momento lineal de la partícula: $$ \vec{L} = \vec{r} \times \vec{p} $$
Su módulo es:
$$
L= r·p·sen\theta=r·m·v·sen\theta
$$
siendo $\theta$ el ángulo que forma la velocidad con el vector de posición de la partícula en cada instante.
El momento angular caracteriza el estado de rotación de un cuerpo.
Ejercicio
Calcula el momento angular de la partícula con respecto al origen de coordenadas.
# Punto respecto al que se calcula el momento angular: O
# Punto de aplicación del vector p: P
# El vector r = OP ya ha sido calculado con anterioridad
# Momento angular: L = OP x p
L = OP.cross_product(p)
# Salida por pantalla
show("Momento angular con respecto al punto (%.2f, %.2f, %.2f) (N m):" % (x0, y0, z0))
show(L.simplify_full())
La derivada del momento angular con respecto al tiempo es: $$ \frac{d\vec{L}}{dt} = \frac d{dt}(\vec{r} \times \vec{p})= \frac{d\vec{r}}{dt}\times \vec{p} + \vec{r} \times \frac{d\vec{p}}{dt} = \vec{v} \times \vec{p} + \vec{r} \times \vec{F}$$ El primer sumando de la expresión anterior, $\vec{v} \times \vec{p}$, es cero, porque $\vec{v}$ y $\vec{p}$ son vectores paralelos y, por tanto, su producto vectorial vale cero. El segundo sumando es el momento de la fuerza: $\vec M = \vec{r} \times \vec{F}$ . Por tanto: $$ \vec{M} = \frac{d\vec{L}}{dt} $$ Esta expresión constituye la ley fundamental de la dinámica de rotación, y es análoga a $\vec{F}=\frac{d\vec{p}}{dt}$ en el caso de la dinámica de traslación.
Ejercicio
Deriva el momento angular y comprueba que coincide con el momento de la fuerza.
# Derivada del momento angular
derivadaL = L.derivative(t)
# Salida por pantalla
show("Derivada del momento angular con respecto al tiempo:")
show(derivadaL.simplify_full())