Courbes parametrees

Views : 39

Compute Environment: Ubuntu 18.04 (Deprecated)

Courbes paramétrées

Étant donné un intervalle $I\subseteq \mathbb{R}$ et une fonction ${\bf r} : I \to \mathbb{R}^n$ sont image est une courbe dans $\mathbb{R}^n$ .

La fonction ${\bf r}$ est une paramétrisation de la courbe ${\mathcal C}$
Il peut avoir d'autres paramétrisations qui donnent lieu à la même courbe.

On va voir comment tracer quels courbes avec SAGEmathCloud.

Exemple 1

Considérons la courbe ${\bf r}(t)=(\cos(2t), \sin(t))$ , il s'agit d'une courbe plane.

var('t')
Courbe = parametric_plot([cos(2*t),sin(4*t)],(t,0,2*pi), color='blue', thickness = 2)
show(Courbe)

t

Exemple 2

Considérons maintenant une courbe dans l'espace ${\bf r}(t)=(t,t^2,t^3)$

Courbe = parametric_plot3d([t,t^2, t^3],(t,-2,2),color='red', thickness=3)
show(Courbe)

3D rendering not yet implemented

Remarques :

Cette courbe est l'intersection de deux surfaces :

Le cylindre parabolique $y=x^2$ ,
Le cylindre cubique $z= x^3$ .

En cas de besoin, posez la question sur ce qu'un cylindre parabolique est.

Voici les deux surfaces en question, avec le courbe d'intersection. Pour tracer les surfaces, on a utilisé des paramétrisations. Ceci fera l'objet d'un chapitre ultérieur.

var('u,v')
Cyl=parametric_plot3d((u,u^2,v),(u,-2,2),(v,-8,8), color='blue', opacity=0.35)
Surf = parametric_plot3d((u,v,u^3),(u,-2,2),(v,0,4),color='green',opacity=0.35)
show(Cyl+Surf+Courbe, frame_aspect_ratio = [4,4,1])

(u, v)

3D rendering not yet implemented

Exemple 3

Il y a des fonctions qui peuvent poser problème : une intégrale qu'on ne peut évaluer analytiquement, par exemple. Un exemple typique serait quelque chose comme la courbe dont l'équation serait $\displaystyle y(x) = \int_{0}^x e^{-u^2} {\rm d}u$ . La primitive n'existe pas, mais ça ne devrait pas nous obliger à nous passer de la courbe. Une façon de procéder serait de définir une fonction séparément, qui tienne compte du fait que l'on veut une intégration numérique, puis utiliser cette fonction pour le graphique.


var('t,u')
def y(t):
	return integral_numerical(e^(-u^2)/sqrt(2*pi),0,t)[0]+1/2

(t, u)

def x(t):
	return t

y(1)

0.797939722603012

Courbe = parametric_plot((x,y),(-5,5),color='blue', thickness=2)
show(Courbe,aspect_ratio=5)

%md
## Exemple : la spirale de Cornu

Il s'agit de la courbe donnée par le chemin $\displaystyle x(t) = \int_0^t  \cos \frac{\pi u^2}{2} {\rm d}u $ et $\displaystyle y(t) = \int_0^t  \sin \frac{\pi u^2}{2} {\rm d}u $.
Ces intégrales ne peuvent pas être évaluées analytiquement, mais on va tracer la courbe quand même.

Exemple : la spirale de Cornu

Il s'agit de la courbe donnée par le chemin $\displaystyle x(t) = \int_0^t \cos \frac{\pi u^2}{2} {\rm d}u$ et $\displaystyle y(t) = \int_0^t \sin \frac{\pi u^2}{2} {\rm d}u$ . Ces intégrales ne peuvent pas être évaluées analytiquement, mais on va tracer la courbe quand même.

var('t,u')
def x(t):
    return integral_numerical(cos(pi*u^2/2),0,t)[0]

(t, u)

def y(t):
    return integral_numerical(sin(pi*u^2/2),0,t)[0]

Première méthode :

Une liste de points, puis les segments les joignant. Ici on divise l'intervalle $[-\pi, \pi]$ en 200 sous intervalles

Points = [(x(t),y(t)) for t in sxrange(-pi,pi,2*pi/200)]
line(Points).show(figsize=[5, 5],aspect_ratio=1)

p = parametric_plot((x,y),(-pi,pi))
show(p)