Continuity.sagews

Continuity

Much of limit analysis relates to a concept known as continuity. A function is said to be continuous on an interval when the function is defined at every point on that interval and undergoes no interruptions, jumps, or breaks. If some function $f(x)$ satisfies these criteria from $x=a$ to $x=b$, for example, we say that $f(x)$ is continuous on the interval $[a, b]$. The brackets mean that the interval is closed -- that it includes the endpoints $a$ and $b$. In other words, that the interval is defined as $a \leq x \leq b$. An open interval $(a, b)$, on the other hand, would not include endpoints $a$ and $b$, and would be defined as $a \lt x \lt b$.

For an example of continuity, start a new worksheet called 02-Continuity, then recreate the following graph using the provided code. (The $f(x)=...$ is superimposed).

p1 = plot(x^2, x, 0, 1)        # Plot x2 from x=0 to x=1
p2 = plot(-x+2, x, 1, 2)       # Plot -x+2 from x=1 to x=2
p3 = plot(x^2-3*x+2, x, 2, 3)  # Plot x2-3*x+2 from x=2 to x=3
pt1 = point((0, 0), rgbcolor='black', pointsize=30)     # Create a black point at (0, 0)
pt2 = point((3, 2), rgbcolor='black', pointsize=30)     # Create another black point at (3, 2)
(p1+p2+p3+pt1+pt2).show(xmin=0, xmax=3, ymin=0, ymax=2) # Combine the plots and points into a single graph with the given bounds

The function $f(x)$ in the graph is known as a piecewise function, or one that has multiple, well, pieces. As you can see, the function travels from $x=0$ to $x=3$ without interruption, and since the two endpoints are closed (designated by the filled-in black circles), $f(x)$ is continuous on the closed interval $[0, 3]$. To think of it another way, if you can trace a function on an interval without picking up your pen (and without running over any holes), the function is continuous on that interval.

Using our knowledge of limits from the previous lesson, we can say that:

$\underset{x\to 1}{\rm{lim}}f(x)=1$ and $\underset{x\to2}{\rm{lim}}f(x)=0$

The Intermediate Value Theorem

One of the more important theorems relating to continuous functions is the Intermediate Value Theorem, which states that if a function $f$ is continuous on a closed interval $[a, b]$ and $k$ is any number between $f(a)$ and $f(b)$, then there must exist at least one number $c$ such that $f(c) = k$. In other words, if $f$ is continuous on $[a, b]$, it must pass through every y-value bounded by $f(a)$ and $f(b)$. In the continuous function graphed above, for example, $f(0) = 0$ and $f(3) = 2$, so $f(x)$ must pass through all y-values bounded by and including $0$ and $2$ on the interval $[0, 3]$, which as one can see, it does.

Look at this example, now, of a function that is not continuous on the interval for which it is shown.

p1 = plot(2*x, x, 0, 1)        # Plot 2*x from x=0 to x=1
p2 = plot(-x+3, x, 1, 2)       # Plot -x+3 from x=1 to x=2
p3 = plot(-(x-3)^3+2, x, 2, 3) # Plot -(x-3)3+2 from x=2 to x=3
l1 = line([(1, 2.1), (1, 2.9)], linestyle='--')     # Create a dashed line to indicate that the function jumps to a y-value of 3 when x is equal to 1
pt1 = point((0, 0), rgbcolor='black', pointsize=30) # Create open (faceted) or closed (filled-in) points to indicate whether the intervals are open or closed
pt2 = point((1, 2), rgbcolor='white', faceted=True, pointsize=30)
pt3 = point((1, 3), rgbcolor='black', pointsize=30)
pt4 = point((2, 1), rgbcolor='black', pointsize=30)
pt5 = point((2, 3), rgbcolor='white', faceted=True, pointsize=30)
pt6 = point((3, 2), rgbcolor='black', pointsize=30)
(p1+p2+p3+l1+pt1+pt2+pt3+pt4+pt5+pt6).show(xmin=0, xmax=3, ymin=0, ymax=3)  # Combine the plots, line, and points into a graph with the given bounds

