Kerr_ergo_a50.ipynb

Kernel: SageMath 8.0.beta0

Meridional plots in Kerr spacetime for $a/m=0.50$

%display latex

O'Neill exponential coordinates:

x,y = var('x y')
r = 1/2*ln(x^2 + y^2)
costh2 = y^2/(x^2+y^2)
sinth2 = x^2/(x^2+y^2)

Function $f$ defining the ergoregion by $f<0$:

a = 0.5
f = r^2 -2*r + a^2*costh2
f

ergo = region_plot(f < 0, (x,-8, 8), (y, -7, 7), incol='lightgray', 
                   bordercol='grey',
                   axes_labels=[r'$\mathrm{e}^{r/m}\sin\theta$', 
                                r'$\mathrm{e}^{r/m}\cos\theta$'])
ergo += text(r'$\mathscr{E}^+$', (1.1*e^2, 0.5*e), color='grey', 
             fontsize=20)
#ergo += text(r'$\mathscr{E}^-$', (1.4, 0.8), color='grey', 
#             fontsize=20)

Various remarkable surfaces:

Rp = exp(1 + sqrt(1-a^2))
Rm = exp(1 - sqrt(1-a^2))
Hp = circle((0,0), Rp, color='black', thickness=2) + \
     text(r'$\mathscr{H}$', (0.77*Rp, 0.77*Rp), color='black', fontsize=20)
Hm = circle((0,0), Rm, color='green', thickness=2) + \
     text(r'$\mathscr{H}_{\rm in}$', (1.2*Rm, 1.05*Rm), color='green', fontsize=20)
R0 = circle((0,0), 1, color='darkorange', linestyle='dotted', thickness=3) + \
      text(r'$r\!=\!0$', (1.1,-1.), color='darkorange', fontsize=16)
sing = circle((1,0), 0.1, color='red', fill=True) + \
       circle((-1,0), 0.1, color='red', fill=True)
rminf = circle((0,0), 0.1, edgecolor='black', facecolor='white', fill=True)
region_label = text(r'${\rm I}$', (-1.2*Rp, 0.8*Rp), fontsize=20) + \
               text(r'${\rm II}$', (-0.5*Rp, 0.4*Rp), fontsize=20) + \
               text(r'${\rm III}$', (-0.3*Rm, 0.5*Rm), fontsize=20)
graph = ergo + Hp + Hm + R0 + sing + rminf + region_label

Carter time machine:

ft = (r^2+a^2)*(r^2+a^2*costh2) + 2*a^2*r*sinth2

tmachine = region_plot(ft < 0, (x,-8, 8), (y, -3, 3), incol='yellow', bordercol='gold')
graph += tmachine
show(graph, aspect_ratio=1)

graph.save("ker_ergo_a50.pdf", aspect_ratio=1)