SharedLifshitz_black_brane.ipynbOpen in CoCalc
Authors: agolubtsova , Eric Gourgoulhon
Views : 20
Description: Jupyter notebook Lifshitz_black_brane.ipynb

Black branes in Lifshitz-like spacetimes

This Jupyter/SageMath worksheet implements some computations of the article

  • I. Ya. Aref'eva, A. A. Golubtsova & E. Gourgoulhon: Analytic black branes in Lifshitz-like backgrounds and thermalization, arXiv:1601.06046

These computations are based on SageManifolds (v0.9)

The worksheet file (ipynb format) can be downloaded from here.

Content

  1. Five-dimensional Lifschitz-like spacetime
  2. Black brane solution

First we set up the notebook to display mathematical objects using LaTeX formatting:

In [1]:
%display latex

1. Five-dimensional Lifshitz-like spacetime

Let us declare the spacetime MM as a 5-dimensional manifold:

In [2]:
M = Manifold(5, 'M') print M
5-dimensional differentiable manifold M

We introduce a first coordinate system on MM:

In [3]:
X0.<t,x,y1,y2,R> = M.chart(r't x y1:y_1 y2:y_2 R:\tilde{r}:(0,+oo)') X0
(M,(t,x,y1,y2,r~))\left(M,(t, x, {y_1}, {y_2}, {\tilde{r}})\right)

Let us consider the following Lifshitz-symmetric metric, parametrized by some real number ν\nu:

In [ ]:
In [ ]:
In [4]:
g = M.lorentzian_metric('g') var('nu', latex_name=r'\nu', domain='real') g[0,0] = -R^(2*nu) g[1,1] = R^(2*nu) g[2,2] = R^2 g[3,3] = R^2 g[4,4] = 1/R^2 g.display()
g=r~2νdtdt+r~2νdxdx+r~2dy1dy1+r~2dy2dy2+1r~2dr~dr~g = -{\tilde{r}}^{2 \, {\nu}} \mathrm{d} t\otimes \mathrm{d} t + {\tilde{r}}^{2 \, {\nu}} \mathrm{d} x\otimes \mathrm{d} x + {\tilde{r}}^{2} \mathrm{d} {y_1}\otimes \mathrm{d} {y_1} + {\tilde{r}}^{2} \mathrm{d} {y_2}\otimes \mathrm{d} {y_2} + \frac{1}{{\tilde{r}}^{2}} \mathrm{d} {\tilde{r}}\otimes \mathrm{d} {\tilde{r}}

A matrix view of the metric components:

In [5]:
g[:]
(r~2ν00000r~2ν00000r~200000r~2000001r~2)\left(\begin{array}{rrrrr} -{\tilde{r}}^{2 \, {\nu}} & 0 & 0 & 0 & 0 \\ 0 & {\tilde{r}}^{2 \, {\nu}} & 0 & 0 & 0 \\ 0 & 0 & {\tilde{r}}^{2} & 0 & 0 \\ 0 & 0 & 0 & {\tilde{r}}^{2} & 0 \\ 0 & 0 & 0 & 0 & \frac{1}{{\tilde{r}}^{2}} \end{array}\right)

This metric is invariant under the Lifshitz scaling (t,x,y1,y2,r~)(λνt,λνx,λy1,λy2,r~λ) (t,x,y_1,y_2,\tilde r) \longmapsto \left(\lambda^\nu t, \lambda^\nu x, \lambda y_1, \lambda y_2, \frac{\tilde r}{\lambda} \right)

  • If ν=1\nu=1 the scaling is isotropic and we recognize the metric of AdS5\mathrm{AdS}_5 in Poincaré coordinates (MM is then the Poincaré patch of AdS5\mathrm{AdS}_5)
  • If ν1\nu\not=1, the scaling is anisotropic

Let us introduce a second coordinate system on MM:

In [6]:
X.<t,x,y1,y2,r> = M.chart('t x y1:y_1 y2:y_2 r') X
(M,(t,x,y1,y2,r))\left(M,(t, x, {y_1}, {y_2}, r)\right)

and relate it to the previous one by the transformation r=lnr~r=\ln\tilde r:

