conformal_Minkowski.ipynb

Kernel: SageMath 10.0.rc1

Conformal completion of Minkowski spacetime

This Jupyter/SageMath notebook is relative to the lectures Geometry and physics of black holes.

It makes use of SageMath differential geometry tools developed through the SageManifolds project.

NB: a version of SageMath at least equal to 9.4 is required to run this notebook:

version()

'SageMath version 10.0.rc1, Release Date: 2023-04-28'

First we set up the notebook to display mathematical objects using LaTeX formatting:

%display latex

Spherical coordinates on Minkowski spacetime

We declare the spacetime manifold $M$:

M = Manifold(4, 'M')
print(M)

4-dimensional differentiable manifold M

and the spherical coordinates $(t,r,\theta,\phi)$ as a chart on $M$:

XS.<t,r,th,ph> = M.chart(r't r:(0,+oo) th:(0,pi):\theta ph:(0,2*pi):\phi')
XS

$\displaystyle \left(M,(t, r, {\theta}, {\phi})\right)$

XS.coord_range()

$\displaystyle t :\ \left( -\infty, +\infty \right) ;\quad r :\ \left( 0 , +\infty \right) ;\quad {\theta} :\ \left( 0 , \pi \right) ;\quad {\phi} :\ \left( 0 , 2 \, \pi \right)$

In term of these coordinates, the Minkowski metric is

g = M.lorentzian_metric('g')
g[0,0] = -1
g[1,1] = 1
g[2,2] = r^2
g[3,3] = r^2*sin(th)^2
g.display()

$\displaystyle g = -\mathrm{d} t\otimes \mathrm{d} t+\mathrm{d} r\otimes \mathrm{d} r + r^{2} \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + r^{2} \sin\left({\theta}\right)^{2} \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}$

Null coordinates

Let us introduce the null coordinates $u=t-r$ (retarded time) and $v=t+r$ (advanced time):

XN.<u,v,th,ph> = M.chart(r'u v th:(0,pi):\theta ph:(0,2*pi):\phi',
                         coord_restrictions=lambda u,v,th,ph: v-u>0)
XN

$\displaystyle \left(M,(u, v, {\theta}, {\phi})\right)$

XN.coord_range()

$\displaystyle u :\ \left( -\infty, +\infty \right) ;\quad v :\ \left( -\infty, +\infty \right) ;\quad {\theta} :\ \left( 0 , \pi \right) ;\quad {\phi} :\ \left( 0 , 2 \, \pi \right)$

XS_to_XN = XS.transition_map(XN, [t-r, t+r, th, ph])
XS_to_XN.display()

