Authors: agolubtsova , Eric Gourgoulhon

Views : 108

Description: 5D Kerr-AdS spacetime with a Nambu-Goto string (case b=0)

5D Kerr-AdS spacetime with a Nambu-Goto string

Case b = 0

This SageMath notebook is relative to the article Holographic drag force in 5d Kerr-AdS black hole by Irina Ya. Aref'eva, Anastasia A. Golubtsova and Eric Gourgoulhon, arXiv:2004.12984.

The involved differential geometry computations are based on tools developed through the SageManifolds project.

NB: a version of SageMath at least equal to 8.2 is required to run this notebook:

In [1]:

version()

'SageMath version 9.0, Release Date: 2020-01-01'

First we set up the notebook to display mathematical objects using LaTeX rendering:

In [2]:

%display latex

Since some computations are quite long, we ask for running them in parallel on 8 cores:

In [3]:

Parallelism().set(nproc=1)  # only nproc=1 works on CoCalc

Spacetime manifold

We declare the Kerr-AdS spacetime as a 5-dimensional Lorentzian manifold:

In [4]:

M = Manifold(5, 'M', r'\mathcal{M}', structure='Lorentzian', metric_name='G')
print(M)

5-dimensional Lorentzian manifold M

Let us define Boyer-Lindquist-type coordinates (rational polynomial version) on $\mathcal{M}$ , via the method chart(), the argument of which is a string expressing the coordinates names, their ranges (the default is $(-\infty,+\infty)$ ) and their LaTeX symbols:

In [5]:

BL.<t,r,mu,ph,ps> = M.chart(r't r:(0,+oo) mu:(0,1):\mu ph:(0,2*pi):\phi ps:(0,2*pi):\psi')
BL

\left(\mathcal{M},(t, r, {\mu}, {\phi}, {\psi})\right)

The coordinate $\mu$ is related to the standard Boyer-Lindquist coordinate $\theta$ by $\mu = \cos\theta$

The coordinate ranges are

In [6]:

BL.coord_range()

t :\ \left( -\infty, +\infty \right) ;\quad r :\ \left( 0 , +\infty \right) ;\quad {\mu} :\ \left( 0 , 1 \right) ;\quad {\phi} :\ \left( 0 , 2 \, \pi \right) ;\quad {\psi} :\ \left( 0 , 2 \, \pi \right)

Note that contrary to the 4-dimensional case, the range of $\mu$ is $(0,1)$ only (cf. Sec. 1.2 of R.C. Myers, arXiv:1111.1903 or Sec. 2 of G.W. Gibbons, H. Lüb, Don N. Page, C.N. Pope, J. Geom. Phys. 53, 49 (2005)). In other words, the range of $\theta$ is $\left(0, \frac{\pi}{2}\right)$ only.

Metric tensor

The 4 parameters $m$ , $a$ , $b$ and $\ell$ of the Kerr-AdS spacetime are declared as symbolic variables, $a$ and $b$ being the two angular momentum parameters and $\ell$ being related to the cosmological constant by $\Lambda = - 6 \ell^2$ :

In [7]:

var('m a b', domain='real')

\left(m, a, b\right)

In [8]:

var('l', domain='real', latex_name=r'\ell')

{\ell}

In [9]:

# Particular cases
# m = 0
# a = 0
b = 0
# b = a

Some auxiliary functions:

In [10]:

keep_Delta = False  # change to False to provide explicit expression for Delta_r, Xi_a, etc...

In [11]:

sig = (1 + r^2*l^2)/r^2
costh2 = mu^2
sinth2 = 1 - mu^2
rho2 = r^2 + a^2*mu^2 + b^2*sinth2
if keep_Delta:
    Delta_r = var('Delta_r', latex_name=r'\Delta_r', domain='real')
    Delta_th = var('Delta_th', latex_name=r'\Delta_\theta', domain='real')
    if a == b:
        Xi_a = var('Xi', latex_name=r'\Xi', domain='real')
        Xi_b = Xi_a
    else:
        Xi_a = var('Xi_a', latex_name=r'\Xi_a', domain='real')
        Xi_b = var('Xi_b', latex_name=r'\Xi_b', domain='real')
    #Delta_th = 1 - a^2*l^2*mu^2 - b^2*l^2*sinth2
    Xi_a = 1 - a^2*l^2
    Xi_b = 1 - b^2*l^2
else:
    Delta_r = (r^2+a^2)*(r^2+b^2)*sig - 2*m
    Delta_th = 1 - a^2*l^2*mu^2 - b^2*l^2*sinth2
    Xi_a = 1 - a^2*l^2
    Xi_b = 1 - b^2*l^2

The metric is set by its components in the coordinate frame associated with the Boyer-Lindquist-type coordinates, which is the current manifold's default frame. These components can be deduced from Eq. (5.22) of the article S.W. Hawking, C.J. Hunter & M.M. Taylor-Robinson, Phys. Rev. D 59, 064005 (1999) (the check of agreement with this equation is performed below):

In [12]:

