SharedPartages / Courbes / CourbesParametrees.sagewsOpen in CoCalc

Courbes paramétrées

Étant donné un intervalle IRI\subseteq \mathbb{R} et une fonction r:IRn{\bf r} : I \to \mathbb{R}^n son image est une courbe dans Rn\mathbb{R}^n.

  • La fonction r{\bf r} est une paramétrisation de la courbe C{\mathcal C}
  • Il peut avoir d'autres paramétrisations qui donnent lieu à la même courbe.

Voyons quelques exemples.

Exemple 1

Considérons la courbe r(t)=(cos(2t),sin(t)){\bf r}(t)=(\cos(2t), \sin(t)), il s'agit d'une courbe plane.

var('t')
Courbe = parametric_plot([cos(2*t),sin(4*t)],(t,0,2*pi), color='blue', thickness = 2)
show(Courbe)
t

Exemple 2

Considérons maintenant une courbe dans l'espace r(t)=(t,t2,t3){\bf r}(t)=(t,t^2,t^3)

var('t') # ce n'est plus vraiment nécessaire car on a déjà déclaré la variable auparavant.
Courbe = parametric_plot3d([t,t^2, t^3],(t,-2,2),color='red', thickness=3)
show(Courbe)
t
3D rendering not yet implemented

On ne voit pas grand chose... Mais cette courbe se trouve sur le cylindre parabolique y=x2y=x^2, et sur la surface z=x3z=x^3. Traçons les deux surfaces, ainsi que la courbe elle-même.

var('t,u,v')
Cyl=parametric_plot3d((u,u^2,v),(u,-2,2),(v,-8,8), color='blue', opacity=0.35)
Surf = parametric_plot3d((u,v,u^3),(u,-2,2),(v,0,4),color='green',opacity=0.35)
Courbe = parametric_plot3d([t,t^2, t^3],(t,-2,2),color='red', thickness=3)
show(Surf+Cyl+Courbe, frame_aspect_ratio=[4,3,1])
(t, u, v)
3D rendering not yet implemented

Exemple 3

Il y a des fonctions qui peuvent poser problème : une intégrale qu'on ne peut évaluer analytiquement. Un exemple typique serait quelque chose comme la courbe dont l'équation serait y(x)=0x12πeu2/2du y(x) = \int_{0}^x \frac{1}{\sqrt{2\pi}}e^{-u^2/2} {\rm d}u La primitive n'est pas une fonction élémentaire, mais ça ne devrait pas nous obliger à nous passer de la courbe. Une façon de procéder serait de définir une fonction séparément, qui tienne compte du fait que l'on veut une intégration numérique, puis utiliser cette fonction pour le graphique.

var('t,u')
def y(t):
	return integral_numerical(e^(-u^2/2)/sqrt(2*pi),0,t)[0]+1/2

def x(t):
	return t

Courbe = parametric_plot((x,y),(-5,5),color='blue', thickness=2)
show(Courbe,aspect_ratio=5)
(t, u)

Exemple 4

On s'intéresse à la courbe intersection du cône x2+y2=z2x^2 + y^2 = z^2 avec le plan z=y+1z=y+1. Grossièrement, deux paramétrisations ont été obtenues :

  • La première est donnée par r1(t)=(±1+2t,t,1+t)\mathbf{r}_1(t)=(\pm\sqrt{1+2t}, t, 1+t). Ce n'est pas une paramétrisation complète, à cause du ±\pm\sqrt{\cdots}. On a besoin de 2 fonctions. Dans les graphiques ci-après elles seront tracées en bleu et en rouge.
  • La deuxième est donnée par r3(t)=(t,s212,s2+12)\mathbf{r}_3(t)=\left(t, \frac{s^2-1}{2}, \frac{s^2 +1}{2}\right). Elle sera tracée en noir.

De plus, nous allons tracer le cône et le plan. Afin d'obtenir un joli cône on utilisera les coordonnées polaires. Voir plus bas.

var('t')
def r1(t) :
	return (sqrt(1+2*t),t,1+t)

def r2(t) :
	return (-sqrt(1+2*t),t,1+t)
t
var('x,y,r')
Plan = plot3d(1+y, (x,-6,6),(y,-3,15), color = "lightgreen", opacity = 0.55)
Cone = parametric_plot3d((r*cos(t), r*sin(t), r), (r,0,10), (t,0,2*pi), color="purple", opacity = 0.5)
C1 = parametric_plot(tuple(r1(t)), (t,-1/2,10), color="blue", thickness = 2)
C2 = parametric_plot(tuple(r2(t)), (t,-1/2,10), color="red",  thickness = 2)
show(C1+C2+Plan+Cone)
(x, y, r)
3D rendering not yet implemented

Voici ce qu'on obtient avec l'autre paramétrisation

def r3(t):
	return (t,(t^2-1)/2, (t^2+1)/2)
C= parametric_plot(tuple(r3(t)), (t,-5,5 ),color="black", thickness = 2)
show(C + Plan + Cone)
3D rendering not yet implemented