CoCalc Public FilesKerr-AdS-5D-string-a_eq_b-AdS.ipynbOpen in with one click!
Authors: agolubtsova , Eric Gourgoulhon
Views : 59
Description: 5D Kerr-AdS spacetime with a Nambu-Goto string in AdS coordinates

5D Kerr-AdS spacetime with a Nambu-Goto string

Case a = b with global AdS coordinates

This SageMath notebook is relative to the article Holographic drag force in 5d Kerr-AdS black hole by Irina Ya. Aref'eva, Anastasia A. Golubtsova and Eric Gourgoulhon, arXiv:2004.12984.

The involved differential geometry computations are based on tools developed through the SageManifolds project.

NB: a version of SageMath at least equal to 8.2 is required to run this notebook:

In [1]:
version()
'SageMath version 9.0, Release Date: 2020-01-01'

First we set up the notebook to display mathematical objects using LaTeX rendering:

In [2]:
%display latex

Since some computations are quite long, we ask for running them in parallel on 8 cores:

In [3]:
Parallelism().set(nproc=1) # only nproc=1 works on CoCalc

Spacetime manifold

We declare the Kerr-AdS spacetime as a 5-dimensional Lorentzian manifold:

In [4]:
M = Manifold(5, 'M', r'\mathcal{M}', structure='Lorentzian', metric_name='G') print(M)
5-dimensional Lorentzian manifold M

Let us define Boyer-Lindquist-type coordinates (rational polynomial version) on M\mathcal{M}, via the method chart(), the argument of which is a string expressing the coordinates names, their ranges (the default is (,+)(-\infty,+\infty)) and their LaTeX symbols:

In [5]:
BL.<t,r,mu,ph,ps> = M.chart(r't r:(0,+oo) mu:(0,1):\mu ph:(0,2*pi):\phi ps:(0,2*pi):\psi') BL
(M,(t,r,μ,ϕ,ψ))\left(\mathcal{M},(t, r, {\mu}, {\phi}, {\psi})\right)

The coordinate μ\mu is related to the standard Boyer-Lindquist coordinate θ\theta by μ=cosθ \mu = \cos\theta

The coordinate ranges are

In [6]:
BL.coord_range()
t: (,+);r: (0,+);μ: (0,1);ϕ: (0,2π);ψ: (0,2π)t :\ \left( -\infty, +\infty \right) ;\quad r :\ \left( 0 , +\infty \right) ;\quad {\mu} :\ \left( 0 , 1 \right) ;\quad {\phi} :\ \left( 0 , 2 \, \pi \right) ;\quad {\psi} :\ \left( 0 , 2 \, \pi \right)

Note that contrary to the 4-dimensional case, the range of μ\mu is (0,1)(0,1) only (cf. Sec. 1.2 of R.C. Myers, arXiv:1111.1903 or Sec. 2 of G.W. Gibbons, H. Lüb, Don N. Page, C.N. Pope, J. Geom. Phys. 53, 49 (2005)). In other words, the range of θ\theta is (0,π2)\left(0, \frac{\pi}{2}\right) only.

Metric tensor

The 4 parameters mm, aa, bb and \ell of the Kerr-AdS spacetime are declared as symbolic variables, aa and bb being the two angular momentum parameters and \ell being related to the cosmological constant by Λ=62\Lambda = - 6 \ell^2:

In [7]:
var('m a b', domain='real')
(m,a,b)\left(m, a, b\right)
In [8]:
var('l', domain='real', latex_name=r'\ell')
{\ell}
In [9]:
# Particular cases # m = 0 # a = 0 # b = 0 b = a
In [10]:
assume(a > 0) assume(1 - a^2*l^2 > 0)

Some auxiliary functions:

In [11]:
keep_Delta = False # change to False to provide explicit expression for Delta_r, Xi_a, etc...
In [12]:
sig = (1 + r^2*l^2)/r^2 costh2 = mu^2 sinth2 = 1 - mu^2 rho2 = r^2 + a^2*mu^2 + b^2*sinth2 if keep_Delta: Delta_r = var('Delta_r', latex_name=r'\Delta_r', domain='real') Delta_th = var('Delta_th', latex_name=r'\Delta_\theta', domain='real') if a == b: Xi_a = var('Xi', latex_name=r'\Xi', domain='real') Xi_b = Xi_a else: Xi_a = var('Xi_a', latex_name=r'\Xi_a', domain='real') Xi_b = var('Xi_b', latex_name=r'\Xi_b', domain='real') #Delta_th = 1 - a^2*l^2*mu^2 - b^2*l^2*sinth2 Xi_a = 1 - a^2*l^2 Xi_b = 1 - b^2*l^2 else: Delta_r = (r^2+a^2)*(r^2+b^2)*sig - 2*m Delta_th = 1 - a^2*l^2*mu^2 - b^2*l^2*sinth2 Xi_a = 1 - a^2*l^2 Xi_b = 1 - b^2*l^2

The metric is set by its components in the coordinate frame associated with the Boyer-Lindquist-type coordinates, which is the current manifold's default frame. These components can be deduced from Eq. (5.22) of the article S.W. Hawking, C.J. Hunter & M.M. Taylor-Robinson, Phys. Rev. D 59, 064005 (1999) (the check of agreement with this equation is performed below):