In [7]:
X0_to_X = X0.transition_map(X, [t, x, y1, y2, ln(R)]) X0_to_X.display()
{t=tx=xy1=y1y2=y2r=log(r~)\left\{\begin{array}{lcl} t & = & t \\ x & = & x \\ {y_1} & = & {y_1} \\ {y_2} & = & {y_2} \\ r & = & \log\left({\tilde{r}}\right) \end{array}\right.

The inverse coordinate transition is computed by means of the method inverse():

In [8]:
X_to_X0 = X0_to_X.inverse() X_to_X0.display()
{t=tx=xy1=y1y2=y2r~=er\left\{\begin{array}{lcl} t & = & t \\ x & = & x \\ {y_1} & = & {y_1} \\ {y_2} & = & {y_2} \\ {\tilde{r}} & = & e^{r} \end{array}\right.

At this stage, the manifold's atlas defined by the user is

In [9]:
M.atlas()
[(M,(t,x,y1,y2,r~)),(M,(t,x,y1,y2,r))]\left[\left(M,(t, x, {y_1}, {y_2}, {\tilde{r}})\right), \left(M,(t, x, {y_1}, {y_2}, r)\right)\right]

and the list of defined vector frames defined is

In [10]:
M.frames()
[(M,(t,x,y1,y2,r~)),(M,(t,x,y1,y2,r))]\left[\left(M, \left(\frac{\partial}{\partial t },\frac{\partial}{\partial x },\frac{\partial}{\partial {y_1} },\frac{\partial}{\partial {y_2} },\frac{\partial}{\partial {\tilde{r}} }\right)\right), \left(M, \left(\frac{\partial}{\partial t },\frac{\partial}{\partial x },\frac{\partial}{\partial {y_1} },\frac{\partial}{\partial {y_2} },\frac{\partial}{\partial r }\right)\right)\right]

The expression of the metric in terms of the new coordinates is

In [11]:
g.display(X.frame(), X)
g=e(2νr)dtdt+e(2νr)dxdx+e(2r)dy1dy1+e(2r)dy2dy2+drdrg = -e^{\left(2 \, {\nu} r\right)} \mathrm{d} t\otimes \mathrm{d} t + e^{\left(2 \, {\nu} r\right)} \mathrm{d} x\otimes \mathrm{d} x + e^{\left(2 \, r\right)} \mathrm{d} {y_1}\otimes \mathrm{d} {y_1} + e^{\left(2 \, r\right)} \mathrm{d} {y_2}\otimes \mathrm{d} {y_2} +\mathrm{d} r\otimes \mathrm{d} r

or, in matrix view:

In [12]:
g[X.frame(),:,X]
(e(2νr)00000e(2νr)00000e(2r)00000e(2r)000001)\left(\begin{array}{rrrrr} -e^{\left(2 \, {\nu} r\right)} & 0 & 0 & 0 & 0 \\ 0 & e^{\left(2 \, {\nu} r\right)} & 0 & 0 & 0 \\ 0 & 0 & e^{\left(2 \, r\right)} & 0 & 0 \\ 0 & 0 & 0 & e^{\left(2 \, r\right)} & 0 \\ 0 & 0 & 0 & 0 & 1 \end{array}\right)

To access to a particular component, we have to specify (i) the frame w.r.t. which it is defined and (ii) the coordinates in which the component is expressed:

In [13]:
g[X.frame(),0,0,X]
e(2νr)-e^{\left(2 \, {\nu} r\right)}
In [14]:
g[X.frame(),0,0] # the default chart is used
r~2ν-{\tilde{r}}^{2 \, {\nu}}

From now on, let us consider the coordinates X=(t,x,y1,y2,r)X = (t,x,y_1,y_2,r) as the default ones on the manifold MM:

In [15]:
M.set_default_chart(X) M.set_default_frame(X.frame())

Then

In [16]:
g.display()
g=e(2νr)dtdt+e(2νr)dxdx+e(2r)dy1dy1+e(2r)dy2dy2+drdrg = -e^{\left(2 \, {\nu} r\right)} \mathrm{d} t\otimes \mathrm{d} t + e^{\left(2 \, {\nu} r\right)} \mathrm{d} x\otimes \mathrm{d} x + e^{\left(2 \, r\right)} \mathrm{d} {y_1}\otimes \mathrm{d} {y_1} + e^{\left(2 \, r\right)} \mathrm{d} {y_2}\otimes \mathrm{d} {y_2} +\mathrm{d} r\otimes \mathrm{d} r
In [17]:
g[:]
(e(2νr)00000e(2νr)00000e(2r)00000e(2r)000001)\left(\begin{array}{rrrrr} -e^{\left(2 \, {\nu} r\right)} & 0 & 0 & 0 & 0 \\ 0 & e^{\left(2 \, {\nu} r\right)} & 0 & 0 & 0 \\ 0 & 0 & e^{\left(2 \, r\right)} & 0 & 0 \\ 0 & 0 & 0 & e^{\left(2 \, r\right)} & 0 \\ 0 & 0 & 0 & 0 & 1 \end{array}\right)
In [18]:
g[0,0]
e(2νr)-e^{\left(2 \, {\nu} r\right)}
In [19]:
g.display_comp()
gtttt=e(2νr)gxxxx=e(2νr)gy1y1y1y1=e(2r)gy2y2y2y2=e(2r)grrrr=1\begin{array}{lcl} g_{ \, t \, t }^{ \phantom{\, t}\phantom{\, t} } & = & -e^{\left(2 \, {\nu} r\right)} \\ g_{ \, x \, x }^{ \phantom{\, x}\phantom{\, x} } & = & e^{\left(2 \, {\nu} r\right)} \\ g_{ \, {y_1} \, {y_1} }^{ \phantom{\, {y_1}}\phantom{\, {y_1}} } & = & e^{\left(2 \, r\right)} \\ g_{ \, {y_2} \, {y_2} }^{ \phantom{\, {y_2}}\phantom{\, {y_2}} } & = & e^{\left(2 \, r\right)} \\ g_{ \, r \, r }^{ \phantom{\, r}\phantom{\, r} } & = & 1 \end{array}

Curvature

The Riemann tensor is

In [20]:
Riem = g.riemann() print Riem
Tensor field Riem(g) of type (1,3) on the 5-dimensional differentiable manifold M
In [21]:
Riem.display_comp(only_nonredundant=True)
Riem(g)txtxtxtx=ν2e(2νr)Riem(g)ty1ty1ty1ty1=νe(2r)Riem(g)ty2ty2ty2ty2=νe(2r)Riem(g)trtrtrtr=ν2Riem(g)xttxxttx=ν2e(2νr)Riem(g)xy1xy1xy1xy1=νe(2r)Riem(g)xy2xy2xy2xy2=νe(2r)Riem(g)xrxrxrxr=ν2Riem(g)y1tty1y1tty1=νe(2νr)Riem(g)y1xxy1y1xxy1=νe(2νr)Riem(g)y1y2y1y2y1y2y1y2=e(2r)Riem(g)y1ry1ry1ry1r=1Riem(g)y2tty2y2tty2=νe(2νr)Riem(g)y2xxy2y2xxy2=νe(2νr)Riem(g)y2y1y1y2y2y1y1y2=e(2r)Riem(g)y2ry2ry2ry2r=1Riem(g)rttrrttr=ν2e(2νr)Riem(g)rxxrrxxr=ν2e(2νr)Riem(g)ry1y1rry1y1r=e(2r)Riem(g)ry2y2rry2y2r=e(2r)\begin{array}{lcl} \mathrm{Riem}\left(g\right)_{ \phantom{\, t} \, x \, t \, x }^{ \, t \phantom{\, x} \phantom{\, t} \phantom{\, x} } & = & -{\nu}^{2} e^{\left(2 \, {\nu} r\right)} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, t} \, {y_1} \, t \, {y_1} }^{ \, t \phantom{\, {y_1}} \phantom{\, t} \phantom{\, {y_1}} } & = & -{\nu} e^{\left(2 \, r\right)} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, t} \, {y_2} \, t \, {y_2} }^{ \, t \phantom{\, {y_2}} \phantom{\, t} \phantom{\, {y_2}} } & = & -{\nu} e^{\left(2 \, r\right)} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, t} \, r \, t \, r }^{ \, t \phantom{\, r} \phantom{\, t} \phantom{\, r} } & = & -{\nu}^{2} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, x} \, t \, t \, x }^{ \, x \phantom{\, t} \phantom{\, t} \phantom{\, x} } & = & -{\nu}^{2} e^{\left(2 \, {\nu} r\right)} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, x} \, {y_1} \, x \, {y_1} }^{ \, x \phantom{\, {y_1}} \phantom{\, x} \phantom{\, {y_1}} } & = & -{\nu} e^{\left(2 \, r\right)} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, x} \, {y_2} \, x \, {y_2} }^{ \, x \phantom{\, {y_2}} \phantom{\, x} \phantom{\, {y_2}} } & = & -{\nu} e^{\left(2 \, r\right)} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, x} \, r \, x \, r }^{ \, x \phantom{\, r} \phantom{\, x} \phantom{\, r} } & = & -{\nu}^{2} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, {y_1}} \, t \, t \, {y_1} }^{ \, {y_1} \phantom{\, t} \phantom{\, t} \phantom{\, {y_1}} } & = & -{\nu} e^{\left(2 \, {\nu} r\right)} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, {y_1}} \, x \, x \, {y_1} }^{ \, {y_1} \phantom{\, x} \phantom{\, x} \phantom{\, {y_1}} } & = & {\nu} e^{\left(2 \, {\nu} r\right)} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, {y_1}} \, {y_2} \, {y_1} \, {y_2} }^{ \, {y_1} \phantom{\, {y_2}} \phantom{\, {y_1}} \phantom{\, {y_2}} } & = & -e^{\left(2 \, r\right)} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, {y_1}} \, r \, {y_1} \, r }^{ \, {y_1} \phantom{\, r} \phantom{\, {y_1}} \phantom{\, r} } & = & -1 \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, {y_2}} \, t \, t \, {y_2} }^{ \, {y_2} \phantom{\, t} \phantom{\, t} \phantom{\, {y_2}} } & = & -{\nu} e^{\left(2 \, {\nu} r\right)} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, {y_2}} \, x \, x \, {y_2} }^{ \, {y_2} \phantom{\, x} \phantom{\, x} \phantom{\, {y_2}} } & = & {\nu} e^{\left(2 \, {\nu} r\right)} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, {y_2}} \, {y_1} \, {y_1} \, {y_2} }^{ \, {y_2} \phantom{\, {y_1}} \phantom{\, {y_1}} \phantom{\, {y_2}} } & = & e^{\left(2 \, r\right)} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, {y_2}} \, r \, {y_2} \, r }^{ \, {y_2} \phantom{\, r} \phantom{\, {y_2}} \phantom{\, r} } & = & -1 \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, r} \, t \, t \, r }^{ \, r \phantom{\, t} \phantom{\, t} \phantom{\, r} } & = & -{\nu}^{2} e^{\left(2 \, {\nu} r\right)} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, r} \, x \, x \, r }^{ \, r \phantom{\, x} \phantom{\, x} \phantom{\, r} } & = & {\nu}^{2} e^{\left(2 \, {\nu} r\right)} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, r} \, {y_1} \, {y_1} \, r }^{ \, r \phantom{\, {y_1}} \phantom{\, {y_1}} \phantom{\, r} } & = & e^{\left(2 \, r\right)} \\ \mathrm{Riem}\left(g\right)_{ \phantom{\, r} \, {y_2} \, {y_2} \, r }^{ \, r \phantom{\, {y_2}} \phantom{\, {y_2}} \phantom{\, r} } & = & e^{\left(2 \, r\right)} \end{array}