G = M.metric()
tmp = 1/rho2*( -Delta_r + Delta_th*(a^2*sinth2 + b^2*mu^2) + a^2*b^2*sig )
G[0,0] = tmp.simplify_full()
tmp = a*sinth2/(rho2*Xi_a)*( Delta_r - (r^2+a^2)*(Delta_th + b^2*sig) )
G[0,3] = tmp.simplify_full()
tmp = b*mu^2/(rho2*Xi_b)*( Delta_r - (r^2+b^2)*(Delta_th + a^2*sig) )
G[0,4] = tmp.simplify_full()
G[1,1] = (rho2/Delta_r).simplify_full()
G[2,2] = (rho2/Delta_th/(1-mu^2)).simplify_full()
tmp = sinth2/(rho2*Xi_a^2)*( - Delta_r*a^2*sinth2 + (r^2+a^2)^2*(Delta_th + sig*b^2*sinth2) ) 
G[3,3] = tmp.simplify_full()
tmp = a*b*sinth2*mu^2/(rho2*Xi_a*Xi_b)*( - Delta_r + sig*(r^2+a^2)*(r^2+b^2) )
G[3,4] = tmp.simplify_full()
tmp = mu^2/(rho2*Xi_b^2)*( - Delta_r*b^2*mu^2 + (r^2+b^2)^2*(Delta_th + sig*a^2*mu^2) )
G[4,4] = tmp.simplify_full()
G.display()

G = \left( \frac{a^{4} {\ell}^{2} {\mu}^{4} - {\ell}^{2} r^{4} - {\left(a^{4} {\ell}^{2} + a^{2}\right)} {\mu}^{2} - {\left(a^{2} {\ell}^{2} + 1\right)} r^{2} + 2 \, m}{a^{2} {\mu}^{2} + r^{2}} \right) \mathrm{d} t\otimes \mathrm{d} t + \left( \frac{a^{5} {\ell}^{2} {\mu}^{4} + {\left(a {\ell}^{2} {\mu}^{2} - a {\ell}^{2}\right)} r^{4} - {\left(a^{5} {\ell}^{2} + 2 \, a m\right)} {\mu}^{2} + {\left(a^{3} {\ell}^{2} {\mu}^{4} - a^{3} {\ell}^{2}\right)} r^{2} + 2 \, a m}{{\left(a^{4} {\ell}^{2} - a^{2}\right)} {\mu}^{2} + {\left(a^{2} {\ell}^{2} - 1\right)} r^{2}} \right) \mathrm{d} t\otimes \mathrm{d} {\phi} + \left( \frac{a^{2} {\mu}^{2} + r^{2}}{{\ell}^{2} r^{4} + {\left(a^{2} {\ell}^{2} + 1\right)} r^{2} + a^{2} - 2 \, m} \right) \mathrm{d} r\otimes \mathrm{d} r + \left( \frac{a^{2} {\mu}^{2} + r^{2}}{a^{2} {\ell}^{2} {\mu}^{4} - {\left(a^{2} {\ell}^{2} + 1\right)} {\mu}^{2} + 1} \right) \mathrm{d} {\mu}\otimes \mathrm{d} {\mu} + \left( \frac{a^{5} {\ell}^{2} {\mu}^{4} + {\left(a {\ell}^{2} {\mu}^{2} - a {\ell}^{2}\right)} r^{4} - {\left(a^{5} {\ell}^{2} + 2 \, a m\right)} {\mu}^{2} + {\left(a^{3} {\ell}^{2} {\mu}^{4} - a^{3} {\ell}^{2}\right)} r^{2} + 2 \, a m}{{\left(a^{4} {\ell}^{2} - a^{2}\right)} {\mu}^{2} + {\left(a^{2} {\ell}^{2} - 1\right)} r^{2}} \right) \mathrm{d} {\phi}\otimes \mathrm{d} t + \left( \frac{{\left(a^{6} {\ell}^{2} - a^{4} + 2 \, a^{2} m\right)} {\mu}^{4} - {\left(a^{2} {\ell}^{2} - {\left(a^{2} {\ell}^{2} - 1\right)} {\mu}^{2} - 1\right)} r^{4} + 2 \, a^{2} m - {\left(a^{6} {\ell}^{2} - a^{4} + 4 \, a^{2} m\right)} {\mu}^{2} - {\left(a^{4} {\ell}^{2} - {\left(a^{4} {\ell}^{2} - a^{2}\right)} {\mu}^{4} - a^{2}\right)} r^{2}}{{\left(a^{6} {\ell}^{4} - 2 \, a^{4} {\ell}^{2} + a^{2}\right)} {\mu}^{2} + {\left(a^{4} {\ell}^{4} - 2 \, a^{2} {\ell}^{2} + 1\right)} r^{2}} \right) \mathrm{d} {\phi}\otimes \mathrm{d} {\phi} + {\mu}^{2} r^{2} \mathrm{d} {\psi}\otimes \mathrm{d} {\psi}

In [13]:

G.display_comp(only_nonredundant=True)