In [13]:
G = M.metric() tmp = 1/rho2*( -Delta_r + Delta_th*(a^2*sinth2 + b^2*mu^2) + a^2*b^2*sig ) G[0,0] = tmp.simplify_full() tmp = a*sinth2/(rho2*Xi_a)*( Delta_r - (r^2+a^2)*(Delta_th + b^2*sig) ) G[0,3] = tmp.simplify_full() tmp = b*mu^2/(rho2*Xi_b)*( Delta_r - (r^2+b^2)*(Delta_th + a^2*sig) ) G[0,4] = tmp.simplify_full() G[1,1] = (rho2/Delta_r).simplify_full() G[2,2] = (rho2/Delta_th/(1-mu^2)).simplify_full() tmp = sinth2/(rho2*Xi_a^2)*( - Delta_r*a^2*sinth2 + (r^2+a^2)^2*(Delta_th + sig*b^2*sinth2) ) G[3,3] = tmp.simplify_full() tmp = a*b*sinth2*mu^2/(rho2*Xi_a*Xi_b)*( - Delta_r + sig*(r^2+a^2)*(r^2+b^2) ) G[3,4] = tmp.simplify_full() tmp = mu^2/(rho2*Xi_b^2)*( - Delta_r*b^2*mu^2 + (r^2+b^2)^2*(Delta_th + sig*a^2*mu^2) ) G[4,4] = tmp.simplify_full() G.display()
G=(a42+2r4+(2a22+1)r2+a22ma2+r2)dtdt+(a52(a2μ2a2)r4(a522am)μ22(a32μ2a32)r22ama42+(a221)r2a2)dtdϕ+(2a32μ2r2+a2μ2r4+(a522am)μ2a42+(a221)r2a2)dtdψ+(a2r2+r42r6+(2a22+1)r4+a4+(a42+2a22m)r2)drdr+(a2+r2a22(a221)μ21)dμdμ+(a52(a2μ2a2)r4(a522am)μ22(a32μ2a32)r22ama42+(a221)r2a2)dϕdt+(a622a2mμ4+(a22(a221)μ21)r4a42a2m(a62a44a2m)μ2+2(a42(a42a2)μ2a2)r2a642a42+(a442a22+1)r2+a2)dϕdϕ+(2(a2mμ4a2mμ2)a642a42+(a442a22+1)r2+a2)dϕdψ+(2a32μ2r2+a2μ2r4+(a522am)μ2a42+(a221)r2a2)dψdt+(2(a2mμ4a2mμ2)a642a42+(a442a22+1)r2+a2)dψdϕ+(2a2mμ4(a221)μ2r42(a42a2)μ2r2(a62a4)μ2a642a42+(a442a22+1)r2+a2)dψdψG = \left( -\frac{a^{4} {\ell}^{2} + {\ell}^{2} r^{4} + {\left(2 \, a^{2} {\ell}^{2} + 1\right)} r^{2} + a^{2} - 2 \, m}{a^{2} + r^{2}} \right) \mathrm{d} t\otimes \mathrm{d} t + \left( -\frac{a^{5} {\ell}^{2} - {\left(a {\ell}^{2} {\mu}^{2} - a {\ell}^{2}\right)} r^{4} - {\left(a^{5} {\ell}^{2} - 2 \, a m\right)} {\mu}^{2} - 2 \, {\left(a^{3} {\ell}^{2} {\mu}^{2} - a^{3} {\ell}^{2}\right)} r^{2} - 2 \, a m}{a^{4} {\ell}^{2} + {\left(a^{2} {\ell}^{2} - 1\right)} r^{2} - a^{2}} \right) \mathrm{d} t\otimes \mathrm{d} {\phi} + \left( -\frac{2 \, a^{3} {\ell}^{2} {\mu}^{2} r^{2} + a {\ell}^{2} {\mu}^{2} r^{4} + {\left(a^{5} {\ell}^{2} - 2 \, a m\right)} {\mu}^{2}}{a^{4} {\ell}^{2} + {\left(a^{2} {\ell}^{2} - 1\right)} r^{2} - a^{2}} \right) \mathrm{d} t\otimes \mathrm{d} {\psi} + \left( \frac{a^{2} r^{2} + r^{4}}{{\ell}^{2} r^{6} + {\left(2 \, a^{2} {\ell}^{2} + 1\right)} r^{4} + a^{4} + {\left(a^{4} {\ell}^{2} + 2 \, a^{2} - 2 \, m\right)} r^{2}} \right) \mathrm{d} r\otimes \mathrm{d} r + \left( -\frac{a^{2} + r^{2}}{a^{2} {\ell}^{2} - {\left(a^{2} {\ell}^{2} - 1\right)} {\mu}^{2} - 1} \right) \mathrm{d} {\mu}\otimes \mathrm{d} {\mu} + \left( -\frac{a^{5} {\ell}^{2} - {\left(a {\ell}^{2} {\mu}^{2} - a {\ell}^{2}\right)} r^{4} - {\left(a^{5} {\ell}^{2} - 2 \, a m\right)} {\mu}^{2} - 2 \, {\left(a^{3} {\ell}^{2} {\mu}^{2} - a^{3} {\ell}^{2}\right)} r^{2} - 2 \, a m}{a^{4} {\ell}^{2} + {\left(a^{2} {\ell}^{2} - 1\right)} r^{2} - a^{2}} \right) \mathrm{d} {\phi}\otimes \mathrm{d} t + \left( -\frac{a^{6} {\ell}^{2} - 2 \, a^{2} m {\mu}^{4} + {\left(a^{2} {\ell}^{2} - {\left(a^{2} {\ell}^{2} - 1\right)} {\mu}^{2} - 1\right)} r^{4} - a^{4} - 2 \, a^{2} m - {\left(a^{6} {\ell}^{2} - a^{4} - 4 \, a^{2} m\right)} {\mu}^{2} + 2 \, {\left(a^{4} {\ell}^{2} - {\left(a^{4} {\ell}^{2} - a^{2}\right)} {\mu}^{2} - a^{2}\right)} r^{2}}{a^{6} {\ell}^{4} - 2 \, a^{4} {\ell}^{2} + {\left(a^{4} {\ell}^{4} - 2 \, a^{2} {\ell}^{2} + 1\right)} r^{2} + a^{2}} \right) \mathrm{d} {\phi}\otimes \mathrm{d} {\phi} + \left( -\frac{2 \, {\left(a^{2} m {\mu}^{4} - a^{2} m {\mu}^{2}\right)}}{a^{6} {\ell}^{4} - 2 \, a^{4} {\ell}^{2} + {\left(a^{4} {\ell}^{4} - 2 \, a^{2} {\ell}^{2} + 1\right)} r^{2} + a^{2}} \right) \mathrm{d} {\phi}\otimes \mathrm{d} {\psi} + \left( -\frac{2 \, a^{3} {\ell}^{2} {\mu}^{2} r^{2} + a {\ell}^{2} {\mu}^{2} r^{4} + {\left(a^{5} {\ell}^{2} - 2 \, a m\right)} {\mu}^{2}}{a^{4} {\ell}^{2} + {\left(a^{2} {\ell}^{2} - 1\right)} r^{2} - a^{2}} \right) \mathrm{d} {\psi}\otimes \mathrm{d} t + \left( -\frac{2 \, {\left(a^{2} m {\mu}^{4} - a^{2} m {\mu}^{2}\right)}}{a^{6} {\ell}^{4} - 2 \, a^{4} {\ell}^{2} + {\left(a^{4} {\ell}^{4} - 2 \, a^{2} {\ell}^{2} + 1\right)} r^{2} + a^{2}} \right) \mathrm{d} {\psi}\otimes \mathrm{d} {\phi} + \left( \frac{2 \, a^{2} m {\mu}^{4} - {\left(a^{2} {\ell}^{2} - 1\right)} {\mu}^{2} r^{4} - 2 \, {\left(a^{4} {\ell}^{2} - a^{2}\right)} {\mu}^{2} r^{2} - {\left(a^{6} {\ell}^{2} - a^{4}\right)} {\mu}^{2}}{a^{6} {\ell}^{4} - 2 \, a^{4} {\ell}^{2} + {\left(a^{4} {\ell}^{4} - 2 \, a^{2} {\ell}^{2} + 1\right)} r^{2} + a^{2}} \right) \mathrm{d} {\psi}\otimes \mathrm{d} {\psi}
In [14]:
G.display_comp(only_nonredundant=True)
Gtttt=a42+2r4+(2a22+1)r2+a22ma2+r2Gtϕtϕ=a52(a2μ2a2)r4(a522am)μ22(a32μ2a32)r22ama42+(a221)r2a2Gtψtψ=2a32μ2r2+a2μ2r4+(a522am)μ2a42+(a221)r2a2Grrrr=a2r2+r42r6+(2a22+1)r4+a4+(a42+2a22m)r2Gμμμμ=a2+r2a22(a221)μ21Gϕϕϕϕ=a622a2mμ4+(a22(a221)μ21)r4a42a2m(a62a44a2m)μ2+2(a42(a42a2)μ2a2)r2a642a42+(a442a22+1)r2+a2Gϕψϕψ=2(a2mμ4a2mμ2)a642a42+(a442a22+1)r2+a2Gψψψψ=2a2mμ4(a221)μ2r42(a42a2)μ2r2(a62a4)μ2a642a42+(a442a22+1)r2+a2\begin{array}{lcl} G_{ \, t \, t }^{ \phantom{\, t}\phantom{\, t} } & = & -\frac{a^{4} {\ell}^{2} + {\ell}^{2} r^{4} + {\left(2 \, a^{2} {\ell}^{2} + 1\right)} r^{2} + a^{2} - 2 \, m}{a^{2} + r^{2}} \\ G_{ \, t \, {\phi} }^{ \phantom{\, t}\phantom{\, {\phi}} } & = & -\frac{a^{5} {\ell}^{2} - {\left(a {\ell}^{2} {\mu}^{2} - a {\ell}^{2}\right)} r^{4} - {\left(a^{5} {\ell}^{2} - 2 \, a m\right)} {\mu}^{2} - 2 \, {\left(a^{3} {\ell}^{2} {\mu}^{2} - a^{3} {\ell}^{2}\right)} r^{2} - 2 \, a m}{a^{4} {\ell}^{2} + {\left(a^{2} {\ell}^{2} - 1\right)} r^{2} - a^{2}} \\ G_{ \, t \, {\psi} }^{ \phantom{\, t}\phantom{\, {\psi}} } & = & -\frac{2 \, a^{3} {\ell}^{2} {\mu}^{2} r^{2} + a {\ell}^{2} {\mu}^{2} r^{4} + {\left(a^{5} {\ell}^{2} - 2 \, a m\right)} {\mu}^{2}}{a^{4} {\ell}^{2} + {\left(a^{2} {\ell}^{2} - 1\right)} r^{2} - a^{2}} \\ G_{ \, r \, r }^{ \phantom{\, r}\phantom{\, r} } & = & \frac{a^{2} r^{2} + r^{4}}{{\ell}^{2} r^{6} + {\left(2 \, a^{2} {\ell}^{2} + 1\right)} r^{4} + a^{4} + {\left(a^{4} {\ell}^{2} + 2 \, a^{2} - 2 \, m\right)} r^{2}} \\ G_{ \, {\mu} \, {\mu} }^{ \phantom{\, {\mu}}\phantom{\, {\mu}} } & = & -\frac{a^{2} + r^{2}}{a^{2} {\ell}^{2} - {\left(a^{2} {\ell}^{2} - 1\right)} {\mu}^{2} - 1} \\ G_{ \, {\phi} \, {\phi} }^{ \phantom{\, {\phi}}\phantom{\, {\phi}} } & = & -\frac{a^{6} {\ell}^{2} - 2 \, a^{2} m {\mu}^{4} + {\left(a^{2} {\ell}^{2} - {\left(a^{2} {\ell}^{2} - 1\right)} {\mu}^{2} - 1\right)} r^{4} - a^{4} - 2 \, a^{2} m - {\left(a^{6} {\ell}^{2} - a^{4} - 4 \, a^{2} m\right)} {\mu}^{2} + 2 \, {\left(a^{4} {\ell}^{2} - {\left(a^{4} {\ell}^{2} - a^{2}\right)} {\mu}^{2} - a^{2}\right)} r^{2}}{a^{6} {\ell}^{4} - 2 \, a^{4} {\ell}^{2} + {\left(a^{4} {\ell}^{4} - 2 \, a^{2} {\ell}^{2} + 1\right)} r^{2} + a^{2}} \\ G_{ \, {\phi} \, {\psi} }^{ \phantom{\, {\phi}}\phantom{\, {\psi}} } & = & -\frac{2 \, {\left(a^{2} m {\mu}^{4} - a^{2} m {\mu}^{2}\right)}}{a^{6} {\ell}^{4} - 2 \, a^{4} {\ell}^{2} + {\left(a^{4} {\ell}^{4} - 2 \, a^{2} {\ell}^{2} + 1\right)} r^{2} + a^{2}} \\ G_{ \, {\psi} \, {\psi} }^{ \phantom{\, {\psi}}\phantom{\, {\psi}} } & = & \frac{2 \, a^{2} m {\mu}^{4} - {\left(a^{2} {\ell}^{2} - 1\right)} {\mu}^{2} r^{4} - 2 \, {\left(a^{4} {\ell}^{2} - a^{2}\right)} {\mu}^{2} r^{2} - {\left(a^{6} {\ell}^{2} - a^{4}\right)} {\mu}^{2}}{a^{6} {\ell}^{4} - 2 \, a^{4} {\ell}^{2} + {\left(a^{4} {\ell}^{4} - 2 \, a^{2} {\ell}^{2} + 1\right)} r^{2} + a^{2}} \end{array}