The Ricci tensor:

In [22]:
Ric = g.ricci() print Ric
Field of symmetric bilinear forms Ric(g) on the 5-dimensional differentiable manifold M
In [23]:
Ric.display()
Ric(g)=2(ν2+ν)e(2νr)dtdt2(ν2+ν)e(2νr)dxdx2(ν+1)e(2r)dy1dy12(ν+1)e(2r)dy2dy2+(2ν22)drdr\mathrm{Ric}\left(g\right) = 2 \, {\left({\nu}^{2} + {\nu}\right)} e^{\left(2 \, {\nu} r\right)} \mathrm{d} t\otimes \mathrm{d} t -2 \, {\left({\nu}^{2} + {\nu}\right)} e^{\left(2 \, {\nu} r\right)} \mathrm{d} x\otimes \mathrm{d} x -2 \, {\left({\nu} + 1\right)} e^{\left(2 \, r\right)} \mathrm{d} {y_1}\otimes \mathrm{d} {y_1} -2 \, {\left({\nu} + 1\right)} e^{\left(2 \, r\right)} \mathrm{d} {y_2}\otimes \mathrm{d} {y_2} + \left( -2 \, {\nu}^{2} - 2 \right) \mathrm{d} r\otimes \mathrm{d} r
In [24]:
Ric.display_comp()
Ric(g)tttt=2(ν2+ν)e(2νr)Ric(g)xxxx=2(ν2+ν)e(2νr)Ric(g)y1y1y1y1=2(ν+1)e(2r)Ric(g)y2y2y2y2=2(ν+1)e(2r)Ric(g)rrrr=2ν22\begin{array}{lcl} \mathrm{Ric}\left(g\right)_{ \, t \, t }^{ \phantom{\, t}\phantom{\, t} } & = & 2 \, {\left({\nu}^{2} + {\nu}\right)} e^{\left(2 \, {\nu} r\right)} \\ \mathrm{Ric}\left(g\right)_{ \, x \, x }^{ \phantom{\, x}\phantom{\, x} } & = & -2 \, {\left({\nu}^{2} + {\nu}\right)} e^{\left(2 \, {\nu} r\right)} \\ \mathrm{Ric}\left(g\right)_{ \, {y_1} \, {y_1} }^{ \phantom{\, {y_1}}\phantom{\, {y_1}} } & = & -2 \, {\left({\nu} + 1\right)} e^{\left(2 \, r\right)} \\ \mathrm{Ric}\left(g\right)_{ \, {y_2} \, {y_2} }^{ \phantom{\, {y_2}}\phantom{\, {y_2}} } & = & -2 \, {\left({\nu} + 1\right)} e^{\left(2 \, r\right)} \\ \mathrm{Ric}\left(g\right)_{ \, r \, r }^{ \phantom{\, r}\phantom{\, r} } & = & -2 \, {\nu}^{2} - 2 \end{array}