\begin{array}{lcl} G_{ \, t \, t }^{ \phantom{\, t}\phantom{\, t} } & = & \frac{a^{4} {\ell}^{2} {\mu}^{4} - {\ell}^{2} r^{4} - {\left(a^{4} {\ell}^{2} + a^{2}\right)} {\mu}^{2} - {\left(a^{2} {\ell}^{2} + 1\right)} r^{2} + 2 \, m}{a^{2} {\mu}^{2} + r^{2}} \\ G_{ \, t \, {\phi} }^{ \phantom{\, t}\phantom{\, {\phi}} } & = & \frac{a^{5} {\ell}^{2} {\mu}^{4} + {\left(a {\ell}^{2} {\mu}^{2} - a {\ell}^{2}\right)} r^{4} - {\left(a^{5} {\ell}^{2} + 2 \, a m\right)} {\mu}^{2} + {\left(a^{3} {\ell}^{2} {\mu}^{4} - a^{3} {\ell}^{2}\right)} r^{2} + 2 \, a m}{{\left(a^{4} {\ell}^{2} - a^{2}\right)} {\mu}^{2} + {\left(a^{2} {\ell}^{2} - 1\right)} r^{2}} \\ G_{ \, r \, r }^{ \phantom{\, r}\phantom{\, r} } & = & \frac{a^{2} {\mu}^{2} + r^{2}}{{\ell}^{2} r^{4} + {\left(a^{2} {\ell}^{2} + 1\right)} r^{2} + a^{2} - 2 \, m} \\ G_{ \, {\mu} \, {\mu} }^{ \phantom{\, {\mu}}\phantom{\, {\mu}} } & = & \frac{a^{2} {\mu}^{2} + r^{2}}{a^{2} {\ell}^{2} {\mu}^{4} - {\left(a^{2} {\ell}^{2} + 1\right)} {\mu}^{2} + 1} \\ G_{ \, {\phi} \, {\phi} }^{ \phantom{\, {\phi}}\phantom{\, {\phi}} } & = & \frac{{\left(a^{6} {\ell}^{2} - a^{4} + 2 \, a^{2} m\right)} {\mu}^{4} - {\left(a^{2} {\ell}^{2} - {\left(a^{2} {\ell}^{2} - 1\right)} {\mu}^{2} - 1\right)} r^{4} + 2 \, a^{2} m - {\left(a^{6} {\ell}^{2} - a^{4} + 4 \, a^{2} m\right)} {\mu}^{2} - {\left(a^{4} {\ell}^{2} - {\left(a^{4} {\ell}^{2} - a^{2}\right)} {\mu}^{4} - a^{2}\right)} r^{2}}{{\left(a^{6} {\ell}^{4} - 2 \, a^{4} {\ell}^{2} + a^{2}\right)} {\mu}^{2} + {\left(a^{4} {\ell}^{4} - 2 \, a^{2} {\ell}^{2} + 1\right)} r^{2}} \\ G_{ \, {\psi} \, {\psi} }^{ \phantom{\, {\psi}}\phantom{\, {\psi}} } & = & {\mu}^{2} r^{2} \end{array}

Check of agreement with Eq. (5.22) of Hawking et al or Eq. (2.3) of 5dKerr-AdS-AGG-5-12

We need the 1-forms $\mathrm{d}t$ , $\mathrm{d}r$ , $\mathrm{d}\mu$ , $\mathrm{d}\phi$ and $\mathrm{d}\psi$ :

In [14]:

dt, dr, dmu, dph, dps = (BL.coframe()[i] for i in M.irange())
dt, dr, dmu, dph, dps

\left(\mathrm{d} t, \mathrm{d} r, \mathrm{d} {\mu}, \mathrm{d} {\phi}, \mathrm{d} {\psi}\right)

In [15]:

print(dt)

1-form dt on the 5-dimensional Lorentzian manifold M

In agreement with $\mu = \cos\theta$ , we introduce the 1-form $\mathrm{d}\theta = - \mathrm{d}\mu /\sin\theta$ , with $\sin\theta = \sqrt{1-\mu^2}$ since $\theta\in\left(0, \frac{\pi}{2}\right)$ :

In [16]:

dth = - 1/sqrt(1 - mu^2)*dmu

In [17]:

s1 = dt - a*sinth2/Xi_a*dph - b*costh2/Xi_b*dps
s1.display()

\mathrm{d} t + \left( -\frac{a {\mu}^{2} - a}{a^{2} {\ell}^{2} - 1} \right) \mathrm{d} {\phi}

In [18]:

s2 = a*dt - (r^2 + a^2)/Xi_a*dph
s2.display()

a \mathrm{d} t + \left( \frac{a^{2} + r^{2}}{a^{2} {\ell}^{2} - 1} \right) \mathrm{d} {\phi}

In [19]:

s3 = b*dt - (r^2 + b^2)/Xi_b*dps
s3.display()

-r^{2} \mathrm{d} {\psi}

In [20]:

s4 = a*b*dt - b*(r^2 + a^2)*sinth2/Xi_a * dph - a*(r^2 + b^2)*costh2/Xi_b * dps
s4.display()

-a {\mu}^{2} r^{2} \mathrm{d} {\psi}

In [21]:

G0 = - Delta_r/rho2 * s1*s1 + Delta_th*sinth2/rho2 * s2*s2 + Delta_th*costh2/rho2 * s3*s3 \
     + rho2/Delta_r * dr*dr + rho2/Delta_th * dth*dth + sig/rho2 * s4*s4