Check of agreement with Eq. (5.22) of Hawking et al or Eq. (2.3) of o

We need the 1-forms dt\mathrm{d}t, dr\mathrm{d}r, dμ\mathrm{d}\mu, dϕ\mathrm{d}\phi and dψ\mathrm{d}\psi:

In [15]:
dt, dr, dmu, dph, dps = (BL.coframe()[i] for i in M.irange()) dt, dr, dmu, dph, dps
(dt,dr,dμ,dϕ,dψ)\left(\mathrm{d} t, \mathrm{d} r, \mathrm{d} {\mu}, \mathrm{d} {\phi}, \mathrm{d} {\psi}\right)
In [16]:
print(dt)
1-form dt on the 5-dimensional Lorentzian manifold M

In agreement with μ=cosθ\mu = \cos\theta, we introduce the 1-form dθ=dμ/sinθ\mathrm{d}\theta = - \mathrm{d}\mu /\sin\theta , with sinθ=1μ2\sin\theta = \sqrt{1-\mu^2} since θ(0,π2)\theta\in\left(0, \frac{\pi}{2}\right):

In [17]:
dth = - 1/sqrt(1 - mu^2)*dmu
In [18]:
s1 = dt - a*sinth2/Xi_a*dph - b*costh2/Xi_b*dps s1.display()
dt+(aμ2aa221)dϕ+(aμ2a221)dψ\mathrm{d} t + \left( -\frac{a {\mu}^{2} - a}{a^{2} {\ell}^{2} - 1} \right) \mathrm{d} {\phi} + \left( \frac{a {\mu}^{2}}{a^{2} {\ell}^{2} - 1} \right) \mathrm{d} {\psi}
In [19]:
s2 = a*dt - (r^2 + a^2)/Xi_a*dph s2.display()
adt+(a2+r2a221)dϕa \mathrm{d} t + \left( \frac{a^{2} + r^{2}}{a^{2} {\ell}^{2} - 1} \right) \mathrm{d} {\phi}
In [20]:
s3 = b*dt - (r^2 + b^2)/Xi_b*dps s3.display()
adt+(a2+r2a221)dψa \mathrm{d} t + \left( \frac{a^{2} + r^{2}}{a^{2} {\ell}^{2} - 1} \right) \mathrm{d} {\psi}
In [21]:
s4 = a*b*dt - b*(r^2 + a^2)*sinth2/Xi_a * dph - a*(r^2 + b^2)*costh2/Xi_b * dps s4.display()
a2dt+(a3μ2a3+(aμ2a)r2a221)dϕ+(a3μ2+aμ2r2a221)dψa^{2} \mathrm{d} t + \left( -\frac{a^{3} {\mu}^{2} - a^{3} + {\left(a {\mu}^{2} - a\right)} r^{2}}{a^{2} {\ell}^{2} - 1} \right) \mathrm{d} {\phi} + \left( \frac{a^{3} {\mu}^{2} + a {\mu}^{2} r^{2}}{a^{2} {\ell}^{2} - 1} \right) \mathrm{d} {\psi}
In [22]:
G0 = - Delta_r/rho2 * s1*s1 + Delta_th*sinth2/rho2 * s2*s2 + Delta_th*costh2/rho2 * s3*s3 \ + rho2/Delta_r * dr*dr + rho2/Delta_th * dth*dth + sig/rho2 * s4*s4 G0.display_comp(only_nonredundant=True)
Xtttt=a42+2r4+(2a22+1)r2+a22ma2+r2Xtϕtϕ=a52(a2μ2a2)r4(a522am)μ22(a32μ2a32)r22ama42+(a221)r2a2Xtψtψ=2a32μ2r2+a2μ2r4+(a522am)μ2a42+(a221)r2a2Xrrrr=a2r2+r42r6+(2a22+1)r4+a4+(a42+2a22m)r2Xμμμμ=a2+r2a22(a221)μ21Xϕtϕt=a52(a2μ2a2)r4(a522am)μ22(a32μ2a32)r22ama42+(a221)r2a2Xϕϕϕϕ=a622a2mμ4+(a22(a221)μ21)r4a42a2m(a62a44a2m)μ2+2(a42(a42a2)μ2a2)r2a642a42+(a442a22+1)r2+a2Xϕψϕψ=2(a2mμ4a2mμ2)a642a42+(a442a22+1)r2+a2Xψtψt=2a32μ2r2+a2μ2r4+(a522am)μ2a42+(a221)r2a2Xψϕψϕ=2(a2mμ4a2mμ2)a642a42+(a442a22+1)r2+a2Xψψψψ=2a2mμ4(a221)μ2r42(a42a2)μ2r2(a62a4)μ2a642a42+(a442a22+1)r2+a2\begin{array}{lcl} X_{ \, t \, t }^{ \phantom{\, t}\phantom{\, t} } & = & -\frac{a^{4} {\ell}^{2} + {\ell}^{2} r^{4} + {\left(2 \, a^{2} {\ell}^{2} + 1\right)} r^{2} + a^{2} - 2 \, m}{a^{2} + r^{2}} \\ X_{ \, t \, {\phi} }^{ \phantom{\, t}\phantom{\, {\phi}} } & = & -\frac{a^{5} {\ell}^{2} - {\left(a {\ell}^{2} {\mu}^{2} - a {\ell}^{2}\right)} r^{4} - {\left(a^{5} {\ell}^{2} - 2 \, a m\right)} {\mu}^{2} - 2 \, {\left(a^{3} {\ell}^{2} {\mu}^{2} - a^{3} {\ell}^{2}\right)} r^{2} - 2 \, a m}{a^{4} {\ell}^{2} + {\left(a^{2} {\ell}^{2} - 1\right)} r^{2} - a^{2}} \\ X_{ \, t \, {\psi} }^{ \phantom{\, t}\phantom{\, {\psi}} } & = & -\frac{2 \, a^{3} {\ell}^{2} {\mu}^{2} r^{2} + a {\ell}^{2} {\mu}^{2} r^{4} + {\left(a^{5} {\ell}^{2} - 2 \, a m\right)} {\mu}^{2}}{a^{4} {\ell}^{2} + {\left(a^{2} {\ell}^{2} - 1\right)} r^{2} - a^{2}} \\ X_{ \, r \, r }^{ \phantom{\, r}\phantom{\, r} } & = & \frac{a^{2} r^{2} + r^{4}}{{\ell}^{2} r^{6} + {\left(2 \, a^{2} {\ell}^{2} + 1\right)} r^{4} + a^{4} + {\left(a^{4} {\ell}^{2} + 2 \, a^{2} - 2 \, m\right)} r^{2}} \\ X_{ \, {\mu} \, {\mu} }^{ \phantom{\, {\mu}}\phantom{\, {\mu}} } & = & -\frac{a^{2} + r^{2}}{a^{2} {\ell}^{2} - {\left(a^{2} {\ell}^{2} - 1\right)} {\mu}^{2} - 1} \\ X_{ \, {\phi} \, t }^{ \phantom{\, {\phi}}\phantom{\, t} } & = & -\frac{a^{5} {\ell}^{2} - {\left(a {\ell}^{2} {\mu}^{2} - a {\ell}^{2}\right)} r^{4} - {\left(a^{5} {\ell}^{2} - 2 \, a m\right)} {\mu}^{2} - 2 \, {\left(a^{3} {\ell}^{2} {\mu}^{2} - a^{3} {\ell}^{2}\right)} r^{2} - 2 \, a m}{a^{4} {\ell}^{2} + {\left(a^{2} {\ell}^{2} - 1\right)} r^{2} - a^{2}} \\ X_{ \, {\phi} \, {\phi} }^{ \phantom{\, {\phi}}\phantom{\, {\phi}} } & = & -\frac{a^{6} {\ell}^{2} - 2 \, a^{2} m {\mu}^{4} + {\left(a^{2} {\ell}^{2} - {\left(a^{2} {\ell}^{2} - 1\right)} {\mu}^{2} - 1\right)} r^{4} - a^{4} - 2 \, a^{2} m - {\left(a^{6} {\ell}^{2} - a^{4} - 4 \, a^{2} m\right)} {\mu}^{2} + 2 \, {\left(a^{4} {\ell}^{2} - {\left(a^{4} {\ell}^{2} - a^{2}\right)} {\mu}^{2} - a^{2}\right)} r^{2}}{a^{6} {\ell}^{4} - 2 \, a^{4} {\ell}^{2} + {\left(a^{4} {\ell}^{4} - 2 \, a^{2} {\ell}^{2} + 1\right)} r^{2} + a^{2}} \\ X_{ \, {\phi} \, {\psi} }^{ \phantom{\, {\phi}}\phantom{\, {\psi}} } & = & -\frac{2 \, {\left(a^{2} m {\mu}^{4} - a^{2} m {\mu}^{2}\right)}}{a^{6} {\ell}^{4} - 2 \, a^{4} {\ell}^{2} + {\left(a^{4} {\ell}^{4} - 2 \, a^{2} {\ell}^{2} + 1\right)} r^{2} + a^{2}} \\ X_{ \, {\psi} \, t }^{ \phantom{\, {\psi}}\phantom{\, t} } & = & -\frac{2 \, a^{3} {\ell}^{2} {\mu}^{2} r^{2} + a {\ell}^{2} {\mu}^{2} r^{4} + {\left(a^{5} {\ell}^{2} - 2 \, a m\right)} {\mu}^{2}}{a^{4} {\ell}^{2} + {\left(a^{2} {\ell}^{2} - 1\right)} r^{2} - a^{2}} \\ X_{ \, {\psi} \, {\phi} }^{ \phantom{\, {\psi}}\phantom{\, {\phi}} } & = & -\frac{2 \, {\left(a^{2} m {\mu}^{4} - a^{2} m {\mu}^{2}\right)}}{a^{6} {\ell}^{4} - 2 \, a^{4} {\ell}^{2} + {\left(a^{4} {\ell}^{4} - 2 \, a^{2} {\ell}^{2} + 1\right)} r^{2} + a^{2}} \\ X_{ \, {\psi} \, {\psi} }^{ \phantom{\, {\psi}}\phantom{\, {\psi}} } & = & \frac{2 \, a^{2} m {\mu}^{4} - {\left(a^{2} {\ell}^{2} - 1\right)} {\mu}^{2} r^{4} - 2 \, {\left(a^{4} {\ell}^{2} - a^{2}\right)} {\mu}^{2} r^{2} - {\left(a^{6} {\ell}^{2} - a^{4}\right)} {\mu}^{2}}{a^{6} {\ell}^{4} - 2 \, a^{4} {\ell}^{2} + {\left(a^{4} {\ell}^{4} - 2 \, a^{2} {\ell}^{2} + 1\right)} r^{2} + a^{2}} \end{array}
In [23]:
G0 == G
True\mathrm{True}

