Kerr-AdS-5D-string-b_a-AdS.ipynb

Kernel: SageMath 9.3

5D Kerr-AdS spacetime with a Nambu-Goto string

Generic case (a,b) in global AdS coordinates

This SageMath notebook is relative to the article Heavy quarks in rotating plasma via holography by Anastasia A. Golubtsova, Eric Gourgoulhon and Marina K. Usova, arXiv:2107.11672.

The involved differential geometry computations are based on tools developed through the SageManifolds project.

NB: a version of SageMath at least equal to 9.1 is required to run this notebook:

version()

'SageMath version 9.3, Release Date: 2021-05-09'

First we set up the notebook to display mathematical objects using LaTeX rendering:

%display latex

Since some computations are quite long, we ask for running them in parallel on 8 cores:

Parallelism().set(nproc=8)

Spacetime manifold

We declare the Kerr-AdS spacetime as a 5-dimensional Lorentzian manifold:

M = Manifold(5, 'M', r'\mathcal{M}', structure='Lorentzian', metric_name='G')
print(M)

5-dimensional Lorentzian manifold M

Let us define Boyer-Lindquist-type coordinates (rational polynomial version) on $\mathcal{M}$, via the method chart(), the argument of which is a string expressing the coordinates names, their ranges (the default is $(-\infty,+\infty)$) and their LaTeX symbols:

BL.<t,r,mu,ph,ps> = M.chart(r't r:(0,+oo) mu:(0,1):\mu ph:(0,2*pi):\phi ps:(0,2*pi):\psi')
BL

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\left(\mathcal{M},(t, r, {\mu}, {\phi}, {\psi})\right)$$

The coordinate $\mu$ is related to the standard Boyer-Lindquist coordinate $\theta$ by $$\mu = \cos\theta$$

The coordinate ranges are

BL.coord_range()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}t :\ \left( -\infty, +\infty \right) ;\quad r :\ \left( 0 , +\infty \right) ;\quad {\mu} :\ \left( 0 , 1 \right) ;\quad {\phi} :\ \left( 0 , 2 \, \pi \right) ;\quad {\psi} :\ \left( 0 , 2 \, \pi \right)$$

Note that contrary to the 4-dimensional case, the range of $\mu$ is $(0,1)$ only (cf. Sec. 1.2 of R.C. Myers, arXiv:1111.1903 or Sec. 2 of G.W. Gibbons, H. Lüb, Don N. Page, C.N. Pope, J. Geom. Phys. 53, 49 (2005)). In other words, the range of $\theta$ is $\left(0, \frac{\pi}{2}\right)$ only.

Metric tensor

The 4 parameters $m$, $a$, $b$ and $\ell$ of the Kerr-AdS spacetime are declared as symbolic variables, $a$ and $b$ being the two angular momentum parameters and $\ell$ being related to the cosmological constant by $\Lambda = - 6 \ell^2$:

var('m a b', domain='real')

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\left(m, a, b\right)$$

In this notebook, we set $$\ell = 1$$

l = 1

assume(a >= 0, a < 1)
assume(b >= 0, b < 1)

Possible particular cases:

#b = a
#a = 0
#b = 0

Some auxiliary functions:

keep_Delta = False  # change to False to provide explicit expression for Delta_r, Xi_a, etc...

sig = (1 + r^2*l^2)/r^2
costh2 = mu^2
sinth2 = 1 - mu^2
rho2 = r^2 + a^2*mu^2 + b^2*sinth2
if keep_Delta:
    Delta_r = var('Delta_r', latex_name=r'\Delta_r', domain='real')
    Delta_th = var('Delta_th', latex_name=r'\Delta_\theta', domain='real')
    if a == b:
        Xi_a = var('Xi', latex_name=r'\Xi', domain='real')
        Xi_b = Xi_a
    else:
        Xi_a = var('Xi_a', latex_name=r'\Xi_a', domain='real')
        Xi_b = var('Xi_b', latex_name=r'\Xi_b', domain='real')
    #Delta_th = 1 - a^2*l^2*mu^2 - b^2*l^2*sinth2
    Xi_a = 1 - a^2*l^2
    Xi_b = 1 - b^2*l^2
else:
    Delta_r = (r^2+a^2)*(r^2+b^2)*sig - 2*m
    Delta_th = 1 - a^2*l^2*mu^2 - b^2*l^2*sinth2
    Xi_a = 1 - a^2*l^2
    Xi_b = 1 - b^2*l^2

The metric is set by its components in the coordinate frame associated with the Boyer-Lindquist-type coordinates, which is the current manifold's default frame. These components can be deduced from Eq. (5.22) of the article S.W. Hawking, C.J. Hunter & M.M. Taylor-Robinson, Phys. Rev. D 59, 064005 (1999) (the check of agreement with this equation is performed below):

G = M.metric()
tmp = 1/rho2*( -Delta_r + Delta_th*(a^2*sinth2 + b^2*mu^2) + a^2*b^2*sig )
G[0,0] = tmp.simplify_full()
tmp = a*sinth2/(rho2*Xi_a)*( Delta_r - (r^2+a^2)*(Delta_th + b^2*sig) )
G[0,3] = tmp.simplify_full()
tmp = b*mu^2/(rho2*Xi_b)*( Delta_r - (r^2+b^2)*(Delta_th + a^2*sig) )
G[0,4] = tmp.simplify_full()
G[1,1] = (rho2/Delta_r).simplify_full()
G[2,2] = (rho2/Delta_th/(1-mu^2)).simplify_full()
tmp = sinth2/(rho2*Xi_a^2)*( - Delta_r*a^2*sinth2 + (r^2+a^2)^2*(Delta_th + sig*b^2*sinth2) ) 
G[3,3] = tmp.simplify_full()
tmp = a*b*sinth2*mu^2/(rho2*Xi_a*Xi_b)*( - Delta_r + sig*(r^2+a^2)*(r^2+b^2) )
G[3,4] = tmp.simplify_full()
tmp = mu^2/(rho2*Xi_b^2)*( - Delta_r*b^2*mu^2 + (r^2+b^2)^2*(Delta_th + sig*a^2*mu^2) )
G[4,4] = tmp.simplify_full()

G.display_comp(only_nonredundant=True)

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{lcl} G_{ \, t \, t }^{ \phantom{\, t}\phantom{\, t} } & = & \frac{{\left(a^{4} - 2 \, a^{2} b^{2} + b^{4}\right)} {\mu}^{4} - r^{4} - {\left(a^{2} + 1\right)} b^{2} - {\left(a^{4} + b^{4} - {\left(2 \, a^{2} + 1\right)} b^{2} + a^{2}\right)} {\mu}^{2} - {\left(a^{2} + b^{2} + 1\right)} r^{2} + 2 \, m}{{\left(a^{2} - b^{2}\right)} {\mu}^{2} + b^{2} + r^{2}} \\ G_{ \, t \, {\phi} }^{ \phantom{\, t}\phantom{\, {\phi}} } & = & -\frac{a^{3} b^{2} - {\left(a^{5} - a^{3} b^{2}\right)} {\mu}^{4} - {\left(a {\mu}^{2} - a\right)} r^{4} + {\left(a^{5} - 2 \, a^{3} b^{2} + 2 \, a m\right)} {\mu}^{2} - {\left(2 \, a b^{2} {\mu}^{2} + {\left(a^{3} - a b^{2}\right)} {\mu}^{4} - a^{3} - a b^{2}\right)} r^{2} - 2 \, a m}{{\left(a^{2} - 1\right)} b^{2} + {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - a^{2}\right)} {\mu}^{2} + {\left(a^{2} - 1\right)} r^{2}} \\ G_{ \, t \, {\psi} }^{ \phantom{\, t}\phantom{\, {\psi}} } & = & -\frac{b {\mu}^{2} r^{4} + {\left(a^{2} b^{3} - b^{5}\right)} {\mu}^{4} + {\left(b^{5} - 2 \, b m\right)} {\mu}^{2} + {\left(2 \, b^{3} {\mu}^{2} + {\left(a^{2} b - b^{3}\right)} {\mu}^{4}\right)} r^{2}}{b^{4} - {\left(b^{4} - {\left(a^{2} + 1\right)} b^{2} + a^{2}\right)} {\mu}^{2} + {\left(b^{2} - 1\right)} r^{2} - b^{2}} \\ G_{ \, r \, r }^{ \phantom{\, r}\phantom{\, r} } & = & \frac{r^{4} + {\left({\left(a^{2} - b^{2}\right)} {\mu}^{2} + b^{2}\right)} r^{2}}{r^{6} + {\left(a^{2} + b^{2} + 1\right)} r^{4} + a^{2} b^{2} + {\left({\left(a^{2} + 1\right)} b^{2} + a^{2} - 2 \, m\right)} r^{2}} \\ G_{ \, {\mu} \, {\mu} }^{ \phantom{\, {\mu}}\phantom{\, {\mu}} } & = & \frac{{\left(a^{2} - b^{2}\right)} {\mu}^{2} + b^{2} + r^{2}}{{\left(a^{2} - b^{2}\right)} {\mu}^{4} - {\left(a^{2} - 2 \, b^{2} + 1\right)} {\mu}^{2} - b^{2} + 1} \\ G_{ \, {\phi} \, {\phi} }^{ \phantom{\, {\phi}}\phantom{\, {\phi}} } & = & \frac{{\left(a^{6} - a^{4} - {\left(a^{4} - a^{2}\right)} b^{2} + 2 \, a^{2} m\right)} {\mu}^{4} + {\left({\left(a^{2} - 1\right)} {\mu}^{2} - a^{2} + 1\right)} r^{4} - {\left(a^{4} - a^{2}\right)} b^{2} + 2 \, a^{2} m - {\left(a^{6} - a^{4} - 2 \, {\left(a^{4} - a^{2}\right)} b^{2} + 4 \, a^{2} m\right)} {\mu}^{2} + {\left(2 \, {\left(a^{2} - 1\right)} b^{2} {\mu}^{2} + {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - a^{2}\right)} {\mu}^{4} - a^{4} - {\left(a^{2} - 1\right)} b^{2} + a^{2}\right)} r^{2}}{{\left(a^{4} - 2 \, a^{2} + 1\right)} b^{2} + {\left(a^{6} - 2 \, a^{4} - {\left(a^{4} - 2 \, a^{2} + 1\right)} b^{2} + a^{2}\right)} {\mu}^{2} + {\left(a^{4} - 2 \, a^{2} + 1\right)} r^{2}} \\ G_{ \, {\phi} \, {\psi} }^{ \phantom{\, {\phi}}\phantom{\, {\psi}} } & = & -\frac{2 \, {\left(a b m {\mu}^{4} - a b m {\mu}^{2}\right)}}{{\left(a^{2} - 1\right)} b^{4} - {\left(a^{2} - 1\right)} b^{2} - {\left({\left(a^{2} - 1\right)} b^{4} + a^{4} - {\left(a^{4} - 1\right)} b^{2} - a^{2}\right)} {\mu}^{2} + {\left({\left(a^{2} - 1\right)} b^{2} - a^{2} + 1\right)} r^{2}} \\ G_{ \, {\psi} \, {\psi} }^{ \phantom{\, {\psi}}\phantom{\, {\psi}} } & = & -\frac{{\left(b^{2} - 1\right)} {\mu}^{2} r^{4} - {\left(b^{6} - {\left(a^{2} + 1\right)} b^{4} + a^{2} b^{2} + 2 \, b^{2} m\right)} {\mu}^{4} + {\left(b^{6} - b^{4}\right)} {\mu}^{2} - {\left({\left(b^{4} - {\left(a^{2} + 1\right)} b^{2} + a^{2}\right)} {\mu}^{4} - 2 \, {\left(b^{4} - b^{2}\right)} {\mu}^{2}\right)} r^{2}}{b^{6} - 2 \, b^{4} - {\left(b^{6} - {\left(a^{2} + 2\right)} b^{4} + {\left(2 \, a^{2} + 1\right)} b^{2} - a^{2}\right)} {\mu}^{2} + {\left(b^{4} - 2 \, b^{2} + 1\right)} r^{2} + b^{2}} \end{array}$$

Check of Eq. (2.9)

We need the 1-forms $\mathrm{d}t$, $\mathrm{d}r$, $\mathrm{d}\mu$, $\mathrm{d}\phi$ and $\mathrm{d}\psi$:

dt, dr, dmu, dph, dps = (BL.coframe()[i] for i in M.irange())
dt, dr, dmu, dph, dps

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\left(\mathrm{d} t, \mathrm{d} r, \mathrm{d} {\mu}, \mathrm{d} {\phi}, \mathrm{d} {\psi}\right)$$

print(dt)

1-form dt on the 5-dimensional Lorentzian manifold M

In agreement with $\mu = \cos\theta$, we introduce the 1-form $$\mathrm{d}\theta = - \mathrm{d}\mu /\sin\theta ,$$ with $\sin\theta = \sqrt{1-\mu^2}$ since $\theta\in\left(0, \frac{\pi}{2}\right)$ :

dth = - 1/sqrt(1 - mu^2)*dmu

s1 = dt - a*sinth2/Xi_a*dph - b*costh2/Xi_b*dps
s1.display()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\mathrm{d} t + \left( -\frac{a {\mu}^{2} - a}{a^{2} - 1} \right) \mathrm{d} {\phi} + \left( \frac{b {\mu}^{2}}{b^{2} - 1} \right) \mathrm{d} {\psi}$$

s2 = a*dt - (r^2 + a^2)/Xi_a*dph
s2.display()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}a \mathrm{d} t + \left( \frac{a^{2} + r^{2}}{a^{2} - 1} \right) \mathrm{d} {\phi}$$

s3 = b*dt - (r^2 + b^2)/Xi_b*dps
s3.display()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}b \mathrm{d} t + \left( \frac{b^{2} + r^{2}}{b^{2} - 1} \right) \mathrm{d} {\psi}$$

s4 = a*b*dt - b*(r^2 + a^2)*sinth2/Xi_a * dph - a*(r^2 + b^2)*costh2/Xi_b * dps
s4.display()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}a b \mathrm{d} t + \left( -\frac{a^{2} b {\mu}^{2} - a^{2} b + {\left(b {\mu}^{2} - b\right)} r^{2}}{a^{2} - 1} \right) \mathrm{d} {\phi} + \left( \frac{a b^{2} {\mu}^{2} + a {\mu}^{2} r^{2}}{b^{2} - 1} \right) \mathrm{d} {\psi}$$

G0 = - Delta_r/rho2 * s1*s1 + Delta_th*sinth2/rho2 * s2*s2 \
     + Delta_th*costh2/rho2 * s3*s3 + rho2/Delta_r * dr*dr \
     + rho2/Delta_th * dth*dth + sig/rho2 * s4*s4

Check of Eq. (2.9):

G0 == G

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\mathrm{True}$$

Einstein equation

The Ricci tensor of $g$ is

if not keep_Delta:
    # Ric = G.ricci()
    # print(Ric)
    pass

if not keep_Delta:
    # show(Ric.display_comp(only_nonredundant=True))
    pass

Let us check that $g$ is a solution of the vacuum Einstein equation with the cosmological constant $\Lambda = - 6 \ell^2$:

Lambda = -6*l^2
if not keep_Delta:
    # print(Ric == 2/3*Lambda*G)
    pass

Conformal metric at the boundary $r\to +\infty$ (check of Eq. (2.11))

The conformal metric:

H = G / (1 + r^2)
H.set_name('H')

H[1,1]

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{r^{4} + {\left({\left(a^{2} - b^{2}\right)} {\mu}^{2} + b^{2}\right)} r^{2}}{{\left(r^{6} + {\left(a^{2} + b^{2} + 1\right)} r^{4} + a^{2} b^{2} + {\left({\left(a^{2} + 1\right)} b^{2} + a^{2} - 2 \, m\right)} r^{2}\right)} {\left(r^{2} + 1\right)}}$$

Let us introduce a function to perform asymptotic expansions up to a given order:

u = var('u')
def asympt(xx, rr, order):
    r"""
    Expansion in terms of 1/rr

    INPUT:

    - ``xx`` -- symbolic expression to expand
    - ``rr`` -- symbolic variable, the inverse of which is the expansion small parameter
    - ``order`` -- order of the expansion

    OUTPUT:

    - symbolic expression representing ``xx`` truncated at degree ``order`` in terms
      of ``1/rr``

    """
    xx = xx.subs({rr: 1/u}).simplify_full()
    xx = xx.series(u, order+1).truncate().simplify_full()
    xx = xx.subs({u: 1/rr}).simplify_full()
    return xx    

Expansion to order $1/r^0$ provides the conformal metric on the boundary $r\to +\infty$:

H0 = M.sym_bilin_form_field(name='H_0')
for i in M.irange():
    for j in M.irange(i):
        H0[i, j] = asympt(H[i,j].expr(), r, 0)
H0.display()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}H_0 = -\mathrm{d} t\otimes \mathrm{d} t + \left( \frac{a {\mu}^{2} - a}{a^{2} - 1} \right) \mathrm{d} t\otimes \mathrm{d} {\phi} + \left( -\frac{b {\mu}^{2}}{b^{2} - 1} \right) \mathrm{d} t\otimes \mathrm{d} {\psi} + \left( \frac{1}{{\left(a^{2} - b^{2}\right)} {\mu}^{4} - {\left(a^{2} - 2 \, b^{2} + 1\right)} {\mu}^{2} - b^{2} + 1} \right) \mathrm{d} {\mu}\otimes \mathrm{d} {\mu} + \left( \frac{a {\mu}^{2} - a}{a^{2} - 1} \right) \mathrm{d} {\phi}\otimes \mathrm{d} t + \left( \frac{{\mu}^{2} - 1}{a^{2} - 1} \right) \mathrm{d} {\phi}\otimes \mathrm{d} {\phi} + \left( -\frac{b {\mu}^{2}}{b^{2} - 1} \right) \mathrm{d} {\psi}\otimes \mathrm{d} t + \left( -\frac{{\mu}^{2}}{b^{2} - 1} \right) \mathrm{d} {\psi}\otimes \mathrm{d} {\psi}$$

This agrees with Eq. (2.11); in particular, we have

H0[2,2].factor()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{{\left(a^{2} {\mu}^{2} - b^{2} {\mu}^{2} + b^{2} - 1\right)} {\left({\mu} + 1\right)} {\left({\mu} - 1\right)}}$$

