Las ecuaciones paramétricas del movimiento de una partícula material de masa 2 kg son: $$ \left.\begin{array}{r}x=sen(2t)\\y=\cos(2t)\\z=3\end{array}\right\} $$ donde las coordenadas vienen dadas en metros y el tiempo en segundos.
var('t')
# -------- DATOS (en unidades del SI) --------
# Ecuaciones paramétricas del movimiento
x(t) = sin(2*t)
y(t) = cos(2*t)
z(t) = 3
# Masa m de la partícula
m = 2
# Instante considerado
t1 = 0
# Centro de curvatura --> punto (x0, y0, z0) respecto al que se calcula el momento
x0 = 0
y0 = 0
z0 = 3
# Intervalo para la representación de la trayectoria
tmin = 0
tmax = pi
# --------- Cálculo de las magnitudes en función del tiempo ----------------
# Posición, velocidad y aceleración
r = vector((x(t), y(t), z(t)))
v = r.derivative(t)
a = r.derivative(t, 2)
# Módulo de la velocidad
modulo_v = v.norm()
# Derivada del módulo de la velocidad
derivada_modulo_v = modulo_v.derivative(t)
# Vector tangente a la trayectoria
ut = v / modulo_v
# Aceleración tangencial
at = derivada_modulo_v*ut
# Aceleración normal
an = a - at
# Módulo de la aceleración normal
modulo_an = an.norm()
# Radio de curvatura
R = modulo_v^2/modulo_an
# Momento lineal
p = m*v
# Fuerza
F = m*a
# Punto O respecto al que se calcula el momento de la fuerza: O(x0, y0, z0) --> centro de curvatura
coordPuntoO = vector((x0, y0, z0))
# Punto P de aplicación de la fuerza --> coincide con el vector de posición de la partícula
# Vector OP = P - O
OP = r - coordPuntoO
# Momento de la fuerza: M = OP x F
M = OP.cross_product(F)
# Momento angular: L = OP x p
L = OP.cross_product(p)
# Derivada del momento angular
derivadaL = L.derivative(t)
# -------- Representación gráfica -----------
# Trayectoria entre los instantes tmin y tmax
trayectoria = parametric_plot((x(t), y(t), z(t)), (t, tmin, tmax), thickness=6, color='purple')
# Origen de coordenadas
origen = point3d((0, 0, 0), size=10, color='black')
# Centro de curvatura
centro = point3d(coordPuntoO, size=10, color='red')
# Punto P que ocupa la partícula en el instante t1
coordPuntoP = r(t=t1)
puntoP = point3d(coordPuntoP, size=20, color='orange')
# Vector OP de origen (x0, y0, z0) y extremo el punto P en el instante t1
vectorOP = arrow3d(coordPuntoO, coordPuntoP)
# Momento angular en el instante t1
L1 = L(t=t1)
vectorL = arrow(coordPuntoO, coordPuntoO + L1)
# -------- SALIDA POR PANTALLA --------
# Posición
show("Posicion en funcion del tiempo (m):")
show(r)
# Velocidad
show("Velocidad en funcion del tiempo (m/s):")
show(v)
show("Modulo de la velocidad en funcion del tiempo (m/s):")
show(modulo_v.simplify_full())
# Aceleración
show("Aceleracion en funcion del tiempo (m/s^2):")
show(a)
# Aceleración tangencial
show("Aceleracion tangencial en funcion del tiempo (m/s^2):")
show(at)
# Aceleración normal
show("Aceleracion normal en funcion del tiempo (m/s^2):")
show(an)
show("Modulo de la aceleracion normal en funcion del tiempo (m/s^2):")
show(modulo_an.simplify_full())
# Fuerza
show("Fuerza en funcion del tiempo (N):")
show(F)
# Momento de la fuerza
show("Momento de la fuerza con respecto al punto (%.2f, %.2f, %.2f) (N m):" % (x0,y0,z0))
show(M)
# Momento angular
show("Momento angular con respecto al punto (%.2f, %.2f, %.2f) (N m):" % (x0, y0, z0))
show(L.simplify_full())
# Representación gráfica
show(trayectoria + origen + centro + puntoP + vectorOP + vectorL)