G0.display_comp(only_nonredundant=True)

\begin{array}{lcl} X_{ \, t \, t }^{ \phantom{\, t}\phantom{\, t} } & = & \frac{a^{4} {\ell}^{2} {\mu}^{4} - {\ell}^{2} r^{4} - {\left(a^{4} {\ell}^{2} + a^{2}\right)} {\mu}^{2} - {\left(a^{2} {\ell}^{2} + 1\right)} r^{2} + 2 \, m}{a^{2} {\mu}^{2} + r^{2}} \\ X_{ \, t \, {\phi} }^{ \phantom{\, t}\phantom{\, {\phi}} } & = & \frac{a^{5} {\ell}^{2} {\mu}^{4} + {\left(a {\ell}^{2} {\mu}^{2} - a {\ell}^{2}\right)} r^{4} - {\left(a^{5} {\ell}^{2} + 2 \, a m\right)} {\mu}^{2} + {\left(a^{3} {\ell}^{2} {\mu}^{4} - a^{3} {\ell}^{2}\right)} r^{2} + 2 \, a m}{{\left(a^{4} {\ell}^{2} - a^{2}\right)} {\mu}^{2} + {\left(a^{2} {\ell}^{2} - 1\right)} r^{2}} \\ X_{ \, r \, r }^{ \phantom{\, r}\phantom{\, r} } & = & \frac{a^{2} {\mu}^{2} + r^{2}}{{\ell}^{2} r^{4} + {\left(a^{2} {\ell}^{2} + 1\right)} r^{2} + a^{2} - 2 \, m} \\ X_{ \, {\mu} \, {\mu} }^{ \phantom{\, {\mu}}\phantom{\, {\mu}} } & = & \frac{a^{2} {\mu}^{2} + r^{2}}{a^{2} {\ell}^{2} {\mu}^{4} - {\left(a^{2} {\ell}^{2} + 1\right)} {\mu}^{2} + 1} \\ X_{ \, {\phi} \, t }^{ \phantom{\, {\phi}}\phantom{\, t} } & = & \frac{a^{5} {\ell}^{2} {\mu}^{4} + {\left(a {\ell}^{2} {\mu}^{2} - a {\ell}^{2}\right)} r^{4} - {\left(a^{5} {\ell}^{2} + 2 \, a m\right)} {\mu}^{2} + {\left(a^{3} {\ell}^{2} {\mu}^{4} - a^{3} {\ell}^{2}\right)} r^{2} + 2 \, a m}{{\left(a^{4} {\ell}^{2} - a^{2}\right)} {\mu}^{2} + {\left(a^{2} {\ell}^{2} - 1\right)} r^{2}} \\ X_{ \, {\phi} \, {\phi} }^{ \phantom{\, {\phi}}\phantom{\, {\phi}} } & = & \frac{{\left(a^{6} {\ell}^{2} - a^{4} + 2 \, a^{2} m\right)} {\mu}^{4} - {\left(a^{2} {\ell}^{2} - {\left(a^{2} {\ell}^{2} - 1\right)} {\mu}^{2} - 1\right)} r^{4} + 2 \, a^{2} m - {\left(a^{6} {\ell}^{2} - a^{4} + 4 \, a^{2} m\right)} {\mu}^{2} - {\left(a^{4} {\ell}^{2} - {\left(a^{4} {\ell}^{2} - a^{2}\right)} {\mu}^{4} - a^{2}\right)} r^{2}}{{\left(a^{6} {\ell}^{4} - 2 \, a^{4} {\ell}^{2} + a^{2}\right)} {\mu}^{2} + {\left(a^{4} {\ell}^{4} - 2 \, a^{2} {\ell}^{2} + 1\right)} r^{2}} \\ X_{ \, {\psi} \, {\psi} }^{ \phantom{\, {\psi}}\phantom{\, {\psi}} } & = & {\mu}^{2} r^{2} \end{array}

In [22]:

G0 == G

\mathrm{True}

Einstein equation

The Ricci tensor of $g$ is

In [23]:

if not keep_Delta:
    # Ric = G.ricci()
    # print(Ric)
    pass

In [24]:

if not keep_Delta:
    # show(Ric.display_comp(only_nonredundant=True))
    pass

Let us check that $g$ is a solution of the vacuum Einstein equation with the cosmological constant $\Lambda = - 6 \ell^2$ :

In [25]:

Lambda = -6*l^2
if not keep_Delta:
    # print(Ric == 2/3*Lambda*G)
    pass

Check of Eq. (2.10)

One must have $a=b$ and keep_Delta == False for the test to pass:

In [26]:

if a == b and not keep_Delta:
    G1 = - (1 + rho2*l^2 - 2*m/rho2) * dt*dt + rho2/Delta_r * dr*dr \
         + rho2/Delta_th * dth*dth \
         + sinth2/Xi_a^2*(rho2*Xi_a + 2*a^2*m/rho2*sinth2) * dph * dph \
         + costh2/Xi_a^2*(rho2*Xi_a + 2*a^2*m/rho2*costh2) * dps * dps \
         + a*sinth2/Xi_a*(rho2*l^2 - 2*m/rho2) * (dt*dph + dph*dt) \
         + a*costh2/Xi_a*(rho2*l^2 - 2*m/rho2) * (dt*dps + dps*dt) \
         + 2*m*a^2*sinth2*costh2/Xi_a^2/rho2 * (dph*dps + dps*dph)
    print(G1 == G)