$\displaystyle \left\{\begin{array}{lcl} u & = & -r + t \\ v & = & r + t \\ {\theta} & = & {\theta} \\ {\phi} & = & {\phi} \end{array}\right.$

XS_to_XN.inverse().display()

$\displaystyle \left\{\begin{array}{lcl} t & = & \frac{1}{2} \, u + \frac{1}{2} \, v \\ r & = & -\frac{1}{2} \, u + \frac{1}{2} \, v \\ {\theta} & = & {\theta} \\ {\phi} & = & {\phi} \end{array}\right.$

In terms of the null coordinates $(u,v,\theta,\phi)$, the Minkowski metric writes

g.display(XN.frame(), XN)

$\displaystyle g = -\frac{1}{2} \mathrm{d} u\otimes \mathrm{d} v -\frac{1}{2} \mathrm{d} v\otimes \mathrm{d} u + \left( \frac{1}{4} \, u^{2} - \frac{1}{2} \, u v + \frac{1}{4} \, v^{2} \right) \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \left( \frac{1}{4} \, u^{2} \sin\left({\theta}\right)^{2} - \frac{1}{2} \, u v \sin\left({\theta}\right)^{2} + \frac{1}{4} \, v^{2} \sin\left({\theta}\right)^{2} \right) \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}$

Let us plot the coordinate grid $(u,v)$ in terms of the coordinates $(t,r)$:

graph = XN.plot(XS, ambient_coords=(r,t), fixed_coords={th: pi/2, ph: pi}, 
                number_values=17, plot_points=200, color='green', 
                style={u: '--', v: '-'}, thickness=1.5)
graph

show(graph, xmin=0, xmax=4, ymin=0, ymax=4, aspect_ratio=1)

graph.save("glo_null_coord.pdf", xmin=0, xmax=4, ymin=0, ymax=4, 
           aspect_ratio=1)

Compactified null coordinates

Instead of $(u,v)$, which span $\mathbb{R}$, let consider the coordinates $U = \mathrm{atan}\, u$ and $V = \mathrm{atan}\, v$, which span $\left(-\frac{\pi}{2}, \frac{\pi}{2}\right)$:

graph = plot(atan(u), (u,-6, 6), thickness=2, axes_labels=[r'$u$', r'$U$']) \
        + line([(-6,-pi/2), (6,-pi/2)], linestyle='--') \
        + line([(-6,pi/2), (6,pi/2)], linestyle='--')
show(graph, aspect_ratio=1)

graph.save('glo_atan.pdf', aspect_ratio=1)

XNC.<U,V,th,ph> = M.chart(r'U:(-pi/2,pi/2) V:(-pi/2,pi/2) th:(0,pi):\theta ph:(0,2*pi):\phi',
                          coord_restrictions=lambda U,V,th,ph: V-U>0)
XNC

$\displaystyle \left(M,(U, V, {\theta}, {\phi})\right)$

XNC.coord_range()

$\displaystyle U :\ \left( -\frac{1}{2} \, \pi , \frac{1}{2} \, \pi \right) ;\quad V :\ \left( -\frac{1}{2} \, \pi , \frac{1}{2} \, \pi \right) ;\quad {\theta} :\ \left( 0 , \pi \right) ;\quad {\phi} :\ \left( 0 , 2 \, \pi \right)$

XN_to_XNC = XN.transition_map(XNC, [atan(u), atan(v), th, ph])
XN_to_XNC.display()

$\displaystyle \left\{\begin{array}{lcl} U & = & \arctan\left(u\right) \\ V & = & \arctan\left(v\right) \\ {\theta} & = & {\theta} \\ {\phi} & = & {\phi} \end{array}\right.$

XN_to_XNC.inverse().display()

$\displaystyle \left\{\begin{array}{lcl} u & = & \frac{\sin\left(U\right)}{\cos\left(U\right)} \\ v & = & \frac{\sin\left(V\right)}{\cos\left(V\right)} \\ {\theta} & = & {\theta} \\ {\phi} & = & {\phi} \end{array}\right.$

Expressed in terms of the coordinates $(U,V,\theta,\phi)$, the metric tensor is

g.display(XNC.frame(), XNC)

$\displaystyle g = -\frac{1}{2 \, \cos\left(U\right)^{2} \cos\left(V\right)^{2}} \mathrm{d} U\otimes \mathrm{d} V -\frac{1}{2 \, \cos\left(U\right)^{2} \cos\left(V\right)^{2}} \mathrm{d} V\otimes \mathrm{d} U + \left( \frac{\cos\left(V\right)^{2} \sin\left(U\right)^{2} - 2 \, \cos\left(U\right) \cos\left(V\right) \sin\left(U\right) \sin\left(V\right) + \cos\left(U\right)^{2} \sin\left(V\right)^{2}}{4 \, \cos\left(U\right)^{2} \cos\left(V\right)^{2}} \right) \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \frac{{\left(\cos\left(V\right)^{2} \sin\left(U\right)^{2} - 2 \, \cos\left(U\right) \cos\left(V\right) \sin\left(U\right) \sin\left(V\right) + \cos\left(U\right)^{2} \sin\left(V\right)^{2}\right)} \sin\left({\theta}\right)^{2}}{4 \, \cos\left(U\right)^{2} \cos\left(V\right)^{2}} \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}$

Let us call $\Omega^{-2}$ the common factor:

Omega = M.scalar_field({XNC: 2*cos(U)*cos(V)}, name='Omega', latex_name=r'\Omega')
Omega.display()

$\displaystyle \begin{array}{llcl} \Omega:& M & \longrightarrow & \mathbb{R} \\ & \left(u, v, {\theta}, {\phi}\right) & \longmapsto & \frac{2}{\sqrt{u^{2} + 1} \sqrt{v^{2} + 1}} \\ & \left(U, V, {\theta}, {\phi}\right) & \longmapsto & 2 \, \cos\left(U\right) \cos\left(V\right) \end{array}$

Omega.display(XS)

$\displaystyle \begin{array}{llcl} \Omega:& M & \longrightarrow & \mathbb{R} \\ & \left(t, r, {\theta}, {\phi}\right) & \longmapsto & \frac{2}{\sqrt{r^{2} + 2 \, r t + t^{2} + 1} \sqrt{r^{2} - 2 \, r t + t^{2} + 1}} \end{array}$

Conformal metric

We introduce the metric $\tilde g = \Omega^2 g$:

gt = M.lorentzian_metric('gt', latex_name=r'\tilde{g}')
gt.set(Omega^2*g)
gt.display(XNC.frame(), XNC)

$\displaystyle \tilde{g} = -2 \mathrm{d} U\otimes \mathrm{d} V -2 \mathrm{d} V\otimes \mathrm{d} U + \left( \cos\left(V\right)^{2} \sin\left(U\right)^{2} - 2 \, \cos\left(U\right) \cos\left(V\right) \sin\left(U\right) \sin\left(V\right) + \cos\left(U\right)^{2} \sin\left(V\right)^{2} \right) \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + {\left(\cos\left(V\right)^{2} \sin\left(U\right)^{2} - 2 \, \cos\left(U\right) \cos\left(V\right) \sin\left(U\right) \sin\left(V\right) + \cos\left(U\right)^{2} \sin\left(V\right)^{2}\right)} \sin\left({\theta}\right)^{2} \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}$

Clearly the metric components ${\tilde g}_{\theta\theta}$ and ${\tilde g}_{\phi\phi}$ can be simplified further. Let us do it by hand, by extracting the symbolic expression via expr():

g22 = gt[XNC.frame(), 2, 2, XNC].expr()
g22

$\displaystyle \cos\left(V\right)^{2} \sin\left(U\right)^{2} - 2 \, \cos\left(U\right) \cos\left(V\right) \sin\left(U\right) \sin\left(V\right) + \cos\left(U\right)^{2} \sin\left(V\right)^{2}$

g22_simpl = g22.factor().reduce_trig()
g22_simpl

$\displaystyle \sin\left(-U + V\right)^{2}$

g33st = gt[XNC.frame(), 3, 3, XNC].expr() / sin(th)^2
g33st

$\displaystyle \cos\left(V\right)^{2} \sin\left(U\right)^{2} - 2 \, \cos\left(U\right) \cos\left(V\right) \sin\left(U\right) \sin\left(V\right) + \cos\left(U\right)^{2} \sin\left(V\right)^{2}$

g33_simpl = g33st.factor().reduce_trig() * sin(th)^2
g33_simpl

$\displaystyle \sin\left(-U + V\right)^{2} \sin\left({\theta}\right)^{2}$

gt.add_comp(XNC.frame())[2,2, XNC] = g22_simpl
gt.add_comp(XNC.frame())[3,3, XNC] = g33_simpl

Hence the final form of the conformal metric in terms of the compactified null coordinates:

gt.display(XNC.frame(), XNC)

$\displaystyle \tilde{g} = -2 \mathrm{d} U\otimes \mathrm{d} V -2 \mathrm{d} V\otimes \mathrm{d} U + \sin\left(-U + V\right)^{2} \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \sin\left(-U + V\right)^{2} \sin\left({\theta}\right)^{2} \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}$

In terms of the non-compactified null coordinates $(u,v,\theta,\phi)$:

gt.display(XN.frame(), XN)

