Vaidya-Lifshitz solution

This Jupyter/SageMath worksheet implements some computations of the article

• I. Ya. Aref'eva, A. A. Golubtsova & E. Gourgoulhon: Analytic black branes in Lifshitz-like backgrounds and thermalization, arXiv:1601.06046

These computations are based on SageManifolds (v0.9).

The worksheet file (ipynb format) can be downloaded from here.

First we set up the notebook to display mathematical objects using LaTeX formatting:

%display latex

Spacetime manifold and coordinates

Let us declare the spacetime $M$ as a 5-dimensional manifold:

M = Manifold(5, 'M')
print M

5-dimensional differentiable manifold M

We introduce coordinates of Eddington-Finkelstein type:

X.<v,x,y1,y2,r> = M.chart('v x y1:y_1 y2:y_2 r')
X

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(M,(v, x, {y_1}, {y_2}, r)\right)$$

The metric tensor:

g = M.lorentzian_metric('g')
nu = var('nu', latex_name=r'\nu', domain='real')
ff = function('f')(v, r)
g[0,0] = -exp(2*nu*r)*ff
g[0,4] = exp(nu*r)
g[1,1] = exp(2*nu*r)
g[2,2] = exp(2*r)
g[3,3] = exp(2*r)
g.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}g = -e^{\left(2 \, {\nu} r\right)} f\left(v, r\right) \mathrm{d} v\otimes \mathrm{d} v + e^{\left({\nu} r\right)} \mathrm{d} v\otimes \mathrm{d} r + e^{\left(2 \, {\nu} r\right)} \mathrm{d} x\otimes \mathrm{d} x + e^{\left(2 \, r\right)} \mathrm{d} {y_1}\otimes \mathrm{d} {y_1} + e^{\left(2 \, r\right)} \mathrm{d} {y_2}\otimes \mathrm{d} {y_2} + e^{\left({\nu} r\right)} \mathrm{d} r\otimes \mathrm{d} v$$

The non-vanishing components of $g$:

g.display_comp()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{lcl} g_{ \, v \, v }^{ \phantom{\, v } \phantom{\, v } } & = & -e^{\left(2 \, {\nu} r\right)} f\left(v, r\right) \\ g_{ \, v \, r }^{ \phantom{\, v } \phantom{\, r } } & = & e^{\left({\nu} r\right)} \\ g_{ \, x \, x }^{ \phantom{\, x } \phantom{\, x } } & = & e^{\left(2 \, {\nu} r\right)} \\ g_{ \, {y_1} \, {y_1} }^{ \phantom{\, {y_1} } \phantom{\, {y_1} } } & = & e^{\left(2 \, r\right)} \\ g_{ \, {y_2} \, {y_2} }^{ \phantom{\, {y_2} } \phantom{\, {y_2} } } & = & e^{\left(2 \, r\right)} \\ g_{ \, r \, v }^{ \phantom{\, r } \phantom{\, v } } & = & e^{\left({\nu} r\right)} \end{array}$$

A matrix view of the components:

g[:]

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(\begin{array}{rrrrr} -e^{\left(2 \, {\nu} r\right)} f\left(v, r\right) & 0 & 0 & 0 & e^{\left({\nu} r\right)} \\ 0 & e^{\left(2 \, {\nu} r\right)} & 0 & 0 & 0 \\ 0 & 0 & e^{\left(2 \, r\right)} & 0 & 0 \\ 0 & 0 & 0 & e^{\left(2 \, r\right)} & 0 \\ e^{\left({\nu} r\right)} & 0 & 0 & 0 & 0 \end{array}\right)$$

Curvature

The Riemann tensor is

Riem = g.riemann()
print Riem

Tensor field Riem(g) of type (1,3) on the 5-dimensional differentiable manifold M

Some component, e.g. $\mathrm{Riem}^0_{\ \, 004}$:

Riem[0,0,0,4]