Global AdS coordinates

ADS.<T,y,ch,Ph,Ps> = M.chart(r'T y:(0,+oo) ch:(0,1):\chi Ph:(0,2*pi):\Phi Ps:(0,2*pi):\Psi')
ADS

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\left(\mathcal{M},(T, y, {\chi}, {\Phi}, {\Psi})\right)$$

ADS.coord_range()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}T :\ \left( -\infty, +\infty \right) ;\quad y :\ \left( 0 , +\infty \right) ;\quad {\chi} :\ \left( 0 , 1 \right) ;\quad {\Phi} :\ \left( 0 , 2 \, \pi \right) ;\quad {\Psi} :\ \left( 0 , 2 \, \pi \right)$$

The transition from the Boyer-Lindquist coordinates to the global AdS coordinates is derived from Eq. (5.24) of S.W. Hawking, C.J. Hunter & M.M. Taylor-Robinson, Phys. Rev. D 59, 064005 (1999):

The following assumptions are required to perform simplifications:

if not (a == 0 or b == 0 or b == a):
    assume((a^2 - b^2)*mu^2 + b^2 + r^2 > 0)
    assume((a^2 - b^2)*ch^2 - a^2 + 1 > 0)

assumptions()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\left[\verb|t|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, \verb|r|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, r > 0, \verb|mu|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, {\mu} > 0, {\mu} < 1, \verb|ph|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, {\phi} > 0, {\phi} < 2 \, \pi, \verb|ps|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, {\psi} > 0, {\psi} < 2 \, \pi, \verb|m|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, \verb|a|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, \verb|b|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, a \geq 0, a < 1, b \geq 0, b < 1, \verb|T|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, \verb|y|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, y > 0, \verb|ch|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, {\chi} > 0, {\chi} < 1, \verb|Ph|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, {\Phi} > 0, {\Phi} < 2 \, \pi, \verb|Ps|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, {\Psi} > 0, {\Psi} < 2 \, \pi, {\left(a^{2} - b^{2}\right)} {\mu}^{2} + b^{2} + r^{2} > 0, {\left(a^{2} - b^{2}\right)} {\chi}^{2} - a^{2} + 1 > 0\right]$$

We import the function simplify_sqrt_real to simplify some square roots, which would not be simplified with simplify_full:

from sage.manifolds.utilities import simplify_sqrt_real

ys = sqrt(Xi_b*(r^2 + a^2)*(1-mu^2) + Xi_a*(r^2 + b^2)*mu^2) \
     /(sqrt(Xi_a)*sqrt(Xi_b))
ys = simplify_sqrt_real(ys.simplify_full())

chs = sqrt(Xi_a)*sqrt(r^2 + b^2)*mu / sqrt(Xi_a*(r^2 + b^2)*mu^2 
                                           + Xi_b*(r^2 + a^2)*(1 - mu^2))
chs = simplify_sqrt_real(chs.simplify_full())

ys

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{\sqrt{-a^{2} b^{2} - {\left(a^{2} - b^{2}\right)} {\mu}^{2} - {\left({\left(a^{2} - b^{2}\right)} {\mu}^{2} + b^{2} - 1\right)} r^{2} + a^{2}}}{\sqrt{a + 1} \sqrt{-a + 1} \sqrt{b + 1} \sqrt{-b + 1}}$$

chs

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{\sqrt{b^{2} + r^{2}} \sqrt{a + 1} \sqrt{-a + 1} {\mu}}{\sqrt{-a^{2} b^{2} - {\left(a^{2} - b^{2}\right)} {\mu}^{2} - {\left({\left(a^{2} - b^{2}\right)} {\mu}^{2} + b^{2} - 1\right)} r^{2} + a^{2}}}$$

BL_to_ADS = BL.transition_map(ADS, [t, ys, chs, ph + a*t, ps + b*t])
BL_to_ADS.display()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\left\{\begin{array}{lcl} T & = & t \\ y & = & \frac{\sqrt{-a^{2} b^{2} - {\left(a^{2} - b^{2}\right)} {\mu}^{2} - {\left({\left(a^{2} - b^{2}\right)} {\mu}^{2} + b^{2} - 1\right)} r^{2} + a^{2}}}{\sqrt{a + 1} \sqrt{-a + 1} \sqrt{b + 1} \sqrt{-b + 1}} \\ {\chi} & = & \frac{\sqrt{b^{2} + r^{2}} \sqrt{a + 1} \sqrt{-a + 1} {\mu}}{\sqrt{-a^{2} b^{2} - {\left(a^{2} - b^{2}\right)} {\mu}^{2} - {\left({\left(a^{2} - b^{2}\right)} {\mu}^{2} + b^{2} - 1\right)} r^{2} + a^{2}}} \\ {\Phi} & = & a t + {\phi} \\ {\Psi} & = & b t + {\psi} \end{array}\right.$$

Discr = (a^2 + b^2 + y^2*((b^2 - a^2)*ch^2 + a^2 - 1))^2 - 4*a^2*b^2 \
        + 4*y^2*((a^2 - b^2)*ch^2 + b^2*(1 - a^2))
Discr = Discr.simplify_full()
Discr

$$\renewcommand{\Bold}[1]{\mathbf{#1}}{\left({\left(a^{4} - 2 \, a^{2} b^{2} + b^{4}\right)} {\chi}^{4} + a^{4} - 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - a^{2}\right)} {\chi}^{2} - 2 \, a^{2} + 1\right)} y^{4} + a^{4} - 2 \, a^{2} b^{2} + b^{4} + 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - {\left(a^{4} - b^{4} - 2 \, a^{2} + 2 \, b^{2}\right)} {\chi}^{2} - a^{2}\right)} y^{2}$$

sqrDiscr = simplify_sqrt_real(sqrt(Discr))

rs2 = 1/2*(y^2*((a^2 - b^2)*ch^2 + 1 - a^2) - a^2 - b^2 + sqrDiscr)
rs2 = rs2.simplify_full()
rs2

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{2} \, {\left({\left(a^{2} - b^{2}\right)} {\chi}^{2} - a^{2} + 1\right)} y^{2} - \frac{1}{2} \, a^{2} - \frac{1}{2} \, b^{2} + \frac{1}{2} \, \sqrt{{\left({\left(a^{4} - 2 \, a^{2} b^{2} + b^{4}\right)} {\chi}^{4} + a^{4} - 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - a^{2}\right)} {\chi}^{2} - 2 \, a^{2} + 1\right)} y^{4} + a^{4} - 2 \, a^{2} b^{2} + b^{4} + 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - {\left(a^{4} - b^{4} - 2 \, a^{2} + 2 \, b^{2}\right)} {\chi}^{2} - a^{2}\right)} y^{2}}$$

Check:

s = (rs2 + a^2)*(rs2 + b^2) - (rs2 + a^2)*(1 - b^2)*y^2*ch^2 \
    - (rs2 + b^2)*(1 - a^2)*y^2*(1 - ch^2) == 0
s.simplify_full()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}0 = 0$$

rs =  simplify_sqrt_real(sqrt(rs2))

mus = sqrt(1 - b^2)/sqrt(rs2 + b^2)*y*ch
mus = simplify_sqrt_real(mus.simplify_full())
mus

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{\sqrt{2} \sqrt{b + 1} \sqrt{-b + 1} {\chi} y}{\sqrt{{\left({\left(a^{2} - b^{2}\right)} {\chi}^{2} - a^{2} + 1\right)} y^{2} - a^{2} + b^{2} + \sqrt{{\left({\left(a^{4} - 2 \, a^{2} b^{2} + b^{4}\right)} {\chi}^{4} + a^{4} - 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - a^{2}\right)} {\chi}^{2} - 2 \, a^{2} + 1\right)} y^{4} + a^{4} - 2 \, a^{2} b^{2} + b^{4} + 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - {\left(a^{4} - b^{4} - 2 \, a^{2} + 2 \, b^{2}\right)} {\chi}^{2} - a^{2}\right)} y^{2}}}}$$

BL_to_ADS.set_inverse(T, rs, mus, Ph - a*T, Ps - b*T, 
                      verbose=True)
BL_to_ADS.inverse().display()

Check of the inverse coordinate transformation:
  t == t  *passed*
  r == r  *passed*
  mu == mu  *passed*
  ph == ph  *passed*
  ps == ps  *passed*
  T == T  *passed*
  y == y  *passed*
  ch == ch  *passed*
  Ph == Ph  *passed*
  Ps == Ps  *passed*

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\left\{\begin{array}{lcl} t & = & T \\ r & = & \frac{1}{2} \, \sqrt{2} \sqrt{{\left({\left(a^{2} - b^{2}\right)} {\chi}^{2} - a^{2} + 1\right)} y^{2} - a^{2} - b^{2} + \sqrt{{\left({\left(a^{4} - 2 \, a^{2} b^{2} + b^{4}\right)} {\chi}^{4} + a^{4} - 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - a^{2}\right)} {\chi}^{2} - 2 \, a^{2} + 1\right)} y^{4} + a^{4} - 2 \, a^{2} b^{2} + b^{4} + 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - {\left(a^{4} - b^{4} - 2 \, a^{2} + 2 \, b^{2}\right)} {\chi}^{2} - a^{2}\right)} y^{2}}} \\ {\mu} & = & \frac{\sqrt{2} \sqrt{b + 1} \sqrt{-b + 1} {\chi} y}{\sqrt{{\left({\left(a^{2} - b^{2}\right)} {\chi}^{2} - a^{2} + 1\right)} y^{2} - a^{2} + b^{2} + \sqrt{{\left({\left(a^{4} - 2 \, a^{2} b^{2} + b^{4}\right)} {\chi}^{4} + a^{4} - 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - a^{2}\right)} {\chi}^{2} - 2 \, a^{2} + 1\right)} y^{4} + a^{4} - 2 \, a^{2} b^{2} + b^{4} + 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - {\left(a^{4} - b^{4} - 2 \, a^{2} + 2 \, b^{2}\right)} {\chi}^{2} - a^{2}\right)} y^{2}}}} \\ {\phi} & = & -T a + {\Phi} \\ {\psi} & = & -T b + {\Psi} \end{array}\right.$$

BL_to_ADS.jacobian()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\left(\begin{array}{rrrrr} 1 & 0 & 0 & 0 & 0 \\ 0 & -\frac{{\left({\left(a^{2} - b^{2}\right)} {\mu}^{2} + b^{2} - 1\right)} r}{\sqrt{-a^{2} b^{2} - {\left(a^{2} - b^{2}\right)} {\mu}^{2} - {\left({\left(a^{2} - b^{2}\right)} {\mu}^{2} + b^{2} - 1\right)} r^{2} + a^{2}} \sqrt{a + 1} \sqrt{-a + 1} \sqrt{b + 1} \sqrt{-b + 1}} & -\frac{{\left(a^{2} - b^{2}\right)} {\mu} r^{2} + {\left(a^{2} - b^{2}\right)} {\mu}}{\sqrt{-a^{2} b^{2} - {\left(a^{2} - b^{2}\right)} {\mu}^{2} - {\left({\left(a^{2} - b^{2}\right)} {\mu}^{2} + b^{2} - 1\right)} r^{2} + a^{2}} \sqrt{a + 1} \sqrt{-a + 1} \sqrt{b + 1} \sqrt{-b + 1}} & 0 & 0 \\ 0 & -\frac{\sqrt{-a^{2} b^{2} - {\left(a^{2} - b^{2}\right)} {\mu}^{2} - {\left({\left(a^{2} - b^{2}\right)} {\mu}^{2} + b^{2} - 1\right)} r^{2} + a^{2}} {\left({\left(b^{4} - {\left(a^{2} + 1\right)} b^{2} + a^{2}\right)} {\mu}^{3} - {\left(b^{4} - {\left(a^{2} + 1\right)} b^{2} + a^{2}\right)} {\mu}\right)} \sqrt{a + 1} \sqrt{-a + 1} r}{{\left(a^{4} b^{4} - 2 \, a^{4} b^{2} + {\left(a^{4} - 2 \, a^{2} b^{2} + b^{4}\right)} {\mu}^{4} + {\left({\left(a^{4} - 2 \, a^{2} b^{2} + b^{4}\right)} {\mu}^{4} + b^{4} - 2 \, {\left(b^{4} - {\left(a^{2} + 1\right)} b^{2} + a^{2}\right)} {\mu}^{2} - 2 \, b^{2} + 1\right)} r^{4} + a^{4} - 2 \, {\left(a^{2} b^{4} + a^{4} - {\left(a^{4} + a^{2}\right)} b^{2}\right)} {\mu}^{2} + 2 \, {\left(a^{2} b^{4} + {\left(a^{4} - 2 \, a^{2} b^{2} + b^{4}\right)} {\mu}^{4} - 2 \, a^{2} b^{2} - {\left({\left(a^{2} + 1\right)} b^{4} + a^{4} - {\left(a^{4} + 2 \, a^{2} + 1\right)} b^{2} + a^{2}\right)} {\mu}^{2} + a^{2}\right)} r^{2}\right)} \sqrt{b^{2} + r^{2}}} & -\frac{{\left(a^{2} b^{2} + {\left(b^{2} - 1\right)} r^{2} - a^{2}\right)} \sqrt{-a^{2} b^{2} - {\left(a^{2} - b^{2}\right)} {\mu}^{2} - {\left({\left(a^{2} - b^{2}\right)} {\mu}^{2} + b^{2} - 1\right)} r^{2} + a^{2}} \sqrt{b^{2} + r^{2}} \sqrt{a + 1} \sqrt{-a + 1}}{a^{4} b^{4} - 2 \, a^{4} b^{2} + {\left(a^{4} - 2 \, a^{2} b^{2} + b^{4}\right)} {\mu}^{4} + {\left({\left(a^{4} - 2 \, a^{2} b^{2} + b^{4}\right)} {\mu}^{4} + b^{4} - 2 \, {\left(b^{4} - {\left(a^{2} + 1\right)} b^{2} + a^{2}\right)} {\mu}^{2} - 2 \, b^{2} + 1\right)} r^{4} + a^{4} - 2 \, {\left(a^{2} b^{4} + a^{4} - {\left(a^{4} + a^{2}\right)} b^{2}\right)} {\mu}^{2} + 2 \, {\left(a^{2} b^{4} + {\left(a^{4} - 2 \, a^{2} b^{2} + b^{4}\right)} {\mu}^{4} - 2 \, a^{2} b^{2} - {\left({\left(a^{2} + 1\right)} b^{4} + a^{4} - {\left(a^{4} + 2 \, a^{2} + 1\right)} b^{2} + a^{2}\right)} {\mu}^{2} + a^{2}\right)} r^{2}} & 0 & 0 \\ a & 0 & 0 & 1 & 0 \\ b & 0 & 0 & 0 & 1 \end{array}\right)$$