The Ricci scalar:

In [25]:
Rscal = g.ricci_scalar() print Rscal
Scalar field r(g) on the 5-dimensional differentiable manifold M
In [26]:
Rscal.display()
r(g):MR(t,x,y1,y2,r~)6ν28ν6(t,x,y1,y2,r)6ν28ν6\begin{array}{llcl} \mathrm{r}\left(g\right):& M & \longrightarrow & \mathbb{R} \\ & \left(t, x, {y_1}, {y_2}, {\tilde{r}}\right) & \longmapsto & -6 \, {\nu}^{2} - 8 \, {\nu} - 6 \\ & \left(t, x, {y_1}, {y_2}, r\right) & \longmapsto & -6 \, {\nu}^{2} - 8 \, {\nu} - 6 \end{array}

We note that the Ricci scalar is constant.

Source model

Let us consider a model based on the following action, involving a dilaton scalar field ϕ\phi and a Maxwell 2-form FF:

where R(g)R(g) is the Ricci scalar of metric gg, Λ\Lambda is the cosmological constant and λ\lambda is the dilatonic coupling constant.

The dilaton scalar field

We consider the following ansatz for the dilaton scalar field ϕ\phi: ϕ=1λ(4r+lnμ), \phi = \frac{1}{\lambda} \left( 4 r + \ln\mu \right), where μ\mu is a constant.

In [27]:
var('mu', latex_name=r'\mu', domain='real') var('lamb', latex_name=r'\lambda', domain='real') phi = M.scalar_field({X: (4*r + ln(mu))/lamb}, name='phi', latex_name=r'\phi') phi.display()
ϕ:MR(t,x,y1,y2,r~)4log(r~)+log(μ)λ(t,x,y1,y2,r)4r+log(μ)λ\begin{array}{llcl} \phi:& M & \longrightarrow & \mathbb{R} \\ & \left(t, x, {y_1}, {y_2}, {\tilde{r}}\right) & \longmapsto & \frac{4 \, \log\left({\tilde{r}}\right) + \log\left({\mu}\right)}{{\lambda}} \\ & \left(t, x, {y_1}, {y_2}, r\right) & \longmapsto & \frac{4 \, r + \log\left({\mu}\right)}{{\lambda}} \end{array}

The 1-form dϕ\mathrm{d}\phi is

In [28]:
dphi = phi.differential() print dphi
1-form dphi on the 5-dimensional differentiable manifold M
In [29]:
dphi.display()
dϕ=4λdr\mathrm{d}\phi = \frac{4}{{\lambda}} \mathrm{d} r
In [30]:
dphi[:] # all the components in the default frame
[0,0,0,0,4λ]\left[0, 0, 0, 0, \frac{4}{{\lambda}}\right]

The 2-form field

We consider the following ansatz for FF: F=12qdy1dy2, F = \frac{1}{2} q \, \mathrm{d}y_1\wedge \mathrm{d}y_2, where qq is a constant.

Let us first get the 1-forms dy1\mathrm{d}y_1 and dy2\mathrm{d}y_2:

In [31]:
X.coframe()
(M,(dt,dx,dy1,dy2,dr))\left(M, \left(\mathrm{d} t,\mathrm{d} x,\mathrm{d} {y_1},\mathrm{d} {y_2},\mathrm{d} r\right)\right)
In [32]:
dy1 = X.coframe()[2] dy2 = X.coframe()[3] print dy1 print dy2 dy1, dy2
1-form dy1 on the 5-dimensional differentiable manifold M 1-form dy2 on the 5-dimensional differentiable manifold M
(dy1,dy2)\left(\mathrm{d} {y_1}, \mathrm{d} {y_2}\right)