$\displaystyle \tilde{g} = \left( -\frac{2}{{\left(u^{2} + 1\right)} v^{2} + u^{2} + 1} \right) \mathrm{d} u\otimes \mathrm{d} v + \left( -\frac{2}{{\left(u^{2} + 1\right)} v^{2} + u^{2} + 1} \right) \mathrm{d} v\otimes \mathrm{d} u + \left( \frac{u^{2} - 2 \, u v + v^{2}}{{\left(u^{2} + 1\right)} v^{2} + u^{2} + 1} \right) \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \left( \frac{u^{2} \sin\left({\theta}\right)^{2} - 2 \, u v \sin\left({\theta}\right)^{2} + v^{2} \sin\left({\theta}\right)^{2}}{{\left(u^{2} + 1\right)} v^{2} + u^{2} + 1} \right) \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}$

and in terms of the default coordinates $(t,r,\theta,\phi)$:

gt.display()

$\displaystyle \tilde{g} = \left( -\frac{4}{r^{4} + t^{4} - 2 \, {\left(r^{2} - 1\right)} t^{2} + 2 \, r^{2} + 1} \right) \mathrm{d} t\otimes \mathrm{d} t + \left( \frac{4}{r^{4} + t^{4} - 2 \, {\left(r^{2} - 1\right)} t^{2} + 2 \, r^{2} + 1} \right) \mathrm{d} r\otimes \mathrm{d} r + \left( \frac{4 \, r^{2}}{r^{4} + t^{4} - 2 \, {\left(r^{2} - 1\right)} t^{2} + 2 \, r^{2} + 1} \right) \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \left( \frac{4 \, r^{2} \sin\left({\theta}\right)^{2}}{r^{4} + t^{4} - 2 \, {\left(r^{2} - 1\right)} t^{2} + 2 \, r^{2} + 1} \right) \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}$

Einstein cylinder coordinates

Let us introduce some coordinates $(\tau,\chi)$ such that the null coordinates $(U,V)$ are respectively half the retarded time $\tau -\chi$ and half the advanced time $\tau+\chi$:

XC.<tau,ch,th,ph> = M.chart(r'tau:(-pi,pi):\tau ch:(0,pi):\chi th:(0,pi):\theta ph:(0,2*pi):\phi',
                            coord_restrictions=lambda tau,ch,th,ph: [tau<pi-ch, tau>ch-pi])
XC

$\displaystyle \left(M,({\tau}, {\chi}, {\theta}, {\phi})\right)$

XC.coord_range()

$\displaystyle {\tau} :\ \left( -\pi , \pi \right) ;\quad {\chi} :\ \left( 0 , \pi \right) ;\quad {\theta} :\ \left( 0 , \pi \right) ;\quad {\phi} :\ \left( 0 , 2 \, \pi \right)$

XC_to_XNC = XC.transition_map(XNC, [(tau-ch)/2, (tau+ch)/2, th, ph])
XC_to_XNC.display()

