# Kerr spacetime in 3+1 Kerr coordinates

This Jupyter/SageMath worksheet is relative to the lectures Geometry and physics of black holes

These computations are based on SageManifolds (v0.9)

Click here to download the worksheet file (ipynb format). To run it, you must start SageMath with the Jupyter notebook, with the command sage -n jupyter

First we set up the notebook to display mathematical objects using LaTeX formatting:

In [1]:
%display latex


## Spacetime

We declare the spacetime manifold $M$:

In [2]:
M = Manifold(4, 'M')
print(M)

4-dimensional differentiable manifold M

and the 3+1 Kerr coordinates $(t,r,\theta,\phi)$ as a chart on $M$:

In [3]:
X.<t,r,th,ph> = M.chart(r't r th:(0,pi):\theta ph:(0,2*pi):\phi')
X

$\left(M,(t, r, {\theta}, {\phi})\right)$
In [4]:
X.coord_range()

$t :\ \left( -\infty, +\infty \right) ;\quad r :\ \left( -\infty, +\infty \right) ;\quad {\theta} :\ \left( 0 , \pi \right) ;\quad {\phi} :\ \left( 0 , 2 \, \pi \right)$

The Kerr parameters $m$ and $a$:

In [5]:
m = var('m', domain='real')
assume(m>0)
a = var('a', domain='real')
assume(a>=0)


## Kerr metric

We define the metric $g$ by its components w.r.t. the 3+1 Kerr coordinates:

In [6]:
g = M.lorentzian_metric('g')
rho2 = r^2 + (a*cos(th))^2
g[0,0] = -(1 - 2*m*r/rho2)
g[0,1] = 2*m*r/rho2
g[0,3] = -2*a*m*r*sin(th)^2/rho2
g[1,1] = 1 + 2*m*r/rho2
g[1,3] = -a*(1 + 2*m*r/rho2)*sin(th)^2
g[2,2] = rho2
g[3,3] = (r^2+a^2+2*m*r*(a*sin(th))^2/rho2)*sin(th)^2
g.display()