Einstein equation

The Ricci tensor of gg is

In [24]:
if not keep_Delta: # Ric = G.ricci() # print(Ric) pass
In [25]:
if not keep_Delta: # show(Ric.display_comp(only_nonredundant=True)) pass

Let us check that gg is a solution of the vacuum Einstein equation with the cosmological constant Λ=62\Lambda = - 6 \ell^2:

In [26]:
Lambda = -6*l^2 if not keep_Delta: # print(Ric == 2/3*Lambda*G) pass

Check of Eq. (2.10)

One must have a=ba=b and keep_Delta == False for the test to pass:

In [27]:
if a == b and not keep_Delta: G1 = - (1 + rho2*l^2 - 2*m/rho2) * dt*dt + rho2/Delta_r * dr*dr \ + rho2/Delta_th * dth*dth \ + sinth2/Xi_a^2*(rho2*Xi_a + 2*a^2*m/rho2*sinth2) * dph * dph \ + costh2/Xi_a^2*(rho2*Xi_a + 2*a^2*m/rho2*costh2) * dps * dps \ + a*sinth2/Xi_a*(rho2*l^2 - 2*m/rho2) * (dt*dph + dph*dt) \ + a*costh2/Xi_a*(rho2*l^2 - 2*m/rho2) * (dt*dps + dps*dt) \ + 2*m*a^2*sinth2*costh2/Xi_a^2/rho2 * (dph*dps + dps*dph) print(G1 == G)
True