$$\newcommand{\Bold}[1]{\mathbf{#1}}-{\nu}^{2} e^{\left({\nu} r\right)} f\left(v, r\right) - \frac{3}{2} \, {\nu} e^{\left({\nu} r\right)} \frac{\partial\,f}{\partial r} - \frac{1}{2} \, e^{\left({\nu} r\right)} \frac{\partial^2\,f}{\partial r^2}$$

The Ricci tensor:

Ric = g.ricci()
print Ric

Field of symmetric bilinear forms Ric(g) on the 5-dimensional differentiable manifold M

Ric.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{Ric}\left(g\right) = \left( 2 \, {\left({\nu}^{2} + {\nu}\right)} e^{\left(2 \, {\nu} r\right)} f\left(v, r\right)^{2} + {\left(2 \, {\nu} + 1\right)} e^{\left(2 \, {\nu} r\right)} f\left(v, r\right) \frac{\partial\,f}{\partial r} - \frac{1}{2} \, {\left({\nu} + 2\right)} e^{\left({\nu} r\right)} \frac{\partial\,f}{\partial v} + \frac{1}{2} \, e^{\left(2 \, {\nu} r\right)} f\left(v, r\right) \frac{\partial^2\,f}{\partial r^2} \right) \mathrm{d} v\otimes \mathrm{d} v + \left( -2 \, {\left({\nu}^{2} + {\nu}\right)} e^{\left({\nu} r\right)} f\left(v, r\right) - {\left(2 \, {\nu} + 1\right)} e^{\left({\nu} r\right)} \frac{\partial\,f}{\partial r} - \frac{1}{2} \, e^{\left({\nu} r\right)} \frac{\partial^2\,f}{\partial r^2} \right) \mathrm{d} v\otimes \mathrm{d} r + \left( -2 \, {\left({\nu}^{2} + {\nu}\right)} e^{\left(2 \, {\nu} r\right)} f\left(v, r\right) - {\nu} e^{\left(2 \, {\nu} r\right)} \frac{\partial\,f}{\partial r} \right) \mathrm{d} x\otimes \mathrm{d} x + \left( -2 \, {\left({\nu} + 1\right)} e^{\left(2 \, r\right)} f\left(v, r\right) - e^{\left(2 \, r\right)} \frac{\partial\,f}{\partial r} \right) \mathrm{d} {y_1}\otimes \mathrm{d} {y_1} + \left( -2 \, {\left({\nu} + 1\right)} e^{\left(2 \, r\right)} f\left(v, r\right) - e^{\left(2 \, r\right)} \frac{\partial\,f}{\partial r} \right) \mathrm{d} {y_2}\otimes \mathrm{d} {y_2} + \left( -2 \, {\left({\nu}^{2} + {\nu}\right)} e^{\left({\nu} r\right)} f\left(v, r\right) - {\left(2 \, {\nu} + 1\right)} e^{\left({\nu} r\right)} \frac{\partial\,f}{\partial r} - \frac{1}{2} \, e^{\left({\nu} r\right)} \frac{\partial^2\,f}{\partial r^2} \right) \mathrm{d} r\otimes \mathrm{d} v + \left( 2 \, {\nu} - 2 \right) \mathrm{d} r\otimes \mathrm{d} r$$

Ric.display_comp()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{lcl} \mathrm{Ric}\left(g\right)_{ \, v \, v }^{ \phantom{\, v } \phantom{\, v } } & = & 2 \, {\left({\nu}^{2} + {\nu}\right)} e^{\left(2 \, {\nu} r\right)} f\left(v, r\right)^{2} + {\left(2 \, {\nu} + 1\right)} e^{\left(2 \, {\nu} r\right)} f\left(v, r\right) \frac{\partial\,f}{\partial r} - \frac{1}{2} \, {\left({\nu} + 2\right)} e^{\left({\nu} r\right)} \frac{\partial\,f}{\partial v} + \frac{1}{2} \, e^{\left(2 \, {\nu} r\right)} f\left(v, r\right) \frac{\partial^2\,f}{\partial r^2} \\ \mathrm{Ric}\left(g\right)_{ \, v \, r }^{ \phantom{\, v } \phantom{\, r } } & = & -2 \, {\left({\nu}^{2} + {\nu}\right)} e^{\left({\nu} r\right)} f\left(v, r\right) - {\left(2 \, {\nu} + 1\right)} e^{\left({\nu} r\right)} \frac{\partial\,f}{\partial r} - \frac{1}{2} \, e^{\left({\nu} r\right)} \frac{\partial^2\,f}{\partial r^2} \\ \mathrm{Ric}\left(g\right)_{ \, x \, x }^{ \phantom{\, x } \phantom{\, x } } & = & -2 \, {\left({\nu}^{2} + {\nu}\right)} e^{\left(2 \, {\nu} r\right)} f\left(v, r\right) - {\nu} e^{\left(2 \, {\nu} r\right)} \frac{\partial\,f}{\partial r} \\ \mathrm{Ric}\left(g\right)_{ \, {y_1} \, {y_1} }^{ \phantom{\, {y_1} } \phantom{\, {y_1} } } & = & -2 \, {\left({\nu} + 1\right)} e^{\left(2 \, r\right)} f\left(v, r\right) - e^{\left(2 \, r\right)} \frac{\partial\,f}{\partial r} \\ \mathrm{Ric}\left(g\right)_{ \, {y_2} \, {y_2} }^{ \phantom{\, {y_2} } \phantom{\, {y_2} } } & = & -2 \, {\left({\nu} + 1\right)} e^{\left(2 \, r\right)} f\left(v, r\right) - e^{\left(2 \, r\right)} \frac{\partial\,f}{\partial r} \\ \mathrm{Ric}\left(g\right)_{ \, r \, v }^{ \phantom{\, r } \phantom{\, v } } & = & -2 \, {\left({\nu}^{2} + {\nu}\right)} e^{\left({\nu} r\right)} f\left(v, r\right) - {\left(2 \, {\nu} + 1\right)} e^{\left({\nu} r\right)} \frac{\partial\,f}{\partial r} - \frac{1}{2} \, e^{\left({\nu} r\right)} \frac{\partial^2\,f}{\partial r^2} \\ \mathrm{Ric}\left(g\right)_{ \, r \, r }^{ \phantom{\, r } \phantom{\, r } } & = & 2 \, {\nu} - 2 \end{array}$$

The Ricci scalar:

Rscal = g.ricci_scalar()
print Rscal

Scalar field r(g) on the 5-dimensional differentiable manifold M

Rscal.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} \mathrm{r}\left(g\right):& M & \longrightarrow & \mathbb{R} \\ & \left(v, x, {y_1}, {y_2}, r\right) & \longmapsto & -2 \, {\left(3 \, {\nu}^{2} + 4 \, {\nu} + 3\right)} f\left(v, r\right) - {\left(5 \, {\nu} + 4\right)} \frac{\partial\,f}{\partial r} - \frac{\partial^2\,f}{\partial r^2} \end{array}$$

Source model

Let us consider a model based on the following action, involving a dilaton scalar field $\phi$ and a Maxwell 2-form $F$:

$$ S = \int \left( R(g) + \Lambda - \frac{1}{2} \nabla_m \phi \nabla^m \phi - \frac{1}{4} e^{\lambda\phi} F_{mn} F^{mn} + 8\pi \mathcal{L}_{\rm shell} \right) \sqrt{-g} \, \mathrm{d}^5 x \qquad\qquad \mbox{(1)}$$

where $R(g)$ is the Ricci scalar of metric $g$, $\Lambda$ is the cosmological constant, $\lambda$ is the dilatonic coupling constant and $\mathcal{L}_{\rm shell}$ is the Lagrangian of some infalling shell of massless matter.

The dilaton scalar field

We consider the following ansatz for the dilaton scalar field $\phi$: $$ \phi = \frac{1}{\lambda} \left( 4 r + \ln\mu \right),$$ where $\mu$ is a constant.

var('mu', latex_name=r'\mu', domain='real')
var('lamb', latex_name=r'\lambda', domain='real')
phi = M.scalar_field({X: (4*r + ln(mu))/lamb}, 
                     name='phi', latex_name=r'\phi')
phi.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} \phi:& M & \longrightarrow & \mathbb{R} \\ & \left(v, x, {y_1}, {y_2}, r\right) & \longmapsto & \frac{4 \, r + \log\left({\mu}\right)}{{\lambda}} \end{array}$$