Then we can form FF according to the above ansatz:

In [33]:
var('q', domain='real') F = q/2 * dy1.wedge(dy2) F.set_name('F') print F F.display()
2-form F on the 5-dimensional differentiable manifold M
F=12qdy1dy2F = \frac{1}{2} \, q \mathrm{d} {y_1}\wedge \mathrm{d} {y_2}

By construction, the 2-form FF is closed (since qq is constant):

In [34]:
print(F.exterior_derivative())
3-form dF on the 5-dimensional differentiable manifold M
In [35]:
F.exterior_derivative().display()
dF=0\mathrm{d}F = 0

Let us evaluate the square FmnFmnF_{mn} F^{mn} of FF:

In [36]:
Fu = F.up(g) print Fu Fu.display()
Tensor field of type (2,0) on the 5-dimensional differentiable manifold M
12qe(4r)y1y212qe(4r)y2y1\frac{1}{2} \, q e^{\left(-4 \, r\right)} \frac{\partial}{\partial {y_1} }\otimes \frac{\partial}{\partial {y_2} } -\frac{1}{2} \, q e^{\left(-4 \, r\right)} \frac{\partial}{\partial {y_2} }\otimes \frac{\partial}{\partial {y_1} }
In [37]:
F2 = F['_{mn}']*Fu['^{mn}'] # using LaTeX notations to denote contraction print F2 F2.display()
Scalar field on the 5-dimensional differentiable manifold M
MR(t,x,y1,y2,r~)q22r~4(t,x,y1,y2,r)12q2e(4r)\begin{array}{llcl} & M & \longrightarrow & \mathbb{R} \\ & \left(t, x, {y_1}, {y_2}, {\tilde{r}}\right) & \longmapsto & \frac{q^{2}}{2 \, {\tilde{r}}^{4}} \\ & \left(t, x, {y_1}, {y_2}, r\right) & \longmapsto & \frac{1}{2} \, q^{2} e^{\left(-4 \, r\right)} \end{array}

We shall also need the tensor Fmn:=FmpFn p\mathcal{F}_{mn} := F_{mp} F_n^{\ \, p}:

In [38]:
FF = F['_mp'] * F.up(g,1)['^p_n'] print FF FF.display()
Tensor field of type (0,2) on the 5-dimensional differentiable manifold M
14q2e(2r)dy1dy1+14q2e(2r)dy2dy2\frac{1}{4} \, q^{2} e^{\left(-2 \, r\right)} \mathrm{d} {y_1}\otimes \mathrm{d} {y_1} + \frac{1}{4} \, q^{2} e^{\left(-2 \, r\right)} \mathrm{d} {y_2}\otimes \mathrm{d} {y_2}

The tensor field F\mathcal{F} is symmetric:

In [39]:
FF == FF.symmetrize()
True\mathrm{True}

Therefore, from now on, we set

In [40]:
FF = FF.symmetrize()

Einstein equation

Let us first introduce the cosmological constant:

In [41]:
var('Lamb', latex_name=r'\Lambda', domain='real')
Λ{\Lambda}

From the action (1), the field equation for the metric gg is Rmn+Λ3g12mϕnϕ12eλϕFmpFn p+112eλϕFrsFrsgmn=0 R_{mn} + \frac{\Lambda}{3} \, g - \frac{1}{2}\partial_m\phi \partial_n\phi -\frac{1}{2} e^{\lambda\phi} F_{mp} F^{\ \, p}_n + \frac{1}{12} e^{\lambda\phi} F_{rs} F^{rs} \, g_{mn} = 0 We write it as

EE == 0

with EE defined by

In [42]:
EE = Ric + Lamb/3*g - 1/2* (dphi*dphi) - 1/2*exp(lamb*phi)*FF \ + 1/12*exp(lamb*phi)*F2*g EE.set_name('E') print EE
Field of symmetric bilinear forms E on the 5-dimensional differentiable manifold M
In [43]:
EE.display_comp(only_nonredundant=True)
Etttt=124(μq248ν2+8Λ48ν)e(2νr)Exxxx=124(μq248ν2+8Λ48ν)e(2νr)Ey1y1y1y1=112(μq24Λ+24ν+24)e(2r)Ey2y2y2y2=112(μq24Λ+24ν+24)e(2r)Errrr=λ2μq248λ2ν2+8(Λ6)λ219224λ2\begin{array}{lcl} E_{ \, t \, t }^{ \phantom{\, t}\phantom{\, t} } & = & -\frac{1}{24} \, {\left({\mu} q^{2} - 48 \, {\nu}^{2} + 8 \, {\Lambda} - 48 \, {\nu}\right)} e^{\left(2 \, {\nu} r\right)} \\ E_{ \, x \, x }^{ \phantom{\, x}\phantom{\, x} } & = & \frac{1}{24} \, {\left({\mu} q^{2} - 48 \, {\nu}^{2} + 8 \, {\Lambda} - 48 \, {\nu}\right)} e^{\left(2 \, {\nu} r\right)} \\ E_{ \, {y_1} \, {y_1} }^{ \phantom{\, {y_1}}\phantom{\, {y_1}} } & = & -\frac{1}{12} \, {\left({\mu} q^{2} - 4 \, {\Lambda} + 24 \, {\nu} + 24\right)} e^{\left(2 \, r\right)} \\ E_{ \, {y_2} \, {y_2} }^{ \phantom{\, {y_2}}\phantom{\, {y_2}} } & = & -\frac{1}{12} \, {\left({\mu} q^{2} - 4 \, {\Lambda} + 24 \, {\nu} + 24\right)} e^{\left(2 \, r\right)} \\ E_{ \, r \, r }^{ \phantom{\, r}\phantom{\, r} } & = & \frac{{\lambda}^{2} {\mu} q^{2} - 48 \, {\lambda}^{2} {\nu}^{2} + 8 \, {\left({\Lambda} - 6\right)} {\lambda}^{2} - 192}{24 \, {\lambda}^{2}} \end{array}