BL_to_ADS.inverse().jacobian()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\left(\begin{array}{rrrrr} 1 & 0 & 0 & 0 & 0 \\ 0 & \frac{\sqrt{2} {\left({\left({\left(a^{4} - 2 \, a^{2} b^{2} + b^{4}\right)} {\chi}^{4} + a^{4} - 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - a^{2}\right)} {\chi}^{2} - 2 \, a^{2} + 1\right)} y^{3} + \sqrt{{\left({\left(a^{4} - 2 \, a^{2} b^{2} + b^{4}\right)} {\chi}^{4} + a^{4} - 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - a^{2}\right)} {\chi}^{2} - 2 \, a^{2} + 1\right)} y^{4} + a^{4} - 2 \, a^{2} b^{2} + b^{4} + 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - {\left(a^{4} - b^{4} - 2 \, a^{2} + 2 \, b^{2}\right)} {\chi}^{2} - a^{2}\right)} y^{2}} {\left({\left(a^{2} - b^{2}\right)} {\chi}^{2} - a^{2} + 1\right)} y + {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - {\left(a^{4} - b^{4} - 2 \, a^{2} + 2 \, b^{2}\right)} {\chi}^{2} - a^{2}\right)} y\right)}}{2 \, \sqrt{{\left({\left(a^{4} - 2 \, a^{2} b^{2} + b^{4}\right)} {\chi}^{4} + a^{4} - 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - a^{2}\right)} {\chi}^{2} - 2 \, a^{2} + 1\right)} y^{4} + a^{4} - 2 \, a^{2} b^{2} + b^{4} + 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - {\left(a^{4} - b^{4} - 2 \, a^{2} + 2 \, b^{2}\right)} {\chi}^{2} - a^{2}\right)} y^{2}} \sqrt{{\left({\left(a^{2} - b^{2}\right)} {\chi}^{2} - a^{2} + 1\right)} y^{2} - a^{2} - b^{2} + \sqrt{{\left({\left(a^{4} - 2 \, a^{2} b^{2} + b^{4}\right)} {\chi}^{4} + a^{4} - 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - a^{2}\right)} {\chi}^{2} - 2 \, a^{2} + 1\right)} y^{4} + a^{4} - 2 \, a^{2} b^{2} + b^{4} + 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - {\left(a^{4} - b^{4} - 2 \, a^{2} + 2 \, b^{2}\right)} {\chi}^{2} - a^{2}\right)} y^{2}}}} & \frac{\sqrt{2} {\left({\left({\left(a^{4} - 2 \, a^{2} b^{2} + b^{4}\right)} {\chi}^{3} - {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - a^{2}\right)} {\chi}\right)} y^{4} + \sqrt{{\left({\left(a^{4} - 2 \, a^{2} b^{2} + b^{4}\right)} {\chi}^{4} + a^{4} - 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - a^{2}\right)} {\chi}^{2} - 2 \, a^{2} + 1\right)} y^{4} + a^{4} - 2 \, a^{2} b^{2} + b^{4} + 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - {\left(a^{4} - b^{4} - 2 \, a^{2} + 2 \, b^{2}\right)} {\chi}^{2} - a^{2}\right)} y^{2}} {\left(a^{2} - b^{2}\right)} {\chi} y^{2} - {\left(a^{4} - b^{4} - 2 \, a^{2} + 2 \, b^{2}\right)} {\chi} y^{2}\right)}}{2 \, \sqrt{{\left({\left(a^{4} - 2 \, a^{2} b^{2} + b^{4}\right)} {\chi}^{4} + a^{4} - 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - a^{2}\right)} {\chi}^{2} - 2 \, a^{2} + 1\right)} y^{4} + a^{4} - 2 \, a^{2} b^{2} + b^{4} + 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - {\left(a^{4} - b^{4} - 2 \, a^{2} + 2 \, b^{2}\right)} {\chi}^{2} - a^{2}\right)} y^{2}} \sqrt{{\left({\left(a^{2} - b^{2}\right)} {\chi}^{2} - a^{2} + 1\right)} y^{2} - a^{2} - b^{2} + \sqrt{{\left({\left(a^{4} - 2 \, a^{2} b^{2} + b^{4}\right)} {\chi}^{4} + a^{4} - 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - a^{2}\right)} {\chi}^{2} - 2 \, a^{2} + 1\right)} y^{4} + a^{4} - 2 \, a^{2} b^{2} + b^{4} + 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - {\left(a^{4} - b^{4} - 2 \, a^{2} + 2 \, b^{2}\right)} {\chi}^{2} - a^{2}\right)} y^{2}}}} & 0 & 0 \\ 0 & -\frac{{\left(\sqrt{{\left({\left(a^{4} - 2 \, a^{2} b^{2} + b^{4}\right)} {\chi}^{4} + a^{4} - 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - a^{2}\right)} {\chi}^{2} - 2 \, a^{2} + 1\right)} y^{4} + a^{4} - 2 \, a^{2} b^{2} + b^{4} + 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - {\left(a^{4} - b^{4} - 2 \, a^{2} + 2 \, b^{2}\right)} {\chi}^{2} - a^{2}\right)} y^{2}} {\left(\sqrt{2} a^{2} - \sqrt{2} b^{2}\right)} \sqrt{b + 1} \sqrt{-b + 1} {\chi} + {\left({\left({\left(\sqrt{2} a^{4} - \sqrt{2} b^{4} - 2 \, \sqrt{2} a^{2} + 2 \, \sqrt{2} b^{2}\right)} {\chi}^{3} - {\left(\sqrt{2} a^{4} - {\left(\sqrt{2} a^{2} - \sqrt{2}\right)} b^{2} - \sqrt{2} a^{2}\right)} {\chi}\right)} y^{2} - {\left(\sqrt{2} a^{4} - 2 \, \sqrt{2} a^{2} b^{2} + \sqrt{2} b^{4}\right)} {\chi}\right)} \sqrt{b + 1} \sqrt{-b + 1}\right)} \sqrt{{\left({\left(a^{2} - b^{2}\right)} {\chi}^{2} - a^{2} + 1\right)} y^{2} - a^{2} + b^{2} + \sqrt{{\left({\left(a^{4} - 2 \, a^{2} b^{2} + b^{4}\right)} {\chi}^{4} + a^{4} - 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - a^{2}\right)} {\chi}^{2} - 2 \, a^{2} + 1\right)} y^{4} + a^{4} - 2 \, a^{2} b^{2} + b^{4} + 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - {\left(a^{4} - b^{4} - 2 \, a^{2} + 2 \, b^{2}\right)} {\chi}^{2} - a^{2}\right)} y^{2}}}}{2 \, {\left({\left({\left(a^{6} - 3 \, a^{4} b^{2} + 3 \, a^{2} b^{4} - b^{6}\right)} {\chi}^{6} - a^{6} - 3 \, {\left(a^{6} + {\left(a^{2} - 1\right)} b^{4} - a^{4} - 2 \, {\left(a^{4} - a^{2}\right)} b^{2}\right)} {\chi}^{4} + 3 \, a^{4} + 3 \, {\left(a^{6} - 2 \, a^{4} - {\left(a^{4} - 2 \, a^{2} + 1\right)} b^{2} + a^{2}\right)} {\chi}^{2} - 3 \, a^{2} + 1\right)} y^{6} - a^{6} + 3 \, a^{4} b^{2} - 3 \, a^{2} b^{4} + b^{6} - {\left(3 \, a^{6} + {\left(3 \, a^{6} + b^{6} + {\left(a^{2} - 4\right)} b^{4} - 4 \, a^{4} - {\left(5 \, a^{4} - 8 \, a^{2}\right)} b^{2}\right)} {\chi}^{4} - 6 \, a^{4} - 3 \, {\left(a^{4} - 2 \, a^{2} + 1\right)} b^{2} - 2 \, {\left(3 \, a^{6} + {\left(a^{2} - 1\right)} b^{4} - 5 \, a^{4} - 2 \, {\left(2 \, a^{4} - 3 \, a^{2} + 1\right)} b^{2} + 2 \, a^{2}\right)} {\chi}^{2} + 3 \, a^{2}\right)} y^{4} - {\left(3 \, a^{6} + 3 \, {\left(a^{2} - 1\right)} b^{4} - 3 \, a^{4} - 6 \, {\left(a^{4} - a^{2}\right)} b^{2} - {\left(3 \, a^{6} + b^{6} + {\left(a^{2} - 4\right)} b^{4} - 4 \, a^{4} - {\left(5 \, a^{4} - 8 \, a^{2}\right)} b^{2}\right)} {\chi}^{2}\right)} y^{2} + \sqrt{{\left({\left(a^{4} - 2 \, a^{2} b^{2} + b^{4}\right)} {\chi}^{4} + a^{4} - 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - a^{2}\right)} {\chi}^{2} - 2 \, a^{2} + 1\right)} y^{4} + a^{4} - 2 \, a^{2} b^{2} + b^{4} + 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - {\left(a^{4} - b^{4} - 2 \, a^{2} + 2 \, b^{2}\right)} {\chi}^{2} - a^{2}\right)} y^{2}} {\left({\left({\left(a^{4} - 2 \, a^{2} b^{2} + b^{4}\right)} {\chi}^{4} + a^{4} - 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - a^{2}\right)} {\chi}^{2} - 2 \, a^{2} + 1\right)} y^{4} + a^{4} - 2 \, a^{2} b^{2} + b^{4} + 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - a^{2}\right)} {\chi}^{2} - a^{2}\right)} y^{2}\right)}\right)}} & -\frac{\sqrt{{\left({\left(a^{2} - b^{2}\right)} {\chi}^{2} - a^{2} + 1\right)} y^{2} - a^{2} + b^{2} + \sqrt{{\left({\left(a^{4} - 2 \, a^{2} b^{2} + b^{4}\right)} {\chi}^{4} + a^{4} - 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - a^{2}\right)} {\chi}^{2} - 2 \, a^{2} + 1\right)} y^{4} + a^{4} - 2 \, a^{2} b^{2} + b^{4} + 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - {\left(a^{4} - b^{4} - 2 \, a^{2} + 2 \, b^{2}\right)} {\chi}^{2} - a^{2}\right)} y^{2}}} {\left(\sqrt{{\left({\left(a^{4} - 2 \, a^{2} b^{2} + b^{4}\right)} {\chi}^{4} + a^{4} - 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - a^{2}\right)} {\chi}^{2} - 2 \, a^{2} + 1\right)} y^{4} + a^{4} - 2 \, a^{2} b^{2} + b^{4} + 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - {\left(a^{4} - b^{4} - 2 \, a^{2} + 2 \, b^{2}\right)} {\chi}^{2} - a^{2}\right)} y^{2}} {\left({\left(\sqrt{2} a^{2} - \sqrt{2}\right)} y^{3} + {\left(\sqrt{2} a^{2} - \sqrt{2} b^{2}\right)} y\right)} \sqrt{b + 1} \sqrt{-b + 1} - {\left({\left(\sqrt{2} a^{4} - {\left(\sqrt{2} a^{4} - {\left(\sqrt{2} a^{2} - \sqrt{2}\right)} b^{2} - \sqrt{2} a^{2}\right)} {\chi}^{2} - 2 \, \sqrt{2} a^{2} + \sqrt{2}\right)} y^{5} + {\left(2 \, \sqrt{2} a^{4} - 2 \, {\left(\sqrt{2} a^{2} - \sqrt{2}\right)} b^{2} - {\left(\sqrt{2} a^{4} - \sqrt{2} b^{4} - 2 \, \sqrt{2} a^{2} + 2 \, \sqrt{2} b^{2}\right)} {\chi}^{2} - 2 \, \sqrt{2} a^{2}\right)} y^{3} + {\left(\sqrt{2} a^{4} - 2 \, \sqrt{2} a^{2} b^{2} + \sqrt{2} b^{4}\right)} y\right)} \sqrt{b + 1} \sqrt{-b + 1}\right)}}{2 \, {\left({\left({\left(a^{6} - 3 \, a^{4} b^{2} + 3 \, a^{2} b^{4} - b^{6}\right)} {\chi}^{6} - a^{6} - 3 \, {\left(a^{6} + {\left(a^{2} - 1\right)} b^{4} - a^{4} - 2 \, {\left(a^{4} - a^{2}\right)} b^{2}\right)} {\chi}^{4} + 3 \, a^{4} + 3 \, {\left(a^{6} - 2 \, a^{4} - {\left(a^{4} - 2 \, a^{2} + 1\right)} b^{2} + a^{2}\right)} {\chi}^{2} - 3 \, a^{2} + 1\right)} y^{6} - a^{6} + 3 \, a^{4} b^{2} - 3 \, a^{2} b^{4} + b^{6} - {\left(3 \, a^{6} + {\left(3 \, a^{6} + b^{6} + {\left(a^{2} - 4\right)} b^{4} - 4 \, a^{4} - {\left(5 \, a^{4} - 8 \, a^{2}\right)} b^{2}\right)} {\chi}^{4} - 6 \, a^{4} - 3 \, {\left(a^{4} - 2 \, a^{2} + 1\right)} b^{2} - 2 \, {\left(3 \, a^{6} + {\left(a^{2} - 1\right)} b^{4} - 5 \, a^{4} - 2 \, {\left(2 \, a^{4} - 3 \, a^{2} + 1\right)} b^{2} + 2 \, a^{2}\right)} {\chi}^{2} + 3 \, a^{2}\right)} y^{4} - {\left(3 \, a^{6} + 3 \, {\left(a^{2} - 1\right)} b^{4} - 3 \, a^{4} - 6 \, {\left(a^{4} - a^{2}\right)} b^{2} - {\left(3 \, a^{6} + b^{6} + {\left(a^{2} - 4\right)} b^{4} - 4 \, a^{4} - {\left(5 \, a^{4} - 8 \, a^{2}\right)} b^{2}\right)} {\chi}^{2}\right)} y^{2} + \sqrt{{\left({\left(a^{4} - 2 \, a^{2} b^{2} + b^{4}\right)} {\chi}^{4} + a^{4} - 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - a^{2}\right)} {\chi}^{2} - 2 \, a^{2} + 1\right)} y^{4} + a^{4} - 2 \, a^{2} b^{2} + b^{4} + 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - {\left(a^{4} - b^{4} - 2 \, a^{2} + 2 \, b^{2}\right)} {\chi}^{2} - a^{2}\right)} y^{2}} {\left({\left({\left(a^{4} - 2 \, a^{2} b^{2} + b^{4}\right)} {\chi}^{4} + a^{4} - 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - a^{2}\right)} {\chi}^{2} - 2 \, a^{2} + 1\right)} y^{4} + a^{4} - 2 \, a^{2} b^{2} + b^{4} + 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - a^{2}\right)} {\chi}^{2} - a^{2}\right)} y^{2}\right)}\right)}} & 0 & 0 \\ -a & 0 & 0 & 1 & 0 \\ -b & 0 & 0 & 0 & 1 \end{array}\right)$$

Remark: despite the rather complicated relation between $y$ and $(r,\mu)$, the ratio $(1 + r^2)/(1 + y^2)$ depends only on $\mu$ and takes a simple form: $$\frac{1 + r^2}{1 + y^2} = \frac{(1 - a^2) (1 - b^2)}{1 - a^2\mu^2 - b^2 (1 - \mu^2)}$$ Indeed:

((1 + r^2)/(1 + ys^2)).simplify_full().factor()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-\frac{{\left(a + 1\right)} {\left(a - 1\right)} {\left(b + 1\right)} {\left(b - 1\right)}}{a^{2} {\mu}^{2} - b^{2} {\mu}^{2} + b^{2} - 1}$$

Metric components in global ADS coordinates

For generic values of $(a,b)$, Sage does not succeed in computing the components of the metric tensor $G$ in a reasonable time. Only for $a=b$ or $b=0$ it manages to do so. For $b=0$, the expression is cumbersome, but for $a=b$, one gets a rather simple expression:

if a == b:
    show(G.display_comp(chart=ADS, only_nonredundant=True))

Asymptotic form of the metric in ADS coordinates (check of Eq. (2.17))

For $y\to +\infty$, the metric tensor $G$ can be approximated by $K$, the expression of the latter in ADS coordinates being given by Eq. (3.27) of Gibbons, Perry & Pope, CQG 22, 1503 (2005) (arXiv:hep-th/0408217) (our Eq. (2.17)):

M.set_default_frame(ADS.frame())
M.set_default_chart(ADS)

K = M.lorentzian_metric('K')
Delta = var('Delta', latex_name=r'\Delta', domain='real')
K[0, 0] = -1 - y^2 + 2*m/(Delta^3*y^2)
K[0, 3] = -2*m*a*(1 - ch^2)/(Delta^3*y^2)
K[0, 4] = -2*m*b*ch^2/(Delta^3*y^2)
K[1, 1] =  1/(1 + y^2 - 2*m/(Delta^3*y^2))
K[2, 2] = y^2/(1 - ch^2)
K[3, 3] = y^2*(1 - ch^2) + 2*m*a^2*(1 - ch^2)^2/(Delta^3*y^2)
K[3, 4] = 2*m*a*b*ch^2*(1 - ch^2)/(Delta^3*y^2)
K[4, 4] = y^2*ch^2 + 2*m*b^2*ch^4/(Delta^3*y^2)
K.display()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}K = \left( -y^{2} + \frac{2 \, m}{{\Delta}^{3} y^{2}} - 1 \right) \mathrm{d} T\otimes \mathrm{d} T + \frac{2 \, {\left({\chi}^{2} - 1\right)} a m}{{\Delta}^{3} y^{2}} \mathrm{d} T\otimes \mathrm{d} {\Phi} -\frac{2 \, b {\chi}^{2} m}{{\Delta}^{3} y^{2}} \mathrm{d} T\otimes \mathrm{d} {\Psi} + \left( \frac{1}{y^{2} - \frac{2 \, m}{{\Delta}^{3} y^{2}} + 1} \right) \mathrm{d} y\otimes \mathrm{d} y + \left( -\frac{y^{2}}{{\chi}^{2} - 1} \right) \mathrm{d} {\chi}\otimes \mathrm{d} {\chi} + \frac{2 \, {\left({\chi}^{2} - 1\right)} a m}{{\Delta}^{3} y^{2}} \mathrm{d} {\Phi}\otimes \mathrm{d} T + \left( -{\left({\chi}^{2} - 1\right)} y^{2} + \frac{2 \, {\left({\chi}^{2} - 1\right)}^{2} a^{2} m}{{\Delta}^{3} y^{2}} \right) \mathrm{d} {\Phi}\otimes \mathrm{d} {\Phi} -\frac{2 \, {\left({\chi}^{2} - 1\right)} a b {\chi}^{2} m}{{\Delta}^{3} y^{2}} \mathrm{d} {\Phi}\otimes \mathrm{d} {\Psi} -\frac{2 \, b {\chi}^{2} m}{{\Delta}^{3} y^{2}} \mathrm{d} {\Psi}\otimes \mathrm{d} T -\frac{2 \, {\left({\chi}^{2} - 1\right)} a b {\chi}^{2} m}{{\Delta}^{3} y^{2}} \mathrm{d} {\Psi}\otimes \mathrm{d} {\Phi} + \left( {\chi}^{2} y^{2} + \frac{2 \, b^{2} {\chi}^{4} m}{{\Delta}^{3} y^{2}} \right) \mathrm{d} {\Psi}\otimes \mathrm{d} {\Psi}$$

In the above expression, we do not have specified $\Delta$. Its explicit expression in terms of $a$, $b$ and $\chi$ is

Delta_abc = (1 - a^2*(1 - ch^2) - b^2*ch^2).simplify_full()
Delta_abc