$\displaystyle \left\{\begin{array}{lcl} U & = & -\frac{1}{2} \, {\chi} + \frac{1}{2} \, {\tau} \\ V & = & \frac{1}{2} \, {\chi} + \frac{1}{2} \, {\tau} \\ {\theta} & = & {\theta} \\ {\phi} & = & {\phi} \end{array}\right.$

XC_to_XNC.inverse().display()

$\displaystyle \left\{\begin{array}{lcl} {\tau} & = & U + V \\ {\chi} & = & -U + V \\ {\theta} & = & {\theta} \\ {\phi} & = & {\phi} \end{array}\right.$

The conformal metric takes then the form of the standard metric on the Einstein cylinder $\mathbb{R}\times\mathbb{S}^3$:

gt.display(XC.frame(), XC)

$\displaystyle \tilde{g} = -\mathrm{d} {\tau}\otimes \mathrm{d} {\tau}+\mathrm{d} {\chi}\otimes \mathrm{d} {\chi} + \sin\left({\chi}\right)^{2} \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}$

The square of the conformal factor expressed in all the coordinates introduced so far:

(Omega^2).display()

$\displaystyle \begin{array}{llcl} {\Omega}^{ 2 } : & M & \longrightarrow & \mathbb{R} \\ & \left(t, r, {\theta}, {\phi}\right) & \longmapsto & \frac{4}{r^{4} + t^{4} - 2 \, {\left(r^{2} - 1\right)} t^{2} + 2 \, r^{2} + 1} \\ & \left(u, v, {\theta}, {\phi}\right) & \longmapsto & \frac{4}{{\left(u^{2} + 1\right)} v^{2} + u^{2} + 1} \\ & \left(U, V, {\theta}, {\phi}\right) & \longmapsto & 4 \, \cos\left(U\right)^{2} \cos\left(V\right)^{2} \\ & \left({\tau}, {\chi}, {\theta}, {\phi}\right) & \longmapsto & 4 \, \cos\left(\frac{1}{2} \, {\chi}\right)^{4} \cos\left(\frac{1}{2} \, {\tau}\right)^{4} - 8 \, \cos\left(\frac{1}{2} \, {\chi}\right)^{2} \cos\left(\frac{1}{2} \, {\tau}\right)^{2} \sin\left(\frac{1}{2} \, {\chi}\right)^{2} \sin\left(\frac{1}{2} \, {\tau}\right)^{2} + 4 \, \sin\left(\frac{1}{2} \, {\chi}\right)^{4} \sin\left(\frac{1}{2} \, {\tau}\right)^{4} \end{array}$

XS_to_XC = M.coord_change(XNC,XC) * M.coord_change(XN, XNC) * M.coord_change(XS, XN)
XS_to_XC.display()

$\displaystyle \left\{\begin{array}{lcl} {\tau} & = & \arctan\left(r + t\right) + \arctan\left(-r + t\right) \\ {\chi} & = & \arctan\left(r + t\right) - \arctan\left(-r + t\right) \\ {\theta} & = & {\theta} \\ {\phi} & = & {\phi} \end{array}\right.$

XC_to_XS = M.coord_change(XN, XS) * M.coord_change(XNC, XN) * M.coord_change(XC,XNC)
XC_to_XS.display()

$\displaystyle \left\{\begin{array}{lcl} t & = & \frac{\cos\left(\frac{1}{2} \, {\tau}\right) \sin\left(\frac{1}{2} \, {\tau}\right)}{\cos\left(\frac{1}{2} \, {\chi}\right)^{2} \cos\left(\frac{1}{2} \, {\tau}\right)^{2} - \sin\left(\frac{1}{2} \, {\chi}\right)^{2} \sin\left(\frac{1}{2} \, {\tau}\right)^{2}} \\ r & = & \frac{\cos\left(\frac{1}{2} \, {\chi}\right) \sin\left(\frac{1}{2} \, {\chi}\right)}{\cos\left(\frac{1}{2} \, {\chi}\right)^{2} \cos\left(\frac{1}{2} \, {\tau}\right)^{2} - \sin\left(\frac{1}{2} \, {\chi}\right)^{2} \sin\left(\frac{1}{2} \, {\tau}\right)^{2}} \\ {\theta} & = & {\theta} \\ {\phi} & = & {\phi} \end{array}\right.$

The expressions for $t$ and $r$ can be simplified:

tc = XC_to_XS(tau,ch,th,ph)[0]
tc

$\displaystyle \frac{\cos\left(\frac{1}{2} \, {\tau}\right) \sin\left(\frac{1}{2} \, {\tau}\right)}{\cos\left(\frac{1}{2} \, {\chi}\right)^{2} \cos\left(\frac{1}{2} \, {\tau}\right)^{2} - \sin\left(\frac{1}{2} \, {\chi}\right)^{2} \sin\left(\frac{1}{2} \, {\tau}\right)^{2}}$

tc.reduce_trig()

$\displaystyle \frac{\sin\left({\tau}\right)}{\cos\left({\chi}\right) + \cos\left({\tau}\right)}$

rc = XC_to_XS(tau,ch,th,ph)[1]
rc

$\displaystyle \frac{\cos\left(\frac{1}{2} \, {\chi}\right) \sin\left(\frac{1}{2} \, {\chi}\right)}{\cos\left(\frac{1}{2} \, {\chi}\right)^{2} \cos\left(\frac{1}{2} \, {\tau}\right)^{2} - \sin\left(\frac{1}{2} \, {\chi}\right)^{2} \sin\left(\frac{1}{2} \, {\tau}\right)^{2}}$

rc.reduce_trig()

$\displaystyle \frac{\sin\left({\chi}\right)}{\cos\left({\chi}\right) + \cos\left({\tau}\right)}$

XS_to_XC.set_inverse(tc.reduce_trig(), rc.reduce_trig(), th, ph)
XC_to_XS = XS_to_XC.inverse()

Check of the inverse coordinate transformation:
  t == t  *passed*
  r == r  *passed*
  th == th  *passed*
  ph == ph  *passed*
  tau == arctan((sin(ch) + sin(tau))/(cos(ch) + cos(tau))) + arctan(-(sin(ch) - sin(tau))/(cos(ch) + cos(tau)))  **failed**
  ch == arctan((sin(ch) + sin(tau))/(cos(ch) + cos(tau))) - arctan(-(sin(ch) - sin(tau))/(cos(ch) + cos(tau)))  **failed**
  th == th  *passed*
  ph == ph  *passed*
NB: a failed report can reflect a mere lack of simplification.

XC_to_XS.display()

$\displaystyle \left\{\begin{array}{lcl} t & = & \frac{\sin\left({\tau}\right)}{\cos\left({\chi}\right) + \cos\left({\tau}\right)} \\ r & = & \frac{\sin\left({\chi}\right)}{\cos\left({\chi}\right) + \cos\left({\tau}\right)} \\ {\theta} & = & {\theta} \\ {\phi} & = & {\phi} \end{array}\right.$

Conformal Penrose diagram

Let us draw the coordinate grid $(t,r)$ in terms of the coordinates $(\tau,\chi)$:

graphXS = XS.plot(XC, ambient_coords=(ch, tau), fixed_coords={th: pi/2, ph: pi}, 
                  max_range=30, number_values=51, plot_points=250, 
                  color={t: 'red', r: 'grey'})
graph_i0 = circle((pi,0), 0.05, fill=True, color='grey') + \
           text(r"$i^0$", (3.3, 0.2), fontsize=18, color='grey') 
graph_ip = circle((0,pi), 0.05, fill=True, color='red') + \
           text(r"$i^+$", (0.25, 3.3), fontsize=18, color='red')
graph_im = circle((0,-pi), 0.05, fill=True, color='red') + \
           text(r"$i^-$", (0.25, -3.3), fontsize=18, color='red')
graph_Ip = line([(0,pi), (pi,0)], color='green', thickness=2) + \
           text(r"$\mathscr{I}^+$", (1.8, 1.8), fontsize=18, color='green')
graph_Im = line([(0,-pi), (pi,0)], color='green', thickness=2) + \
           text(r"$\mathscr{I}^-$", (1.8, -1.8), fontsize=18, color='green')
graph = graphXS + graph_i0 + graph_ip + graph_im + graph_Ip + graph_Im
show(graph, figsize=8)

graph.save('glo_conf_diag_Mink.pdf', figsize=8)

Some blow-up near $i^0$:

graph = XS.plot(XC, ambient_coords=(ch, tau), fixed_coords={th: pi/2, ph: pi}, 
                max_range=100, number_values=41, plot_points=200, 
                color={t: 'red', r: 'grey'})
graph += circle((pi,0), 0.005, fill=True, color='grey') + \
         text(r"$i^0$", (pi, 0.02), fontsize=18, color='grey') 
show(graph, xmin=3., xmax=3.2, ymin=-0.2, ymax=0.2, aspect_ratio=1)

To produce a more satisfactory figure, let us use some logarithmic radial coordinate:

XL.<t, rh, th, ph> = M.chart(r't rh:\rho th:(0,pi):\theta ph:(0,2*pi):\phi')
XL

$\displaystyle \left(M,(t, {\rho}, {\theta}, {\phi})\right)$

XS_to_XL = XS.transition_map(XL, [t, ln(r), th, ph])
XS_to_XL.display()

$\displaystyle \left\{\begin{array}{lcl} t & = & t \\ {\rho} & = & \log\left(r\right) \\ {\theta} & = & {\theta} \\ {\phi} & = & {\phi} \end{array}\right.$

XS_to_XL.inverse().display()

$\displaystyle \left\{\begin{array}{lcl} t & = & t \\ r & = & e^{{\rho}} \\ {\theta} & = & {\theta} \\ {\phi} & = & {\phi} \end{array}\right.$

XL_to_XC = M.coord_change(XS, XC) * M.coord_change(XL, XS)
XC_to_XL = M.coord_change(XS, XL) * M.coord_change(XC, XS)

graph = XL.plot(XC, ambient_coords=(ch, tau), fixed_coords={th: pi/2, ph: pi}, 
                ranges={t: (-20, 20), rh: (-2, 10)}, number_values=19, 
                color={t: 'red', rh: 'grey'})
graph += circle((pi,0), 0.005, fill=True, color='grey') + \
         text(r"$i^0$", (pi, 0.02), fontsize=18, color='grey') 
show(graph, xmin=3., xmax=3.2, ymin=-0.2, ymax=0.2, aspect_ratio=1)

Null radial geodesics in the conformal diagram

To get a view of the null radial geodesics in the conformal diagram, it suffices to plot the chart $(u,v,\theta,\phi)$ in terms of the chart $(\tau,\chi,\theta,\phi)$. The following plot shows

• the null geodesics defined by $(u,\theta,\phi) = (u_0, \pi/2,\pi)$ for 17 values of $u_0$ evenly spaced in $[-8,8]$ (dashed lines)

• the null geodesics defined by $(v,\theta,\phi) = (v_0, \pi/2,\pi)$ for 17 values of $v_0$ evenly spaced in $[-8,8]$ (solid lines)

graphXN = XN.plot(XC, ambient_coords=(ch, tau), fixed_coords={th: pi/2, ph: pi}, 
                  number_values=17, plot_points=150, color='green', 
                  style={u: '--', v: '-'}, thickness=1.5)
graph = graphXN + graph_i0 + graph_ip + graph_im + graph_Ip + graph_Im
show(graph, figsize=8)

graph.save('glo_conf_Mink_null.pdf', figsize=8)

Conformal factor

The conformal factor expressed in various coordinate systems:

Omega.display()

$\displaystyle \begin{array}{llcl} \Omega:& M & \longrightarrow & \mathbb{R} \\ & \left(t, r, {\theta}, {\phi}\right) & \longmapsto & \frac{2}{\sqrt{r^{2} + 2 \, r t + t^{2} + 1} \sqrt{r^{2} - 2 \, r t + t^{2} + 1}} \\ & \left(u, v, {\theta}, {\phi}\right) & \longmapsto & \frac{2}{\sqrt{u^{2} + 1} \sqrt{v^{2} + 1}} \\ & \left(U, V, {\theta}, {\phi}\right) & \longmapsto & 2 \, \cos\left(U\right) \cos\left(V\right) \\ & \left({\tau}, {\chi}, {\theta}, {\phi}\right) & \longmapsto & 2 \, \cos\left(\frac{1}{2} \, {\chi}\right)^{2} \cos\left(\frac{1}{2} \, {\tau}\right)^{2} - 2 \, \sin\left(\frac{1}{2} \, {\chi}\right)^{2} \sin\left(\frac{1}{2} \, {\tau}\right)^{2} \\ & \left(t, {\rho}, {\theta}, {\phi}\right) & \longmapsto & \frac{2}{\sqrt{t^{2} + 2 \, t e^{{\rho}} + e^{\left(2 \, {\rho}\right)} + 1} \sqrt{t^{2} - 2 \, t e^{{\rho}} + e^{\left(2 \, {\rho}\right)} + 1}} \end{array}$

The expression in terms of $(\tau,\chi,\theta,\phi)$ can be simplified:

Omega.expr(XC)

$\displaystyle 2 \, \cos\left(\frac{1}{2} \, {\chi}\right)^{2} \cos\left(\frac{1}{2} \, {\tau}\right)^{2} - 2 \, \sin\left(\frac{1}{2} \, {\chi}\right)^{2} \sin\left(\frac{1}{2} \, {\tau}\right)^{2}$

s = Omega.expr(XC) - cos(tau) - cos(ch)
s.trig_reduce()

$\displaystyle 0$

Hence we set

Omega.add_expr(cos(tau) + cos(ch), XC)
Omega.display()

$\displaystyle \begin{array}{llcl} \Omega:& M & \longrightarrow & \mathbb{R} \\ & \left(t, r, {\theta}, {\phi}\right) & \longmapsto & \frac{2}{\sqrt{r^{2} + 2 \, r t + t^{2} + 1} \sqrt{r^{2} - 2 \, r t + t^{2} + 1}} \\ & \left(u, v, {\theta}, {\phi}\right) & \longmapsto & \frac{2}{\sqrt{u^{2} + 1} \sqrt{v^{2} + 1}} \\ & \left(U, V, {\theta}, {\phi}\right) & \longmapsto & 2 \, \cos\left(U\right) \cos\left(V\right) \\ & \left({\tau}, {\chi}, {\theta}, {\phi}\right) & \longmapsto & \cos\left({\chi}\right) + \cos\left({\tau}\right) \\ & \left(t, {\rho}, {\theta}, {\phi}\right) & \longmapsto & \frac{2}{\sqrt{t^{2} + 2 \, t e^{{\rho}} + e^{\left(2 \, {\rho}\right)} + 1} \sqrt{t^{2} - 2 \, t e^{{\rho}} + e^{\left(2 \, {\rho}\right)} + 1}} \end{array}$

A plot of $\Omega$ in terms of the coordinates $(\tau,\chi)$:

graph = plot3d(Omega.expr(XC), (tau,-pi,pi), (ch,0,pi)) \
        + plot3d(0, (tau,-pi,pi), (ch,0,pi), color='yellow', opacity=0.7)
show(graph, aspect_ratio=1, axes_labels=['tau', 'chi', 'Omega'])

show(graph, aspect_ratio=1, viewer='tachyon')

Differential of the conformal factor

The 1-form $\mathrm{d}\Omega$ is:

dOmega = Omega.differential()
print(dOmega)

1-form dOmega on the 4-dimensional differentiable manifold M

dOmega.display()

$\displaystyle \mathrm{d}\Omega = \left( -\frac{4 \, {\left(t^{3} - {\left(r^{2} - 1\right)} t\right)} \sqrt{r^{2} + 2 \, r t + t^{2} + 1} \sqrt{r^{2} - 2 \, r t + t^{2} + 1}}{r^{8} + t^{8} - 4 \, {\left(r^{2} - 1\right)} t^{6} + 4 \, r^{6} + 2 \, {\left(3 \, r^{4} - 2 \, r^{2} + 3\right)} t^{4} + 6 \, r^{4} - 4 \, {\left(r^{6} + r^{4} - r^{2} - 1\right)} t^{2} + 4 \, r^{2} + 1} \right) \mathrm{d} t + \left( -\frac{4 \, {\left(r^{3} - r t^{2} + r\right)} \sqrt{r^{2} + 2 \, r t + t^{2} + 1} \sqrt{r^{2} - 2 \, r t + t^{2} + 1}}{r^{8} + t^{8} - 4 \, {\left(r^{2} - 1\right)} t^{6} + 4 \, r^{6} + 2 \, {\left(3 \, r^{4} - 2 \, r^{2} + 3\right)} t^{4} + 6 \, r^{4} - 4 \, {\left(r^{6} + r^{4} - r^{2} - 1\right)} t^{2} + 4 \, r^{2} + 1} \right) \mathrm{d} r$

dOmega.display(XNC.frame(), XNC)

$\displaystyle \mathrm{d}\Omega = -2 \, \cos\left(V\right) \sin\left(U\right) \mathrm{d} U -2 \, \cos\left(U\right) \sin\left(V\right) \mathrm{d} V$

M.set_default_chart(XNC)
M.set_default_frame(XNC.frame())

dOmega.display()

$\displaystyle \mathrm{d}\Omega = -2 \, \cos\left(V\right) \sin\left(U\right) \mathrm{d} U -2 \, \cos\left(U\right) \sin\left(V\right) \mathrm{d} V$

dOmega1 = M.one_form()
dOmega1[0] = -2*cos(V)*sin(U)
dOmega1[1] = -2*cos(U)*sin(V)
dOmega1.display()

$\displaystyle -2 \, \cos\left(V\right) \sin\left(U\right) \mathrm{d} U -2 \, \cos\left(U\right) \sin\left(V\right) \mathrm{d} V$

dOmega1.display(XC.frame(), XC)

$\displaystyle -2 \, \cos\left(\frac{1}{2} \, {\tau}\right) \sin\left(\frac{1}{2} \, {\tau}\right) \mathrm{d} {\tau} -2 \, \cos\left(\frac{1}{2} \, {\chi}\right) \sin\left(\frac{1}{2} \, {\chi}\right) \mathrm{d} {\chi}$

Einstein static universe

E = Manifold(4, 'E')
print(E)

4-dimensional differentiable manifold E

XE.<tau,ch,th,ph> = E.chart(r'tau:\tau ch:(0,pi):\chi th:(0,pi):\theta ph:(0,2*pi):\phi')
XE

$\displaystyle \left(E,({\tau}, {\chi}, {\theta}, {\phi})\right)$

XE.coord_range()

$\displaystyle {\tau} :\ \left( -\infty, +\infty \right) ;\quad {\chi} :\ \left( 0 , \pi \right) ;\quad {\theta} :\ \left( 0 , \pi \right) ;\quad {\phi} :\ \left( 0 , 2 \, \pi \right)$

XC.coord_range()

$\displaystyle {\tau} :\ \left( -\pi , \pi \right) ;\quad {\chi} :\ \left( 0 , \pi \right) ;\quad {\theta} :\ \left( 0 , \pi \right) ;\quad {\phi} :\ \left( 0 , 2 \, \pi \right)$

Embedding of $M$ in $E$

Phi = M.diff_map(E, {(XC, XE): [tau, ch, th, ph]},
                 name='Phi', latex_name=r'\Phi')
print(Phi)
Phi.display()

Differentiable map Phi from the 4-dimensional differentiable manifold M to the 4-dimensional differentiable manifold E

$\displaystyle \begin{array}{llcl} \Phi:& M & \longrightarrow & E \\ & \left(t, r, {\theta}, {\phi}\right) & \longmapsto & \left({\tau}, {\chi}, {\theta}, {\phi}\right) = \left(\arctan\left(r + t\right) + \arctan\left(-r + t\right), \arctan\left(r + t\right) - \arctan\left(-r + t\right), {\theta}, {\phi}\right) \\ & \left(u, v, {\theta}, {\phi}\right) & \longmapsto & \left({\tau}, {\chi}, {\theta}, {\phi}\right) = \left(\arctan\left(u\right) + \arctan\left(v\right), -\arctan\left(u\right) + \arctan\left(v\right), {\theta}, {\phi}\right) \\ & \left(U, V, {\theta}, {\phi}\right) & \longmapsto & \left({\tau}, {\chi}, {\theta}, {\phi}\right) = \left(U + V, -U + V, {\theta}, {\phi}\right) \\ & \left({\tau}, {\chi}, {\theta}, {\phi}\right) & \longmapsto & \left({\tau}, {\chi}, {\theta}, {\phi}\right) = \left({\tau}, {\chi}, {\theta}, {\phi}\right) \\ & \left(t, {\rho}, {\theta}, {\phi}\right) & \longmapsto & \left({\tau}, {\chi}, {\theta}, {\phi}\right) = \left(\arctan\left(t + e^{{\rho}}\right) + \arctan\left(t - e^{{\rho}}\right), \arctan\left(t + e^{{\rho}}\right) - \arctan\left(t - e^{{\rho}}\right), {\theta}, {\phi}\right) \end{array}$

XS.plot(XE, mapping=Phi, ambient_coords=(ch, tau), fixed_coords={th: pi/2, ph: pi}, 
        plot_points=200, color={t: 'red', r: 'grey'})

Embedding of $E$ in $\mathbb{R}^5$

R5 = Manifold(5, 'R^5', latex_name=r'\mathbb{R}^5')
print(R5)

5-dimensional differentiable manifold R^5

X5.<tau,W,X,Y,Z> = R5.chart(r'tau:\tau W X Y Z')
X5

$\displaystyle \left(\mathbb{R}^5,({\tau}, W, X, Y, Z)\right)$

Psi = E.diff_map(R5, {(XE, X5): [tau,
                                 cos(ch),
                                 sin(ch)*sin(th)*cos(ph), 
                                 sin(ch)*sin(th)*sin(ph), 
                                 sin(ch)*cos(th)]},
                 name='Psi', latex_name=r'\Psi')
print(Psi)
Psi.display()

Differentiable map Psi from the 4-dimensional differentiable manifold E to the 5-dimensional differentiable manifold R^5

$\displaystyle \begin{array}{llcl} \Psi:& E & \longrightarrow & \mathbb{R}^5 \\ & \left({\tau}, {\chi}, {\theta}, {\phi}\right) & \longmapsto & \left({\tau}, W, X, Y, Z\right) = \left({\tau}, \cos\left({\chi}\right), \cos\left({\phi}\right) \sin\left({\chi}\right) \sin\left({\theta}\right), \sin\left({\chi}\right) \sin\left({\phi}\right) \sin\left({\theta}\right), \cos\left({\theta}\right) \sin\left({\chi}\right)\right) \end{array}$

The Einstein cylinder:

graphE = XE.plot(X5, ambient_coords=(W,X,tau), mapping=Psi, 
                 fixed_coords={th:pi/2, ph:0.001}, max_range=4, 
                 number_values=9, color='silver', thickness=0.5,
                 label_axes=False)  # phi = 0 
graphE += XE.plot(X5, ambient_coords=(W,X,tau), mapping=Psi, 
                  fixed_coords={th:pi/2, ph:pi}, max_range=4, 
                  number_values=9, color='silver', thickness=0.5,
                  label_axes=False)  # phi = pi
show(graphE, aspect_ratio=1, axes_labels=['W', 'X', 'tau'])

Embedding of $M$ in $\mathbb{R}^5$

The embedding $\Theta:\, M\rightarrow \mathbb{R}^5$ is obtained by composition of the embeddings $\Phi:\, M\rightarrow E$ and $\Psi:\, E\rightarrow \mathbb{R}^5$:

Theta = Psi * Phi
print(Theta)
Theta.display()

Differentiable map from the 4-dimensional differentiable manifold M to the 5-dimensional differentiable manifold R^5

$\displaystyle \begin{array}{llcl} & M & \longrightarrow & \mathbb{R}^5 \\ & \left(t, r, {\theta}, {\phi}\right) & \longmapsto & \left({\tau}, W, X, Y, Z\right) = \left(\arctan\left(r + t\right) + \arctan\left(-r + t\right), -\frac{\sqrt{r^{2} + 2 \, r t + t^{2} + 1} \sqrt{r^{2} - 2 \, r t + t^{2} + 1} {\left(r^{2} - t^{2} - 1\right)}}{r^{4} + t^{4} - 2 \, {\left(r^{2} - 1\right)} t^{2} + 2 \, r^{2} + 1}, \frac{2 \, \sqrt{r^{2} + 2 \, r t + t^{2} + 1} \sqrt{r^{2} - 2 \, r t + t^{2} + 1} r \cos\left({\phi}\right) \sin\left({\theta}\right)}{r^{4} + t^{4} - 2 \, {\left(r^{2} - 1\right)} t^{2} + 2 \, r^{2} + 1}, \frac{2 \, \sqrt{r^{2} + 2 \, r t + t^{2} + 1} \sqrt{r^{2} - 2 \, r t + t^{2} + 1} r \sin\left({\phi}\right) \sin\left({\theta}\right)}{r^{4} + t^{4} - 2 \, {\left(r^{2} - 1\right)} t^{2} + 2 \, r^{2} + 1}, \frac{2 \, \sqrt{r^{2} + 2 \, r t + t^{2} + 1} \sqrt{r^{2} - 2 \, r t + t^{2} + 1} r \cos\left({\theta}\right)}{r^{4} + t^{4} - 2 \, {\left(r^{2} - 1\right)} t^{2} + 2 \, r^{2} + 1}\right) \\ & \left(u, v, {\theta}, {\phi}\right) & \longmapsto & \left({\tau}, W, X, Y, Z\right) = \left(\arctan\left(u\right) + \arctan\left(v\right), \frac{\sqrt{u^{2} + 1} {\left(u v + 1\right)} \sqrt{v^{2} + 1}}{{\left(u^{2} + 1\right)} v^{2} + u^{2} + 1}, -\frac{{\left(u \cos\left({\phi}\right) \sin\left({\theta}\right) - v \cos\left({\phi}\right) \sin\left({\theta}\right)\right)} \sqrt{u^{2} + 1} \sqrt{v^{2} + 1}}{{\left(u^{2} + 1\right)} v^{2} + u^{2} + 1}, -\frac{{\left(u \sin\left({\phi}\right) \sin\left({\theta}\right) - v \sin\left({\phi}\right) \sin\left({\theta}\right)\right)} \sqrt{u^{2} + 1} \sqrt{v^{2} + 1}}{{\left(u^{2} + 1\right)} v^{2} + u^{2} + 1}, -\frac{\sqrt{u^{2} + 1} \sqrt{v^{2} + 1} {\left(u \cos\left({\theta}\right) - v \cos\left({\theta}\right)\right)}}{{\left(u^{2} + 1\right)} v^{2} + u^{2} + 1}\right) \\ & \left(U, V, {\theta}, {\phi}\right) & \longmapsto & \left({\tau}, W, X, Y, Z\right) = \left(U + V, \cos\left(U\right) \cos\left(V\right) + \sin\left(U\right) \sin\left(V\right), -{\left(\cos\left(V\right) \sin\left(U\right) - \cos\left(U\right) \sin\left(V\right)\right)} \cos\left({\phi}\right) \sin\left({\theta}\right), -{\left(\cos\left(V\right) \sin\left(U\right) - \cos\left(U\right) \sin\left(V\right)\right)} \sin\left({\phi}\right) \sin\left({\theta}\right), -{\left(\cos\left(V\right) \sin\left(U\right) - \cos\left(U\right) \sin\left(V\right)\right)} \cos\left({\theta}\right)\right) \\ & \left({\tau}, {\chi}, {\theta}, {\phi}\right) & \longmapsto & \left({\tau}, W, X, Y, Z\right) = \left({\tau}, \cos\left({\chi}\right), \cos\left({\phi}\right) \sin\left({\chi}\right) \sin\left({\theta}\right), \sin\left({\chi}\right) \sin\left({\phi}\right) \sin\left({\theta}\right), \cos\left({\theta}\right) \sin\left({\chi}\right)\right) \\ & \left(t, {\rho}, {\theta}, {\phi}\right) & \longmapsto & \left({\tau}, W, X, Y, Z\right) = \left(\arctan\left(t + e^{{\rho}}\right) + \arctan\left(t - e^{{\rho}}\right), \frac{\sqrt{t^{2} + 2 \, t e^{{\rho}} + e^{\left(2 \, {\rho}\right)} + 1} \sqrt{t^{2} - 2 \, t e^{{\rho}} + e^{\left(2 \, {\rho}\right)} + 1} {\left(t^{2} - e^{\left(2 \, {\rho}\right)} + 1\right)}}{t^{4} - 2 \, t^{2} {\left(e^{\left(2 \, {\rho}\right)} - 1\right)} + e^{\left(4 \, {\rho}\right)} + 2 \, e^{\left(2 \, {\rho}\right)} + 1}, \frac{2 \, \sqrt{t^{2} + 2 \, t e^{{\rho}} + e^{\left(2 \, {\rho}\right)} + 1} \sqrt{t^{2} - 2 \, t e^{{\rho}} + e^{\left(2 \, {\rho}\right)} + 1} \cos\left({\phi}\right) e^{{\rho}} \sin\left({\theta}\right)}{t^{4} - 2 \, t^{2} {\left(e^{\left(2 \, {\rho}\right)} - 1\right)} + e^{\left(4 \, {\rho}\right)} + 2 \, e^{\left(2 \, {\rho}\right)} + 1}, \frac{2 \, \sqrt{t^{2} + 2 \, t e^{{\rho}} + e^{\left(2 \, {\rho}\right)} + 1} \sqrt{t^{2} - 2 \, t e^{{\rho}} + e^{\left(2 \, {\rho}\right)} + 1} e^{{\rho}} \sin\left({\phi}\right) \sin\left({\theta}\right)}{t^{4} - 2 \, t^{2} {\left(e^{\left(2 \, {\rho}\right)} - 1\right)} + e^{\left(4 \, {\rho}\right)} + 2 \, e^{\left(2 \, {\rho}\right)} + 1}, \frac{2 \, \sqrt{t^{2} + 2 \, t e^{{\rho}} + e^{\left(2 \, {\rho}\right)} + 1} \sqrt{t^{2} - 2 \, t e^{{\rho}} + e^{\left(2 \, {\rho}\right)} + 1} \cos\left({\theta}\right) e^{{\rho}}}{t^{4} - 2 \, t^{2} {\left(e^{\left(2 \, {\rho}\right)} - 1\right)} + e^{\left(4 \, {\rho}\right)} + 2 \, e^{\left(2 \, {\rho}\right)} + 1}\right) \end{array}$

graphM = XS.plot(X5, ambient_coords=(W,X,tau), mapping=Theta, 
                 fixed_coords={th:pi/2, ph:0.001}, max_range=30, 
                 number_values=51, plot_points=250, color={t:'red', r:'black'}, 
                 label_axes=False)  # phi = 0 
graphM += XS.plot(X5, ambient_coords=(W,X,tau), mapping=Theta, 
                  fixed_coords={th:pi/2, ph:pi}, max_range=30, 
                  number_values=51, plot_points=250, color={t:'red', r:'black'}, 
                  label_axes=False)  # phi = pi
show(graphE+graphM, aspect_ratio=1, axes_labels=['W', 'X', 'tau'])

graph = (graphE+graphM).rotate((0,0,1), 0.2)
show(graph, aspect_ratio=(2,2,1), viewer='tachyon', 
     frame=False, figsize=20)

graph = (graphE+graphM).rotate((0,0,1), pi)
show(graph, aspect_ratio=(2,2,1), viewer='tachyon', 
     frame=False, figsize=20)

graphMN = XN.plot(X5, ambient_coords=(W,X,tau), mapping=Theta, 
                  fixed_coords={th:pi/2, ph:0.001}, max_range=16, 
                  number_values=21, plot_points=150, color='green', 
                  style={u: '--', v: '-'}, label_axes=False)  # phi = 0 
graphMN += XN.plot(X5, ambient_coords=(W,X,tau), mapping=Theta, 
                   fixed_coords={th:pi/2, ph:pi}, max_range=16, 
                   number_values=21, plot_points=150, color='green', 
                   style={u: '--', v: '-'}, label_axes=False)  # phi = pi

show(graphE+graphMN, aspect_ratio=1, frame=False)

show(graphE+graphMN, aspect_ratio=(2,2,1), viewer='tachyon', 
     frame=False, figsize=20)