We note that EE==0 leads to only 3 independent equations:

In [44]:
eq1 = (EE[0,0]/exp(2*nu*r)).expr() eq1
124μq2+2ν213Λ+2ν-\frac{1}{24} \, {\mu} q^{2} + 2 \, {\nu}^{2} - \frac{1}{3} \, {\Lambda} + 2 \, {\nu}
In [45]:
eq2 = (EE[2,2]/exp(2*r)).expr() eq2
112μq2+13Λ2ν2-\frac{1}{12} \, {\mu} q^{2} + \frac{1}{3} \, {\Lambda} - 2 \, {\nu} - 2
In [46]:
eq3 = EE[4,4].expr().expand() eq3
124μq22ν2+13Λ8λ22\frac{1}{24} \, {\mu} q^{2} - 2 \, {\nu}^{2} + \frac{1}{3} \, {\Lambda} - \frac{8}{{\lambda}^{2}} - 2

Dilaton field equation

First we evaluate mmϕ\nabla_m \nabla^m \phi:

In [47]:
nab = g.connection() print nab nab
Levi-Civita connection nabla_g associated with the Lorentzian metric g on the 5-dimensional differentiable manifold M
g\nabla_{g}
In [48]:
box_phi = nab(nab(phi).up(g)).trace() print box_phi box_phi.display()
Scalar field on the 5-dimensional differentiable manifold M
MR(t,x,y1,y2,r~)8(ν+1)λ(t,x,y1,y2,r)8(ν+1)λ\begin{array}{llcl} & M & \longrightarrow & \mathbb{R} \\ & \left(t, x, {y_1}, {y_2}, {\tilde{r}}\right) & \longmapsto & \frac{8 \, {\left({\nu} + 1\right)}}{{\lambda}} \\ & \left(t, x, {y_1}, {y_2}, r\right) & \longmapsto & \frac{8 \, {\left({\nu} + 1\right)}}{{\lambda}} \end{array}

From the action (1), the field equation for ϕ\phi is mmϕ=λ4eλϕFmnFmn \nabla_m \nabla^m \phi = \frac{\lambda}{4} e^{\lambda\phi} F_{mn} F^{mn} We write it as

DE == 0

with DE defined by

In [49]:
DE = box_phi - lamb/4*exp(lamb*phi) * F2 print DE
Scalar field on the 5-dimensional differentiable manifold M
In [50]:
DE.display()
MR(t,x,y1,y2,r~)λ2μq264ν648λ(t,x,y1,y2,r)λ2μq264ν648λ\begin{array}{llcl} & M & \longrightarrow & \mathbb{R} \\ & \left(t, x, {y_1}, {y_2}, {\tilde{r}}\right) & \longmapsto & -\frac{{\lambda}^{2} {\mu} q^{2} - 64 \, {\nu} - 64}{8 \, {\lambda}} \\ & \left(t, x, {y_1}, {y_2}, r\right) & \longmapsto & -\frac{{\lambda}^{2} {\mu} q^{2} - 64 \, {\nu} - 64}{8 \, {\lambda}} \end{array}

Hence the dilaton field equation provides a fourth equation:

In [51]:
eq4 = DE.expr().expand() eq4
18λμq2+8νλ+8λ-\frac{1}{8} \, {\lambda} {\mu} q^{2} + \frac{8 \, {\nu}}{{\lambda}} + \frac{8}{{\lambda}}

Maxwell equation

From the action (1), the field equation for FF is m(eλϕFmn)=0 \nabla_m \left( e^{\lambda\phi} F^{mn} \right)= 0 We write it as

ME == 0

with ME defined by

In [52]:
ME = nab(exp(lamb*phi)*Fu).trace(0,2) print ME ME.display()
Vector field on the 5-dimensional differentiable manifold M
00

We get identically zero; indeed the tensor p(eλϕFmn)\nabla_p (e^{\lambda\phi} F^{mn}) has a vanishing trace, as we can check:

In [53]:
nab(exp(lamb*phi)*Fu).display()
μqy1y2dr12μqe(2r)y1rdy2μqy2y1dr+12μqe(2r)y2rdy1+12μqe(2r)ry1dy212μqe(2r)ry2dy1{\mu} q \frac{\partial}{\partial {y_1} }\otimes \frac{\partial}{\partial {y_2} }\otimes \mathrm{d} r -\frac{1}{2} \, {\mu} q e^{\left(2 \, r\right)} \frac{\partial}{\partial {y_1} }\otimes \frac{\partial}{\partial r }\otimes \mathrm{d} {y_2} -{\mu} q \frac{\partial}{\partial {y_2} }\otimes \frac{\partial}{\partial {y_1} }\otimes \mathrm{d} r + \frac{1}{2} \, {\mu} q e^{\left(2 \, r\right)} \frac{\partial}{\partial {y_2} }\otimes \frac{\partial}{\partial r }\otimes \mathrm{d} {y_1} + \frac{1}{2} \, {\mu} q e^{\left(2 \, r\right)} \frac{\partial}{\partial r }\otimes \frac{\partial}{\partial {y_1} }\otimes \mathrm{d} {y_2} -\frac{1}{2} \, {\mu} q e^{\left(2 \, r\right)} \frac{\partial}{\partial r }\otimes \frac{\partial}{\partial {y_2} }\otimes \mathrm{d} {y_1}