The 1-form $\mathrm{d}\phi$ is

dphi = phi.differential()
print dphi

1-form dphi on the 5-dimensional differentiable manifold M

dphi.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{d}\phi = \frac{4}{{\lambda}} \mathrm{d} r$$

The components of $\mathrm{d}\phi$ is the default frame of $M$ are

dphi[:]

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left[0, 0, 0, 0, \frac{4}{{\lambda}}\right]$$

The 2-form field

We consider the following ansatz for $F$: $$ F = \frac{1}{2} q \, \mathrm{d}y_1\wedge \mathrm{d}y_2, $$ where $q$ is a constant.

Let us first get the 1-forms $\mathrm{d}y_1$ and $\mathrm{d}y_2$:

X.coframe()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(M ,\left(\mathrm{d} v,\mathrm{d} x,\mathrm{d} {y_1},\mathrm{d} {y_2},\mathrm{d} r\right)\right)$$

dy1 = X.coframe()[2]
dy2 = X.coframe()[3]
print dy1
print dy2
dy1, dy2

1-form dy1 on the 5-dimensional differentiable manifold M
1-form dy2 on the 5-dimensional differentiable manifold M

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(\mathrm{d} {y_1}, \mathrm{d} {y_2}\right)$$

Then we can form $F$ according to the above ansatz:

var('q', domain='real')
F = q/2 * dy1.wedge(dy2)
F.set_name('F')
print F
F.display()

2-form F on the 5-dimensional differentiable manifold M