Check of Eq. (2.14)

One must have $b=0$ and keep_Delta == False for the test to pass:

In [27]:

if b == 0 and not keep_Delta:
    s1 = dt - a*sinth2/Xi_a*dph
    s2 = a*dt - (r^2 + a^2)/Xi_a*dph
    G2 = - Delta_r/rho2* s1*s1 + rho2/Delta_r * dr*dr + rho2/Delta_th * dth*dth \
         + Delta_th*sinth2/rho2* s2*s2 + r^2*costh2 * dps*dps
    print(G2 == G)

True

String worldsheet

The string worldsheet as a 2-dimensional Lorentzian manifold:

In [28]:

W = Manifold(2, 'W', structure='Lorentzian')
print(W)

2-dimensional Lorentzian manifold W

Let us assume that the string worldsheet is parametrized by $(t,r)$ :

In [29]:

XW.<t,r> = W.chart(r't r:(0,+oo)')
XW

\left(W,(t, r)\right)

The string embedding in Kerr-AdS spacetime, as an expansion about a straight string solution in AdS:

In [30]:

Mu0 = var('Mu0', latex_name=r'\mu_0', domain='real')
Phi0 = var('Phi0', latex_name=r'\Phi_0', domain='real')
Psi0 = var('Psi0', latex_name=r'\Psi_0', domain='real')
beta1 = var('beta1', latex_name=r'\beta_1', domain='real')
beta2 = var('beta2', latex_name=r'\beta_2', domain='real')

cosTh0 = Mu0
sinTh0 = sqrt(1 - Mu0^2)

mu_s = Mu0 + a^2*function('mu_1')(r)
ph_s = Phi0 + beta1*a*l^2*t + beta1*a*function('phi_1')(r)
ps_s = Psi0 + beta2*a*l^2*t + beta2*a*function('psi_1')(r)

F = W.diff_map(M, {(XW, BL): [t, r, mu_s, ph_s, ps_s]}, name='F') 
F.display()

\begin{array}{llcl} F:& W & \longrightarrow & \mathcal{M} \\ & \left(t, r\right) & \longmapsto & \left(t, r, {\mu}, {\phi}, {\psi}\right) = \left(t, r, a^{2} \mu_{1}\left(r\right) + {\mu_0}, a {\beta_1} {\ell}^{2} t + a {\beta_1} \phi_{1}\left(r\right) + {\Phi_0}, a {\beta_2} {\ell}^{2} t + a {\beta_2} \psi_{1}\left(r\right) + {\Psi_0}\right) \end{array}

In [31]:

F.jacobian_matrix()

\left(\begin{array}{rr} 1 & 0 \\ 0 & 1 \\ 0 & a^{2} \frac{\partial}{\partial r}\mu_{1}\left(r\right) \\ a {\beta_1} {\ell}^{2} & a {\beta_1} \frac{\partial}{\partial r}\phi_{1}\left(r\right) \\ a {\beta_2} {\ell}^{2} & a {\beta_2} \frac{\partial}{\partial r}\psi_{1}\left(r\right) \end{array}\right)

Induced metric on the string worldsheet

The string worldsheet metric is the metric $g$ induced by the spacetime metric $G$ , i.e. the pullback of $G$ by the embedding $F$ :

In [32]:

g = W.metric()
g.set(F.pullback(G))

In [33]:

g[0,0]