The function shown in the graph is not continuous on the closed interval $[0, 3]$, since it has discontinuities at both $x=1$ and $x=2$. A discontinuity is any x-value at which a function has an interruption, break or jump -- something that would require you to pick up your pen if you were tracing the function. The filled-in black circles, again, indicate that the interval includes that point, while the open circles indicate that the interval excludes that point. The dashed line at $x=1$ shows that $f(1) = 3$, not $2$.

Since the above graph has at least one discontinuity, it does not satisfy the requirements of the Intermediate Value Theorem and therefore does not have to pass through every y-value between $f(0)$ and $f(3)$.

Even though $f(1) = 3$, however, the limit of $f(x)$ as $x$ approaches $1$ does not equal $3$, since the function approaches a value of $2$ from both sides of $x=1$. But what about the limit of $f(x)$ as $x$ approaches $2$? The function does not approach one specific value from either side of $x=2$, but we can still describe its behavior from the right or the left. This is the basis of one-sided limits, which is the topic of the next section.

Practice Problems

Determine which of the following functions are continuous on the closed intervals for which they are shown. For functions that are not continuous, determine the x-coordinates of their discontinuities.

# Just a note -- sin(x) transformed doesn't actually follow the same curve as x2
p1 = plot((x+1)^2-1, x, -2, 0)
p2 = plot(5/4*sin(pi*x/2), x, 0, 2)
p3 = plot((x-3)^2-1, x, 2, 4)
pt1 = point((-2, 0), rgbcolor='black', pointsize=30)
pt2 = point((4, 0), rgbcolor='black', pointsize=30)
(p1+p2+p3+pt1+pt2).show()

1)

p = plot(tan(x), x, -pi, pi, randomize=False, plot_points=101)
pt1 = point((-pi, 0), rgbcolor='black', pointsize=30)
pt2 = point((pi, 0), rgbcolor='black', pointsize=30)
(p+pt1+pt2).show(xmin=-pi, xmax=pi, ymin=-10, ymax=10)

2)

# exp() means 'e to the ___'
p1 = plot(exp(x/5)-1, x, 0, e)
p2 = plot(ln(x), x, e, e^2)
pt1 = point((0, 0), rgbcolor='black', pointsize=30)
pt2 = point((e, exp(e/5)-1), rgbcolor='black', pointsize=30)
pt3 = point((e, 1), faceted=True, rgbcolor='white', pointsize=30)
pt4 = point((e^2, 2), rgbcolor='black', pointsize=30)
(p1+p2+pt1+pt2+pt3+pt4).show(ymin=0, ymax=2)

3)

Determine the value or values of k that will make each function continuous on the given interval.*

4) $f(x)= \begin{cases} 3x-2 & 0\leq x\leq k \\ 2x+3 & k \leq x \leq6 \end{cases}$

5) $f(x) = \begin{cases} \cos(x) & 0\leq x \leq\pi/2 \\ \sin(x+k) & \pi/2 \leq x \leq \pi \end{cases}$

6) $f(x) = \begin{cases} x^3-6x^2+kx-6 & 0\leq x \leq4 \\ 2x-13+k & 4 \leq x \leq 6 \end{cases}$

Use the Intermediate Value Theorem to demonstrate that a solution exists to each equation on the interval given.

7) $4x^3+2x^2-15x+4=50; [1,3]$

8) $\cos(x)-\sin(x)-x=2; [-1,1]$

9) $x^5 = \sqrt{x+3}; [1,2]$

To view answers, select this cell and paste it into your own sagews, and then double click on it

*As a SageMath-based way of checking your answers, you can use solve $(...==..., k)$ to solve the given equation for $k$. For example, to solve for $x$ when the expression $x^2-4x+4$ is equal to $0$, you would use:

solve(x^2-4*x+4==0, x)

[x == 2]

Two equals signs (as used here) signifies a test for equality, while a single equals sign signifies assignment. For example, x==1 means 'does x equal 1?' whereas x=1 means 'assign 1 to x'.

[Previous: Limits](Limits.sagews) | [To Main](Introduction.sagews) | [Next: One-Sided Limits](One-Sided_Limits.sagews)

︠71c4ba22-bce1-486b-b5a5-b5a49862d547︠