Summary

We have 4 equations involving the constants λ\lambda, μ\mu, ν\nu, qq and Λ\Lambda:

In [54]:
eq1 == 0
124μq2+2ν213Λ+2ν=0-\frac{1}{24} \, {\mu} q^{2} + 2 \, {\nu}^{2} - \frac{1}{3} \, {\Lambda} + 2 \, {\nu} = 0
In [55]:
eq2 == 0
112μq2+13Λ2ν2=0-\frac{1}{12} \, {\mu} q^{2} + \frac{1}{3} \, {\Lambda} - 2 \, {\nu} - 2 = 0
In [56]:
eq3 == 0
124μq22ν2+13Λ8λ22=0\frac{1}{24} \, {\mu} q^{2} - 2 \, {\nu}^{2} + \frac{1}{3} \, {\Lambda} - \frac{8}{{\lambda}^{2}} - 2 = 0
In [57]:
eq4 == 0
18λμq2+8νλ+8λ=0-\frac{1}{8} \, {\lambda} {\mu} q^{2} + \frac{8 \, {\nu}}{{\lambda}} + \frac{8}{{\lambda}} = 0

Solution for ν=1\nu=1 (AdS5\mathrm{AdS}_5)

In [58]:
eqs = [eq1, eq2, eq3, eq4] neqs = [eq.subs(nu=1) for eq in eqs]
In [59]:
[eq == 0 for eq in neqs]
[124μq213Λ+4=0,112μq2+13Λ4=0,124μq2+13Λ8λ24=0,18λμq2+16λ=0]\left[-\frac{1}{24} \, {\mu} q^{2} - \frac{1}{3} \, {\Lambda} + 4 = 0, -\frac{1}{12} \, {\mu} q^{2} + \frac{1}{3} \, {\Lambda} - 4 = 0, \frac{1}{24} \, {\mu} q^{2} + \frac{1}{3} \, {\Lambda} - \frac{8}{{\lambda}^{2}} - 4 = 0, -\frac{1}{8} \, {\lambda} {\mu} q^{2} + \frac{16}{{\lambda}} = 0\right]
In [60]:
solve([eq == 0 for eq in neqs], lamb, mu, Lamb, q)
[]\left[\right]

Hence there is no solution for AdS5\mathrm{AdS}_5 with the above ansatz.

Solution for ν=2\nu = 2

In [61]:
neqs = [eq.subs(nu=2) for eq in eqs] [eq == 0 for eq in neqs]
[124μq213Λ+12=0,112μq2+13Λ6=0,124μq2+13Λ8λ210=0,18λμq2+24λ=0]\left[-\frac{1}{24} \, {\mu} q^{2} - \frac{1}{3} \, {\Lambda} + 12 = 0, -\frac{1}{12} \, {\mu} q^{2} + \frac{1}{3} \, {\Lambda} - 6 = 0, \frac{1}{24} \, {\mu} q^{2} + \frac{1}{3} \, {\Lambda} - \frac{8}{{\lambda}^{2}} - 10 = 0, -\frac{1}{8} \, {\lambda} {\mu} q^{2} + \frac{24}{{\lambda}} = 0\right]
In [62]:
solve([eq == 0 for eq in neqs], lamb, mu, Lamb, q)
[[λ=2,μ=48r12,Λ=30,q=r1],[λ=(2),μ=48r22,Λ=30,q=r2]]\left[\left[{\lambda} = 2, {\mu} = \frac{48}{r_{1}^{2}}, {\Lambda} = 30, q = r_{1}\right], \left[{\lambda} = \left(-2\right), {\mu} = \frac{48}{r_{2}^{2}}, {\Lambda} = 30, q = r_{2}\right]\right]

Hence there are two families of solutions, each famility being parametrized by e.g. qq. Indeed, in the above writing, r1r_1 and r2r_2 stand for arbitrary parameters (nothing to do with the coordinate rr).

Solution for ν=4\nu = 4

In [63]:
neqs = [eq.subs(nu=4) for eq in eqs] [eq == 0 for eq in neqs]
[124μq213Λ+40=0,112μq2+13Λ10=0,124μq2+13Λ8λ234=0,18λμq2+40λ=0]\left[-\frac{1}{24} \, {\mu} q^{2} - \frac{1}{3} \, {\Lambda} + 40 = 0, -\frac{1}{12} \, {\mu} q^{2} + \frac{1}{3} \, {\Lambda} - 10 = 0, \frac{1}{24} \, {\mu} q^{2} + \frac{1}{3} \, {\Lambda} - \frac{8}{{\lambda}^{2}} - 34 = 0, -\frac{1}{8} \, {\lambda} {\mu} q^{2} + \frac{40}{{\lambda}} = 0\right]
In [64]:
solve([eq == 0 for eq in neqs], lamb, mu, Lamb, q)
[[λ=233,μ=240r32,Λ=90,q=r3],[λ=233,μ=240r42,Λ=90,q=r4]]\left[\left[{\lambda} = \frac{2}{3} \, \sqrt{3}, {\mu} = \frac{240}{r_{3}^{2}}, {\Lambda} = 90, q = r_{3}\right], \left[{\lambda} = -\frac{2}{3} \, \sqrt{3}, {\mu} = \frac{240}{r_{4}^{2}}, {\Lambda} = 90, q = r_{4}\right]\right]

Hence there are two families of solutions, each family being parametrized by e.g. qq. Note that, as above, rir_i, with ii an integer, stands for an arbitrary parameter (nothing to do with the coordinate rr).

2. Black brane solution

We add a blackening factor f(r)f(r) to the metric; i.e. we declare a new metric gg according to