$$\renewcommand{\Bold}[1]{\mathbf{#1}}{\left(a^{2} - b^{2}\right)} {\chi}^{2} - a^{2} + 1$$

Check of Eq. (2.17) for $a=b$:

For $a=b$, $G$ and $K$ differ only by a term proportional to $\mathrm{d}y\otimes\mathrm{d}y$:

if a == b:
    K0 = K.copy(name='K')
    K0.apply_map(lambda x: x.subs({Delta: Delta_abc}))
    GmK = G - K0
    show(GmK.display())

This difference is only of order $O(1/y^6)$:

if a == b:
    es = sum(asympt(GmK[1,1].expr(), y, k) for k in range(9))
    show(es)

Setting the metric to its asymptotic form:

G.set(K)
G.display()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}G = \left( -y^{2} + \frac{2 \, m}{{\Delta}^{3} y^{2}} - 1 \right) \mathrm{d} T\otimes \mathrm{d} T + \frac{2 \, {\left({\chi}^{2} - 1\right)} a m}{{\Delta}^{3} y^{2}} \mathrm{d} T\otimes \mathrm{d} {\Phi} -\frac{2 \, b {\chi}^{2} m}{{\Delta}^{3} y^{2}} \mathrm{d} T\otimes \mathrm{d} {\Psi} + \left( \frac{1}{y^{2} - \frac{2 \, m}{{\Delta}^{3} y^{2}} + 1} \right) \mathrm{d} y\otimes \mathrm{d} y + \left( -\frac{y^{2}}{{\chi}^{2} - 1} \right) \mathrm{d} {\chi}\otimes \mathrm{d} {\chi} + \frac{2 \, {\left({\chi}^{2} - 1\right)} a m}{{\Delta}^{3} y^{2}} \mathrm{d} {\Phi}\otimes \mathrm{d} T + \left( -{\left({\chi}^{2} - 1\right)} y^{2} + \frac{2 \, {\left({\chi}^{2} - 1\right)}^{2} a^{2} m}{{\Delta}^{3} y^{2}} \right) \mathrm{d} {\Phi}\otimes \mathrm{d} {\Phi} -\frac{2 \, {\left({\chi}^{2} - 1\right)} a b {\chi}^{2} m}{{\Delta}^{3} y^{2}} \mathrm{d} {\Phi}\otimes \mathrm{d} {\Psi} -\frac{2 \, b {\chi}^{2} m}{{\Delta}^{3} y^{2}} \mathrm{d} {\Psi}\otimes \mathrm{d} T -\frac{2 \, {\left({\chi}^{2} - 1\right)} a b {\chi}^{2} m}{{\Delta}^{3} y^{2}} \mathrm{d} {\Psi}\otimes \mathrm{d} {\Phi} + \left( {\chi}^{2} y^{2} + \frac{2 \, b^{2} {\chi}^{4} m}{{\Delta}^{3} y^{2}} \right) \mathrm{d} {\Psi}\otimes \mathrm{d} {\Psi}$$

G.display_comp()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{lcl} G_{ \, T \, T }^{ \phantom{\, T}\phantom{\, T} } & = & -y^{2} + \frac{2 \, m}{{\Delta}^{3} y^{2}} - 1 \\ G_{ \, T \, {\Phi} }^{ \phantom{\, T}\phantom{\, {\Phi}} } & = & \frac{2 \, {\left({\chi}^{2} - 1\right)} a m}{{\Delta}^{3} y^{2}} \\ G_{ \, T \, {\Psi} }^{ \phantom{\, T}\phantom{\, {\Psi}} } & = & -\frac{2 \, b {\chi}^{2} m}{{\Delta}^{3} y^{2}} \\ G_{ \, y \, y }^{ \phantom{\, y}\phantom{\, y} } & = & \frac{1}{y^{2} - \frac{2 \, m}{{\Delta}^{3} y^{2}} + 1} \\ G_{ \, {\chi} \, {\chi} }^{ \phantom{\, {\chi}}\phantom{\, {\chi}} } & = & -\frac{y^{2}}{{\chi}^{2} - 1} \\ G_{ \, {\Phi} \, T }^{ \phantom{\, {\Phi}}\phantom{\, T} } & = & \frac{2 \, {\left({\chi}^{2} - 1\right)} a m}{{\Delta}^{3} y^{2}} \\ G_{ \, {\Phi} \, {\Phi} }^{ \phantom{\, {\Phi}}\phantom{\, {\Phi}} } & = & -{\left({\chi}^{2} - 1\right)} y^{2} + \frac{2 \, {\left({\chi}^{2} - 1\right)}^{2} a^{2} m}{{\Delta}^{3} y^{2}} \\ G_{ \, {\Phi} \, {\Psi} }^{ \phantom{\, {\Phi}}\phantom{\, {\Psi}} } & = & -\frac{2 \, {\left({\chi}^{2} - 1\right)} a b {\chi}^{2} m}{{\Delta}^{3} y^{2}} \\ G_{ \, {\Psi} \, T }^{ \phantom{\, {\Psi}}\phantom{\, T} } & = & -\frac{2 \, b {\chi}^{2} m}{{\Delta}^{3} y^{2}} \\ G_{ \, {\Psi} \, {\Phi} }^{ \phantom{\, {\Psi}}\phantom{\, {\Phi}} } & = & -\frac{2 \, {\left({\chi}^{2} - 1\right)} a b {\chi}^{2} m}{{\Delta}^{3} y^{2}} \\ G_{ \, {\Psi} \, {\Psi} }^{ \phantom{\, {\Psi}}\phantom{\, {\Psi}} } & = & {\chi}^{2} y^{2} + \frac{2 \, b^{2} {\chi}^{4} m}{{\Delta}^{3} y^{2}} \end{array}$$

String worldsheet

The string worldsheet as a 2-dimensional Lorentzian submanifold of $\mathcal{M}$:

W = Manifold(2, 'W', ambient=M, structure='Lorentzian')
print(W)

2-dimensional Lorentzian submanifold W immersed in the 5-dimensional Lorentzian manifold M

Let us assume that the string worldsheet is parametrized by $(T,y)$:

XW.<T,y> = W.chart(r'T y:(0,+oo)')
XW

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\left(W,(T, y)\right)$$

The string embedding in Kerr-AdS spacetime, as an expansion about a straight string solution in AdS (Eq. (4.27) of the paper):

ch0 = var('ch0', latex_name=r'\chi_0', domain='real')
Phi0 = var('Phi0', latex_name=r'\Phi_0', domain='real')
Psi0 = var('Psi0', latex_name=r'\Psi_0', domain='real')

cosTh0 = ch0
sinTh0 = sqrt(1 - ch0^2)

ch_s = ch0 + (a+b)^2*function('chi_1')(y)
Ph_s = Phi0 + a*T + a*function('Phi_1')(y)
Ps_s = Psi0 + b*T + b*function('Psi_1')(y)

F = W.diff_map(M, {(XW, ADS): [T, y, ch_s, Ph_s, Ps_s]}, name='F') 

W.set_embedding(F)

F.display(XW, ADS)

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} F:& W & \longrightarrow & \mathcal{M} \\ & \left(T, y\right) & \longmapsto & \left(T, y, {\chi}, {\Phi}, {\Psi}\right) = \left(T, y, {\left(a + b\right)}^{2} \chi_{1}\left(y\right) + {\chi_0}, T a + a \Phi_{1}\left(y\right) + {\Phi_0}, T b + b \Psi_{1}\left(y\right) + {\Psi_0}\right) \end{array}$$

F.jacobian_matrix()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\left(\begin{array}{rr} 1 & 0 \\ 0 & 1 \\ 0 & {\left(a^{2} + 2 \, a b + b^{2}\right)} \frac{\partial}{\partial y}\chi_{1}\left(y\right) \\ a & a \frac{\partial}{\partial y}\Phi_{1}\left(y\right) \\ b & b \frac{\partial}{\partial y}\Psi_{1}\left(y\right) \end{array}\right)$$

Induced metric on the string worldsheet

The string worldsheet metric is the metric $g$ induced by the spacetime metric $G$, i.e. the pullback of $G$ by the embedding $F$:

Because of the bug #27492, which impedes parallel computations involving symbolic functions, such as $\chi_1$, we set back to serial computations:

Parallelism().set(nproc=1)  

g = W.induced_metric()

g[0,0]

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{8 \, {\left(a^{10} + 6 \, a^{9} b + 13 \, a^{8} b^{2} + 8 \, a^{7} b^{3} - 14 \, a^{6} b^{4} - 28 \, a^{5} b^{5} - 14 \, a^{4} b^{6} + 8 \, a^{3} b^{7} + 13 \, a^{2} b^{8} + 6 \, a b^{9} + b^{10}\right)} {\chi_0} m \chi_{1}\left(y\right)^{3} + 2 \, {\left(a^{12} + 8 \, a^{11} b + 26 \, a^{10} b^{2} + 40 \, a^{9} b^{3} + 15 \, a^{8} b^{4} - 48 \, a^{7} b^{5} - 84 \, a^{6} b^{6} - 48 \, a^{5} b^{7} + 15 \, a^{4} b^{8} + 40 \, a^{3} b^{9} + 26 \, a^{2} b^{10} + 8 \, a b^{11} + b^{12}\right)} m \chi_{1}\left(y\right)^{4} - {\Delta}^{3} y^{2} + {\left({\Delta}^{3} a^{2} - {\Delta}^{3} - {\left({\Delta}^{3} a^{2} - {\Delta}^{3} b^{2}\right)} {\chi_0}^{2}\right)} y^{4} - {\left({\left({\Delta}^{3} a^{6} + 4 \, {\Delta}^{3} a^{5} b + 5 \, {\Delta}^{3} a^{4} b^{2} - 5 \, {\Delta}^{3} a^{2} b^{4} - 4 \, {\Delta}^{3} a b^{5} - {\Delta}^{3} b^{6}\right)} y^{4} + 4 \, {\left(a^{8} - {\left(a^{2} - 1\right)} b^{6} - a^{6} - 4 \, {\left(a^{3} - a\right)} b^{5} - 5 \, {\left(a^{4} - a^{2}\right)} b^{4} + 5 \, {\left(a^{6} - a^{4}\right)} b^{2} - 3 \, {\left(a^{8} + 4 \, a^{7} b + 4 \, a^{6} b^{2} - 4 \, a^{5} b^{3} - 10 \, a^{4} b^{4} - 4 \, a^{3} b^{5} + 4 \, a^{2} b^{6} + 4 \, a b^{7} + b^{8}\right)} {\chi_0}^{2} + 4 \, {\left(a^{7} - a^{5}\right)} b\right)} m\right)} \chi_{1}\left(y\right)^{2} + 2 \, {\left({\left(a^{4} - 2 \, a^{2} b^{2} + b^{4}\right)} {\chi_0}^{4} + a^{4} - 2 \, {\left(a^{4} - {\left(a^{2} - 1\right)} b^{2} - a^{2}\right)} {\chi_0}^{2} - 2 \, a^{2} + 1\right)} m - 2 \, {\left({\left({\Delta}^{3} a^{4} + 2 \, {\Delta}^{3} a^{3} b - 2 \, {\Delta}^{3} a b^{3} - {\Delta}^{3} b^{4}\right)} {\chi_0} y^{4} - 4 \, {\left({\left(a^{6} + 2 \, a^{5} b - a^{4} b^{2} - 4 \, a^{3} b^{3} - a^{2} b^{4} + 2 \, a b^{5} + b^{6}\right)} {\chi_0}^{3} - {\left(a^{6} - {\left(a^{2} - 1\right)} b^{4} - a^{4} - 2 \, {\left(a^{3} - a\right)} b^{3} + 2 \, {\left(a^{5} - a^{3}\right)} b\right)} {\chi_0}\right)} m\right)} \chi_{1}\left(y\right)}{{\Delta}^{3} y^{2}}$$

Nambu-Goto action

The determinant of $g$ is

detg = g.determinant().expr()

Let us define a function for expansions in $a$ and $b$ up to a given order:

eps = var('eps', latex_name=r'\epsilon', domain='real')
def expand_ab(expr, order):
    res = expr.subs({a: eps*a, b: eps*b})
    res = res.series(eps, order+1).truncate()
    res = res.subs({eps: 1}).simplify_full()
    return res

Delta3_4 = expand_ab((Delta_abc)^3, 4)
Delta3_4