Global AdS coordinates

In [28]:
ADS.<T,y,mu,Ph,Ps> = M.chart(r't y:(a/sqrt(1-a^2*l^2),+oo) mu:(0,1):\mu Ph:(0,2*pi):\Phi Ps:(0,2*pi):\Psi') ADS
(M,(t,y,μ,Φ,Ψ))\left(\mathcal{M},(t, y, {\mu}, {\Phi}, {\Psi})\right)
In [29]:
ADS.coord_range()
t: (,+);y: (aa22+1,+);μ: (0,1);Φ: (0,2π);Ψ: (0,2π)t :\ \left( -\infty, +\infty \right) ;\quad y :\ \left( \frac{a}{\sqrt{-a^{2} {\ell}^{2} + 1}} , +\infty \right) ;\quad {\mu} :\ \left( 0 , 1 \right) ;\quad {\Phi} :\ \left( 0 , 2 \, \pi \right) ;\quad {\Psi} :\ \left( 0 , 2 \, \pi \right)
In [30]:
assumptions()
[txisxreal,rxisxreal,r>0,muxisxreal,μ>0,μ<1,phxisxreal,ϕ>0,ϕ<2π,psxisxreal,ψ>0,ψ<2π,mxisxreal,axisxreal,bxisxreal,lxisxreal,a>0,a22+1>0,yxisxreal,y>aa22+1,Phxisxreal,Φ>0,Φ<2π,Psxisxreal,Ψ>0,Ψ<2π]\left[\verb|t|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, \verb|r|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, r > 0, \verb|mu|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, {\mu} > 0, {\mu} < 1, \verb|ph|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, {\phi} > 0, {\phi} < 2 \, \pi, \verb|ps|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, {\psi} > 0, {\psi} < 2 \, \pi, \verb|m|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, \verb|a|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, \verb|b|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, \verb|l|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, a > 0, -a^{2} {\ell}^{2} + 1 > 0, \verb|y|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, y > \frac{a}{\sqrt{-a^{2} {\ell}^{2} + 1}}, \verb|Ph|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, {\Phi} > 0, {\Phi} < 2 \, \pi, \verb|Ps|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, {\Psi} > 0, {\Psi} < 2 \, \pi\right]