In [65]:
g = M.lorentzian_metric('g') ff = function('f')(r) g[0,0] = -ff*exp(2*nu*r) g[1,1] = exp(2*nu*r) g[2,2] = exp(2*r) g[3,3] = exp(2*r) g[4,4] = 1/ff g.display()
g=e(2νr)f(r)dtdt+e(2νr)dxdx+e(2r)dy1dy1+e(2r)dy2dy2+1f(r)drdrg = -e^{\left(2 \, {\nu} r\right)} f\left(r\right) \mathrm{d} t\otimes \mathrm{d} t + e^{\left(2 \, {\nu} r\right)} \mathrm{d} x\otimes \mathrm{d} x + e^{\left(2 \, r\right)} \mathrm{d} {y_1}\otimes \mathrm{d} {y_1} + e^{\left(2 \, r\right)} \mathrm{d} {y_2}\otimes \mathrm{d} {y_2} + \frac{1}{f\left(r\right)} \mathrm{d} r\otimes \mathrm{d} r

The Ricci tensor of gg is

In [66]:
Ric = g.ricci() print Ric
Field of symmetric bilinear forms Ric(g) on the 5-dimensional differentiable manifold M
In [67]:
Ric.display_comp()
Ric(g)tttt=2(ν2+ν)e(2νr)f(r)2+(2ν+1)e(2νr)f(r)fr+12e(2νr)f(r)2fr2Ric(g)xxxx=2(ν2+ν)e(2νr)f(r)νe(2νr)frRic(g)y1y1y1y1=2(ν+1)e(2r)f(r)e(2r)frRic(g)y2y2y2y2=2(ν+1)e(2r)f(r)e(2r)frRic(g)rrrr=4(ν2+1)f(r)+2(2ν+1)fr+2fr22f(r)\begin{array}{lcl} \mathrm{Ric}\left(g\right)_{ \, t \, t }^{ \phantom{\, t}\phantom{\, t} } & = & 2 \, {\left({\nu}^{2} + {\nu}\right)} e^{\left(2 \, {\nu} r\right)} f\left(r\right)^{2} + {\left(2 \, {\nu} + 1\right)} e^{\left(2 \, {\nu} r\right)} f\left(r\right) \frac{\partial\,f}{\partial r} + \frac{1}{2} \, e^{\left(2 \, {\nu} r\right)} f\left(r\right) \frac{\partial^2\,f}{\partial r ^ 2} \\ \mathrm{Ric}\left(g\right)_{ \, x \, x }^{ \phantom{\, x}\phantom{\, x} } & = & -2 \, {\left({\nu}^{2} + {\nu}\right)} e^{\left(2 \, {\nu} r\right)} f\left(r\right) - {\nu} e^{\left(2 \, {\nu} r\right)} \frac{\partial\,f}{\partial r} \\ \mathrm{Ric}\left(g\right)_{ \, {y_1} \, {y_1} }^{ \phantom{\, {y_1}}\phantom{\, {y_1}} } & = & -2 \, {\left({\nu} + 1\right)} e^{\left(2 \, r\right)} f\left(r\right) - e^{\left(2 \, r\right)} \frac{\partial\,f}{\partial r} \\ \mathrm{Ric}\left(g\right)_{ \, {y_2} \, {y_2} }^{ \phantom{\, {y_2}}\phantom{\, {y_2}} } & = & -2 \, {\left({\nu} + 1\right)} e^{\left(2 \, r\right)} f\left(r\right) - e^{\left(2 \, r\right)} \frac{\partial\,f}{\partial r} \\ \mathrm{Ric}\left(g\right)_{ \, r \, r }^{ \phantom{\, r}\phantom{\, r} } & = & -\frac{4 \, {\left({\nu}^{2} + 1\right)} f\left(r\right) + 2 \, {\left(2 \, {\nu} + 1\right)} \frac{\partial\,f}{\partial r} + \frac{\partial^2\,f}{\partial r ^ 2}}{2 \, f\left(r\right)} \end{array}

By construction, the 2-form FF does not depend on gg; hence there is no need to reevaluate it:

In [68]:
F.display()
F=12qdy1dy2F = \frac{1}{2} \, q \mathrm{d} {y_1}\wedge \mathrm{d} {y_2}

On the contrary, we need to reevaluate its metric dual, in order to compute F2:=FmnFmnF^2 := F_{mn} F^{mn}:

In [69]:
Fu = F.up(g) print Fu Fu.display()
Tensor field of type (2,0) on the 5-dimensional differentiable manifold M
12qe(4r)y1y212qe(4r)y2y1\frac{1}{2} \, q e^{\left(-4 \, r\right)} \frac{\partial}{\partial {y_1} }\otimes \frac{\partial}{\partial {y_2} } -\frac{1}{2} \, q e^{\left(-4 \, r\right)} \frac{\partial}{\partial {y_2} }\otimes \frac{\partial}{\partial {y_1} }
In [70]:
F2 = F['_{mn}']*Fu['^{mn}'] # using LaTeX notations to denote contraction print F2 F2.display()
Scalar field on the 5-dimensional differentiable manifold M
MR(t,x,y1,y2,r~)q22r~4(t,x,y1,y2,r)12q2e(4r)\begin{array}{llcl} & M & \longrightarrow & \mathbb{R} \\ & \left(t, x, {y_1}, {y_2}, {\tilde{r}}\right) & \longmapsto & \frac{q^{2}}{2 \, {\tilde{r}}^{4}} \\ & \left(t, x, {y_1}, {y_2}, r\right) & \longmapsto & \frac{1}{2} \, q^{2} e^{\left(-4 \, r\right)} \end{array}