$$\renewcommand{\Bold}[1]{\mathbf{#1}}3 \, {\left(a^{4} - 2 \, a^{2} b^{2} + b^{4}\right)} {\chi}^{4} + 3 \, a^{4} - 3 \, {\left(2 \, a^{4} - {\left(2 \, a^{2} - 1\right)} b^{2} - a^{2}\right)} {\chi}^{2} - 3 \, a^{2} + 1$$

Delta6_4 = expand_ab((Delta_abc)^6, 4)
Delta6_4

$$\renewcommand{\Bold}[1]{\mathbf{#1}}15 \, {\left(a^{4} - 2 \, a^{2} b^{2} + b^{4}\right)} {\chi}^{4} + 15 \, a^{4} - 6 \, {\left(5 \, a^{4} - {\left(5 \, a^{2} - 1\right)} b^{2} - a^{2}\right)} {\chi}^{2} - 6 \, a^{2} + 1$$

Expanding at fourth order in $a$ and $b$ (will be required latter):

detg_4 = expand_ab(detg, 4)
detg_4 = detg_4.subs({Delta^3: Delta3_4, Delta^6: Delta6_4})
detg_4 = detg_4.simplify_full()
detg_4 = expand_ab(detg_4, 4)

For the time being, only the expansion at second order in $a$ is required:

detg_2 = expand_ab(detg_4, 2)
detg_2 

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-\frac{{\left({\left(a^{2} - b^{2}\right)} {\chi_0}^{2} - a^{2} + 1\right)} y^{4} - {\left({\left(a^{2} {\chi_0}^{2} - a^{2}\right)} y^{8} + 2 \, {\left(a^{2} {\chi_0}^{2} - a^{2}\right)} y^{6} + {\left(a^{2} {\chi_0}^{2} - a^{2} - 4 \, {\left(a^{2} {\chi_0}^{2} - a^{2}\right)} m\right)} y^{4} - 4 \, {\left(a^{2} {\chi_0}^{2} - a^{2}\right)} m y^{2} + 4 \, {\left(a^{2} {\chi_0}^{2} - a^{2}\right)} m^{2}\right)} \frac{\partial}{\partial y}\Phi_{1}\left(y\right)^{2} + {\left(b^{2} {\chi_0}^{2} y^{8} + 2 \, b^{2} {\chi_0}^{2} y^{6} - 4 \, b^{2} {\chi_0}^{2} m y^{2} + 4 \, b^{2} {\chi_0}^{2} m^{2} - {\left(4 \, b^{2} {\chi_0}^{2} m - b^{2} {\chi_0}^{2}\right)} y^{4}\right)} \frac{\partial}{\partial y}\Psi_{1}\left(y\right)^{2} - 2 \, {\left(2 \, {\left(a^{2} - b^{2}\right)} {\chi_0}^{2} - 2 \, a^{2} + 1\right)} m + y^{2}}{y^{4} + y^{2} - 2 \, m}$$

The Nambu-Goto Lagrangian at second order in $a$ and $b$:

L_2 = expand_ab(sqrt(-detg_2), 2)
L_2

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{{\left({\left(a^{2} - b^{2}\right)} {\chi_0}^{2} - a^{2} + 2\right)} y^{4} - {\left({\left(a^{2} {\chi_0}^{2} - a^{2}\right)} y^{8} + 2 \, {\left(a^{2} {\chi_0}^{2} - a^{2}\right)} y^{6} + {\left(a^{2} {\chi_0}^{2} - a^{2} - 4 \, {\left(a^{2} {\chi_0}^{2} - a^{2}\right)} m\right)} y^{4} - 4 \, {\left(a^{2} {\chi_0}^{2} - a^{2}\right)} m y^{2} + 4 \, {\left(a^{2} {\chi_0}^{2} - a^{2}\right)} m^{2}\right)} \frac{\partial}{\partial y}\Phi_{1}\left(y\right)^{2} + {\left(b^{2} {\chi_0}^{2} y^{8} + 2 \, b^{2} {\chi_0}^{2} y^{6} - 4 \, b^{2} {\chi_0}^{2} m y^{2} + 4 \, b^{2} {\chi_0}^{2} m^{2} - {\left(4 \, b^{2} {\chi_0}^{2} m - b^{2} {\chi_0}^{2}\right)} y^{4}\right)} \frac{\partial}{\partial y}\Psi_{1}\left(y\right)^{2} - 4 \, {\left({\left(a^{2} - b^{2}\right)} {\chi_0}^{2} - a^{2} + 1\right)} m + 2 \, y^{2}}{2 \, {\left(y^{4} + y^{2} - 2 \, m\right)}}$$

L_2.numerator()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-a^{2} {\chi_0}^{2} y^{8} \frac{\partial}{\partial y}\Phi_{1}\left(y\right)^{2} + b^{2} {\chi_0}^{2} y^{8} \frac{\partial}{\partial y}\Psi_{1}\left(y\right)^{2} - 2 \, a^{2} {\chi_0}^{2} y^{6} \frac{\partial}{\partial y}\Phi_{1}\left(y\right)^{2} + a^{2} y^{8} \frac{\partial}{\partial y}\Phi_{1}\left(y\right)^{2} + 2 \, b^{2} {\chi_0}^{2} y^{6} \frac{\partial}{\partial y}\Psi_{1}\left(y\right)^{2} + 4 \, a^{2} {\chi_0}^{2} m y^{4} \frac{\partial}{\partial y}\Phi_{1}\left(y\right)^{2} - 4 \, b^{2} {\chi_0}^{2} m y^{4} \frac{\partial}{\partial y}\Psi_{1}\left(y\right)^{2} - a^{2} {\chi_0}^{2} y^{4} \frac{\partial}{\partial y}\Phi_{1}\left(y\right)^{2} + 2 \, a^{2} y^{6} \frac{\partial}{\partial y}\Phi_{1}\left(y\right)^{2} + b^{2} {\chi_0}^{2} y^{4} \frac{\partial}{\partial y}\Psi_{1}\left(y\right)^{2} + 4 \, a^{2} {\chi_0}^{2} m y^{2} \frac{\partial}{\partial y}\Phi_{1}\left(y\right)^{2} - 4 \, a^{2} m y^{4} \frac{\partial}{\partial y}\Phi_{1}\left(y\right)^{2} - 4 \, b^{2} {\chi_0}^{2} m y^{2} \frac{\partial}{\partial y}\Psi_{1}\left(y\right)^{2} + a^{2} {\chi_0}^{2} y^{4} - b^{2} {\chi_0}^{2} y^{4} - 4 \, a^{2} {\chi_0}^{2} m^{2} \frac{\partial}{\partial y}\Phi_{1}\left(y\right)^{2} + a^{2} y^{4} \frac{\partial}{\partial y}\Phi_{1}\left(y\right)^{2} + 4 \, b^{2} {\chi_0}^{2} m^{2} \frac{\partial}{\partial y}\Psi_{1}\left(y\right)^{2} - 4 \, a^{2} m y^{2} \frac{\partial}{\partial y}\Phi_{1}\left(y\right)^{2} - a^{2} y^{4} + 4 \, a^{2} m^{2} \frac{\partial}{\partial y}\Phi_{1}\left(y\right)^{2} - 4 \, a^{2} {\chi_0}^{2} m + 4 \, b^{2} {\chi_0}^{2} m + 2 \, y^{4} + 4 \, a^{2} m + 2 \, y^{2} - 4 \, m$$

L_2.denominator()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}2 \, y^{4} + 2 \, y^{2} - 4 \, m$$

Euler-Lagrange equations

def euler_lagrange(lagr, qs, var):
    r"""
    Derive the Euler-Lagrange equations from a given Lagrangian.

    INPUT:

    - ``lagr`` -- symbolic expression representing the Lagrangian density
    - ``qs`` -- either a single symbolic function or a list/tuple of
      symbolic functions, representing the `q`'s; these functions must
      appear in ``lagr`` up to at most their first derivatives
    - ``var`` -- either a single variable, typically `t` (1-dimensional
      problem) or a list/tuple of symbolic variables

    OUTPUT:

    - list of Euler-Lagrange equations; if only one function is involved, the
      single Euler-Lagrannge equation is returned instead.

    """
    if not isinstance(qs, (list, tuple)):
        qs = [qs]
    if not isinstance(var, (list, tuple)):
        var = [var]
    n = len(qs)
    d = len(var)
    qv = [SR.var('qxxxx{}'.format(q)) for q in qs]
    dqv = [[SR.var('qxxxx{}_{}'.format(q, v)) for v in var] for q in qs]
    subs = {qs[i](*var): qv[i] for i in range(n)}
    subs_inv = {qv[i]: qs[i](*var) for i in range(n)}
    for i in range(n):
        subs.update({diff(qs[i](*var), var[j]): dqv[i][j]
                     for j in range(d)})
        subs_inv.update({dqv[i][j]: diff(qs[i](*var), var[j])
                         for j in range(d)})
    lg = lagr.substitute(subs)
    eqs = []
    for i in range(n):
        dLdq = diff(lg, qv[i]).simplify_full()
        dLdq = dLdq.substitute(subs_inv)
        ddL = 0
        for j in range(d):
            h =  diff(lg, dqv[i][j]).simplify_full()
            h = h.substitute(subs_inv)
            ddL += diff(h, var[j])
        eqs.append((dLdq - ddL).simplify_full() == 0)
    if n == 1:
        return eqs[0]
    return eqs

We compute the Euler-Lagrange equations from $L_2$ for $\Phi_1$ and $\Psi_1$:

eqs = euler_lagrange(L_2, [Phi_1, Psi_1], y)
eqs

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\left[2 \, {\left(2 \, {\left(a^{2} {\chi_0}^{2} - a^{2}\right)} y^{3} + {\left(a^{2} {\chi_0}^{2} - a^{2}\right)} y\right)} \frac{\partial}{\partial y}\Phi_{1}\left(y\right) + {\left({\left(a^{2} {\chi_0}^{2} - a^{2}\right)} y^{4} + {\left(a^{2} {\chi_0}^{2} - a^{2}\right)} y^{2} - 2 \, {\left(a^{2} {\chi_0}^{2} - a^{2}\right)} m\right)} \frac{\partial^{2}}{(\partial y)^{2}}\Phi_{1}\left(y\right) = 0, -2 \, {\left(2 \, b^{2} {\chi_0}^{2} y^{3} + b^{2} {\chi_0}^{2} y\right)} \frac{\partial}{\partial y}\Psi_{1}\left(y\right) - {\left(b^{2} {\chi_0}^{2} y^{4} + b^{2} {\chi_0}^{2} y^{2} - 2 \, b^{2} {\chi_0}^{2} m\right)} \frac{\partial^{2}}{(\partial y)^{2}}\Psi_{1}\left(y\right) = 0\right]$$

Solving the equation for $\Phi_1$ (Eq. (4.29))

eq_Phi1 = eqs[0]
eq_Phi1

$$\renewcommand{\Bold}[1]{\mathbf{#1}}2 \, {\left(2 \, {\left(a^{2} {\chi_0}^{2} - a^{2}\right)} y^{3} + {\left(a^{2} {\chi_0}^{2} - a^{2}\right)} y\right)} \frac{\partial}{\partial y}\Phi_{1}\left(y\right) + {\left({\left(a^{2} {\chi_0}^{2} - a^{2}\right)} y^{4} + {\left(a^{2} {\chi_0}^{2} - a^{2}\right)} y^{2} - 2 \, {\left(a^{2} {\chi_0}^{2} - a^{2}\right)} m\right)} \frac{\partial^{2}}{(\partial y)^{2}}\Phi_{1}\left(y\right) = 0$$

eq_Phi1 = (eq_Phi1/(a^2*(ch0^2-1))).simplify_full()
eq_Phi1

$$\renewcommand{\Bold}[1]{\mathbf{#1}}2 \, {\left(2 \, y^{3} + y\right)} \frac{\partial}{\partial y}\Phi_{1}\left(y\right) + {\left(y^{4} + y^{2} - 2 \, m\right)} \frac{\partial^{2}}{(\partial y)^{2}}\Phi_{1}\left(y\right) = 0$$

Phi1_sol(y) = desolve(eq_Phi1, Phi_1(y), ivar=y)
Phi1_sol(y)

$$\renewcommand{\Bold}[1]{\mathbf{#1}}K_{1} \int \frac{1}{y^{4} + y^{2} - 2 \, m}\,{d y} + K_{2}$$

We recover Eqs. (4.29) with $K_1 = \mathfrak{p}$ and $K_2=0$.

The symbolic constants $K_1$ and $K_2$ are actually denoted _K1 and _K2 by SageMath, as print reveals:

print(Phi1_sol(y))

_K1*integrate(1/(y^4 + y^2 - 2*m), y) + _K2

Hence we perform the substitutions with SR.var('_K1') and SR.var('_K2'):

pf = var("pf", latex_name=r"\mathfrak{p}", domain='real')
Phi1_sol(y) = Phi1_sol(y).subs({SR.var('_K1'): pf, SR.var('_K2'): 0})
Phi1_sol(y)

$$\renewcommand{\Bold}[1]{\mathbf{#1}}{\mathfrak{p}} \int \frac{1}{y^{4} + y^{2} - 2 \, m}\,{d y}$$

Solving the equation for $\Psi_1$ (Eq. (4.29))

eq_Psi1 = eqs[1]
eq_Psi1

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-2 \, {\left(2 \, b^{2} {\chi_0}^{2} y^{3} + b^{2} {\chi_0}^{2} y\right)} \frac{\partial}{\partial y}\Psi_{1}\left(y\right) - {\left(b^{2} {\chi_0}^{2} y^{4} + b^{2} {\chi_0}^{2} y^{2} - 2 \, b^{2} {\chi_0}^{2} m\right)} \frac{\partial^{2}}{(\partial y)^{2}}\Psi_{1}\left(y\right) = 0$$

eq_Phi1 = (eq_Psi1/(b^2*ch0^2)).simplify_full()
eq_Phi1

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-2 \, {\left(2 \, y^{3} + y\right)} \frac{\partial}{\partial y}\Psi_{1}\left(y\right) - {\left(y^{4} + y^{2} - 2 \, m\right)} \frac{\partial^{2}}{(\partial y)^{2}}\Psi_{1}\left(y\right) = 0$$

Psi1_sol(y) = desolve(eq_Psi1, Psi_1(y), ivar=y)
Psi1_sol(y)

$$\renewcommand{\Bold}[1]{\mathbf{#1}}K_{1} \int \frac{1}{y^{4} + y^{2} - 2 \, m}\,{d y} + K_{2}$$

We recover Eq. (4.29) with $K_1 = \mathfrak{q}$ and $K_2=0$.

qf = var('qf', latex_name=r"\mathfrak{q}", domain='real')
Psi1_sol(y) = Psi1_sol(y).subs({SR.var('_K1'): qf, SR.var('_K2'): 0})
Psi1_sol(y)

$$\renewcommand{\Bold}[1]{\mathbf{#1}}{\mathfrak{q}} \int \frac{1}{y^{4} + y^{2} - 2 \, m}\,{d y}$$

Nambu-Goto Lagrangian at fourth order in $a$ and $b$

L_4 = expand_ab(sqrt(-detg_4), 4)

eqs = euler_lagrange(L_4, [Phi_1, Psi_1, chi_1], y)

The equation for $\chi_1$

eq_chi1 = eqs[2]
eq_chi1

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{{\left({\left(a^{4} + 2 \, a^{3} b - 2 \, a b^{3} - b^{4}\right)} {\chi_0}^{3} - {\left(a^{4} + 2 \, a^{3} b - 2 \, a b^{3} - b^{4}\right)} {\chi_0}\right)} y^{4} - {\left({\left({\left(a^{4} + 2 \, a^{3} b + a^{2} b^{2}\right)} {\chi_0}^{3} - {\left(a^{4} + 2 \, a^{3} b + a^{2} b^{2}\right)} {\chi_0}\right)} y^{8} + 2 \, {\left({\left(a^{4} + 2 \, a^{3} b + a^{2} b^{2}\right)} {\chi_0}^{3} - {\left(a^{4} + 2 \, a^{3} b + a^{2} b^{2}\right)} {\chi_0}\right)} y^{6} + {\left({\left(a^{4} + 2 \, a^{3} b + a^{2} b^{2}\right)} {\chi_0}^{3} - {\left(a^{4} + 2 \, a^{3} b + a^{2} b^{2}\right)} {\chi_0} - 4 \, {\left({\left(a^{4} + 2 \, a^{3} b + a^{2} b^{2}\right)} {\chi_0}^{3} - {\left(a^{4} + 2 \, a^{3} b + a^{2} b^{2}\right)} {\chi_0}\right)} m\right)} y^{4} - 4 \, {\left({\left(a^{4} + 2 \, a^{3} b + a^{2} b^{2}\right)} {\chi_0}^{3} - {\left(a^{4} + 2 \, a^{3} b + a^{2} b^{2}\right)} {\chi_0}\right)} m y^{2} + 4 \, {\left({\left(a^{4} + 2 \, a^{3} b + a^{2} b^{2}\right)} {\chi_0}^{3} - {\left(a^{4} + 2 \, a^{3} b + a^{2} b^{2}\right)} {\chi_0}\right)} m^{2}\right)} \frac{\partial}{\partial y}\Phi_{1}\left(y\right)^{2} + {\left({\left({\left(a^{2} b^{2} + 2 \, a b^{3} + b^{4}\right)} {\chi_0}^{3} - {\left(a^{2} b^{2} + 2 \, a b^{3} + b^{4}\right)} {\chi_0}\right)} y^{8} + 2 \, {\left({\left(a^{2} b^{2} + 2 \, a b^{3} + b^{4}\right)} {\chi_0}^{3} - {\left(a^{2} b^{2} + 2 \, a b^{3} + b^{4}\right)} {\chi_0}\right)} y^{6} + {\left({\left(a^{2} b^{2} + 2 \, a b^{3} + b^{4}\right)} {\chi_0}^{3} - {\left(a^{2} b^{2} + 2 \, a b^{3} + b^{4}\right)} {\chi_0} - 4 \, {\left({\left(a^{2} b^{2} + 2 \, a b^{3} + b^{4}\right)} {\chi_0}^{3} - {\left(a^{2} b^{2} + 2 \, a b^{3} + b^{4}\right)} {\chi_0}\right)} m\right)} y^{4} - 4 \, {\left({\left(a^{2} b^{2} + 2 \, a b^{3} + b^{4}\right)} {\chi_0}^{3} - {\left(a^{2} b^{2} + 2 \, a b^{3} + b^{4}\right)} {\chi_0}\right)} m y^{2} + 4 \, {\left({\left(a^{2} b^{2} + 2 \, a b^{3} + b^{4}\right)} {\chi_0}^{3} - {\left(a^{2} b^{2} + 2 \, a b^{3} + b^{4}\right)} {\chi_0}\right)} m^{2}\right)} \frac{\partial}{\partial y}\Psi_{1}\left(y\right)^{2} - 4 \, {\left({\left(a^{4} + 2 \, a^{3} b - 2 \, a b^{3} - b^{4}\right)} {\chi_0}^{3} - {\left(a^{4} + 2 \, a^{3} b - 2 \, a b^{3} - b^{4}\right)} {\chi_0}\right)} m + 2 \, {\left(2 \, {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} y^{7} + 3 \, {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} y^{5} + {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4} - 4 \, {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} m\right)} y^{3} - 2 \, {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} m y\right)} \frac{\partial}{\partial y}\chi_{1}\left(y\right) + {\left({\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} y^{8} + 2 \, {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} y^{6} + {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4} - 4 \, {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} m\right)} y^{4} - 4 \, {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} m y^{2} + 4 \, {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} m^{2}\right)} \frac{\partial^{2}}{(\partial y)^{2}}\chi_{1}\left(y\right)}{{\left({\chi_0}^{2} - 1\right)} y^{4} + {\left({\chi_0}^{2} - 1\right)} y^{2} - 2 \, {\left({\chi_0}^{2} - 1\right)} m} = 0$$

eq_chi1.lhs().denominator().simplify_full()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}{\left({\chi_0}^{2} - 1\right)} y^{4} + {\left({\chi_0}^{2} - 1\right)} y^{2} - 2 \, {\left({\chi_0}^{2} - 1\right)} m$$

eq_chi1 = eq_chi1.lhs().numerator().simplify_full() == 0
eq_chi1

$$\renewcommand{\Bold}[1]{\mathbf{#1}}{\left({\left(a^{4} + 2 \, a^{3} b - 2 \, a b^{3} - b^{4}\right)} {\chi_0}^{3} - {\left(a^{4} + 2 \, a^{3} b - 2 \, a b^{3} - b^{4}\right)} {\chi_0}\right)} y^{4} - {\left({\left({\left(a^{4} + 2 \, a^{3} b + a^{2} b^{2}\right)} {\chi_0}^{3} - {\left(a^{4} + 2 \, a^{3} b + a^{2} b^{2}\right)} {\chi_0}\right)} y^{8} + 2 \, {\left({\left(a^{4} + 2 \, a^{3} b + a^{2} b^{2}\right)} {\chi_0}^{3} - {\left(a^{4} + 2 \, a^{3} b + a^{2} b^{2}\right)} {\chi_0}\right)} y^{6} + {\left({\left(a^{4} + 2 \, a^{3} b + a^{2} b^{2}\right)} {\chi_0}^{3} - {\left(a^{4} + 2 \, a^{3} b + a^{2} b^{2}\right)} {\chi_0} - 4 \, {\left({\left(a^{4} + 2 \, a^{3} b + a^{2} b^{2}\right)} {\chi_0}^{3} - {\left(a^{4} + 2 \, a^{3} b + a^{2} b^{2}\right)} {\chi_0}\right)} m\right)} y^{4} - 4 \, {\left({\left(a^{4} + 2 \, a^{3} b + a^{2} b^{2}\right)} {\chi_0}^{3} - {\left(a^{4} + 2 \, a^{3} b + a^{2} b^{2}\right)} {\chi_0}\right)} m y^{2} + 4 \, {\left({\left(a^{4} + 2 \, a^{3} b + a^{2} b^{2}\right)} {\chi_0}^{3} - {\left(a^{4} + 2 \, a^{3} b + a^{2} b^{2}\right)} {\chi_0}\right)} m^{2}\right)} \frac{\partial}{\partial y}\Phi_{1}\left(y\right)^{2} + {\left({\left({\left(a^{2} b^{2} + 2 \, a b^{3} + b^{4}\right)} {\chi_0}^{3} - {\left(a^{2} b^{2} + 2 \, a b^{3} + b^{4}\right)} {\chi_0}\right)} y^{8} + 2 \, {\left({\left(a^{2} b^{2} + 2 \, a b^{3} + b^{4}\right)} {\chi_0}^{3} - {\left(a^{2} b^{2} + 2 \, a b^{3} + b^{4}\right)} {\chi_0}\right)} y^{6} + {\left({\left(a^{2} b^{2} + 2 \, a b^{3} + b^{4}\right)} {\chi_0}^{3} - {\left(a^{2} b^{2} + 2 \, a b^{3} + b^{4}\right)} {\chi_0} - 4 \, {\left({\left(a^{2} b^{2} + 2 \, a b^{3} + b^{4}\right)} {\chi_0}^{3} - {\left(a^{2} b^{2} + 2 \, a b^{3} + b^{4}\right)} {\chi_0}\right)} m\right)} y^{4} - 4 \, {\left({\left(a^{2} b^{2} + 2 \, a b^{3} + b^{4}\right)} {\chi_0}^{3} - {\left(a^{2} b^{2} + 2 \, a b^{3} + b^{4}\right)} {\chi_0}\right)} m y^{2} + 4 \, {\left({\left(a^{2} b^{2} + 2 \, a b^{3} + b^{4}\right)} {\chi_0}^{3} - {\left(a^{2} b^{2} + 2 \, a b^{3} + b^{4}\right)} {\chi_0}\right)} m^{2}\right)} \frac{\partial}{\partial y}\Psi_{1}\left(y\right)^{2} - 4 \, {\left({\left(a^{4} + 2 \, a^{3} b - 2 \, a b^{3} - b^{4}\right)} {\chi_0}^{3} - {\left(a^{4} + 2 \, a^{3} b - 2 \, a b^{3} - b^{4}\right)} {\chi_0}\right)} m + 2 \, {\left(2 \, {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} y^{7} + 3 \, {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} y^{5} + {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4} - 4 \, {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} m\right)} y^{3} - 2 \, {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} m y\right)} \frac{\partial}{\partial y}\chi_{1}\left(y\right) + {\left({\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} y^{8} + 2 \, {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} y^{6} + {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4} - 4 \, {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} m\right)} y^{4} - 4 \, {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} m y^{2} + 4 \, {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} m^{2}\right)} \frac{\partial^{2}}{(\partial y)^{2}}\chi_{1}\left(y\right) = 0$$

We plug the solutions obtained previously for $\Phi_1(y)$ and $\Psi_1(y)$ in this equation:

eq_chi1 = eq_chi1.substitute_function(Phi_1, 
                                      Phi1_sol).substitute_function(Psi_1, 
                                                                    Psi1_sol)
eq_chi1 = eq_chi1.simplify_full()
eq_chi1

$$\renewcommand{\Bold}[1]{\mathbf{#1}}{\left({\left(a^{4} + 2 \, a^{3} b - 2 \, a b^{3} - b^{4}\right)} {\chi_0}^{3} - {\left(a^{4} + 2 \, a^{3} b - 2 \, a b^{3} - b^{4}\right)} {\chi_0}\right)} y^{4} - {\left({\left(a^{4} + 2 \, a^{3} b + a^{2} b^{2}\right)} {\chi_0}^{3} - {\left(a^{4} + 2 \, a^{3} b + a^{2} b^{2}\right)} {\chi_0}\right)} {\mathfrak{p}}^{2} + {\left({\left(a^{2} b^{2} + 2 \, a b^{3} + b^{4}\right)} {\chi_0}^{3} - {\left(a^{2} b^{2} + 2 \, a b^{3} + b^{4}\right)} {\chi_0}\right)} {\mathfrak{q}}^{2} - 4 \, {\left({\left(a^{4} + 2 \, a^{3} b - 2 \, a b^{3} - b^{4}\right)} {\chi_0}^{3} - {\left(a^{4} + 2 \, a^{3} b - 2 \, a b^{3} - b^{4}\right)} {\chi_0}\right)} m + 2 \, {\left(2 \, {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} y^{7} + 3 \, {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} y^{5} + {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4} - 4 \, {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} m\right)} y^{3} - 2 \, {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} m y\right)} \frac{\partial}{\partial y}\chi_{1}\left(y\right) + {\left({\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} y^{8} + 2 \, {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} y^{6} + {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4} - 4 \, {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} m\right)} y^{4} - 4 \, {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} m y^{2} + 4 \, {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} m^{2}\right)} \frac{\partial^{2}}{(\partial y)^{2}}\chi_{1}\left(y\right) = 0$$

Check of Eq. (4.30)

lhs = eq_chi1.lhs()
lhs = lhs.simplify_full()
lhs

$$\renewcommand{\Bold}[1]{\mathbf{#1}}{\left({\left(a^{4} + 2 \, a^{3} b - 2 \, a b^{3} - b^{4}\right)} {\chi_0}^{3} - {\left(a^{4} + 2 \, a^{3} b - 2 \, a b^{3} - b^{4}\right)} {\chi_0}\right)} y^{4} - {\left({\left(a^{4} + 2 \, a^{3} b + a^{2} b^{2}\right)} {\chi_0}^{3} - {\left(a^{4} + 2 \, a^{3} b + a^{2} b^{2}\right)} {\chi_0}\right)} {\mathfrak{p}}^{2} + {\left({\left(a^{2} b^{2} + 2 \, a b^{3} + b^{4}\right)} {\chi_0}^{3} - {\left(a^{2} b^{2} + 2 \, a b^{3} + b^{4}\right)} {\chi_0}\right)} {\mathfrak{q}}^{2} - 4 \, {\left({\left(a^{4} + 2 \, a^{3} b - 2 \, a b^{3} - b^{4}\right)} {\chi_0}^{3} - {\left(a^{4} + 2 \, a^{3} b - 2 \, a b^{3} - b^{4}\right)} {\chi_0}\right)} m + 2 \, {\left(2 \, {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} y^{7} + 3 \, {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} y^{5} + {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4} - 4 \, {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} m\right)} y^{3} - 2 \, {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} m y\right)} \frac{\partial}{\partial y}\chi_{1}\left(y\right) + {\left({\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} y^{8} + 2 \, {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} y^{6} + {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4} - 4 \, {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} m\right)} y^{4} - 4 \, {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} m y^{2} + 4 \, {\left(a^{4} + 4 \, a^{3} b + 6 \, a^{2} b^{2} + 4 \, a b^{3} + b^{4}\right)} m^{2}\right)} \frac{\partial^{2}}{(\partial y)^{2}}\chi_{1}\left(y\right)$$

s = lhs.coefficient(diff(chi_1(y), y, 2))  # coefficient of chi_1''
s.factor()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}{\left(y^{4} + y^{2} - 2 \, m\right)}^{2} {\left(a + b\right)}^{4}$$

s1 = (lhs/s - diff(chi_1(y), y, 2)).simplify_full()
s1

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{{\left({\left(a^{2} - b^{2}\right)} {\chi_0}^{3} - {\left(a^{2} - b^{2}\right)} {\chi_0}\right)} y^{4} - {\left(a^{2} {\chi_0}^{3} - a^{2} {\chi_0}\right)} {\mathfrak{p}}^{2} + {\left(b^{2} {\chi_0}^{3} - b^{2} {\chi_0}\right)} {\mathfrak{q}}^{2} - 4 \, {\left({\left(a^{2} - b^{2}\right)} {\chi_0}^{3} - {\left(a^{2} - b^{2}\right)} {\chi_0}\right)} m + 2 \, {\left(2 \, {\left(a^{2} + 2 \, a b + b^{2}\right)} y^{7} + 3 \, {\left(a^{2} + 2 \, a b + b^{2}\right)} y^{5} + {\left(a^{2} + 2 \, a b + b^{2} - 4 \, {\left(a^{2} + 2 \, a b + b^{2}\right)} m\right)} y^{3} - 2 \, {\left(a^{2} + 2 \, a b + b^{2}\right)} m y\right)} \frac{\partial}{\partial y}\chi_{1}\left(y\right)}{{\left(a^{2} + 2 \, a b + b^{2}\right)} y^{8} + 2 \, {\left(a^{2} + 2 \, a b + b^{2}\right)} y^{6} + {\left(a^{2} + 2 \, a b + b^{2} - 4 \, {\left(a^{2} + 2 \, a b + b^{2}\right)} m\right)} y^{4} - 4 \, {\left(a^{2} + 2 \, a b + b^{2}\right)} m y^{2} + 4 \, {\left(a^{2} + 2 \, a b + b^{2}\right)} m^{2}}$$

b1 = s1.coefficient(diff(chi_1(y), y)).factor()
b1

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{2 \, {\left(2 \, y^{2} + 1\right)} y}{y^{4} + y^{2} - 2 \, m}$$

b2 = (s1 - b1*diff(chi_1(y), y)).simplify_full().factor()
b2

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{{\left(a^{2} y^{4} - b^{2} y^{4} - a^{2} {\mathfrak{p}}^{2} + b^{2} {\mathfrak{q}}^{2} - 4 \, a^{2} m + 4 \, b^{2} m\right)} {\left({\chi_0} + 1\right)} {\left({\chi_0} - 1\right)} {\chi_0}}{{\left(y^{4} + y^{2} - 2 \, m\right)}^{2} {\left(a + b\right)}^{2}}$$

The equation for $\chi_1$ is thus:

eq_chi1 = diff(chi_1(y), y, 2) + b1*diff(chi_1(y), y) + b2 == 0
eq_chi1

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{2 \, {\left(2 \, y^{2} + 1\right)} y \frac{\partial}{\partial y}\chi_{1}\left(y\right)}{y^{4} + y^{2} - 2 \, m} + \frac{{\left(a^{2} y^{4} - b^{2} y^{4} - a^{2} {\mathfrak{p}}^{2} + b^{2} {\mathfrak{q}}^{2} - 4 \, a^{2} m + 4 \, b^{2} m\right)} {\left({\chi_0} + 1\right)} {\left({\chi_0} - 1\right)} {\chi_0}}{{\left(y^{4} + y^{2} - 2 \, m\right)}^{2} {\left(a + b\right)}^{2}} + \frac{\partial^{2}}{(\partial y)^{2}}\chi_{1}\left(y\right) = 0$$

Given that $$\chi_1(y) = - \sin\Theta_0 \; \Theta_1(y) = - \sqrt{1-\chi_0^2} \; \Theta_1(y)$$ and $$\sin2\Theta_0 = 2\chi_0\sqrt{1-\chi_0^2}$$ we get for the following equation for $\Upsilon = \Theta_1'$ (defining $\Theta_2 := 2 \Theta_0$):

Y = function('Y', latex_name=r'\Upsilon')
Th2 = var('Th2', latex_name=r'\Theta_2', domain='real')
eq_Y = diff(Y(y), y) + b1*Y(y) \
       - b2/(1 - ch0)/(1 + ch0)/ch0*sin(Th2)/2 == 0
eq_Y

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{2 \, {\left(2 \, y^{2} + 1\right)} y \Upsilon\left(y\right)}{y^{4} + y^{2} - 2 \, m} + \frac{{\left(a^{2} y^{4} - b^{2} y^{4} - a^{2} {\mathfrak{p}}^{2} + b^{2} {\mathfrak{q}}^{2} - 4 \, a^{2} m + 4 \, b^{2} m\right)} \sin\left({\Theta_2}\right)}{2 \, {\left(y^{4} + y^{2} - 2 \, m\right)}^{2} {\left(a + b\right)}^{2}} + \frac{\partial}{\partial y}\Upsilon\left(y\right) = 0$$

This agrees with Eq. (4.30) of the paper.

Solving the equation for $\Upsilon := \Theta_1'$

Y_sol(y) = desolve(eq_Y, Y(y), ivar=y)

The solution involves an integral that SageMath is not capable to evaluate with the default integrator. Printing Y_sol provides the unvaluated form of the integral, in order to compute it by means of FriCAS:

print(Y_sol(y))

1/2*(2*_C - (a*sin(Th2) - b*sin(Th2))*y/(a + b) - integrate(-(a^2*pf^2 - b^2*qf^2 + (a^2 - b^2)*y^2 + 2*(a^2 - b^2)*m)/(y^4 + y^2 - 2*m), y)*sin(Th2)/(a^2 + 2*a*b + b^2))/(y^4 + y^2 - 2*m)

The solution involves some constant, denoted _C by SageMath. We rename it C_1 and rewrite the above solution as

C_1 = var('C_1')
Integ(y) = function('Integ')(y)
Y_sol0(y) = 1/2*(2*C_1 - (a*sin(Th2) - b*sin(Th2))*y/(a + b) \
                 - Integ(y)*sin(Th2)/(a^2 + 2*a*b + b^2))/(y^4 + y^2 - 2*m)
Y_sol0(y)

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{2 \, C_{1} - \frac{{\left(a \sin\left({\Theta_2}\right) - b \sin\left({\Theta_2}\right)\right)} y}{a + b} - \frac{{\rm Integ}\left(y\right) \sin\left({\Theta_2}\right)}{a^{2} + 2 \, a b + b^{2}}}{2 \, {\left(y^{4} + y^{2} - 2 \, m\right)}}$$

Integ(y) represents the integral $I(y)$, whose integrand, $F(y)$ say, is read from the output of print(Y_sol(Y)):

F(y) = -(a^2*pf^2 - b^2*qf^2 + (a^2 - b^2)*y^2 + 2*(a^2 - b^2)*m)/(y^4 + y^2 - 2*m)
F(y)

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-\frac{a^{2} {\mathfrak{p}}^{2} - b^{2} {\mathfrak{q}}^{2} + {\left(a^{2} - b^{2}\right)} y^{2} + 2 \, {\left(a^{2} - b^{2}\right)} m}{y^{4} + y^{2} - 2 \, m}$$

We split the integral in two parts: $$I(y) = F_1 \; s_1(y) + F_2 \; s_2(y)$$ with $$s_1(y) := \int^y \frac{\bar{y}^2}{\bar{y}^4 + \bar{y}^2 - 2m} \, \mathrm{d}\bar{y}, \qquad s_2(y) := \int^y \frac{\mathrm{d}\bar{y}}{\bar{y}^4 + \bar{y}^2 - 2m}$$ and

F1 = -(a^2 - b^2)
F1

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-a^{2} + b^{2}$$

F2 = -(a^2*pf^2 - b^2*qf^2 + 2*(a^2 - b^2)*m)
F2

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-a^{2} {\mathfrak{p}}^{2} + b^{2} {\mathfrak{q}}^{2} - 2 \, {\left(a^{2} - b^{2}\right)} m$$

Check:

bool(F(y) == F1*y^2/(y^4 + y^2 - 2*m) + F2/(y^4 + y^2 - 2*m))

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\mathrm{True}$$

Let us evaluate $s_1(y)$ by means of FriCAS:

s1 = integrate(y^2/(y^4 + y^2 - 2*m), y, algorithm='fricas')
s1

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{2} \, \sqrt{\frac{1}{2}} \sqrt{-\frac{\sqrt{8 \, m + 1} + 1}{8 \, m + 1}} \log\left(\sqrt{\frac{1}{2}} \sqrt{8 \, m + 1} \sqrt{-\frac{\sqrt{8 \, m + 1} + 1}{8 \, m + 1}} + y\right) - \frac{1}{2} \, \sqrt{\frac{1}{2}} \sqrt{-\frac{\sqrt{8 \, m + 1} + 1}{8 \, m + 1}} \log\left(-\sqrt{\frac{1}{2}} \sqrt{8 \, m + 1} \sqrt{-\frac{\sqrt{8 \, m + 1} + 1}{8 \, m + 1}} + y\right) - \frac{1}{2} \, \sqrt{\frac{1}{2}} \sqrt{\frac{\sqrt{8 \, m + 1} - 1}{8 \, m + 1}} \log\left(\sqrt{\frac{1}{2}} \sqrt{8 \, m + 1} \sqrt{\frac{\sqrt{8 \, m + 1} - 1}{8 \, m + 1}} + y\right) + \frac{1}{2} \, \sqrt{\frac{1}{2}} \sqrt{\frac{\sqrt{8 \, m + 1} - 1}{8 \, m + 1}} \log\left(-\sqrt{\frac{1}{2}} \sqrt{8 \, m + 1} \sqrt{\frac{\sqrt{8 \, m + 1} - 1}{8 \, m + 1}} + y\right)$$

s1 = s1.canonicalize_radical().simplify_log()
s1

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{\sqrt{2} \sqrt{\sqrt{8 \, m + 1} - 1} \log\left(\frac{\sqrt{2} y - \sqrt{\sqrt{8 \, m + 1} - 1}}{\sqrt{2} y + \sqrt{\sqrt{8 \, m + 1} - 1}}\right) + \sqrt{2} \sqrt{-\sqrt{8 \, m + 1} - 1} \log\left(\frac{\sqrt{2} y + \sqrt{-\sqrt{8 \, m + 1} - 1}}{\sqrt{2} y - \sqrt{-\sqrt{8 \, m + 1} - 1}}\right)}{4 \, \sqrt{8 \, m + 1}}$$

Check:

diff(s1, y).simplify_full()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{y^{2}}{y^{4} + y^{2} - 2 \, m}$$

Similarly, we evaluate $s_2(y)$ by means of FriCAS:

s2 = integrate(1/(y^4 + y^2 - 2*m), y, algorithm='fricas')
s2

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-\frac{1}{4} \, \sqrt{\frac{\frac{8 \, m^{2} + m}{\sqrt{8 \, m^{3} + m^{2}}} + 1}{8 \, m^{2} + m}} \log\left(\frac{1}{2} \, {\left(8 \, m - \frac{8 \, m^{2} + m}{\sqrt{8 \, m^{3} + m^{2}}} + 1\right)} \sqrt{\frac{\frac{8 \, m^{2} + m}{\sqrt{8 \, m^{3} + m^{2}}} + 1}{8 \, m^{2} + m}} + 2 \, y\right) + \frac{1}{4} \, \sqrt{\frac{\frac{8 \, m^{2} + m}{\sqrt{8 \, m^{3} + m^{2}}} + 1}{8 \, m^{2} + m}} \log\left(-\frac{1}{2} \, {\left(8 \, m - \frac{8 \, m^{2} + m}{\sqrt{8 \, m^{3} + m^{2}}} + 1\right)} \sqrt{\frac{\frac{8 \, m^{2} + m}{\sqrt{8 \, m^{3} + m^{2}}} + 1}{8 \, m^{2} + m}} + 2 \, y\right) - \frac{1}{4} \, \sqrt{-\frac{\frac{8 \, m^{2} + m}{\sqrt{8 \, m^{3} + m^{2}}} - 1}{8 \, m^{2} + m}} \log\left(\frac{1}{2} \, {\left(8 \, m + \frac{8 \, m^{2} + m}{\sqrt{8 \, m^{3} + m^{2}}} + 1\right)} \sqrt{-\frac{\frac{8 \, m^{2} + m}{\sqrt{8 \, m^{3} + m^{2}}} - 1}{8 \, m^{2} + m}} + 2 \, y\right) + \frac{1}{4} \, \sqrt{-\frac{\frac{8 \, m^{2} + m}{\sqrt{8 \, m^{3} + m^{2}}} - 1}{8 \, m^{2} + m}} \log\left(-\frac{1}{2} \, {\left(8 \, m + \frac{8 \, m^{2} + m}{\sqrt{8 \, m^{3} + m^{2}}} + 1\right)} \sqrt{-\frac{\frac{8 \, m^{2} + m}{\sqrt{8 \, m^{3} + m^{2}}} - 1}{8 \, m^{2} + m}} + 2 \, y\right)$$

s2 = s2.canonicalize_radical().simplify_log()
s2

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{\sqrt{-8 \, m + \sqrt{8 \, m + 1} - 1} \log\left(\frac{4 \, {\left(8 \, m + 1\right)}^{\frac{1}{4}} \sqrt{m} y - \sqrt{-8 \, m + \sqrt{8 \, m + 1} - 1} {\left(\sqrt{8 \, m + 1} + 1\right)}}{4 \, {\left(8 \, m + 1\right)}^{\frac{1}{4}} \sqrt{m} y + \sqrt{-8 \, m + \sqrt{8 \, m + 1} - 1} {\left(\sqrt{8 \, m + 1} + 1\right)}}\right) + \sqrt{8 \, m + \sqrt{8 \, m + 1} + 1} \log\left(\frac{4 \, {\left(8 \, m + 1\right)}^{\frac{1}{4}} \sqrt{m} y - \sqrt{8 \, m + \sqrt{8 \, m + 1} + 1} {\left(\sqrt{8 \, m + 1} - 1\right)}}{4 \, {\left(8 \, m + 1\right)}^{\frac{1}{4}} \sqrt{m} y + \sqrt{8 \, m + \sqrt{8 \, m + 1} + 1} {\left(\sqrt{8 \, m + 1} - 1\right)}}\right)}{4 \, {\left(8 \, m + 1\right)}^{\frac{3}{4}} \sqrt{m}}$$

Check:

diff(s2, y).simplify_full()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{y^{4} + y^{2} - 2 \, m}$$

In the above expressions for $s_1(y)$ and $s_2(y)$, there appears $\sqrt{1 + 8 m}$, which can be rewritten $$\sqrt{1 + 8 m} = 2 y_H^2 + 1$$ where $y_H$ is the positive root of $y_H^4 + y_H^2 - 2m = 0$. More precisely, we perform the following substitution: $$m = \frac{1}{2} y_H^2 (y_H^2 + 1)$$

yH = var('yH', latex_name=r'y_H', domain='real')
assume(yH > 0)
m_yH = yH^2*(yH^2 + 1)/2
s1 = s1.subs({m: m_yH}).canonicalize_radical().simplify_log()
s1

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-\frac{{y_H} \log\left(\frac{y + {y_H}}{y - {y_H}}\right) + i \, \sqrt{{y_H}^{2} + 1} \log\left(\frac{y - i \, \sqrt{{y_H}^{2} + 1}}{y + i \, \sqrt{{y_H}^{2} + 1}}\right)}{2 \, {\left(2 \, {y_H}^{2} + 1\right)}}$$

In the second $\log$, we recognize the $\mathrm{arccot}$ function, via the identity $$\mathrm{arccot}\, x = \frac{i}{2} \ln\left( \frac{x - i}{x + i} \right) .$$ Given that $\mathrm{arccot}\, x = \pi/2 - \mathrm{arctan}\, x$, we use this identity as $$i \ln\left( \frac{x - i}{x + i} \right) = - 2 \, \mathrm{arctan}(x) + \pi$$

Thus, we perform the following substitution, disregarding the additive constant $\pi$:

s1 = s1.subs({I*sqrt(yH^2 + 1)*log((y - I*sqrt(yH^2 + 1))/(y + I*sqrt(yH^2 + 1))):
              -2*sqrt(yH^2 + 1)*atan(y/sqrt(yH^2 + 1))})
s1

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-\frac{{y_H} \log\left(\frac{y + {y_H}}{y - {y_H}}\right) - 2 \, \sqrt{{y_H}^{2} + 1} \arctan\left(\frac{y}{\sqrt{{y_H}^{2} + 1}}\right)}{2 \, {\left(2 \, {y_H}^{2} + 1\right)}}$$

Let us check that we have indeed a primitive of $y\mapsto \frac{y^2}{y^4 + y^2 - 2m}$:

Ds1 = diff(s1, y).simplify_full()
Ds1

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{y^{2}}{y^{4} - {y_H}^{4} + y^{2} - {y_H}^{2}}$$

yH_m = sqrt(sqrt(1 + 8*m) - 1)/sqrt(2)
Ds1.subs({yH: yH_m}).simplify_full()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{y^{2}}{y^{4} + y^{2} - 2 \, m}$$

Similarly, let us express $s_2$ in terms of $y_H$:

s2 = s2.subs({m: m_yH}).canonicalize_radical().simplify_log()
s2

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{i \, {y_H} \log\left(\frac{-i \, {y_H}^{2} + \sqrt{{y_H}^{2} + 1} y - i}{i \, {y_H}^{2} + \sqrt{{y_H}^{2} + 1} y + i}\right) + \sqrt{{y_H}^{2} + 1} \log\left(\frac{y - {y_H}}{y + {y_H}}\right)}{2 \, {\left(2 \, {y_H}^{3} + {y_H}\right)} \sqrt{{y_H}^{2} + 1}}$$

Again, we use the identity $$i \ln\left( \frac{x - i}{x + i} \right) = - 2 \, \mathrm{arctan}(x) + \pi$$ to rewrite $s_2$ as

s2 = s2.subs({I*yH*log((-I*yH^2 + sqrt(yH^2 + 1)*y - I)/(I*yH^2 + sqrt(yH^2 + 1)*y + I)):
              -2*yH*atan(y/sqrt(yH^2 + 1))})
s2

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-\frac{2 \, {y_H} \arctan\left(\frac{y}{\sqrt{{y_H}^{2} + 1}}\right) - \sqrt{{y_H}^{2} + 1} \log\left(\frac{y - {y_H}}{y + {y_H}}\right)}{2 \, {\left(2 \, {y_H}^{3} + {y_H}\right)} \sqrt{{y_H}^{2} + 1}}$$

Let us also replace $\ln\left(\frac{y - y_H}{y + y_H}\right)$ by $-\ln\left(\frac{y + y_H}{y - y_H}\right)$ in order to have the same log term as in $s_1(y)$:

s2 = s2.subs({log((y - yH)/(y + yH)): - log((y + yH)/(y - yH))})
s2

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-\frac{2 \, {y_H} \arctan\left(\frac{y}{\sqrt{{y_H}^{2} + 1}}\right) + \sqrt{{y_H}^{2} + 1} \log\left(\frac{y + {y_H}}{y - {y_H}}\right)}{2 \, {\left(2 \, {y_H}^{3} + {y_H}\right)} \sqrt{{y_H}^{2} + 1}}$$

Let us check that we have indeed a primitive of $y\mapsto \frac{1}{y^4 + y^2 - 2m}$:

Ds2 = diff(s2, y).simplify_full()
Ds2

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{y^{4} - {y_H}^{4} + y^{2} - {y_H}^{2}}$$

Ds2.subs({yH: yH_m}).simplify_full()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{y^{4} + y^{2} - 2 \, m}$$

The full integral is thus

Integ0 = (F1*s1 + F2*s2).simplify_full()
Integ0

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{{\left(a^{2} {\mathfrak{p}}^{2} - b^{2} {\mathfrak{q}}^{2} + {\left(a^{2} - b^{2}\right)} {y_H}^{2} + 2 \, {\left(a^{2} - b^{2}\right)} m\right)} \sqrt{{y_H}^{2} + 1} \log\left(\frac{y + {y_H}}{y - {y_H}}\right) - 2 \, {\left({\left(a^{2} - b^{2}\right)} {y_H}^{3} - {\left(a^{2} {\mathfrak{p}}^{2} - b^{2} {\mathfrak{q}}^{2} - a^{2} + b^{2} + 2 \, {\left(a^{2} - b^{2}\right)} m\right)} {y_H}\right)} \arctan\left(\frac{y}{\sqrt{{y_H}^{2} + 1}}\right)}{2 \, {\left(2 \, {y_H}^{3} + {y_H}\right)} \sqrt{{y_H}^{2} + 1}}$$

so that the solution is

Y_sol(y) = Y_sol0(y).subs({Integ(y): Integ0}).simplify_full()
Y_sol(y)

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{2 \, {\left({\left(a^{2} \sin\left({\Theta_2}\right) - b^{2} \sin\left({\Theta_2}\right)\right)} {y_H}^{3} - {\left(a^{2} {\mathfrak{p}}^{2} \sin\left({\Theta_2}\right) - b^{2} {\mathfrak{q}}^{2} \sin\left({\Theta_2}\right) - a^{2} \sin\left({\Theta_2}\right) + b^{2} \sin\left({\Theta_2}\right) + 2 \, {\left(a^{2} \sin\left({\Theta_2}\right) - b^{2} \sin\left({\Theta_2}\right)\right)} m\right)} {y_H}\right)} \arctan\left(\frac{y}{\sqrt{{y_H}^{2} + 1}}\right) + {\left(4 \, {\left(2 \, C_{1} a^{2} + 4 \, C_{1} a b + 2 \, C_{1} b^{2} - {\left(a^{2} \sin\left({\Theta_2}\right) - b^{2} \sin\left({\Theta_2}\right)\right)} y\right)} {y_H}^{3} + 2 \, {\left(2 \, C_{1} a^{2} + 4 \, C_{1} a b + 2 \, C_{1} b^{2} - {\left(a^{2} \sin\left({\Theta_2}\right) - b^{2} \sin\left({\Theta_2}\right)\right)} y\right)} {y_H} - {\left(a^{2} {\mathfrak{p}}^{2} \sin\left({\Theta_2}\right) - b^{2} {\mathfrak{q}}^{2} \sin\left({\Theta_2}\right) + {\left(a^{2} \sin\left({\Theta_2}\right) - b^{2} \sin\left({\Theta_2}\right)\right)} {y_H}^{2} + 2 \, {\left(a^{2} \sin\left({\Theta_2}\right) - b^{2} \sin\left({\Theta_2}\right)\right)} m\right)} \log\left(\frac{y + {y_H}}{y - {y_H}}\right)\right)} \sqrt{{y_H}^{2} + 1}}{4 \, {\left(2 \, {\left({\left(a^{2} + 2 \, a b + b^{2}\right)} y^{4} + {\left(a^{2} + 2 \, a b + b^{2}\right)} y^{2} - 2 \, {\left(a^{2} + 2 \, a b + b^{2}\right)} m\right)} {y_H}^{3} + {\left({\left(a^{2} + 2 \, a b + b^{2}\right)} y^{4} + {\left(a^{2} + 2 \, a b + b^{2}\right)} y^{2} - 2 \, {\left(a^{2} + 2 \, a b + b^{2}\right)} m\right)} {y_H}\right)} \sqrt{{y_H}^{2} + 1}}$$

Y_sol(y).numerator().simplify_full()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}2 \, {\left({\left(a^{2} \sin\left({\Theta_2}\right) - b^{2} \sin\left({\Theta_2}\right)\right)} {y_H}^{3} - {\left(a^{2} {\mathfrak{p}}^{2} \sin\left({\Theta_2}\right) - b^{2} {\mathfrak{q}}^{2} \sin\left({\Theta_2}\right) - a^{2} \sin\left({\Theta_2}\right) + b^{2} \sin\left({\Theta_2}\right) + 2 \, {\left(a^{2} \sin\left({\Theta_2}\right) - b^{2} \sin\left({\Theta_2}\right)\right)} m\right)} {y_H}\right)} \arctan\left(\frac{y}{\sqrt{{y_H}^{2} + 1}}\right) + {\left(4 \, {\left(2 \, C_{1} a^{2} + 4 \, C_{1} a b + 2 \, C_{1} b^{2} - {\left(a^{2} \sin\left({\Theta_2}\right) - b^{2} \sin\left({\Theta_2}\right)\right)} y\right)} {y_H}^{3} + 2 \, {\left(2 \, C_{1} a^{2} + 4 \, C_{1} a b + 2 \, C_{1} b^{2} - {\left(a^{2} \sin\left({\Theta_2}\right) - b^{2} \sin\left({\Theta_2}\right)\right)} y\right)} {y_H} - {\left(a^{2} {\mathfrak{p}}^{2} \sin\left({\Theta_2}\right) - b^{2} {\mathfrak{q}}^{2} \sin\left({\Theta_2}\right) + {\left(a^{2} \sin\left({\Theta_2}\right) - b^{2} \sin\left({\Theta_2}\right)\right)} {y_H}^{2} + 2 \, {\left(a^{2} \sin\left({\Theta_2}\right) - b^{2} \sin\left({\Theta_2}\right)\right)} m\right)} \log\left(\frac{y + {y_H}}{y - {y_H}}\right)\right)} \sqrt{{y_H}^{2} + 1}$$

Y_sol(y).denominator().factor()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}4 \, {\left(y^{4} + y^{2} - 2 \, m\right)} {\left(2 \, {y_H}^{2} + 1\right)} \sqrt{{y_H}^{2} + 1} {\left(a + b\right)}^{2} {y_H}$$

Let us check that Y_sol is indeed a solution of the differential equation for $\Upsilon$:

eq_Y.substitute_function(Y, Y_sol).subs({yH: yH_m}).simplify_full()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}0 = 0$$

print(Y_sol(y))

1/4*(2*((a^2*sin(Th2) - b^2*sin(Th2))*yH^3 - (a^2*pf^2*sin(Th2) - b^2*qf^2*sin(Th2) - a^2*sin(Th2) + b^2*sin(Th2) + 2*(a^2*sin(Th2) - b^2*sin(Th2))*m)*yH)*arctan(y/sqrt(yH^2 + 1)) + (4*(2*C_1*a^2 + 4*C_1*a*b + 2*C_1*b^2 - (a^2*sin(Th2) - b^2*sin(Th2))*y)*yH^3 + 2*(2*C_1*a^2 + 4*C_1*a*b + 2*C_1*b^2 - (a^2*sin(Th2) - b^2*sin(Th2))*y)*yH - (a^2*pf^2*sin(Th2) - b^2*qf^2*sin(Th2) + (a^2*sin(Th2) - b^2*sin(Th2))*yH^2 + 2*(a^2*sin(Th2) - b^2*sin(Th2))*m)*log((y + yH)/(y - yH)))*sqrt(yH^2 + 1))/((2*((a^2 + 2*a*b + b^2)*y^4 + (a^2 + 2*a*b + b^2)*y^2 - 2*(a^2 + 2*a*b + b^2)*m)*yH^3 + ((a^2 + 2*a*b + b^2)*y^4 + (a^2 + 2*a*b + b^2)*y^2 - 2*(a^2 + 2*a*b + b^2)*m)*yH)*sqrt(yH^2 + 1))

Check of Eq. (4.31) (expression of $\Theta'_1 = \Upsilon$)

The term involving the constant $C_1$ agrees with that of Eq. (4.31):

s = Y_sol(y).coefficient(C_1).simplify_full()
s

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{y^{4} + y^{2} - 2 \, m}$$

Let us remove it from $\Upsilon$ and divide the result by $\sin(2\Theta_0)$:

Y1 = ((Y_sol(y) - s*C_1)/sin(Th2)).simplify_full()
Y1

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{2 \, {\left({\left(a^{2} - b^{2}\right)} {y_H}^{3} - {\left(a^{2} {\mathfrak{p}}^{2} - b^{2} {\mathfrak{q}}^{2} - a^{2} + b^{2} + 2 \, {\left(a^{2} - b^{2}\right)} m\right)} {y_H}\right)} \arctan\left(\frac{y}{\sqrt{{y_H}^{2} + 1}}\right) - {\left(4 \, {\left(a^{2} - b^{2}\right)} y {y_H}^{3} + 2 \, {\left(a^{2} - b^{2}\right)} y {y_H} + {\left(a^{2} {\mathfrak{p}}^{2} - b^{2} {\mathfrak{q}}^{2} + {\left(a^{2} - b^{2}\right)} {y_H}^{2} + 2 \, {\left(a^{2} - b^{2}\right)} m\right)} \log\left(\frac{y + {y_H}}{y - {y_H}}\right)\right)} \sqrt{{y_H}^{2} + 1}}{4 \, {\left(2 \, {\left({\left(a^{2} + 2 \, a b + b^{2}\right)} y^{4} + {\left(a^{2} + 2 \, a b + b^{2}\right)} y^{2} - 2 \, {\left(a^{2} + 2 \, a b + b^{2}\right)} m\right)} {y_H}^{3} + {\left({\left(a^{2} + 2 \, a b + b^{2}\right)} y^{4} + {\left(a^{2} + 2 \, a b + b^{2}\right)} y^{2} - 2 \, {\left(a^{2} + 2 \, a b + b^{2}\right)} m\right)} {y_H}\right)} \sqrt{{y_H}^{2} + 1}}$$

The coefficient of the arctan term is

s = Y1.coefficient(arctan(y/sqrt(yH^2 + 1))).simplify_full().factor()
s

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-\frac{a^{2} {\mathfrak{p}}^{2} - b^{2} {\mathfrak{q}}^{2} - a^{2} {y_H}^{2} + b^{2} {y_H}^{2} + 2 \, a^{2} m - 2 \, b^{2} m - a^{2} + b^{2}}{2 \, {\left(y^{4} + y^{2} - 2 \, m\right)} {\left(2 \, {y_H}^{2} + 1\right)} \sqrt{{y_H}^{2} + 1} {\left(a + b\right)}^{2}}$$

The numerator of this term agrees with Eq. (4.31), once we express $m$ in terms of $y_H$:

s.numerator().subs({m: m_yH}).simplify_full()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-{\left(a^{2} - b^{2}\right)} {y_H}^{4} - a^{2} {\mathfrak{p}}^{2} + b^{2} {\mathfrak{q}}^{2} + a^{2} - b^{2}$$

The denominator agrees with Eq. (4.31) as well:

s.denominator()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}2 \, {\left(y^{4} + y^{2} - 2 \, m\right)} {\left(2 \, {y_H}^{2} + 1\right)} \sqrt{{y_H}^{2} + 1} {\left(a + b\right)}^{2}$$

Let us remove the arctan term from $\Upsilon$:

Y2 = (Y1 - s*arctan(y/sqrt(yH^2 + 1))).simplify_full()
Y2

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-\frac{4 \, {\left(a^{2} - b^{2}\right)} y {y_H}^{3} + 2 \, {\left(a^{2} - b^{2}\right)} y {y_H} + {\left(a^{2} {\mathfrak{p}}^{2} - b^{2} {\mathfrak{q}}^{2} + {\left(a^{2} - b^{2}\right)} {y_H}^{2} + 2 \, {\left(a^{2} - b^{2}\right)} m\right)} \log\left(\frac{y + {y_H}}{y - {y_H}}\right)}{4 \, {\left(2 \, {\left({\left(a^{2} + 2 \, a b + b^{2}\right)} y^{4} + {\left(a^{2} + 2 \, a b + b^{2}\right)} y^{2} - 2 \, {\left(a^{2} + 2 \, a b + b^{2}\right)} m\right)} {y_H}^{3} + {\left({\left(a^{2} + 2 \, a b + b^{2}\right)} y^{4} + {\left(a^{2} + 2 \, a b + b^{2}\right)} y^{2} - 2 \, {\left(a^{2} + 2 \, a b + b^{2}\right)} m\right)} {y_H}\right)}}$$

Y2.numerator().simplify_full()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-4 \, {\left(a^{2} - b^{2}\right)} y {y_H}^{3} - 2 \, {\left(a^{2} - b^{2}\right)} y {y_H} - {\left(a^{2} {\mathfrak{p}}^{2} - b^{2} {\mathfrak{q}}^{2} + {\left(a^{2} - b^{2}\right)} {y_H}^{2} + 2 \, {\left(a^{2} - b^{2}\right)} m\right)} \log\left(\frac{y + {y_H}}{y - {y_H}}\right)$$

Y2.denominator().factor()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}4 \, {\left(y^{4} + y^{2} - 2 \, m\right)} {\left(2 \, {y_H}^{2} + 1\right)} {\left(a + b\right)}^{2} {y_H}$$

The coefficient of the log term is

s = Y2.coefficient(log((y + yH)/(y - yH))).simplify_full().factor()
s

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-\frac{a^{2} {\mathfrak{p}}^{2} - b^{2} {\mathfrak{q}}^{2} + a^{2} {y_H}^{2} - b^{2} {y_H}^{2} + 2 \, a^{2} m - 2 \, b^{2} m}{4 \, {\left(y^{4} + y^{2} - 2 \, m\right)} {\left(2 \, {y_H}^{2} + 1\right)} {\left(a + b\right)}^{2} {y_H}}$$

The numerator and denominator both agree with Eq. (4.31):

s.numerator().subs({m: m_yH}).simplify_full()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-{\left(a^{2} - b^{2}\right)} {y_H}^{4} - a^{2} {\mathfrak{p}}^{2} + b^{2} {\mathfrak{q}}^{2} - 2 \, {\left(a^{2} - b^{2}\right)} {y_H}^{2}$$

s.denominator()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}4 \, {\left(y^{4} + y^{2} - 2 \, m\right)} {\left(2 \, {y_H}^{2} + 1\right)} {\left(a + b\right)}^{2} {y_H}$$

Given that $$\mathrm{artanh}\, x = \frac{1}{2} \ln\left( \frac{1 + x}{1 - x} \right)$$ we have $$\ln \left( \frac{x + 1}{x - 1} \right) = 2\, \mathrm{artanh}\left(\frac{1}{x}\right)$$

Hence the term in $\ln\left(\frac{y + y_H}{y - y_H}\right)$ agrees with the corresponding term in Eq. (4.30).

Finally, the last term in $\Upsilon$ is

Y3 = (Y2 - s*log((y + yH)/(y - yH))).simplify_full()
Y3.factor()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-\frac{{\left(a - b\right)} y}{2 \, {\left(y^{4} + y^{2} - 2 \, m\right)} {\left(a + b\right)}}$$

This term agrees with Eq. (4.31), given the simplification $\frac{a^2 - b^2}{(a + b)^2} = \frac{a - b}{a + b}$.

Conjugate momenta

def conjugate_momenta(lagr, qs, var):
    r"""
    Compute the conjugate momenta from a given Lagrangian.

    INPUT:

    - ``lagr`` -- symbolic expression representing the Lagrangian density
    - ``qs`` -- either a single symbolic function or a list/tuple of
      symbolic functions, representing the `q`'s; these functions must
      appear in ``lagr`` up to at most their first derivatives
    - ``var`` -- either a single variable, typically `t` (1-dimensional
      problem) or a list/tuple of symbolic variables; in the latter case the
      time coordinate must the first one

    OUTPUT:

    - list of conjugate momenta; if only one function is involved, the
      single conjugate momentum is returned instead.

    """
    if not isinstance(qs, (list, tuple)):
        qs = [qs]
    if not isinstance(var, (list, tuple)):
        var = [var]
    n = len(qs)
    d = len(var)
    dqvt = [SR.var('qxxxx{}_t'.format(q)) for q in qs]
    subs = {diff(qs[i](*var), var[0]): dqvt[i] for i in range(n)}
    subs_inv = {dqvt[i]: diff(qs[i](*var), var[0]) for i in range(n)}
    lg = lagr.substitute(subs)
    ps = [diff(lg, dotq).simplify_full().substitute(subs_inv) for dotq in dqvt]
    if n == 1:
        return ps[0]
    return ps

pis = conjugate_momenta(L_2, [Phi_1, Psi_1], y)
pis

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\left[-{\left(a^{2} {\chi_0}^{2} - a^{2}\right)} y^{4} \frac{\partial}{\partial y}\Phi_{1}\left(y\right) - {\left(a^{2} {\chi_0}^{2} - a^{2}\right)} y^{2} \frac{\partial}{\partial y}\Phi_{1}\left(y\right) + 2 \, {\left(a^{2} {\chi_0}^{2} - a^{2}\right)} m \frac{\partial}{\partial y}\Phi_{1}\left(y\right), b^{2} {\chi_0}^{2} y^{4} \frac{\partial}{\partial y}\Psi_{1}\left(y\right) + b^{2} {\chi_0}^{2} y^{2} \frac{\partial}{\partial y}\Psi_{1}\left(y\right) - 2 \, b^{2} {\chi_0}^{2} m \frac{\partial}{\partial y}\Psi_{1}\left(y\right)\right]$$

$\pi^y_\Phi$:

pi_Phi_y = (pis[0]/a).substitute_function(Phi_1, Phi1_sol).simplify_full()
pi_Phi_y

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-{\left(a {\chi_0}^{2} - a\right)} {\mathfrak{p}}$$

$\pi_\Psi^y$:

pi_Psi_y = (pis[1]/b).substitute_function(Psi_1, Psi1_sol).simplify_full()
pi_Psi_y

$$\renewcommand{\Bold}[1]{\mathbf{#1}}b {\chi_0}^{2} {\mathfrak{q}}$$

Check of Eq. (4.33)

We start from $\pi^y_\Theta$ as given by Eq. (4.32):

pi_Theta = ((y^4 + y^2 - 2*m)*(a + b)^2*Y_sol(y)).simplify_full()
pi_Theta 

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{2 \, {\left({\left(a^{2} \sin\left({\Theta_2}\right) - b^{2} \sin\left({\Theta_2}\right)\right)} {y_H}^{3} - {\left(a^{2} {\mathfrak{p}}^{2} \sin\left({\Theta_2}\right) - b^{2} {\mathfrak{q}}^{2} \sin\left({\Theta_2}\right) - a^{2} \sin\left({\Theta_2}\right) + b^{2} \sin\left({\Theta_2}\right) + 2 \, {\left(a^{2} \sin\left({\Theta_2}\right) - b^{2} \sin\left({\Theta_2}\right)\right)} m\right)} {y_H}\right)} \arctan\left(\frac{y}{\sqrt{{y_H}^{2} + 1}}\right) + {\left(4 \, {\left(2 \, C_{1} a^{2} + 4 \, C_{1} a b + 2 \, C_{1} b^{2} - {\left(a^{2} \sin\left({\Theta_2}\right) - b^{2} \sin\left({\Theta_2}\right)\right)} y\right)} {y_H}^{3} + 2 \, {\left(2 \, C_{1} a^{2} + 4 \, C_{1} a b + 2 \, C_{1} b^{2} - {\left(a^{2} \sin\left({\Theta_2}\right) - b^{2} \sin\left({\Theta_2}\right)\right)} y\right)} {y_H} - {\left(a^{2} {\mathfrak{p}}^{2} \sin\left({\Theta_2}\right) - b^{2} {\mathfrak{q}}^{2} \sin\left({\Theta_2}\right) + {\left(a^{2} \sin\left({\Theta_2}\right) - b^{2} \sin\left({\Theta_2}\right)\right)} {y_H}^{2} + 2 \, {\left(a^{2} \sin\left({\Theta_2}\right) - b^{2} \sin\left({\Theta_2}\right)\right)} m\right)} \log\left(\frac{y + {y_H}}{y - {y_H}}\right)\right)} \sqrt{{y_H}^{2} + 1}}{4 \, {\left(2 \, {y_H}^{3} + {y_H}\right)} \sqrt{{y_H}^{2} + 1}}$$

Let us perform an expansion in $1/y$ for $y\rightarrow +\infty$:

u = var('u')
assume(u > 0)
s = pi_Theta.subs({y: 1/u}).simplify_log()
s = s.taylor(u, 0, 2)
s = s.subs({u: 1/y})
s

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-\frac{1}{2} \, {\left(a^{2} \sin\left({\Theta_2}\right) - b^{2} \sin\left({\Theta_2}\right)\right)} y - \frac{a^{2} \sin\left({\Theta_2}\right) - b^{2} \sin\left({\Theta_2}\right)}{2 \, y} - \frac{\pi a^{2} {\mathfrak{p}}^{2} \sin\left({\Theta_2}\right) - \pi b^{2} {\mathfrak{q}}^{2} \sin\left({\Theta_2}\right) - \pi a^{2} \sin\left({\Theta_2}\right) + \pi b^{2} \sin\left({\Theta_2}\right) - {\left(\pi a^{2} \sin\left({\Theta_2}\right) - \pi b^{2} \sin\left({\Theta_2}\right)\right)} {y_H}^{2} + 2 \, {\left(\pi a^{2} \sin\left({\Theta_2}\right) - \pi b^{2} \sin\left({\Theta_2}\right)\right)} m - 4 \, {\left(C_{1} a^{2} + 2 \, C_{1} a b + C_{1} b^{2} + 2 \, {\left(C_{1} a^{2} + 2 \, C_{1} a b + C_{1} b^{2}\right)} {y_H}^{2}\right)} \sqrt{{y_H}^{2} + 1}}{4 \, {\left(2 \, {y_H}^{2} + 1\right)} \sqrt{{y_H}^{2} + 1}}$$

We consider $\frac{\pi^y_\Theta}{\sin(2\Theta_0)}$:

s1 = (s/sin(Th2)).expand()
s1

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-\frac{\pi a^{2} {\mathfrak{p}}^{2}}{4 \, {\left(2 \, {y_H}^{2} + 1\right)} \sqrt{{y_H}^{2} + 1}} + \frac{\pi b^{2} {\mathfrak{q}}^{2}}{4 \, {\left(2 \, {y_H}^{2} + 1\right)} \sqrt{{y_H}^{2} + 1}} + \frac{\pi a^{2} {y_H}^{2}}{4 \, {\left(2 \, {y_H}^{2} + 1\right)} \sqrt{{y_H}^{2} + 1}} - \frac{\pi b^{2} {y_H}^{2}}{4 \, {\left(2 \, {y_H}^{2} + 1\right)} \sqrt{{y_H}^{2} + 1}} - \frac{1}{2} \, a^{2} y + \frac{1}{2} \, b^{2} y + \frac{2 \, C_{1} a^{2} {y_H}^{2}}{{\left(2 \, {y_H}^{2} + 1\right)} \sin\left({\Theta_2}\right)} + \frac{4 \, C_{1} a b {y_H}^{2}}{{\left(2 \, {y_H}^{2} + 1\right)} \sin\left({\Theta_2}\right)} + \frac{2 \, C_{1} b^{2} {y_H}^{2}}{{\left(2 \, {y_H}^{2} + 1\right)} \sin\left({\Theta_2}\right)} - \frac{\pi a^{2} m}{2 \, {\left(2 \, {y_H}^{2} + 1\right)} \sqrt{{y_H}^{2} + 1}} + \frac{\pi b^{2} m}{2 \, {\left(2 \, {y_H}^{2} + 1\right)} \sqrt{{y_H}^{2} + 1}} + \frac{\pi a^{2}}{4 \, {\left(2 \, {y_H}^{2} + 1\right)} \sqrt{{y_H}^{2} + 1}} - \frac{\pi b^{2}}{4 \, {\left(2 \, {y_H}^{2} + 1\right)} \sqrt{{y_H}^{2} + 1}} - \frac{a^{2}}{2 \, y} + \frac{b^{2}}{2 \, y} + \frac{C_{1} a^{2}}{{\left(2 \, {y_H}^{2} + 1\right)} \sin\left({\Theta_2}\right)} + \frac{2 \, C_{1} a b}{{\left(2 \, {y_H}^{2} + 1\right)} \sin\left({\Theta_2}\right)} + \frac{C_{1} b^{2}}{{\left(2 \, {y_H}^{2} + 1\right)} \sin\left({\Theta_2}\right)}$$

The term in factor of $C_1$ is

s1.coefficient(C_1).factor()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{{\left(a + b\right)}^{2}}{\sin\left({\Theta_2}\right)}$$

Hence this terms agrees with Eq. (4.32). We remove it from the main term:

s2 = (s1 - s1.coefficient(C_1)*C_1).simplify_full()
s2

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-\frac{4 \, {\left({\left(a^{2} - b^{2}\right)} y^{2} + a^{2} - b^{2}\right)} {y_H}^{4} + 2 \, {\left(a^{2} - b^{2}\right)} y^{2} + 6 \, {\left({\left(a^{2} - b^{2}\right)} y^{2} + a^{2} - b^{2}\right)} {y_H}^{2} + 2 \, a^{2} - 2 \, b^{2} - {\left({\left(\pi a^{2} - \pi b^{2}\right)} y {y_H}^{2} - {\left(\pi a^{2} {\mathfrak{p}}^{2} - \pi b^{2} {\mathfrak{q}}^{2} - \pi a^{2} + \pi b^{2} + 2 \, {\left(\pi a^{2} - \pi b^{2}\right)} m\right)} y\right)} \sqrt{{y_H}^{2} + 1}}{4 \, {\left(2 \, y {y_H}^{4} + 3 \, y {y_H}^{2} + y\right)}}$$

s2.numerator().simplify_full()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-4 \, {\left({\left(a^{2} - b^{2}\right)} y^{2} + a^{2} - b^{2}\right)} {y_H}^{4} - 2 \, {\left(a^{2} - b^{2}\right)} y^{2} - 6 \, {\left({\left(a^{2} - b^{2}\right)} y^{2} + a^{2} - b^{2}\right)} {y_H}^{2} - 2 \, a^{2} + 2 \, b^{2} + {\left({\left(\pi a^{2} - \pi b^{2}\right)} y {y_H}^{2} - {\left(\pi a^{2} {\mathfrak{p}}^{2} - \pi b^{2} {\mathfrak{q}}^{2} - \pi a^{2} + \pi b^{2} + 2 \, {\left(\pi a^{2} - \pi b^{2}\right)} m\right)} y\right)} \sqrt{{y_H}^{2} + 1}$$

s2.denominator().factor()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}4 \, {\left(2 \, {y_H}^{2} + 1\right)} {\left({y_H}^{2} + 1\right)} y$$

Let divide both the numerator and denominator by $y$

s2n = (s2.numerator()/y).expand()
s2n

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-4 \, a^{2} y {y_H}^{4} + 4 \, b^{2} y {y_H}^{4} - \pi \sqrt{{y_H}^{2} + 1} a^{2} {\mathfrak{p}}^{2} + \pi \sqrt{{y_H}^{2} + 1} b^{2} {\mathfrak{q}}^{2} + \pi \sqrt{{y_H}^{2} + 1} a^{2} {y_H}^{2} - \pi \sqrt{{y_H}^{2} + 1} b^{2} {y_H}^{2} - 6 \, a^{2} y {y_H}^{2} + 6 \, b^{2} y {y_H}^{2} - \frac{4 \, a^{2} {y_H}^{4}}{y} + \frac{4 \, b^{2} {y_H}^{4}}{y} - 2 \, \pi \sqrt{{y_H}^{2} + 1} a^{2} m + 2 \, \pi \sqrt{{y_H}^{2} + 1} b^{2} m + \pi \sqrt{{y_H}^{2} + 1} a^{2} - \pi \sqrt{{y_H}^{2} + 1} b^{2} - 2 \, a^{2} y + 2 \, b^{2} y - \frac{6 \, a^{2} {y_H}^{2}}{y} + \frac{6 \, b^{2} {y_H}^{2}}{y} - \frac{2 \, a^{2}}{y} + \frac{2 \, b^{2}}{y}$$

s2d = (s2.denominator()/y).factor()
s2d

$$\renewcommand{\Bold}[1]{\mathbf{#1}}4 \, {\left(2 \, {y_H}^{2} + 1\right)} {\left({y_H}^{2} + 1\right)}$$

The coefficient of the term in $y$ is

s = s2n.coefficient(y).factor()
s/s2d

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-\frac{1}{2} \, {\left(a + b\right)} {\left(a - b\right)}$$

This is in agreement with Eq. (4.33).

We remove it:

s3n = (s2n - s*y).simplify_full().expand()
s3n

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-\pi \sqrt{{y_H}^{2} + 1} a^{2} {\mathfrak{p}}^{2} + \pi \sqrt{{y_H}^{2} + 1} b^{2} {\mathfrak{q}}^{2} + \pi \sqrt{{y_H}^{2} + 1} a^{2} {y_H}^{2} - \pi \sqrt{{y_H}^{2} + 1} b^{2} {y_H}^{2} - \frac{4 \, a^{2} {y_H}^{4}}{y} + \frac{4 \, b^{2} {y_H}^{4}}{y} - 2 \, \pi \sqrt{{y_H}^{2} + 1} a^{2} m + 2 \, \pi \sqrt{{y_H}^{2} + 1} b^{2} m + \pi \sqrt{{y_H}^{2} + 1} a^{2} - \pi \sqrt{{y_H}^{2} + 1} b^{2} - \frac{6 \, a^{2} {y_H}^{2}}{y} + \frac{6 \, b^{2} {y_H}^{2}}{y} - \frac{2 \, a^{2}}{y} + \frac{2 \, b^{2}}{y}$$

The coefficient of the term in $1/y$ is

s = s3n.coefficient(y^(-1)).factor()
s/s2d

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-\frac{1}{2} \, {\left(a + b\right)} {\left(a - b\right)}$$

This is in agreement with Eq. (4.33).

Finally the remaining term is

s4n = (s3n - s/y).simplify_full().expand()
s4n

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-\pi \sqrt{{y_H}^{2} + 1} a^{2} {\mathfrak{p}}^{2} + \pi \sqrt{{y_H}^{2} + 1} b^{2} {\mathfrak{q}}^{2} + \pi \sqrt{{y_H}^{2} + 1} a^{2} {y_H}^{2} - \pi \sqrt{{y_H}^{2} + 1} b^{2} {y_H}^{2} - 2 \, \pi \sqrt{{y_H}^{2} + 1} a^{2} m + 2 \, \pi \sqrt{{y_H}^{2} + 1} b^{2} m + \pi \sqrt{{y_H}^{2} + 1} a^{2} - \pi \sqrt{{y_H}^{2} + 1} b^{2}$$

s4n.factor()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-\pi {\left(a^{2} {\mathfrak{p}}^{2} - b^{2} {\mathfrak{q}}^{2} - a^{2} {y_H}^{2} + b^{2} {y_H}^{2} + 2 \, a^{2} m - 2 \, b^{2} m - a^{2} + b^{2}\right)} \sqrt{{y_H}^{2} + 1}$$

s = s4n.factor()/s2d
s

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-\frac{\pi {\left(a^{2} {\mathfrak{p}}^{2} - b^{2} {\mathfrak{q}}^{2} - a^{2} {y_H}^{2} + b^{2} {y_H}^{2} + 2 \, a^{2} m - 2 \, b^{2} m - a^{2} + b^{2}\right)}}{4 \, {\left(2 \, {y_H}^{2} + 1\right)} \sqrt{{y_H}^{2} + 1}}$$

s.subs({m: m_yH}).factor()

$$\renewcommand{\Bold}[1]{\mathbf{#1}}-\frac{\pi {\left(a^{2} {y_H}^{4} - b^{2} {y_H}^{4} + a^{2} {\mathfrak{p}}^{2} - b^{2} {\mathfrak{q}}^{2} - a^{2} + b^{2}\right)}}{4 \, {\left(2 \, {y_H}^{2} + 1\right)} \sqrt{{y_H}^{2} + 1}}$$

The denominator clearly agrees with Eq. (4.33).

Conclusion: we have full agreement with Eq. (4.33).