Transition from the Boyer-Lindquist coordinates to the AdS global coordinates, according to Eq. (5.24) of S.W. Hawking, C.J. Hunter & M.M. Taylor-Robinson, Phys. Rev. D 59, 064005 (1999):

In [31]:
BL_to_ADS = BL.transition_map(ADS, [t, sqrt(r^2 + a^2)/sqrt(Xi_a), mu, ph + a*l^2*t, ps + a*l^2*t]) BL_to_ADS.display()
{t=ty=a2+r2a22+1μ=μΦ=a2t+ϕΨ=a2t+ψ\left\{\begin{array}{lcl} t & = & t \\ y & = & \frac{\sqrt{a^{2} + r^{2}}}{\sqrt{-a^{2} {\ell}^{2} + 1}} \\ {\mu} & = & {\mu} \\ {\Phi} & = & a {\ell}^{2} t + {\phi} \\ {\Psi} & = & a {\ell}^{2} t + {\psi} \end{array}\right.
In [32]:
BL_to_ADS.set_inverse(t, sqrt(Xi_a*y^2 - a^2), mu, Ph - a*l^2*t, Ps - a*l^2*t, verbose=True) BL_to_ADS.inverse().display()
Check of the inverse coordinate transformation: t == t *passed* r == r *passed* mu == mu *passed* ph == ph *passed* ps == ps *passed* t == t *passed* y == abs(y) **failed** mu == mu *passed* Ph == Ph *passed* Ps == Ps *passed* NB: a failed report can reflect a mere lack of simplification.
{t=tr=(a221)y2a2μ=μϕ=a2t+Φψ=a2t+Ψ\left\{\begin{array}{lcl} t & = & t \\ r & = & \sqrt{-{\left(a^{2} {\ell}^{2} - 1\right)} y^{2} - a^{2}} \\ {\mu} & = & {\mu} \\ {\phi} & = & -a {\ell}^{2} t + {\Phi} \\ {\psi} & = & -a {\ell}^{2} t + {\Psi} \end{array}\right.

Metric tensor is global AdS coordinates

In [33]:
G.display_comp(chart=ADS, only_nonredundant=True)
Gtttt=(a683a46+3a242)y4+(a663a44+3a221)y2+2m(a663a44+3a221)y2GtΦtΦ=2(amμ2am)(a663a44+3a221)y2GtΨtΨ=2amμ2(a663a44+3a221)y2Gyyyy=(a663a44+3a221)y4(a683a46+3a242)y6+(a663a44+3a221)y42(a221)my22a2mGμμμμ=y2μ21GΦΦΦΦ=2a2mμ44a2mμ2(a663a44+3a22(a663a44+3a221)μ21)y4+2a2m(a663a44+3a221)y2GΦΨΦΨ=2(a2mμ4a2mμ2)(a663a44+3a221)y2GΨΨΨΨ=2a2mμ4(a663a44+3a221)μ2y4(a663a44+3a221)y2\begin{array}{lcl} G_{ \, t \, t }^{ \phantom{\, t}\phantom{\, t} } & = & -\frac{{\left(a^{6} {\ell}^{8} - 3 \, a^{4} {\ell}^{6} + 3 \, a^{2} {\ell}^{4} - {\ell}^{2}\right)} y^{4} + {\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{2} + 2 \, m}{{\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{2}} \\ G_{ \, t \, {\Phi} }^{ \phantom{\, t}\phantom{\, {\Phi}} } & = & -\frac{2 \, {\left(a m {\mu}^{2} - a m\right)}}{{\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{2}} \\ G_{ \, t \, {\Psi} }^{ \phantom{\, t}\phantom{\, {\Psi}} } & = & \frac{2 \, a m {\mu}^{2}}{{\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{2}} \\ G_{ \, y \, y }^{ \phantom{\, y}\phantom{\, y} } & = & \frac{{\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{4}}{{\left(a^{6} {\ell}^{8} - 3 \, a^{4} {\ell}^{6} + 3 \, a^{2} {\ell}^{4} - {\ell}^{2}\right)} y^{6} + {\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{4} - 2 \, {\left(a^{2} {\ell}^{2} - 1\right)} m y^{2} - 2 \, a^{2} m} \\ G_{ \, {\mu} \, {\mu} }^{ \phantom{\, {\mu}}\phantom{\, {\mu}} } & = & -\frac{y^{2}}{{\mu}^{2} - 1} \\ G_{ \, {\Phi} \, {\Phi} }^{ \phantom{\, {\Phi}}\phantom{\, {\Phi}} } & = & -\frac{2 \, a^{2} m {\mu}^{4} - 4 \, a^{2} m {\mu}^{2} - {\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - {\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} {\mu}^{2} - 1\right)} y^{4} + 2 \, a^{2} m}{{\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{2}} \\ G_{ \, {\Phi} \, {\Psi} }^{ \phantom{\, {\Phi}}\phantom{\, {\Psi}} } & = & \frac{2 \, {\left(a^{2} m {\mu}^{4} - a^{2} m {\mu}^{2}\right)}}{{\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{2}} \\ G_{ \, {\Psi} \, {\Psi} }^{ \phantom{\, {\Psi}}\phantom{\, {\Psi}} } & = & -\frac{2 \, a^{2} m {\mu}^{4} - {\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} {\mu}^{2} y^{4}}{{\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{2}} \end{array}

From now on, we set the AdS coordinates as the default chart on M\mathcal{M}:

In [34]:
M.set_default_chart(ADS) M.set_default_frame(ADS.frame())

Then

In [35]:
G.display_comp(only_nonredundant=True)
Gtttt=(a683a46+3a242)y4+(a663a44+3a221)y2+2m(a663a44+3a221)y2GtΦtΦ=2(amμ2am)(a663a44+3a221)y2GtΨtΨ=2amμ2(a663a44+3a221)y2Gyyyy=(a663a44+3a221)y4(a683a46+3a242)y6+(a663a44+3a221)y42(a221)my22a2mGμμμμ=y2μ21GΦΦΦΦ=2a2mμ44a2mμ2(a663a44+3a22(a663a44+3a221)μ21)y4+2a2m(a663a44+3a221)y2GΦΨΦΨ=2(a2mμ4a2mμ2)(a663a44+3a221)y2GΨΨΨΨ=2a2mμ4(a663a44+3a221)μ2y4(a663a44+3a221)y2\begin{array}{lcl} G_{ \, t \, t }^{ \phantom{\, t}\phantom{\, t} } & = & -\frac{{\left(a^{6} {\ell}^{8} - 3 \, a^{4} {\ell}^{6} + 3 \, a^{2} {\ell}^{4} - {\ell}^{2}\right)} y^{4} + {\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{2} + 2 \, m}{{\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{2}} \\ G_{ \, t \, {\Phi} }^{ \phantom{\, t}\phantom{\, {\Phi}} } & = & -\frac{2 \, {\left(a m {\mu}^{2} - a m\right)}}{{\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{2}} \\ G_{ \, t \, {\Psi} }^{ \phantom{\, t}\phantom{\, {\Psi}} } & = & \frac{2 \, a m {\mu}^{2}}{{\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{2}} \\ G_{ \, y \, y }^{ \phantom{\, y}\phantom{\, y} } & = & \frac{{\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{4}}{{\left(a^{6} {\ell}^{8} - 3 \, a^{4} {\ell}^{6} + 3 \, a^{2} {\ell}^{4} - {\ell}^{2}\right)} y^{6} + {\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{4} - 2 \, {\left(a^{2} {\ell}^{2} - 1\right)} m y^{2} - 2 \, a^{2} m} \\ G_{ \, {\mu} \, {\mu} }^{ \phantom{\, {\mu}}\phantom{\, {\mu}} } & = & -\frac{y^{2}}{{\mu}^{2} - 1} \\ G_{ \, {\Phi} \, {\Phi} }^{ \phantom{\, {\Phi}}\phantom{\, {\Phi}} } & = & -\frac{2 \, a^{2} m {\mu}^{4} - 4 \, a^{2} m {\mu}^{2} - {\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - {\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} {\mu}^{2} - 1\right)} y^{4} + 2 \, a^{2} m}{{\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{2}} \\ G_{ \, {\Phi} \, {\Psi} }^{ \phantom{\, {\Phi}}\phantom{\, {\Psi}} } & = & \frac{2 \, {\left(a^{2} m {\mu}^{4} - a^{2} m {\mu}^{2}\right)}}{{\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{2}} \\ G_{ \, {\Psi} \, {\Psi} }^{ \phantom{\, {\Psi}}\phantom{\, {\Psi}} } & = & -\frac{2 \, a^{2} m {\mu}^{4} - {\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} {\mu}^{2} y^{4}}{{\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{2}} \end{array}

Comparison with Eq. (5.32) of S.W. Hawking, C.J. Hunter & M.M. Taylor-Robinson, Phys. Rev. D 59, 064005 (1999) (or Eq. (2.18) of our paper):

In [36]:
dt, dy, dmu, dPh, dPs = (ADS.coframe()[i] for i in M.irange()) dt, dy, dmu, dPh, dPs
(dt,dy,dμ,dΦ,dΨ)\left(\mathrm{d} t, \mathrm{d} y, \mathrm{d} {\mu}, \mathrm{d} {\Phi}, \mathrm{d} {\Psi}\right)
In [37]:
s = dt - a*sinth2*dPh - a*costh2*dPs s.display()
dt+(aμ2a)dΦaμ2dΨ\mathrm{d} t + \left( a {\mu}^{2} - a \right) \mathrm{d} {\Phi} -a {\mu}^{2} \mathrm{d} {\Psi}
In [38]:
dth.display()
(1μ+1μ+1)dμ\left( -\frac{1}{\sqrt{{\mu} + 1} \sqrt{-{\mu} + 1}} \right) \mathrm{d} {\mu}
In [39]:
G1 = - (1 + y^2*l^2)* dt*dt \ + y^2*(dth*dth + sinth2* dPh*dPh + costh2* dPs*dPs) \ + 2*m/(y^2*Xi_a^3)* s*s \ + y^4/(y^4*(1 + y^2*l^2) - 2*m*y^2/Xi_a^2 + 2*m*a^2/Xi_a^3)* dy*dy # NB: note the Xi_a^3 term in the factor of s*s differs from Eq. (5.32) of Hawking et al (1999) G == G1
True\mathrm{True}

String worldsheet

The string worldsheet as a 2-dimensional pseudo-Riemannian manifold (we don't assume Lorentzian signature here):

In [40]:
W = Manifold(2, 'W', structure='pseudo-Riemannian') print(W)
2-dimensional Riemannian manifold W

Let us assume that the string worldsheet is parametrized by (t,y)(t,y):

In [41]:
XW.<t,y> = W.chart(r't y:(a/sqrt(1-a^2*l^2),+oo)') XW
(W,(t,y))\left(W,(t, y)\right)

The string embedding in Kerr-AdS spacetime, as an expansion about a straight string solution in AdS (Eqs. (4.30)-(4.32) of the paper)

In [42]:
Mu0 = var('Mu0', latex_name=r'\mu_0', domain='real') Phi0 = var('Phi0', latex_name=r'\Phi_0', domain='real') Psi0 = var('Psi0', latex_name=r'\Psi_0', domain='real') beta1 = var('beta1', latex_name=r'\beta_1', domain='real') beta2 = var('beta2', latex_name=r'\beta_2', domain='real') cosTh0 = Mu0 sinTh0 = sqrt(1 - Mu0^2) mu_s = Mu0 + a^2*function('mu_1')(y) Ph_s = Phi0 + beta1*a*l^2*t + beta1*a*function('Phi_1')(y) Ps_s = Psi0 + beta2*a*l^2*t + beta2*a*function('Psi_1')(y) F = W.diff_map(M, {(XW, ADS): [t, y, mu_s, Ph_s, Ps_s]}, name='F') F.display()
F:WM(t,y)(t,r,μ,ϕ,ψ)=(t,(a221)y2a2,a2μ1(y)+μ0,(aβ1a)2t+aβ1Φ1(y)+Φ0,(aβ2a)2t+aβ2Ψ1(y)+Ψ0)(t,y)(t,y,μ,Φ,Ψ)=(t,y,a2μ1(y)+μ0,aβ12t+aβ1Φ1(y)+Φ0,aβ22t+aβ2Ψ1(y)+Ψ0)\begin{array}{llcl} F:& W & \longrightarrow & \mathcal{M} \\ & \left(t, y\right) & \longmapsto & \left(t, r, {\mu}, {\phi}, {\psi}\right) = \left(t, \sqrt{-{\left(a^{2} {\ell}^{2} - 1\right)} y^{2} - a^{2}}, a^{2} \mu_{1}\left(y\right) + {\mu_0}, {\left(a {\beta_1} - a\right)} {\ell}^{2} t + a {\beta_1} \Phi_{1}\left(y\right) + {\Phi_0}, {\left(a {\beta_2} - a\right)} {\ell}^{2} t + a {\beta_2} \Psi_{1}\left(y\right) + {\Psi_0}\right) \\ & \left(t, y\right) & \longmapsto & \left(t, y, {\mu}, {\Phi}, {\Psi}\right) = \left(t, y, a^{2} \mu_{1}\left(y\right) + {\mu_0}, a {\beta_1} {\ell}^{2} t + a {\beta_1} \Phi_{1}\left(y\right) + {\Phi_0}, a {\beta_2} {\ell}^{2} t + a {\beta_2} \Psi_{1}\left(y\right) + {\Psi_0}\right) \end{array}
In [43]:
F.jacobian_matrix()
(10010a2yμ1(y)aβ12aβ1yΦ1(y)aβ22aβ2yΨ1(y))\left(\begin{array}{rr} 1 & 0 \\ 0 & 1 \\ 0 & a^{2} \frac{\partial}{\partial y}\mu_{1}\left(y\right) \\ a {\beta_1} {\ell}^{2} & a {\beta_1} \frac{\partial}{\partial y}\Phi_{1}\left(y\right) \\ a {\beta_2} {\ell}^{2} & a {\beta_2} \frac{\partial}{\partial y}\Psi_{1}\left(y\right) \end{array}\right)

Induced metric on the string worldsheet

The string worldsheet metric is the metric gg induced by the spacetime metric GG, i.e. the pullback of GG by the embedding FF:

In [44]:
g = W.metric() g.set(F.pullback(G))
In [45]:
g[0,0]
2(a12β122a12β1β2+a12β22)4mμ1(y)4+8(μ0a10β122μ0a10β1β2+μ0a10β22)4mμ1(y)3((μ02a8β22(μ021)a8β12)10(3μ02a6β223(μ021)a6β12+a6)8+3(μ02a4β22(μ021)a4β12+a4)6(μ02a2β22(μ021)a2β12+3a2)4+2)y4+(a663a44+3a221)y2+(((a12β12a12β22)103(a10β12a10β22)8+3(a8β12a8β22)6(a6β12a6β22)4)y4+4((3μ02a8β22+(3μ021)a8β12(6μ021)a8β1β2)4+(a6β1a6β2)2)m)μ1(y)2+2((μ04a4β22+(μ042μ02+1)a4β122(μ04μ02)a4β1β2)42(μ02a2β2(μ021)a2β1)2+1)m+2(((μ0a10β12μ0a10β22)103(μ0a8β12μ0a8β22)8+3(μ0a6β12μ0a6β22)6(μ0a4β12μ0a4β22)4)y4+4((μ03a6β22+(μ03μ0)a6β12(2μ03μ0)a6β1β2)4+(μ0a4β1μ0a4β2)2)m)μ1(y)(a663a44+3a221)y2-\frac{2 \, {\left(a^{12} {\beta_1}^{2} - 2 \, a^{12} {\beta_1} {\beta_2} + a^{12} {\beta_2}^{2}\right)} {\ell}^{4} m \mu_{1}\left(y\right)^{4} + 8 \, {\left({\mu_0} a^{10} {\beta_1}^{2} - 2 \, {\mu_0} a^{10} {\beta_1} {\beta_2} + {\mu_0} a^{10} {\beta_2}^{2}\right)} {\ell}^{4} m \mu_{1}\left(y\right)^{3} - {\left({\left({\mu_0}^{2} a^{8} {\beta_2}^{2} - {\left({\mu_0}^{2} - 1\right)} a^{8} {\beta_1}^{2}\right)} {\ell}^{10} - {\left(3 \, {\mu_0}^{2} a^{6} {\beta_2}^{2} - 3 \, {\left({\mu_0}^{2} - 1\right)} a^{6} {\beta_1}^{2} + a^{6}\right)} {\ell}^{8} + 3 \, {\left({\mu_0}^{2} a^{4} {\beta_2}^{2} - {\left({\mu_0}^{2} - 1\right)} a^{4} {\beta_1}^{2} + a^{4}\right)} {\ell}^{6} - {\left({\mu_0}^{2} a^{2} {\beta_2}^{2} - {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} + 3 \, a^{2}\right)} {\ell}^{4} + {\ell}^{2}\right)} y^{4} + {\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{2} + {\left({\left({\left(a^{12} {\beta_1}^{2} - a^{12} {\beta_2}^{2}\right)} {\ell}^{10} - 3 \, {\left(a^{10} {\beta_1}^{2} - a^{10} {\beta_2}^{2}\right)} {\ell}^{8} + 3 \, {\left(a^{8} {\beta_1}^{2} - a^{8} {\beta_2}^{2}\right)} {\ell}^{6} - {\left(a^{6} {\beta_1}^{2} - a^{6} {\beta_2}^{2}\right)} {\ell}^{4}\right)} y^{4} + 4 \, {\left({\left(3 \, {\mu_0}^{2} a^{8} {\beta_2}^{2} + {\left(3 \, {\mu_0}^{2} - 1\right)} a^{8} {\beta_1}^{2} - {\left(6 \, {\mu_0}^{2} - 1\right)} a^{8} {\beta_1} {\beta_2}\right)} {\ell}^{4} + {\left(a^{6} {\beta_1} - a^{6} {\beta_2}\right)} {\ell}^{2}\right)} m\right)} \mu_{1}\left(y\right)^{2} + 2 \, {\left({\left({\mu_0}^{4} a^{4} {\beta_2}^{2} + {\left({\mu_0}^{4} - 2 \, {\mu_0}^{2} + 1\right)} a^{4} {\beta_1}^{2} - 2 \, {\left({\mu_0}^{4} - {\mu_0}^{2}\right)} a^{4} {\beta_1} {\beta_2}\right)} {\ell}^{4} - 2 \, {\left({\mu_0}^{2} a^{2} {\beta_2} - {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}\right)} {\ell}^{2} + 1\right)} m + 2 \, {\left({\left({\left({\mu_0} a^{10} {\beta_1}^{2} - {\mu_0} a^{10} {\beta_2}^{2}\right)} {\ell}^{10} - 3 \, {\left({\mu_0} a^{8} {\beta_1}^{2} - {\mu_0} a^{8} {\beta_2}^{2}\right)} {\ell}^{8} + 3 \, {\left({\mu_0} a^{6} {\beta_1}^{2} - {\mu_0} a^{6} {\beta_2}^{2}\right)} {\ell}^{6} - {\left({\mu_0} a^{4} {\beta_1}^{2} - {\mu_0} a^{4} {\beta_2}^{2}\right)} {\ell}^{4}\right)} y^{4} + 4 \, {\left({\left({\mu_0}^{3} a^{6} {\beta_2}^{2} + {\left({\mu_0}^{3} - {\mu_0}\right)} a^{6} {\beta_1}^{2} - {\left(2 \, {\mu_0}^{3} - {\mu_0}\right)} a^{6} {\beta_1} {\beta_2}\right)} {\ell}^{4} + {\left({\mu_0} a^{4} {\beta_1} - {\mu_0} a^{4} {\beta_2}\right)} {\ell}^{2}\right)} m\right)} \mu_{1}\left(y\right)}{{\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{2}}