$$\newcommand{\Bold}[1]{\mathbf{#1}}F = \frac{1}{2} \, q \mathrm{d} {y_1}\wedge \mathrm{d} {y_2}$$

By construction, the 2-form $F$ is closed (since $q$ is constant):

xder(F).display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{d}F = 0$$

Let us evaluate the square $F_{mn} F^{mn}$ of $F$:

Fu = F.up(g)
F2 = F['_{mn}']*Fu['^{mn}']  # using LaTeX notations to denote contraction
print F2
F2.display()

Scalar field on the 5-dimensional differentiable manifold M

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} & M & \longrightarrow & \mathbb{R} \\ & \left(v, x, {y_1}, {y_2}, r\right) & \longmapsto & \frac{1}{2} \, q^{2} e^{\left(-4 \, r\right)} \end{array}$$

We shall also need the tensor $\mathcal{F}_{mn} := F_{mp} F_n^{\ \, p}$:

FF = F['_mp'] * F.up(g,1)['^p_n']
print FF
FF.display()

Tensor field of type (0,2) on the 5-dimensional differentiable manifold M

$$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{4} \, q^{2} e^{\left(-2 \, r\right)} \mathrm{d} {y_1}\otimes \mathrm{d} {y_1} + \frac{1}{4} \, q^{2} e^{\left(-2 \, r\right)} \mathrm{d} {y_2}\otimes \mathrm{d} {y_2}$$

The tensor field $\mathcal{F}$ is symmetric:

FF == FF.symmetrize()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{True}$$

Therefore, from now on, we set

FF = FF.symmetrize()

The infalling shell of massless particles

Energy-momentum tensor of the infalling shell:

dv = X.coframe()[0]
T = function('T00', latex_name='T_{00}')(v,r)*dv*dv
T.set_name('T')
T.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}T = T_{00}\left(v, r\right) \mathrm{d} v\otimes \mathrm{d} v$$

Einstein equation

Let us first introduce (minus twice) the cosmological constant:

var('Lamb', latex_name=r'\Lambda', domain='real')