\frac{{\left({\mu_0}^{4} + {\mu_0}^{2}\right)} a^{4} {\ell}^{2} + {\left({\left({\mu_0}^{4} - {\mu_0}^{2}\right)} a^{8} {\beta_1}^{2} + 2 \, {\left({\mu_0}^{4} - {\mu_0}^{2}\right)} a^{8} {\beta_1} + {\left({\mu_0}^{4} - {\mu_0}^{2}\right)} a^{8}\right)} {\ell}^{6} - {\left({\left({\mu_0}^{4} - {\mu_0}^{2}\right)} a^{6} {\beta_1}^{2} + 2 \, {\left({\mu_0}^{4} - {\mu_0}^{2}\right)} a^{6} {\beta_1} + {\left(2 \, {\mu_0}^{4} - {\mu_0}^{2}\right)} a^{6}\right)} {\ell}^{4} + {\left({\mu_0}^{2} a^{6} {\beta_2}^{2} {\ell}^{8} - {\left(2 \, {\mu_0}^{2} a^{4} {\beta_2}^{2} - {\left({\mu_0}^{2} - 1\right)} a^{4} {\beta_1}^{2} - 2 \, {\left({\mu_0}^{2} - 1\right)} a^{4} {\beta_1} + a^{4}\right)} {\ell}^{6} + {\left({\mu_0}^{2} a^{2} {\beta_2}^{2} - {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} - 2 \, {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1} + 2 \, a^{2}\right)} {\ell}^{4} - {\ell}^{2}\right)} r^{4} + {\left(2 \, a^{12} {\beta_1}^{2} {\ell}^{4} m + a^{12} {\ell}^{2} + {\left(a^{16} {\beta_1}^{2} + 2 \, a^{16} {\beta_1} + a^{16}\right)} {\ell}^{6} - {\left(a^{14} {\beta_1}^{2} + 2 \, a^{14} {\beta_1} + 2 \, a^{14}\right)} {\ell}^{4} + {\left(a^{16} {\beta_2}^{2} {\ell}^{8} + {\left(a^{14} {\beta_1}^{2} - 2 \, a^{14} {\beta_2}^{2} + 2 \, a^{14} {\beta_1}\right)} {\ell}^{6} - {\left(a^{12} {\beta_1}^{2} - a^{12} {\beta_2}^{2} + 2 \, a^{12} {\beta_1}\right)} {\ell}^{4}\right)} r^{2}\right)} \mu_{1}\left(r\right)^{4} - {\mu_0}^{2} a^{2} + 4 \, {\left(2 \, {\mu_0} a^{10} {\beta_1}^{2} {\ell}^{4} m + {\mu_0} a^{10} {\ell}^{2} + {\left({\mu_0} a^{14} {\beta_1}^{2} + 2 \, {\mu_0} a^{14} {\beta_1} + {\mu_0} a^{14}\right)} {\ell}^{6} - {\left({\mu_0} a^{12} {\beta_1}^{2} + 2 \, {\mu_0} a^{12} {\beta_1} + 2 \, {\mu_0} a^{12}\right)} {\ell}^{4} + {\left({\mu_0} a^{14} {\beta_2}^{2} {\ell}^{8} + {\left({\mu_0} a^{12} {\beta_1}^{2} - 2 \, {\mu_0} a^{12} {\beta_2}^{2} + 2 \, {\mu_0} a^{12} {\beta_1}\right)} {\ell}^{6} - {\left({\mu_0} a^{10} {\beta_1}^{2} - {\mu_0} a^{10} {\beta_2}^{2} + 2 \, {\mu_0} a^{10} {\beta_1}\right)} {\ell}^{4}\right)} r^{2}\right)} \mu_{1}\left(r\right)^{3} + {\left({\mu_0}^{4} a^{8} {\beta_2}^{2} {\ell}^{8} - {\left(2 \, {\mu_0}^{4} a^{6} {\beta_2}^{2} - {\left({\mu_0}^{4} - 1\right)} a^{6} {\beta_1}^{2} - 2 \, {\left({\mu_0}^{4} - 1\right)} a^{6} {\beta_1} + a^{6}\right)} {\ell}^{6} + {\left({\mu_0}^{4} a^{4} {\beta_2}^{2} - {\left({\mu_0}^{4} - 1\right)} a^{4} {\beta_1}^{2} - 2 \, {\left({\mu_0}^{4} - 1\right)} a^{4} {\beta_1} + a^{4}\right)} {\ell}^{4} + a^{2} {\ell}^{2} - 1\right)} r^{2} + {\left({\left(6 \, {\mu_0}^{2} + 1\right)} a^{8} {\ell}^{2} + {\left({\left(6 \, {\mu_0}^{2} - 1\right)} a^{12} {\beta_1}^{2} + 2 \, {\left(6 \, {\mu_0}^{2} - 1\right)} a^{12} {\beta_1} + {\left(6 \, {\mu_0}^{2} - 1\right)} a^{12}\right)} {\ell}^{6} - a^{6} - {\left({\left(6 \, {\mu_0}^{2} - 1\right)} a^{10} {\beta_1}^{2} + 2 \, {\left(6 \, {\mu_0}^{2} - 1\right)} a^{10} {\beta_1} + {\left(12 \, {\mu_0}^{2} - 1\right)} a^{10}\right)} {\ell}^{4} + {\left(a^{10} {\beta_2}^{2} {\ell}^{8} + {\left(a^{8} {\beta_1}^{2} - 2 \, a^{8} {\beta_2}^{2} + 2 \, a^{8} {\beta_1}\right)} {\ell}^{6} - {\left(a^{6} {\beta_1}^{2} - a^{6} {\beta_2}^{2} + 2 \, a^{6} {\beta_1}\right)} {\ell}^{4}\right)} r^{4} + 6 \, {\left({\mu_0}^{2} a^{12} {\beta_2}^{2} {\ell}^{8} + {\left({\mu_0}^{2} a^{10} {\beta_1}^{2} - 2 \, {\mu_0}^{2} a^{10} {\beta_2}^{2} + 2 \, {\mu_0}^{2} a^{10} {\beta_1}\right)} {\ell}^{6} - {\left({\mu_0}^{2} a^{8} {\beta_1}^{2} - {\mu_0}^{2} a^{8} {\beta_2}^{2} + 2 \, {\mu_0}^{2} a^{8} {\beta_1}\right)} {\ell}^{4}\right)} r^{2} + 4 \, {\left(a^{6} {\beta_1} {\ell}^{2} + {\left({\left(3 \, {\mu_0}^{2} - 1\right)} a^{8} {\beta_1}^{2} - a^{8} {\beta_1}\right)} {\ell}^{4}\right)} m\right)} \mu_{1}\left(r\right)^{2} + 2 \, {\left({\left({\left({\mu_0}^{4} - 2 \, {\mu_0}^{2} + 1\right)} a^{4} {\beta_1}^{2} - 2 \, {\left({\mu_0}^{2} - 1\right)} a^{4} {\beta_1} + a^{4}\right)} {\ell}^{4} + 2 \, {\left({\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1} - a^{2}\right)} {\ell}^{2} + 1\right)} m + 2 \, {\left({\left(2 \, {\mu_0}^{3} + {\mu_0}\right)} a^{6} {\ell}^{2} + {\left({\left(2 \, {\mu_0}^{3} - {\mu_0}\right)} a^{10} {\beta_1}^{2} + 2 \, {\left(2 \, {\mu_0}^{3} - {\mu_0}\right)} a^{10} {\beta_1} + {\left(2 \, {\mu_0}^{3} - {\mu_0}\right)} a^{10}\right)} {\ell}^{6} - {\mu_0} a^{4} - {\left({\left(2 \, {\mu_0}^{3} - {\mu_0}\right)} a^{8} {\beta_1}^{2} + 2 \, {\left(2 \, {\mu_0}^{3} - {\mu_0}\right)} a^{8} {\beta_1} + {\left(4 \, {\mu_0}^{3} - {\mu_0}\right)} a^{8}\right)} {\ell}^{4} + {\left({\mu_0} a^{8} {\beta_2}^{2} {\ell}^{8} + {\left({\mu_0} a^{6} {\beta_1}^{2} - 2 \, {\mu_0} a^{6} {\beta_2}^{2} + 2 \, {\mu_0} a^{6} {\beta_1}\right)} {\ell}^{6} - {\left({\mu_0} a^{4} {\beta_1}^{2} - {\mu_0} a^{4} {\beta_2}^{2} + 2 \, {\mu_0} a^{4} {\beta_1}\right)} {\ell}^{4}\right)} r^{4} + 2 \, {\left({\mu_0}^{3} a^{10} {\beta_2}^{2} {\ell}^{8} + {\left({\mu_0}^{3} a^{8} {\beta_1}^{2} - 2 \, {\mu_0}^{3} a^{8} {\beta_2}^{2} + 2 \, {\mu_0}^{3} a^{8} {\beta_1}\right)} {\ell}^{6} - {\left({\mu_0}^{3} a^{6} {\beta_1}^{2} - {\mu_0}^{3} a^{6} {\beta_2}^{2} + 2 \, {\mu_0}^{3} a^{6} {\beta_1}\right)} {\ell}^{4}\right)} r^{2} + 4 \, {\left({\mu_0} a^{4} {\beta_1} {\ell}^{2} + {\left({\left({\mu_0}^{3} - {\mu_0}\right)} a^{6} {\beta_1}^{2} - {\mu_0} a^{6} {\beta_1}\right)} {\ell}^{4}\right)} m\right)} \mu_{1}\left(r\right)}{{\mu_0}^{2} a^{6} {\ell}^{4} - 2 \, {\mu_0}^{2} a^{4} {\ell}^{2} + {\mu_0}^{2} a^{2} + {\left(a^{4} {\ell}^{4} - 2 \, a^{2} {\ell}^{2} + 1\right)} r^{2} + {\left(a^{10} {\ell}^{4} - 2 \, a^{8} {\ell}^{2} + a^{6}\right)} \mu_{1}\left(r\right)^{2} + 2 \, {\left({\mu_0} a^{8} {\ell}^{4} - 2 \, {\mu_0} a^{6} {\ell}^{2} + {\mu_0} a^{4}\right)} \mu_{1}\left(r\right)}