$g = \left( -\frac{a^{2} \cos\left({\theta}\right)^{2} - 2 \, m r + r^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \right) \mathrm{d} t\otimes \mathrm{d} t + \left( \frac{2 \, m r}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \right) \mathrm{d} t\otimes \mathrm{d} r + \left( -\frac{2 \, a m r \sin\left({\theta}\right)^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \right) \mathrm{d} t\otimes \mathrm{d} {\phi} + \left( \frac{2 \, m r}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \right) \mathrm{d} r\otimes \mathrm{d} t + \left( \frac{a^{2} \cos\left({\theta}\right)^{2} + 2 \, m r + r^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \right) \mathrm{d} r\otimes \mathrm{d} r + \left( -\frac{{\left(a^{3} \cos\left({\theta}\right)^{2} + 2 \, a m r + a r^{2}\right)} \sin\left({\theta}\right)^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \right) \mathrm{d} r\otimes \mathrm{d} {\phi} + \left( a^{2} \cos\left({\theta}\right)^{2} + r^{2} \right) \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \left( -\frac{2 \, a m r \sin\left({\theta}\right)^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \right) \mathrm{d} {\phi}\otimes \mathrm{d} t + \left( -\frac{{\left(a^{3} \cos\left({\theta}\right)^{2} + 2 \, a m r + a r^{2}\right)} \sin\left({\theta}\right)^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \right) \mathrm{d} {\phi}\otimes \mathrm{d} r + \left( \frac{2 \, a^{2} m r \sin\left({\theta}\right)^{4} + {\left(a^{2} r^{2} + r^{4} + {\left(a^{4} + a^{2} r^{2}\right)} \cos\left({\theta}\right)^{2}\right)} \sin\left({\theta}\right)^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \right) \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}$
In [7]:
g.display_comp()

$\begin{array}{lcl} g_{ \, t \, t }^{ \phantom{\, t } \phantom{\, t } } & = & -\frac{a^{2} \cos\left({\theta}\right)^{2} - 2 \, m r + r^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \\ g_{ \, t \, r }^{ \phantom{\, t } \phantom{\, r } } & = & \frac{2 \, m r}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \\ g_{ \, t \, {\phi} }^{ \phantom{\, t } \phantom{\, {\phi} } } & = & -\frac{2 \, a m r \sin\left({\theta}\right)^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \\ g_{ \, r \, t }^{ \phantom{\, r } \phantom{\, t } } & = & \frac{2 \, m r}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \\ g_{ \, r \, r }^{ \phantom{\, r } \phantom{\, r } } & = & \frac{a^{2} \cos\left({\theta}\right)^{2} + 2 \, m r + r^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \\ g_{ \, r \, {\phi} }^{ \phantom{\, r } \phantom{\, {\phi} } } & = & -\frac{{\left(a^{3} \cos\left({\theta}\right)^{2} + 2 \, a m r + a r^{2}\right)} \sin\left({\theta}\right)^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \\ g_{ \, {\theta} \, {\theta} }^{ \phantom{\, {\theta} } \phantom{\, {\theta} } } & = & a^{2} \cos\left({\theta}\right)^{2} + r^{2} \\ g_{ \, {\phi} \, t }^{ \phantom{\, {\phi} } \phantom{\, t } } & = & -\frac{2 \, a m r \sin\left({\theta}\right)^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \\ g_{ \, {\phi} \, r }^{ \phantom{\, {\phi} } \phantom{\, r } } & = & -\frac{{\left(a^{3} \cos\left({\theta}\right)^{2} + 2 \, a m r + a r^{2}\right)} \sin\left({\theta}\right)^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \\ g_{ \, {\phi} \, {\phi} }^{ \phantom{\, {\phi} } \phantom{\, {\phi} } } & = & \frac{2 \, a^{2} m r \sin\left({\theta}\right)^{4} + {\left(a^{2} r^{2} + r^{4} + {\left(a^{4} + a^{2} r^{2}\right)} \cos\left({\theta}\right)^{2}\right)} \sin\left({\theta}\right)^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \end{array}$

The inverse metric is pretty simple:

In [8]:
g.inverse()[:]

$\left(\begin{array}{rrrr} -\frac{a^{2} \cos\left({\theta}\right)^{2} + 2 \, m r + r^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} & \frac{2 \, m r}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} & 0 & 0 \\ \frac{2 \, m r}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} & \frac{a^{2} - 2 \, m r + r^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} & 0 & \frac{a}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \\ 0 & 0 & \frac{1}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} & 0 \\ 0 & \frac{a}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} & 0 & -\frac{1}{a^{2} \sin\left({\theta}\right)^{4} - {\left(a^{2} + r^{2}\right)} \sin\left({\theta}\right)^{2}} \end{array}\right)$

as well as the determinant w.r.t. to the 3+1 Kerr coordinates:

In [9]:
g.determinant().display()

$\begin{array}{llcl} & M & \longrightarrow & \mathbb{R} \\ & \left(t, r, {\theta}, {\phi}\right) & \longmapsto & a^{4} \cos\left({\theta}\right)^{6} - {\left(a^{4} - 2 \, a^{2} r^{2}\right)} \cos\left({\theta}\right)^{4} - r^{4} - {\left(2 \, a^{2} r^{2} - r^{4}\right)} \cos\left({\theta}\right)^{2} \end{array}$
In [10]:
g.determinant() == - (rho2*sin(th))^2

$\mathrm{True}$

Let us check that we are dealing with a solution of the Einstein equation in vacuum:

In [11]:
g.ricci().display()  # long: takes 1 or 2 minutes

$\mathrm{Ric}\left(g\right) = 0$

The Christoffel symbols w.r.t. the 3+1 Kerr coordinates:

In [12]:
g.christoffel_symbols_display()

$\begin{array}{lcl} \Gamma_{ \phantom{\, t } \, t \, t }^{ \, t \phantom{\, t } \phantom{\, t } } & = & -\frac{2 \, {\left(a^{2} m^{2} r \cos\left({\theta}\right)^{2} - m^{2} r^{3}\right)}}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \\ \Gamma_{ \phantom{\, t } \, t \, r }^{ \, t \phantom{\, t } \phantom{\, r } } & = & -\frac{a^{4} m \cos\left({\theta}\right)^{4} + 2 \, a^{2} m^{2} r \cos\left({\theta}\right)^{2} - 2 \, m^{2} r^{3} - m r^{4}}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \\ \Gamma_{ \phantom{\, t } \, t \, {\theta} }^{ \, t \phantom{\, t } \phantom{\, {\theta} } } & = & -\frac{2 \, a^{2} m r \cos\left({\theta}\right) \sin\left({\theta}\right)}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \\ \Gamma_{ \phantom{\, t } \, t \, {\phi} }^{ \, t \phantom{\, t } \phantom{\, {\phi} } } & = & \frac{2 \, {\left(a^{3} m^{2} r \cos\left({\theta}\right)^{2} - a m^{2} r^{3}\right)} \sin\left({\theta}\right)^{2}}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \\ \Gamma_{ \phantom{\, t } \, r \, r }^{ \, t \phantom{\, r } \phantom{\, r } } & = & -\frac{2 \, {\left(a^{4} m \cos\left({\theta}\right)^{4} + a^{2} m^{2} r \cos\left({\theta}\right)^{2} - m^{2} r^{3} - m r^{4}\right)}}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \\ \Gamma_{ \phantom{\, t } \, r \, {\theta} }^{ \, t \phantom{\, r } \phantom{\, {\theta} } } & = & -\frac{2 \, a^{2} m r \cos\left({\theta}\right) \sin\left({\theta}\right)}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \\ \Gamma_{ \phantom{\, t } \, r \, {\phi} }^{ \, t \phantom{\, r } \phantom{\, {\phi} } } & = & \frac{{\left(a^{5} m \cos\left({\theta}\right)^{4} + 2 \, a^{3} m^{2} r \cos\left({\theta}\right)^{2} - 2 \, a m^{2} r^{3} - a m r^{4}\right)} \sin\left({\theta}\right)^{2}}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \\ \Gamma_{ \phantom{\, t } \, {\theta} \, {\theta} }^{ \, t \phantom{\, {\theta} } \phantom{\, {\theta} } } & = & -\frac{2 \, m r^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \\ \Gamma_{ \phantom{\, t } \, {\theta} \, {\phi} }^{ \, t \phantom{\, {\theta} } \phantom{\, {\phi} } } & = & \frac{2 \, a^{3} m r \cos\left({\theta}\right) \sin\left({\theta}\right)^{3}}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \\ \Gamma_{ \phantom{\, t } \, {\phi} \, {\phi} }^{ \, t \phantom{\, {\phi} } \phantom{\, {\phi} } } & = & -\frac{2 \, {\left({\left(a^{4} m^{2} r \cos\left({\theta}\right)^{2} - a^{2} m^{2} r^{3}\right)} \sin\left({\theta}\right)^{4} + {\left(a^{4} m r^{2} \cos\left({\theta}\right)^{4} + 2 \, a^{2} m r^{4} \cos\left({\theta}\right)^{2} + m r^{6}\right)} \sin\left({\theta}\right)^{2}\right)}}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \\ \Gamma_{ \phantom{\, r } \, t \, t }^{ \, r \phantom{\, t } \phantom{\, t } } & = & \frac{a^{2} m r^{2} - 2 \, m^{2} r^{3} + m r^{4} - {\left(a^{4} m - 2 \, a^{2} m^{2} r + a^{2} m r^{2}\right)} \cos\left({\theta}\right)^{2}}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \\ \Gamma_{ \phantom{\, r } \, t \, r }^{ \, r \phantom{\, t } \phantom{\, r } } & = & \frac{2 \, a^{2} m^{2} r \cos\left({\theta}\right)^{2} - 2 \, m^{2} r^{3} - {\left(a^{4} m \cos\left({\theta}\right)^{2} - a^{2} m r^{2}\right)} \sin\left({\theta}\right)^{2}}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \\ \Gamma_{ \phantom{\, r } \, t \, {\phi} }^{ \, r \phantom{\, t } \phantom{\, {\phi} } } & = & -\frac{{\left(a^{3} m r^{2} - 2 \, a m^{2} r^{3} + a m r^{4} - {\left(a^{5} m - 2 \, a^{3} m^{2} r + a^{3} m r^{2}\right)} \cos\left({\theta}\right)^{2}\right)} \sin\left({\theta}\right)^{2}}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \\ \Gamma_{ \phantom{\, r } \, r \, r }^{ \, r \phantom{\, r } \phantom{\, r } } & = & \frac{2 \, a^{4} m \cos\left({\theta}\right)^{4} + a^{2} m r^{2} - 2 \, m^{2} r^{3} - m r^{4} - {\left(a^{4} m - 2 \, a^{2} m^{2} r + a^{2} m r^{2}\right)} \cos\left({\theta}\right)^{2}}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \\ \Gamma_{ \phantom{\, r } \, r \, {\theta} }^{ \, r \phantom{\, r } \phantom{\, {\theta} } } & = & -\frac{a^{2} \cos\left({\theta}\right) \sin\left({\theta}\right)}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \\ \Gamma_{ \phantom{\, r } \, r \, {\phi} }^{ \, r \phantom{\, r } \phantom{\, {\phi} } } & = & \frac{{\left(a^{5} m \cos\left({\theta}\right)^{2} - a^{3} m r^{2}\right)} \sin\left({\theta}\right)^{4} + {\left(a^{5} r \cos\left({\theta}\right)^{4} + 2 \, a m^{2} r^{3} + a r^{5} - 2 \, {\left(a^{3} m^{2} r - a^{3} r^{3}\right)} \cos\left({\theta}\right)^{2}\right)} \sin\left({\theta}\right)^{2}}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \\ \Gamma_{ \phantom{\, r } \, {\theta} \, {\theta} }^{ \, r \phantom{\, {\theta} } \phantom{\, {\theta} } } & = & -\frac{a^{2} r - 2 \, m r^{2} + r^{3}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \\ \Gamma_{ \phantom{\, r } \, {\phi} \, {\phi} }^{ \, r \phantom{\, {\phi} } \phantom{\, {\phi} } } & = & \frac{{\left(a^{4} m r^{2} - 2 \, a^{2} m^{2} r^{3} + a^{2} m r^{4} - {\left(a^{6} m - 2 \, a^{4} m^{2} r + a^{4} m r^{2}\right)} \cos\left({\theta}\right)^{2}\right)} \sin\left({\theta}\right)^{4} - {\left(a^{2} r^{5} - 2 \, m r^{6} + r^{7} + {\left(a^{6} r - 2 \, a^{4} m r^{2} + a^{4} r^{3}\right)} \cos\left({\theta}\right)^{4} + 2 \, {\left(a^{4} r^{3} - 2 \, a^{2} m r^{4} + a^{2} r^{5}\right)} \cos\left({\theta}\right)^{2}\right)} \sin\left({\theta}\right)^{2}}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \\ \Gamma_{ \phantom{\, {\theta} } \, t \, t }^{ \, {\theta} \phantom{\, t } \phantom{\, t } } & = & -\frac{2 \, a^{2} m r \cos\left({\theta}\right) \sin\left({\theta}\right)}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \\ \Gamma_{ \phantom{\, {\theta} } \, t \, r }^{ \, {\theta} \phantom{\, t } \phantom{\, r } } & = & -\frac{2 \, a^{2} m r \cos\left({\theta}\right) \sin\left({\theta}\right)}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \\ \Gamma_{ \phantom{\, {\theta} } \, t \, {\phi} }^{ \, {\theta} \phantom{\, t } \phantom{\, {\phi} } } & = & \frac{2 \, {\left(a^{3} m r + a m r^{3}\right)} \cos\left({\theta}\right) \sin\left({\theta}\right)}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \\ \Gamma_{ \phantom{\, {\theta} } \, r \, r }^{ \, {\theta} \phantom{\, r } \phantom{\, r } } & = & -\frac{2 \, a^{2} m r \cos\left({\theta}\right) \sin\left({\theta}\right)}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \\ \Gamma_{ \phantom{\, {\theta} } \, r \, {\theta} }^{ \, {\theta} \phantom{\, r } \phantom{\, {\theta} } } & = & \frac{r}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \\ \Gamma_{ \phantom{\, {\theta} } \, r \, {\phi} }^{ \, {\theta} \phantom{\, r } \phantom{\, {\phi} } } & = & \frac{{\left(a^{5} \cos\left({\theta}\right)^{5} + 2 \, a^{3} r^{2} \cos\left({\theta}\right)^{3} + {\left(2 \, a^{3} m r + 2 \, a m r^{3} + a r^{4}\right)} \cos\left({\theta}\right)\right)} \sin\left({\theta}\right)}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \\ \Gamma_{ \phantom{\, {\theta} } \, {\theta} \, {\theta} }^{ \, {\theta} \phantom{\, {\theta} } \phantom{\, {\theta} } } & = & -\frac{a^{2} \cos\left({\theta}\right) \sin\left({\theta}\right)}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \\ \Gamma_{ \phantom{\, {\theta} } \, {\phi} \, {\phi} }^{ \, {\theta} \phantom{\, {\phi} } \phantom{\, {\phi} } } & = & -\frac{{\left({\left(a^{6} - 2 \, a^{4} m r + a^{4} r^{2}\right)} \cos\left({\theta}\right)^{5} + 2 \, {\left(a^{4} r^{2} - 2 \, a^{2} m r^{3} + a^{2} r^{4}\right)} \cos\left({\theta}\right)^{3} + {\left(2 \, a^{4} m r + 4 \, a^{2} m r^{3} + a^{2} r^{4} + r^{6}\right)} \cos\left({\theta}\right)\right)} \sin\left({\theta}\right)}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \\ \Gamma_{ \phantom{\, {\phi} } \, t \, t }^{ \, {\phi} \phantom{\, t } \phantom{\, t } } & = & -\frac{a^{3} m \cos\left({\theta}\right)^{2} - a m r^{2}}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \\ \Gamma_{ \phantom{\, {\phi} } \, t \, r }^{ \, {\phi} \phantom{\, t } \phantom{\, r } } & = & -\frac{a^{3} m \cos\left({\theta}\right)^{2} - a m r^{2}}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \\ \Gamma_{ \phantom{\, {\phi} } \, t \, {\theta} }^{ \, {\phi} \phantom{\, t } \phantom{\, {\theta} } } & = & -\frac{2 \, a m r \cos\left({\theta}\right)}{{\left(a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}\right)} \sin\left({\theta}\right)} \\ \Gamma_{ \phantom{\, {\phi} } \, t \, {\phi} }^{ \, {\phi} \phantom{\, t } \phantom{\, {\phi} } } & = & \frac{{\left(a^{4} m \cos\left({\theta}\right)^{2} - a^{2} m r^{2}\right)} \sin\left({\theta}\right)^{2}}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \\ \Gamma_{ \phantom{\, {\phi} } \, r \, r }^{ \, {\phi} \phantom{\, r } \phantom{\, r } } & = & -\frac{a^{3} m \cos\left({\theta}\right)^{2} - a m r^{2}}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \\ \Gamma_{ \phantom{\, {\phi} } \, r \, {\theta} }^{ \, {\phi} \phantom{\, r } \phantom{\, {\theta} } } & = & -\frac{a^{3} \cos\left({\theta}\right)^{3} + {\left(2 \, a m r + a r^{2}\right)} \cos\left({\theta}\right)}{{\left(a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}\right)} \sin\left({\theta}\right)} \\ \Gamma_{ \phantom{\, {\phi} } \, r \, {\phi} }^{ \, {\phi} \phantom{\, r } \phantom{\, {\phi} } } & = & \frac{a^{4} r \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{3} \cos\left({\theta}\right)^{2} + r^{5} + {\left(a^{4} m \cos\left({\theta}\right)^{2} - a^{2} m r^{2}\right)} \sin\left({\theta}\right)^{2}}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \\ \Gamma_{ \phantom{\, {\phi} } \, {\theta} \, {\theta} }^{ \, {\phi} \phantom{\, {\theta} } \phantom{\, {\theta} } } & = & -\frac{a r}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \\ \Gamma_{ \phantom{\, {\phi} } \, {\theta} \, {\phi} }^{ \, {\phi} \phantom{\, {\theta} } \phantom{\, {\phi} } } & = & \frac{a^{4} \cos\left({\theta}\right)^{5} - 2 \, {\left(a^{2} m r - a^{2} r^{2}\right)} \cos\left({\theta}\right)^{3} + {\left(2 \, a^{2} m r + r^{4}\right)} \cos\left({\theta}\right)}{{\left(a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}\right)} \sin\left({\theta}\right)} \\ \Gamma_{ \phantom{\, {\phi} } \, {\phi} \, {\phi} }^{ \, {\phi} \phantom{\, {\phi} } \phantom{\, {\phi} } } & = & -\frac{{\left(a^{5} m \cos\left({\theta}\right)^{2} - a^{3} m r^{2}\right)} \sin\left({\theta}\right)^{4} + {\left(a^{5} r \cos\left({\theta}\right)^{4} + 2 \, a^{3} r^{3} \cos\left({\theta}\right)^{2} + a r^{5}\right)} \sin\left({\theta}\right)^{2}}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \end{array}$

## Vector normal to the hypersurfaces $r=\mathrm{const}$

In [13]:
dr = X.coframe()[1]
print(dr)
dr.display()

1-form dr on the 4-dimensional differentiable manifold M
$\mathrm{d} r = \mathrm{d} r$
In [14]:
nr = dr.up(g)
print(nr)
nr.display()

Vector field on the 4-dimensional differentiable manifold M
$\left( \frac{2 \, m r}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \right) \frac{\partial}{\partial t } + \left( \frac{a^{2} - 2 \, m r + r^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \right) \frac{\partial}{\partial r } + \left( \frac{a}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \right) \frac{\partial}{\partial {\phi} }$
In [15]:
assume(a^2<m^2)
rp = m + sqrt(m^2-a^2)
rp

$m + \sqrt{-a^{2} + m^{2}}$
In [16]:
p = M.point(coords=(t,rp,th,ph), name='p')
print(p)

Point p on the 4-dimensional differentiable manifold M
In [17]:
X(p)

$\left(t, m + \sqrt{-a^{2} + m^{2}}, {\theta}, {\phi}\right)$
In [18]:
nrH = nr.at(p)
print(nrH)

Tangent vector at Point p on the 4-dimensional differentiable manifold M
In [19]:
Tp = M.tangent_space(p)
print(Tp)

Tangent space at Point p on the 4-dimensional differentiable manifold M
In [20]:
Tp.default_basis()

$\left(\frac{\partial}{\partial t },\frac{\partial}{\partial r },\frac{\partial}{\partial {\theta} },\frac{\partial}{\partial {\phi} }\right)$
In [21]:
nrH[:]

$\left[-\frac{2 \, {\left(\sqrt{a + m} \sqrt{-a + m} m + m^{2}\right)}}{a^{2} \sin\left({\theta}\right)^{2} - 2 \, \sqrt{a + m} \sqrt{-a + m} m - 2 \, m^{2}}, 0, 0, -\frac{a}{a^{2} \sin\left({\theta}\right)^{2} - 2 \, \sqrt{a + m} \sqrt{-a + m} m - 2 \, m^{2}}\right]$
In [22]:
OmegaH = a/(2*m*rp)
OmegaH

$\frac{a}{2 \, {\left(m + \sqrt{-a^{2} + m^{2}}\right)} m}$
In [23]:
xi = X.frame()[0]
xi

$\frac{\partial}{\partial t }$
In [24]:
eta = X.frame()[3]
eta

$\frac{\partial}{\partial {\phi} }$
In [25]:
chi = xi + OmegaH*eta
chi.display()

$\frac{\partial}{\partial t } + \frac{a}{2 \, {\left(\sqrt{a + m} \sqrt{-a + m} m + m^{2}\right)}} \frac{\partial}{\partial {\phi} }$

## Ingoing principal null geodesics

In [26]:
k = M.vector_field(name='k')
k[0] = 1
k[1] = -1
k.display()

$k = \frac{\partial}{\partial t }-\frac{\partial}{\partial r }$

Let us check that $k$ is a null vector:

In [27]:
g(k,k).display()

$\begin{array}{llcl} g\left(k,k\right):& M & \longrightarrow & \mathbb{R} \\ & \left(t, r, {\theta}, {\phi}\right) & \longmapsto & 0 \end{array}$

Computation of $\nabla_k k$:

In [28]:
nab = g.connection()
acc = nab(k).contract(k)
acc.display()

$0$
In [29]:
nab(k).display()

$\nabla_{g} k = \left( \frac{a^{2} m \cos\left({\theta}\right)^{2} - m r^{2}}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \frac{\partial}{\partial t }\otimes \mathrm{d} t + \left( \frac{a^{2} m \cos\left({\theta}\right)^{2} - m r^{2}}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \frac{\partial}{\partial t }\otimes \mathrm{d} r + \left( -\frac{{\left(a^{3} m \cos\left({\theta}\right)^{2} - a m r^{2}\right)} \sin\left({\theta}\right)^{2}}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \frac{\partial}{\partial t }\otimes \mathrm{d} {\phi} + \left( -\frac{a^{2} m \cos\left({\theta}\right)^{2} - m r^{2}}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \frac{\partial}{\partial r }\otimes \mathrm{d} t + \left( -\frac{a^{2} m \cos\left({\theta}\right)^{2} - m r^{2}}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \frac{\partial}{\partial r }\otimes \mathrm{d} r + \left( \frac{a^{2} \cos\left({\theta}\right) \sin\left({\theta}\right)}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \right) \frac{\partial}{\partial r }\otimes \mathrm{d} {\theta} + \left( -\frac{{\left(a^{3} m - a^{3} r\right)} \sin\left({\theta}\right)^{4} - {\left(a^{3} m - a^{3} r - a m r^{2} - a r^{3}\right)} \sin\left({\theta}\right)^{2}}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \frac{\partial}{\partial r }\otimes \mathrm{d} {\phi} + \left( -\frac{r}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \right) \frac{\partial}{\partial {\theta} }\otimes \mathrm{d} {\theta} + \left( -\frac{a \cos\left({\theta}\right) \sin\left({\theta}\right)}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \right) \frac{\partial}{\partial {\theta} }\otimes \mathrm{d} {\phi} + \frac{a \cos\left({\theta}\right)}{{\left(a^{2} \cos\left({\theta}\right)^{2} + r^{2}\right)} \sin\left({\theta}\right)} \frac{\partial}{\partial {\phi} }\otimes \mathrm{d} {\theta} + \left( -\frac{r}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \right) \frac{\partial}{\partial {\phi} }\otimes \mathrm{d} {\phi}$

## Outgoing principal null geodesics

In [30]:
el = M.vector_field(name='el', latex_name=r'\ell')
el[0] = 1/2 + m*r/(r^2+a^2)
el[1] = 1/2 - m*r/(r^2+a^2)
el[3] = a/(r^2+a^2)
el.display()

$\ell = \left( \frac{a^{2} + 2 \, m r + r^{2}}{2 \, {\left(a^{2} + r^{2}\right)}} \right) \frac{\partial}{\partial t } + \left( \frac{a^{2} - 2 \, m r + r^{2}}{2 \, {\left(a^{2} + r^{2}\right)}} \right) \frac{\partial}{\partial r } + \left( \frac{a}{a^{2} + r^{2}} \right) \frac{\partial}{\partial {\phi} }$