$$\newcommand{\Bold}[1]{\mathbf{#1}}{\Lambda}$$

From the action (1), the field equation for the metric $g$ is $$ R_{mn} + \frac{\Lambda}{3} \, g - \frac{1}{2}\partial_m\phi \partial_n\phi -\frac{1}{2} e^{\lambda\phi} F_{mp} F^{\ \, p}_n + \frac{1}{12} e^{\lambda\phi} F_{rs} F^{rs} \, g_{mn} - 8\pi T_{mn} = 0 $$ We write it as

EE == 0

with EE defined by

EE = Ric + Lamb/3*g - 1/2* (dphi*dphi) -  1/2*exp(lamb*phi)*FF \
     + 1/12*exp(lamb*phi)*F2*g -8*pi*T
EE.set_name('E')
print EE

Tensor field E of type (0,2) on the 5-dimensional differentiable manifold M

EE.display_comp(only_nonredundant=True)

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{lcl} E_{ \, v \, v }^{ \phantom{\, v } \phantom{\, v } } & = & 2 \, {\left({\nu}^{2} + {\nu}\right)} e^{\left(2 \, {\nu} r\right)} f\left(v, r\right)^{2} + {\left(2 \, {\nu} + 1\right)} e^{\left(2 \, {\nu} r\right)} f\left(v, r\right) \frac{\partial\,f}{\partial r} - \frac{1}{24} \, {\left({\mu} q^{2} + 8 \, {\Lambda}\right)} e^{\left(2 \, {\nu} r\right)} f\left(v, r\right) - \frac{1}{2} \, {\left({\nu} + 2\right)} e^{\left({\nu} r\right)} \frac{\partial\,f}{\partial v} + \frac{1}{2} \, e^{\left(2 \, {\nu} r\right)} f\left(v, r\right) \frac{\partial^2\,f}{\partial r^2} - 8 \, \pi T_{00}\left(v, r\right) \\ E_{ \, v \, r }^{ \phantom{\, v } \phantom{\, r } } & = & -2 \, {\left({\nu}^{2} + {\nu}\right)} e^{\left({\nu} r\right)} f\left(v, r\right) - {\left(2 \, {\nu} + 1\right)} e^{\left({\nu} r\right)} \frac{\partial\,f}{\partial r} + \frac{1}{24} \, {\left({\mu} q^{2} + 8 \, {\Lambda}\right)} e^{\left({\nu} r\right)} - \frac{1}{2} \, e^{\left({\nu} r\right)} \frac{\partial^2\,f}{\partial r^2} \\ E_{ \, x \, x }^{ \phantom{\, x } \phantom{\, x } } & = & -2 \, {\left({\nu}^{2} + {\nu}\right)} e^{\left(2 \, {\nu} r\right)} f\left(v, r\right) - {\nu} e^{\left(2 \, {\nu} r\right)} \frac{\partial\,f}{\partial r} + \frac{1}{24} \, {\left({\mu} q^{2} + 8 \, {\Lambda}\right)} e^{\left(2 \, {\nu} r\right)} \\ E_{ \, {y_1} \, {y_1} }^{ \phantom{\, {y_1} } \phantom{\, {y_1} } } & = & -2 \, {\left({\nu} + 1\right)} e^{\left(2 \, r\right)} f\left(v, r\right) - \frac{1}{12} \, {\left({\mu} q^{2} - 4 \, {\Lambda}\right)} e^{\left(2 \, r\right)} - e^{\left(2 \, r\right)} \frac{\partial\,f}{\partial r} \\ E_{ \, {y_2} \, {y_2} }^{ \phantom{\, {y_2} } \phantom{\, {y_2} } } & = & -2 \, {\left({\nu} + 1\right)} e^{\left(2 \, r\right)} f\left(v, r\right) - \frac{1}{12} \, {\left({\mu} q^{2} - 4 \, {\Lambda}\right)} e^{\left(2 \, r\right)} - e^{\left(2 \, r\right)} \frac{\partial\,f}{\partial r} \\ E_{ \, r \, v }^{ \phantom{\, r } \phantom{\, v } } & = & -2 \, {\left({\nu}^{2} + {\nu}\right)} e^{\left({\nu} r\right)} f\left(v, r\right) - {\left(2 \, {\nu} + 1\right)} e^{\left({\nu} r\right)} \frac{\partial\,f}{\partial r} + \frac{1}{24} \, {\left({\mu} q^{2} + 8 \, {\Lambda}\right)} e^{\left({\nu} r\right)} - \frac{1}{2} \, e^{\left({\nu} r\right)} \frac{\partial^2\,f}{\partial r^2} \\ E_{ \, r \, r }^{ \phantom{\, r } \phantom{\, r } } & = & \frac{2 \, {\left({\lambda}^{2} {\nu} - {\lambda}^{2} - 4\right)}}{{\lambda}^{2}} \end{array}$$

We note that EE==0 leads to 5 independent equations:

eq1 = EE[0,0]
eq1

$$\newcommand{\Bold}[1]{\mathbf{#1}}2 \, {\left({\nu}^{2} + {\nu}\right)} e^{\left(2 \, {\nu} r\right)} f\left(v, r\right)^{2} + {\left(2 \, {\nu} + 1\right)} e^{\left(2 \, {\nu} r\right)} f\left(v, r\right) \frac{\partial\,f}{\partial r} - \frac{1}{24} \, {\left({\mu} q^{2} + 8 \, {\Lambda}\right)} e^{\left(2 \, {\nu} r\right)} f\left(v, r\right) - \frac{1}{2} \, {\left({\nu} + 2\right)} e^{\left({\nu} r\right)} \frac{\partial\,f}{\partial v} + \frac{1}{2} \, e^{\left(2 \, {\nu} r\right)} f\left(v, r\right) \frac{\partial^2\,f}{\partial r^2} - 8 \, \pi T_{00}\left(v, r\right)$$

eq2 = EE[0,4]/exp(nu*r)
eq2

$$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{24} \, {\mu} q^{2} - 2 \, {\left({\nu}^{2} + {\nu}\right)} f\left(v, r\right) - {\left(2 \, {\nu} + 1\right)} \frac{\partial\,f}{\partial r} + \frac{1}{3} \, {\Lambda} - \frac{1}{2} \, \frac{\partial^2\,f}{\partial r^2}$$

eq3 = EE[1,1]/exp(2*nu*r)
eq3

$$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{24} \, {\mu} q^{2} - 2 \, {\left({\nu}^{2} + {\nu}\right)} f\left(v, r\right) - {\nu} \frac{\partial\,f}{\partial r} + \frac{1}{3} \, {\Lambda}$$

eq4 = EE[2,2]/exp(2*r)
eq4

$$\newcommand{\Bold}[1]{\mathbf{#1}}-\frac{1}{12} \, {\mu} q^{2} - 2 \, {\left({\nu} + 1\right)} f\left(v, r\right) + \frac{1}{3} \, {\Lambda} - \frac{\partial\,f}{\partial r}$$

eq5 = EE[4,4]*lamb^2/2
eq5

$$\newcommand{\Bold}[1]{\mathbf{#1}}{\lambda}^{2} {\nu} - {\lambda}^{2} - 4$$

Dilaton field equation

First we evaluate $\nabla_m \nabla^m \phi$:

nab = g.connection()
print nab
nab

Levi-Civita connection nabla_g associated with the Lorentzian metric g on the 5-dimensional differentiable manifold M

$$\newcommand{\Bold}[1]{\mathbf{#1}}\nabla_{g}$$

box_phi = nab(nab(phi).up(g)).trace()
print box_phi
box_phi.display()

Scalar field on the 5-dimensional differentiable manifold M

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} & M & \longrightarrow & \mathbb{R} \\ & \left(v, x, {y_1}, {y_2}, r\right) & \longmapsto & \frac{4 \, {\left(2 \, {\left({\nu} + 1\right)} f\left(v, r\right) + \frac{\partial\,f}{\partial r}\right)}}{{\lambda}} \end{array}$$

From the action (1), the field equation for $\phi$ is $$ \nabla_m \nabla^m \phi = \frac{\lambda}{4} e^{\lambda\phi} F_{mn} F^{mn}$$ We write it as

DE == 0

with DE defined by

DE = box_phi - lamb/4*exp(lamb*phi) * F2
print DE

Scalar field on the 5-dimensional differentiable manifold M

DE.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} & M & \longrightarrow & \mathbb{R} \\ & \left(v, x, {y_1}, {y_2}, r\right) & \longmapsto & -\frac{{\lambda}^{2} {\mu} q^{2} - 64 \, {\left({\nu} + 1\right)} f\left(v, r\right) - 32 \, \frac{\partial\,f}{\partial r}}{8 \, {\lambda}} \end{array}$$

Hence the dilaton field equation provides a 6th equation:

eq6 = DE.coord_function()*8*lamb
eq6

$$\newcommand{\Bold}[1]{\mathbf{#1}}-{\lambda}^{2} {\mu} q^{2} + 64 \, {\left({\nu} + 1\right)} f\left(v, r\right) + 32 \, \frac{\partial\,f}{\partial r}$$

Maxwell equation

From the action (1), the field equation for $F$ is $$ \nabla_m \left( e^{\lambda\phi} F^{mn} \right)= 0 $$ We write it as

ME == 0

with ME defined by

ME = nab(exp(lamb*phi)*Fu).trace(0,2)
print ME
ME.display()

Vector field on the 5-dimensional differentiable manifold M

$$\newcommand{\Bold}[1]{\mathbf{#1}}0$$

We get identically zero. Hence the Maxwell equation does not bring another equation to be solved.

Summary

We have 6 equations to solve:

eqs = [eq1, eq2, eq3, eq4, eq5, eq6]
for eq in eqs:
    pretty_print(eq)

$$\newcommand{\Bold}[1]{\mathbf{#1}}2 \, {\left({\nu}^{2} + {\nu}\right)} e^{\left(2 \, {\nu} r\right)} f\left(v, r\right)^{2} + {\left(2 \, {\nu} + 1\right)} e^{\left(2 \, {\nu} r\right)} f\left(v, r\right) \frac{\partial\,f}{\partial r} - \frac{1}{24} \, {\left({\mu} q^{2} + 8 \, {\Lambda}\right)} e^{\left(2 \, {\nu} r\right)} f\left(v, r\right) - \frac{1}{2} \, {\left({\nu} + 2\right)} e^{\left({\nu} r\right)} \frac{\partial\,f}{\partial v} + \frac{1}{2} \, e^{\left(2 \, {\nu} r\right)} f\left(v, r\right) \frac{\partial^2\,f}{\partial r^2} - 8 \, \pi T_{00}\left(v, r\right)$$

$$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{24} \, {\mu} q^{2} - 2 \, {\left({\nu}^{2} + {\nu}\right)} f\left(v, r\right) - {\left(2 \, {\nu} + 1\right)} \frac{\partial\,f}{\partial r} + \frac{1}{3} \, {\Lambda} - \frac{1}{2} \, \frac{\partial^2\,f}{\partial r^2}$$

$$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{24} \, {\mu} q^{2} - 2 \, {\left({\nu}^{2} + {\nu}\right)} f\left(v, r\right) - {\nu} \frac{\partial\,f}{\partial r} + \frac{1}{3} \, {\Lambda}$$

$$\newcommand{\Bold}[1]{\mathbf{#1}}-\frac{1}{12} \, {\mu} q^{2} - 2 \, {\left({\nu} + 1\right)} f\left(v, r\right) + \frac{1}{3} \, {\Lambda} - \frac{\partial\,f}{\partial r}$$

$$\newcommand{\Bold}[1]{\mathbf{#1}}{\lambda}^{2} {\nu} - {\lambda}^{2} - 4$$

$$\newcommand{\Bold}[1]{\mathbf{#1}}-{\lambda}^{2} {\mu} q^{2} + 64 \, {\left({\nu} + 1\right)} f\left(v, r\right) + 32 \, \frac{\partial\,f}{\partial r}$$

Solutions

Let us show that solutions exists for $\nu=2$ and $\nu=4$ with the following specific form of the blackening function:

$$ f(v,r) = 1 - m(v) e^{-(2\nu +2)r} $$

To this aim, we declare

fm(v,r) = 1 - function('m')(v)*exp(-(2*nu+2)*r)
fm

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left( v, r \right) \ {\mapsto} \ -e^{\left(-2 \, {\left({\nu} + 1\right)} r\right)} m\left(v\right) + 1$$

and substitute this function for $f(v,r)$ in all the equations:

eq1m = eq1.expr().substitute_function(f, fm).simplify_full()
eq1m

$$\newcommand{\Bold}[1]{\mathbf{#1}}-\frac{1}{24} \, {\left(192 \, \pi T_{00}\left(v, r\right) e^{\left({\nu} r + 2 \, r\right)} - {\left({\mu} q^{2} - 48 \, {\nu}^{2} + 8 \, {\Lambda} - 48 \, {\nu}\right)} e^{\left({\nu} r\right)} m\left(v\right) + {\left({\mu} q^{2} - 48 \, {\nu}^{2} + 8 \, {\Lambda} - 48 \, {\nu}\right)} e^{\left(3 \, {\nu} r + 2 \, r\right)} - 12 \, {\left({\nu} + 2\right)} D[0]\left(m\right)\left(v\right)\right)} e^{\left(-{\nu} r - 2 \, r\right)}$$

eq1m = (eq1m * exp(nu*r+2*r)).simplify_full()
eq1m

$$\newcommand{\Bold}[1]{\mathbf{#1}}-8 \, \pi T_{00}\left(v, r\right) e^{\left({\nu} r + 2 \, r\right)} + \frac{1}{24} \, {\left({\mu} q^{2} - 48 \, {\nu}^{2} + 8 \, {\Lambda} - 48 \, {\nu}\right)} e^{\left({\nu} r\right)} m\left(v\right) - \frac{1}{24} \, {\left({\mu} q^{2} - 48 \, {\nu}^{2} + 8 \, {\Lambda} - 48 \, {\nu}\right)} e^{\left(3 \, {\nu} r + 2 \, r\right)} + \frac{1}{2} \, {\left({\nu} + 2\right)} D[0]\left(m\right)\left(v\right)$$

Note that in this expression $D[0](m)(v)$ stands for $\mathrm{d}m/\mathrm{d}v$.

eq2m = eq2.expr().substitute_function(f, fm).simplify_full()
eq2m

$$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{24} \, {\mu} q^{2} - 2 \, {\nu}^{2} + \frac{1}{3} \, {\Lambda} - 2 \, {\nu}$$

eq3m = eq3.expr().substitute_function(f, fm).simplify_full()
eq3m

$$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{24} \, {\mu} q^{2} - 2 \, {\nu}^{2} + \frac{1}{3} \, {\Lambda} - 2 \, {\nu}$$

eq4m = eq4.expr().substitute_function(f, fm).simplify_full()
eq4m

$$\newcommand{\Bold}[1]{\mathbf{#1}}-\frac{1}{12} \, {\mu} q^{2} + \frac{1}{3} \, {\Lambda} - 2 \, {\nu} - 2$$

eq5m = eq5.expr().substitute_function(f, fm).simplify_full()
eq5m

$$\newcommand{\Bold}[1]{\mathbf{#1}}{\lambda}^{2} {\nu} - {\lambda}^{2} - 4$$

eq6m = eq6.expr().substitute_function(f, fm).simplify_full()
eq6m

$$\newcommand{\Bold}[1]{\mathbf{#1}}-{\lambda}^{2} {\mu} q^{2} + 64 \, {\nu} + 64$$

eqs = [eq1m, eq2m, eq3m, eq4m, eq5m, eq6m]

Solution for $\nu = 2$

neqs = [eq.subs(nu=2).simplify_full() for eq in eqs]
[eq == 0 for eq in neqs]

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left[-8 \, \pi T_{00}\left(v, r\right) e^{\left(4 \, r\right)} + \frac{1}{24} \, {\left({\mu} q^{2} + 8 \, {\Lambda} - 288\right)} e^{\left(2 \, r\right)} m\left(v\right) - \frac{1}{24} \, {\left({\mu} q^{2} + 8 \, {\Lambda} - 288\right)} e^{\left(8 \, r\right)} + 2 \, D[0]\left(m\right)\left(v\right) = 0, \frac{1}{24} \, {\mu} q^{2} + \frac{1}{3} \, {\Lambda} - 12 = 0, \frac{1}{24} \, {\mu} q^{2} + \frac{1}{3} \, {\Lambda} - 12 = 0, -\frac{1}{12} \, {\mu} q^{2} + \frac{1}{3} \, {\Lambda} - 6 = 0, {\lambda}^{2} - 4 = 0, -{\lambda}^{2} {\mu} q^{2} + 192 = 0\right]$$

Let us first search for a solution of all the equations but the first one:

eqs2 = eqs[1:] # we skip eq1m
neqs = [eq.subs(nu=2).simplify_full() for eq in eqs2]
[eq == 0 for eq in neqs]

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left[\frac{1}{24} \, {\mu} q^{2} + \frac{1}{3} \, {\Lambda} - 12 = 0, \frac{1}{24} \, {\mu} q^{2} + \frac{1}{3} \, {\Lambda} - 12 = 0, -\frac{1}{12} \, {\mu} q^{2} + \frac{1}{3} \, {\Lambda} - 6 = 0, {\lambda}^{2} - 4 = 0, -{\lambda}^{2} {\mu} q^{2} + 192 = 0\right]$$

solve([eq == 0 for eq in neqs], lamb, mu, Lamb, q)

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left[\left[{\lambda} = \left(-2\right), {\mu} = \frac{48}{r_{1}^{2}}, {\Lambda} = 30, q = r_{1}\right], \left[{\lambda} = 2, {\mu} = \frac{48}{r_{2}^{2}}, {\Lambda} = 30, q = r_{2}\right]\right]$$

Then, we substitute the found solution in the first equation:

eq = eq1m.subs({nu:2, Lamb:30, lamb:2, mu:48/q^2})
eq

$$\newcommand{\Bold}[1]{\mathbf{#1}}-8 \, \pi T_{00}\left(v, r\right) e^{\left(4 \, r\right)} + 2 \, D[0]\left(m\right)\left(v\right)$$

Hence, for any choice of $m(v)$, we get a solution with $$ \Lambda=30,\quad \lambda = \pm 2, \quad\mu = \frac{48}{q^2} $$ and $$ T_{00}(\nu,r) = \frac{1}{4\pi e^{4 r}} \frac{\mathrm{d}m}{\mathrm{d}v} $$

Solution for $\nu=4$

neqs = [eq.subs(nu=4).simplify_full() for eq in eqs]
[eq == 0 for eq in neqs]

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left[-8 \, \pi T_{00}\left(v, r\right) e^{\left(6 \, r\right)} + \frac{1}{24} \, {\left({\mu} q^{2} + 8 \, {\Lambda} - 960\right)} e^{\left(4 \, r\right)} m\left(v\right) - \frac{1}{24} \, {\left({\mu} q^{2} + 8 \, {\Lambda} - 960\right)} e^{\left(14 \, r\right)} + 3 \, D[0]\left(m\right)\left(v\right) = 0, \frac{1}{24} \, {\mu} q^{2} + \frac{1}{3} \, {\Lambda} - 40 = 0, \frac{1}{24} \, {\mu} q^{2} + \frac{1}{3} \, {\Lambda} - 40 = 0, -\frac{1}{12} \, {\mu} q^{2} + \frac{1}{3} \, {\Lambda} - 10 = 0, 3 \, {\lambda}^{2} - 4 = 0, -{\lambda}^{2} {\mu} q^{2} + 320 = 0\right]$$

Let us first search for a solution of all the equations but the first one:

eqs2 = eqs[1:] # we skip eq1m
neqs = [eq.subs(nu=4).simplify_full() for eq in eqs2]
[eq == 0 for eq in neqs]

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left[\frac{1}{24} \, {\mu} q^{2} + \frac{1}{3} \, {\Lambda} - 40 = 0, \frac{1}{24} \, {\mu} q^{2} + \frac{1}{3} \, {\Lambda} - 40 = 0, -\frac{1}{12} \, {\mu} q^{2} + \frac{1}{3} \, {\Lambda} - 10 = 0, 3 \, {\lambda}^{2} - 4 = 0, -{\lambda}^{2} {\mu} q^{2} + 320 = 0\right]$$

solve([eq == 0 for eq in neqs], lamb, mu, Lamb, q)

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left[\left[{\lambda} = \frac{2}{3} \, \sqrt{3}, {\mu} = \frac{240}{r_{3}^{2}}, {\Lambda} = 90, q = r_{3}\right], \left[{\lambda} = -\frac{2}{3} \, \sqrt{3}, {\mu} = \frac{240}{r_{4}^{2}}, {\Lambda} = 90, q = r_{4}\right]\right]$$

Then, we substitute the found solution in the first equation:

eq = eq1m.subs({nu:4, Lamb:90, lamb:2/sqrt(3), mu:240/q^2})
eq

$$\newcommand{\Bold}[1]{\mathbf{#1}}-8 \, \pi T_{00}\left(v, r\right) e^{\left(6 \, r\right)} + 3 \, D[0]\left(m\right)\left(v\right)$$

Hence, for any choice of $m(v)$, we get a solution with $$ \Lambda=90,\quad \lambda = \pm \frac{2}{\sqrt{3}}, \quad\mu = \frac{240}{q^2} $$ and $$ T_{00}(\nu,r) = \frac{3}{8\pi e^{6 r}} \frac{\mathrm{d}m}{\mathrm{d}v} $$