In [34]:

# g[0,0].expr().factor()

Reduced form of $g_{tr}$ :

In [35]:

if b == 0 and not keep_Delta:
    gtr = a^2*sinth2/(rho2*Xi_a^2)*(beta1*Xi_a*(Delta_r - Delta_th*(r^2 + a^2)) \
                                    + beta1^2*l^2*(Delta_th*(r^2 + a^2)^2 
                                                   - a^2*Delta_r*sinth2)) \
                                  * diff(phi_1(r), r) \
          + a^2*l^2*beta2^2*r^2*costh2 * diff(psi_1(r), r)
    gtr = gtr.subs({mu: mu_s, ph: ph_s, ps: ps_s})
    print(g[0,1] == gtr)

True

Reduced form of $g_{tt}$ :

In [36]:

if b == 0 and not keep_Delta:
    gtt = (a^2*Delta_th*sinth2 - Delta_r)/rho2 \
          + (2*beta1*a^2*l^2*sinth2*(Delta_r - Delta_th*(r^2 + a^2)))/(rho2*Xi_a) \
          + beta1^2*a^2*l^4*sinth2/(rho2*Xi_a^2)*(Delta_th*(r^2 + a^2)^2 - a^2*Delta_r*sinth2) \
          + beta2^2*a^2*l^4*r^2*costh2
    gtt = gtt.subs({mu: mu_s, ph: ph_s, ps: ps_s})
    print(g[0,0] == gtt)

True

Reduced form of $g_{rr}$ :

In [37]:

if b == 0 and not keep_Delta:
    grr = rho2/Delta_r + a^2*beta1^2*sinth2/(Xi_a^2*rho2)*(Delta_th*(r^2 + a^2)^2
                                          - Delta_r*a^2*sinth2)*diff(phi_1(r), r)^2 \
          + a^4*rho2/Delta_th/sinth2*diff(mu_1(r), r)^2 \
          + beta2^2*a^2*r^2*costh2*diff(psi_1(r), r)^2
    grr = grr.subs({mu: mu_s, ph: ph_s, ps: ps_s})
    print(g[1,1] == grr)

True

Nambu-Goto action

In [38]:

detg = g.determinant().expr()

Expanding at second order in $a$ :

In [39]:

detg_a2 = detg.series(a, 3).truncate().simplify_full()
detg_a2

\frac{{\left({\left({\mu_0}^{2} a^{2} {\beta_2}^{2} - {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} - 2 \, {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}\right)} {\ell}^{4} - {\ell}^{2}\right)} r^{4} - {\left({\mu_0}^{2} - 1\right)} a^{2} + {\left({\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} {\ell}^{4} r^{8} + 2 \, {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} {\ell}^{2} r^{6} - 4 \, {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} m r^{2} + 4 \, {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} m^{2} - {\left(4 \, {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} {\ell}^{2} m - {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2}\right)} r^{4}\right)} \frac{\partial}{\partial r}\phi_{1}\left(r\right)^{2} - {\left({\mu_0}^{2} a^{2} {\beta_2}^{2} {\ell}^{4} r^{8} + 2 \, {\mu_0}^{2} a^{2} {\beta_2}^{2} {\ell}^{2} r^{6} - 4 \, {\mu_0}^{2} a^{2} {\beta_2}^{2} m r^{2} + 4 \, {\mu_0}^{2} a^{2} {\beta_2}^{2} m^{2} - {\left(4 \, {\mu_0}^{2} a^{2} {\beta_2}^{2} {\ell}^{2} m - {\mu_0}^{2} a^{2} {\beta_2}^{2}\right)} r^{4}\right)} \frac{\partial}{\partial r}\psi_{1}\left(r\right)^{2} + 2 \, {\left(2 \, {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1} {\ell}^{2} + 1\right)} m - r^{2}}{{\ell}^{2} r^{4} + r^{2} - 2 \, m}

The Nambu-Goto Lagrangian at second order in $a$ :

In [40]:

L_a2 = (sqrt(-detg_a2)).series(a, 3).truncate().simplify_full()
L_a2

-\frac{{\left({\left({\mu_0}^{2} a^{2} {\beta_2}^{2} - {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} - 2 \, {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}\right)} {\ell}^{4} - 2 \, {\ell}^{2}\right)} r^{4} - {\left({\mu_0}^{2} - 1\right)} a^{2} + {\left({\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} {\ell}^{4} r^{8} + 2 \, {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} {\ell}^{2} r^{6} - 4 \, {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} m r^{2} + 4 \, {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} m^{2} - {\left(4 \, {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} {\ell}^{2} m - {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2}\right)} r^{4}\right)} \frac{\partial}{\partial r}\phi_{1}\left(r\right)^{2} - {\left({\mu_0}^{2} a^{2} {\beta_2}^{2} {\ell}^{4} r^{8} + 2 \, {\mu_0}^{2} a^{2} {\beta_2}^{2} {\ell}^{2} r^{6} - 4 \, {\mu_0}^{2} a^{2} {\beta_2}^{2} m r^{2} + 4 \, {\mu_0}^{2} a^{2} {\beta_2}^{2} m^{2} - {\left(4 \, {\mu_0}^{2} a^{2} {\beta_2}^{2} {\ell}^{2} m - {\mu_0}^{2} a^{2} {\beta_2}^{2}\right)} r^{4}\right)} \frac{\partial}{\partial r}\psi_{1}\left(r\right)^{2} + 4 \, {\left({\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1} {\ell}^{2} + 1\right)} m - 2 \, r^{2}}{2 \, {\left({\ell}^{2} r^{4} + r^{2} - 2 \, m\right)}}

In [41]:

L_a2.numerator()

-{\mu_0}^{2} a^{2} {\beta_1}^{2} {\ell}^{4} r^{8} \frac{\partial}{\partial r}\phi_{1}\left(r\right)^{2} + {\mu_0}^{2} a^{2} {\beta_2}^{2} {\ell}^{4} r^{8} \frac{\partial}{\partial r}\psi_{1}\left(r\right)^{2} + a^{2} {\beta_1}^{2} {\ell}^{4} r^{8} \frac{\partial}{\partial r}\phi_{1}\left(r\right)^{2} - 2 \, {\mu_0}^{2} a^{2} {\beta_1}^{2} {\ell}^{2} r^{6} \frac{\partial}{\partial r}\phi_{1}\left(r\right)^{2} + 2 \, {\mu_0}^{2} a^{2} {\beta_2}^{2} {\ell}^{2} r^{6} \frac{\partial}{\partial r}\psi_{1}\left(r\right)^{2} + 4 \, {\mu_0}^{2} a^{2} {\beta_1}^{2} {\ell}^{2} m r^{4} \frac{\part