Kernel: SageMath 9.3

5D Kerr-AdS spacetime with a Nambu-Goto string

Case a = b with global AdS coordinates

This SageMath notebook is relative to the article Holographic drag force in 5d Kerr-AdS black hole by Irina Ya. Aref'eva, Anastasia A. Golubtsova and Eric Gourgoulhon, arXiv:2004.12984.

The involved differential geometry computations are based on tools developed through the SageManifolds project.

NB: a version of SageMath at least equal to 8.2 is required to run this notebook:

In [1]:

version()

'SageMath version 9.3, Release Date: 2021-05-09'

First we set up the notebook to display mathematical objects using LaTeX rendering:

In [2]:

%display latex

Since some computations are quite long, we ask for running them in parallel on 8 cores:

In [3]:

Parallelism().set(nproc=1)  # only nproc=1 works on CoCalc

Spacetime manifold

We declare the Kerr-AdS spacetime as a 5-dimensional Lorentzian manifold:

In [4]:

M = Manifold(5, 'M', r'\mathcal{M}', structure='Lorentzian', metric_name='G')
print(M)

5-dimensional Lorentzian manifold M

Let us define Boyer-Lindquist-type coordinates (rational polynomial version) on $\mathcal{M}$ , via the method chart(), the argument of which is a string expressing the coordinates names, their ranges (the default is $(-\infty,+\infty)$ ) and their LaTeX symbols:

In [5]:

BL.<t,r,mu,ph,ps> = M.chart(r't r:(0,+oo) mu:(0,1):\mu ph:(0,2*pi):\phi ps:(0,2*pi):\psi')
BL

\renewcommand{\Bold}[1]{\mathbf{#1}}\left(\mathcal{M},(t, r, {\mu}, {\phi}, {\psi})\right)

The coordinate $\mu$ is related to the standard Boyer-Lindquist coordinate $\theta$ by $\mu = \cos\theta$

The coordinate ranges are

In [6]:

BL.coord_range()

\renewcommand{\Bold}[1]{\mathbf{#1}}t :\ \left( -\infty, +\infty \right) ;\quad r :\ \left( 0 , +\infty \right) ;\quad {\mu} :\ \left( 0 , 1 \right) ;\quad {\phi} :\ \left( 0 , 2 \, \pi \right) ;\quad {\psi} :\ \left( 0 , 2 \, \pi \right)

Note that contrary to the 4-dimensional case, the range of $\mu$ is $(0,1)$ only (cf. Sec. 1.2 of R.C. Myers, arXiv:1111.1903 or Sec. 2 of G.W. Gibbons, H. Lüb, Don N. Page, C.N. Pope, J. Geom. Phys. 53, 49 (2005)). In other words, the range of $\theta$ is $\left(0, \frac{\pi}{2}\right)$ only.

Metric tensor

The 4 parameters $m$ , $a$ , $b$ and $\ell$ of the Kerr-AdS spacetime are declared as symbolic variables, $a$ and $b$ being the two angular momentum parameters and $\ell$ being related to the cosmological constant by $\Lambda = - 6 \ell^2$ :

In [7]:

var('m a b', domain='real')

\renewcommand{\Bold}[1]{\mathbf{#1}}\left(m, a, b\right)

In [8]:

var('l', domain='real', latex_name=r'\ell')

\renewcommand{\Bold}[1]{\mathbf{#1}}{\ell}

In [9]:

# Particular cases
# m = 0
# a = 0
# b = 0
b = a

In [10]:

assume(a > 0)
assume(1 - a^2*l^2 > 0)

Some auxiliary functions:

In [11]:

keep_Delta = False  # change to False to provide explicit expression for Delta_r, Xi_a, etc...

In [12]:

sig = (1 + r^2*l^2)/r^2
costh2 = mu^2
sinth2 = 1 - mu^2
rho2 = r^2 + a^2*mu^2 + b^2*sinth2
if keep_Delta:
    Delta_r = var('Delta_r', latex_name=r'\Delta_r', domain='real')
    Delta_th = var('Delta_th', latex_name=r'\Delta_\theta', domain='real')
    if a == b:
        Xi_a = var('Xi', latex_name=r'\Xi', domain='real')
        Xi_b = Xi_a
    else:
        Xi_a = var('Xi_a', latex_name=r'\Xi_a', domain='real')
        Xi_b = var('Xi_b', latex_name=r'\Xi_b', domain='real')
    #Delta_th = 1 - a^2*l^2*mu^2 - b^2*l^2*sinth2
    Xi_a = 1 - a^2*l^2
    Xi_b = 1 - b^2*l^2
else:
    Delta_r = (r^2+a^2)*(r^2+b^2)*sig - 2*m
    Delta_th = 1 - a^2*l^2*mu^2 - b^2*l^2*sinth2
    Xi_a = 1 - a^2*l^2
    Xi_b = 1 - b^2*l^2

The metric is set by its components in the coordinate frame associated with the Boyer-Lindquist-type coordinates, which is the current manifold's default frame. These components can be deduced from Eq. (5.22) of the article S.W. Hawking, C.J. Hunter & M.M. Taylor-Robinson, Phys. Rev. D 59, 064005 (1999) (the check of agreement with this equation is performed below):

In [13]:

G = M.metric()
tmp = 1/rho2*( -Delta_r + Delta_th*(a^2*sinth2 + b^2*mu^2) + a^2*b^2*sig )
G[0,0] = tmp.simplify_full()
tmp = a*sinth2/(rho2*Xi_a)*( Delta_r - (r^2+a^2)*(Delta_th + b^2*sig) )
G[0,3] = tmp.simplify_full()
tmp = b*mu^2/(rho2*Xi_b)*( Delta_r - (r^2+b^2)*(Delta_th + a^2*sig) )
G[0,4] = tmp.simplify_full()
G[1,1] = (rho2/Delta_r).simplify_full()
G[2,2] = (rho2/Delta_th/(1-mu^2)).simplify_full()
tmp = sinth2/(rho2*Xi_a^2)*( - Delta_r*a^2*sinth2 + (r^2+a^2)^2*(Delta_th + sig*b^2*sinth2) ) 
G[3,3] = tmp.simplify_full()
tmp = a*b*sinth2*mu^2/(rho2*Xi_a*Xi_b)*( - Delta_r + sig*(r^2+a^2)*(r^2+b^2) )
G[3,4] = tmp.simplify_full()
tmp = mu^2/(rho2*Xi_b^2)*( - Delta_r*b^2*mu^2 + (r^2+b^2)^2*(Delta_th + sig*a^2*mu^2) )
G[4,4] = tmp.simplify_full()
G.display()

\renewcommand{\Bold}[1]{\mathbf{#1}}G = \left( -\frac{a^{4} {\ell}^{2} + {\ell}^{2} r^{4} + {\left(2 \, a^{2} {\ell}^{2} + 1\right)} r^{2} + a^{2} - 2 \, m}{a^{2} + r^{2}} \right) \mathrm{d} t\otimes \mathrm{d} t + \left( -\frac{a^{5} {\ell}^{2} - {\left(a {\ell}^{2} {\mu}^{2} - a {\ell}^{2}\right)} r^{4} - {\left(a^{5} {\ell}^{2} - 2 \, a m\right)} {\mu}^{2} - 2 \, {\left(a^{3} {\ell}^{2} {\mu}^{2} - a^{3} {\ell}^{2}\right)} r^{2} - 2 \, a m}{a^{4} {\ell}^{2} + {\left(a^{2} {\ell}^{2} - 1\right)} r^{2} - a^{2}} \right) \mathrm{d} t\otimes \mathrm{d} {\phi} + \left( -\frac{2 \, a^{3} {\ell}^{2} {\mu}^{2} r^{2} + a {\ell}^{2} {\mu}^{2} r^{4} + {\left(a^{5} {\ell}^{2} - 2 \, a m\right)} {\mu}^{2}}{a^{4} {\ell}^{2} + {\left(a^{2} {\ell}^{2} - 1\right)} r^{2} - a^{2}} \right) \mathrm{d} t\otimes \mathrm{d} {\psi} + \left( \frac{a^{2} r^{2} + r^{4}}{{\ell}^{2} r^{6} + {\left(2 \, a^{2} {\ell}^{2} + 1\right)} r^{4} + a^{4} + {\left(a^{4} {\ell}^{2} + 2 \, a^{2} - 2 \, m\right)} r^{2}} \right) \mathrm{d} r\otimes \mathrm{d} r + \left( -\frac{a^{2} + r^{2}}{a^{2} {\ell}^{2} - {\left(a^{2} {\ell}^{2} - 1\right)} {\mu}^{2} - 1} \right) \mathrm{d} {\mu}\otimes \mathrm{d} {\mu} + \left( -\frac{a^{5} {\ell}^{2} - {\left(a {\ell}^{2} {\mu}^{2} - a {\ell}^{2}\right)} r^{4} - {\left(a^{5} {\ell}^{2} - 2 \, a m\right)} {\mu}^{2} - 2 \, {\left(a^{3} {\ell}^{2} {\mu}^{2} - a^{3} {\ell}^{2}\right)} r^{2} - 2 \, a m}{a^{4} {\ell}^{2} + {\left(a^{2} {\ell}^{2} - 1\right)} r^{2} - a^{2}} \right) \mathrm{d} {\phi}\otimes \mathrm{d} t + \left( -\frac{a^{6} {\ell}^{2} - 2 \, a^{2} m {\mu}^{4} + {\left(a^{2} {\ell}^{2} - {\left(a^{2} {\ell}^{2} - 1\right)} {\mu}^{2} - 1\right)} r^{4} - a^{4} - 2 \, a^{2} m - {\left(a^{6} {\ell}^{2} - a^{4} - 4 \, a^{2} m\right)} {\mu}^{2} + 2 \, {\left(a^{4} {\ell}^{2} - {\left(a^{4} {\ell}^{2} - a^{2}\right)} {\mu}^{2} - a^{2}\right)} r^{2}}{a^{6} {\ell}^{4} - 2 \, a^{4} {\ell}^{2} + {\left(a^{4} {\ell}^{4} - 2 \, a^{2} {\ell}^{2} + 1\right)} r^{2} + a^{2}} \right) \mathrm{d} {\phi}\otimes \mathrm{d} {\phi} + \left( -\frac{2 \, {\left(a^{2} m {\mu}^{4} - a^{2} m {\mu}^{2}\right)}}{a^{6} {\ell}^{4} - 2 \, a^{4} {\ell}^{2} + {\left(a^{4} {\ell}^{4} - 2 \, a^{2} {\ell}^{2} + 1\right)} r^{2} + a^{2}} \right) \mathrm{d} {\phi}\otimes \mathrm{d} {\psi} + \left( -\frac{2 \, a^{3} {\ell}^{2} {\mu}^{2} r^{2} + a {\ell}^{2} {\mu}^{2} r^{4} + {\left(a^{5} {\ell}^{2} - 2 \, a m\right)} {\mu}^{2}}{a^{4} {\ell}^{2} + {\left(a^{2} {\ell}^{2} - 1\right)} r^{2} - a^{2}} \right) \mathrm{d} {\psi}\otimes \mathrm{d} t + \left( -\frac{2 \, {\left(a^{2} m {\mu}^{4} - a^{2} m {\mu}^{2}\right)}}{a^{6} {\ell}^{4} - 2 \, a^{4} {\ell}^{2} + {\left(a^{4} {\ell}^{4} - 2 \, a^{2} {\ell}^{2} + 1\right)} r^{2} + a^{2}} \right) \mathrm{d} {\psi}\otimes \mathrm{d} {\phi} + \left( \frac{2 \, a^{2} m {\mu}^{4} - {\left(a^{2} {\ell}^{2} - 1\right)} {\mu}^{2} r^{4} - 2 \, {\left(a^{4} {\ell}^{2} - a^{2}\right)} {\mu}^{2} r^{2} - {\left(a^{6} {\ell}^{2} - a^{4}\right)} {\mu}^{2}}{a^{6} {\ell}^{4} - 2 \, a^{4} {\ell}^{2} + {\left(a^{4} {\ell}^{4} - 2 \, a^{2} {\ell}^{2} + 1\right)} r^{2} + a^{2}} \right) \mathrm{d} {\psi}\otimes \mathrm{d} {\psi}

In [14]:

G.display_comp(only_nonredundant=True)

\renewcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{lcl} G_{ \, t \, t }^{ \phantom{\, t}\phantom{\, t} } & = & -\frac{a^{4} {\ell}^{2} + {\ell}^{2} r^{4} + {\left(2 \, a^{2} {\ell}^{2} + 1\right)} r^{2} + a^{2} - 2 \, m}{a^{2} + r^{2}} \\ G_{ \, t \, {\phi} }^{ \phantom{\, t}\phantom{\, {\phi}} } & = & -\frac{a^{5} {\ell}^{2} - {\left(a {\ell}^{2} {\mu}^{2} - a {\ell}^{2}\right)} r^{4} - {\left(a^{5} {\ell}^{2} - 2 \, a m\right)} {\mu}^{2} - 2 \, {\left(a^{3} {\ell}^{2} {\mu}^{2} - a^{3} {\ell}^{2}\right)} r^{2} - 2 \, a m}{a^{4} {\ell}^{2} + {\left(a^{2} {\ell}^{2} - 1\right)} r^{2} - a^{2}} \\ G_{ \, t \, {\psi} }^{ \phantom{\, t}\phantom{\, {\psi}} } & = & -\frac{2 \, a^{3} {\ell}^{2} {\mu}^{2} r^{2} + a {\ell}^{2} {\mu}^{2} r^{4} + {\left(a^{5} {\ell}^{2} - 2 \, a m\right)} {\mu}^{2}}{a^{4} {\ell}^{2} + {\left(a^{2} {\ell}^{2} - 1\right)} r^{2} - a^{2}} \\ G_{ \, r \, r }^{ \phantom{\, r}\phantom{\, r} } & = & \frac{a^{2} r^{2} + r^{4}}{{\ell}^{2} r^{6} + {\left(2 \, a^{2} {\ell}^{2} + 1\right)} r^{4} + a^{4} + {\left(a^{4} {\ell}^{2} + 2 \, a^{2} - 2 \, m\right)} r^{2}} \\ G_{ \, {\mu} \, {\mu} }^{ \phantom{\, {\mu}}\phantom{\, {\mu}} } & = & -\frac{a^{2} + r^{2}}{a^{2} {\ell}^{2} - {\left(a^{2} {\ell}^{2} - 1\right)} {\mu}^{2} - 1} \\ G_{ \, {\phi} \, {\phi} }^{ \phantom{\, {\phi}}\phantom{\, {\phi}} } & = & -\frac{a^{6} {\ell}^{2} - 2 \, a^{2} m {\mu}^{4} + {\left(a^{2} {\ell}^{2} - {\left(a^{2} {\ell}^{2} - 1\right)} {\mu}^{2} - 1\right)} r^{4} - a^{4} - 2 \, a^{2} m - {\left(a^{6} {\ell}^{2} - a^{4} - 4 \, a^{2} m\right)} {\mu}^{2} + 2 \, {\left(a^{4} {\ell}^{2} - {\left(a^{4} {\ell}^{2} - a^{2}\right)} {\mu}^{2} - a^{2}\right)} r^{2}}{a^{6} {\ell}^{4} - 2 \, a^{4} {\ell}^{2} + {\left(a^{4} {\ell}^{4} - 2 \, a^{2} {\ell}^{2} + 1\right)} r^{2} + a^{2}} \\ G_{ \, {\phi} \, {\psi} }^{ \phantom{\, {\phi}}\phantom{\, {\psi}} } & = & -\frac{2 \, {\left(a^{2} m {\mu}^{4} - a^{2} m {\mu}^{2}\right)}}{a^{6} {\ell}^{4} - 2 \, a^{4} {\ell}^{2} + {\left(a^{4} {\ell}^{4} - 2 \, a^{2} {\ell}^{2} + 1\right)} r^{2} + a^{2}} \\ G_{ \, {\psi} \, {\psi} }^{ \phantom{\, {\psi}}\phantom{\, {\psi}} } & = & \frac{2 \, a^{2} m {\mu}^{4} - {\left(a^{2} {\ell}^{2} - 1\right)} {\mu}^{2} r^{4} - 2 \, {\left(a^{4} {\ell}^{2} - a^{2}\right)} {\mu}^{2} r^{2} - {\left(a^{6} {\ell}^{2} - a^{4}\right)} {\mu}^{2}}{a^{6} {\ell}^{4} - 2 \, a^{4} {\ell}^{2} + {\left(a^{4} {\ell}^{4} - 2 \, a^{2} {\ell}^{2} + 1\right)} r^{2} + a^{2}} \end{array}

Check of agreement with Eq. (5.22) of Hawking et al or Eq. (2.3) of o

We need the 1-forms $\mathrm{d}t$ , $\mathrm{d}r$ , $\mathrm{d}\mu$ , $\mathrm{d}\phi$ and $\mathrm{d}\psi$ :

In [15]:

dt, dr, dmu, dph, dps = (BL.coframe()[i] for i in M.irange())
dt, dr, dmu, dph, dps

\renewcommand{\Bold}[1]{\mathbf{#1}}\left(\mathrm{d} t, \mathrm{d} r, \mathrm{d} {\mu}, \mathrm{d} {\phi}, \mathrm{d} {\psi}\right)

In [16]:

print(dt)

1-form dt on the 5-dimensional Lorentzian manifold M

In agreement with $\mu = \cos\theta$ , we introduce the 1-form $\mathrm{d}\theta = - \mathrm{d}\mu /\sin\theta$ , with $\sin\theta = \sqrt{1-\mu^2}$ since $\theta\in\left(0, \frac{\pi}{2}\right)$ :

In [17]:

dth = - 1/sqrt(1 - mu^2)*dmu

In [18]:

s1 = dt - a*sinth2/Xi_a*dph - b*costh2/Xi_b*dps
s1.display()

\renewcommand{\Bold}[1]{\mathbf{#1}}\mathrm{d} t + \left( -\frac{a {\mu}^{2} - a}{a^{2} {\ell}^{2} - 1} \right) \mathrm{d} {\phi} + \left( \frac{a {\mu}^{2}}{a^{2} {\ell}^{2} - 1} \right) \mathrm{d} {\psi}

In [19]:

s2 = a*dt - (r^2 + a^2)/Xi_a*dph
s2.display()

\renewcommand{\Bold}[1]{\mathbf{#1}}a \mathrm{d} t + \left( \frac{a^{2} + r^{2}}{a^{2} {\ell}^{2} - 1} \right) \mathrm{d} {\phi}

In [20]:

s3 = b*dt - (r^2 + b^2)/Xi_b*dps
s3.display()

\renewcommand{\Bold}[1]{\mathbf{#1}}a \mathrm{d} t + \left( \frac{a^{2} + r^{2}}{a^{2} {\ell}^{2} - 1} \right) \mathrm{d} {\psi}

In [21]:

s4 = a*b*dt - b*(r^2 + a^2)*sinth2/Xi_a * dph - a*(r^2 + b^2)*costh2/Xi_b * dps
s4.display()

\renewcommand{\Bold}[1]{\mathbf{#1}}a^{2} \mathrm{d} t + \left( -\frac{a^{3} {\mu}^{2} - a^{3} + {\left(a {\mu}^{2} - a\right)} r^{2}}{a^{2} {\ell}^{2} - 1} \right) \mathrm{d} {\phi} + \left( \frac{a^{3} {\mu}^{2} + a {\mu}^{2} r^{2}}{a^{2} {\ell}^{2} - 1} \right) \mathrm{d} {\psi}

In [22]:

G0 = - Delta_r/rho2 * s1*s1 + Delta_th*sinth2/rho2 * s2*s2 + Delta_th*costh2/rho2 * s3*s3 \
     + rho2/Delta_r * dr*dr + rho2/Delta_th * dth*dth + sig/rho2 * s4*s4
G0.display_comp(only_nonredundant=True)

\renewcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{lcl} X_{ \, t \, t }^{ \phantom{\, t}\phantom{\, t} } & = & -\frac{a^{4} {\ell}^{2} + {\ell}^{2} r^{4} + {\left(2 \, a^{2} {\ell}^{2} + 1\right)} r^{2} + a^{2} - 2 \, m}{a^{2} + r^{2}} \\ X_{ \, t \, {\phi} }^{ \phantom{\, t}\phantom{\, {\phi}} } & = & -\frac{a^{5} {\ell}^{2} - {\left(a {\ell}^{2} {\mu}^{2} - a {\ell}^{2}\right)} r^{4} - {\left(a^{5} {\ell}^{2} - 2 \, a m\right)} {\mu}^{2} - 2 \, {\left(a^{3} {\ell}^{2} {\mu}^{2} - a^{3} {\ell}^{2}\right)} r^{2} - 2 \, a m}{a^{4} {\ell}^{2} + {\left(a^{2} {\ell}^{2} - 1\right)} r^{2} - a^{2}} \\ X_{ \, t \, {\psi} }^{ \phantom{\, t}\phantom{\, {\psi}} } & = & -\frac{2 \, a^{3} {\ell}^{2} {\mu}^{2} r^{2} + a {\ell}^{2} {\mu}^{2} r^{4} + {\left(a^{5} {\ell}^{2} - 2 \, a m\right)} {\mu}^{2}}{a^{4} {\ell}^{2} + {\left(a^{2} {\ell}^{2} - 1\right)} r^{2} - a^{2}} \\ X_{ \, r \, r }^{ \phantom{\, r}\phantom{\, r} } & = & -\frac{a^{2} {\mu}^{2} - {\left({\mu}^{2} - 1\right)} a^{2} + r^{2}}{2 \, m - \frac{{\left({\ell}^{2} r^{2} + 1\right)} {\left(a^{2} + r^{2}\right)}^{2}}{r^{2}}} \\ X_{ \, {\mu} \, {\mu} }^{ \phantom{\, {\mu}}\phantom{\, {\mu}} } & = & -\frac{a^{2} + r^{2}}{a^{2} {\ell}^{2} - {\left(a^{2} {\ell}^{2} - 1\right)} {\mu}^{2} - 1} \\ X_{ \, {\phi} \, t }^{ \phantom{\, {\phi}}\phantom{\, t} } & = & -\frac{a^{5} {\ell}^{2} - {\left(a {\ell}^{2} {\mu}^{2} - a {\ell}^{2}\right)} r^{4} - {\left(a^{5} {\ell}^{2} - 2 \, a m\right)} {\mu}^{2} - 2 \, {\left(a^{3} {\ell}^{2} {\mu}^{2} - a^{3} {\ell}^{2}\right)} r^{2} - 2 \, a m}{a^{4} {\ell}^{2} + {\left(a^{2} {\ell}^{2} - 1\right)} r^{2} - a^{2}} \\ X_{ \, {\phi} \, {\phi} }^{ \phantom{\, {\phi}}\phantom{\, {\phi}} } & = & -\frac{a^{6} {\ell}^{2} - 2 \, a^{2} m {\mu}^{4} + {\left(a^{2} {\ell}^{2} - {\left(a^{2} {\ell}^{2} - 1\right)} {\mu}^{2} - 1\right)} r^{4} - a^{4} - 2 \, a^{2} m - {\left(a^{6} {\ell}^{2} - a^{4} - 4 \, a^{2} m\right)} {\mu}^{2} + 2 \, {\left(a^{4} {\ell}^{2} - {\left(a^{4} {\ell}^{2} - a^{2}\right)} {\mu}^{2} - a^{2}\right)} r^{2}}{a^{6} {\ell}^{4} - 2 \, a^{4} {\ell}^{2} + {\left(a^{4} {\ell}^{4} - 2 \, a^{2} {\ell}^{2} + 1\right)} r^{2} + a^{2}} \\ X_{ \, {\phi} \, {\psi} }^{ \phantom{\, {\phi}}\phantom{\, {\psi}} } & = & -\frac{2 \, {\left(a^{2} m {\mu}^{4} - a^{2} m {\mu}^{2}\right)}}{a^{6} {\ell}^{4} - 2 \, a^{4} {\ell}^{2} + {\left(a^{4} {\ell}^{4} - 2 \, a^{2} {\ell}^{2} + 1\right)} r^{2} + a^{2}} \\ X_{ \, {\psi} \, t }^{ \phantom{\, {\psi}}\phantom{\, t} } & = & -\frac{2 \, a^{3} {\ell}^{2} {\mu}^{2} r^{2} + a {\ell}^{2} {\mu}^{2} r^{4} + {\left(a^{5} {\ell}^{2} - 2 \, a m\right)} {\mu}^{2}}{a^{4} {\ell}^{2} + {\left(a^{2} {\ell}^{2} - 1\right)} r^{2} - a^{2}} \\ X_{ \, {\psi} \, {\phi} }^{ \phantom{\, {\psi}}\phantom{\, {\phi}} } & = & -\frac{2 \, {\left(a^{2} m {\mu}^{4} - a^{2} m {\mu}^{2}\right)}}{a^{6} {\ell}^{4} - 2 \, a^{4} {\ell}^{2} + {\left(a^{4} {\ell}^{4} - 2 \, a^{2} {\ell}^{2} + 1\right)} r^{2} + a^{2}} \\ X_{ \, {\psi} \, {\psi} }^{ \phantom{\, {\psi}}\phantom{\, {\psi}} } & = & \frac{2 \, a^{2} m {\mu}^{4} - {\left(a^{2} {\ell}^{2} - 1\right)} {\mu}^{2} r^{4} - 2 \, {\left(a^{4} {\ell}^{2} - a^{2}\right)} {\mu}^{2} r^{2} - {\left(a^{6} {\ell}^{2} - a^{4}\right)} {\mu}^{2}}{a^{6} {\ell}^{4} - 2 \, a^{4} {\ell}^{2} + {\left(a^{4} {\ell}^{4} - 2 \, a^{2} {\ell}^{2} + 1\right)} r^{2} + a^{2}} \end{array}

In [23]:

G0 == G

\renewcommand{\Bold}[1]{\mathbf{#1}}\mathrm{True}

Einstein equation

The Ricci tensor of $g$ is

In [24]:

if not keep_Delta:
    # Ric = G.ricci()
    # print(Ric)
    pass

In [25]:

if not keep_Delta:
    # show(Ric.display_comp(only_nonredundant=True))
    pass

Let us check that $g$ is a solution of the vacuum Einstein equation with the cosmological constant $\Lambda = - 6 \ell^2$ :

In [26]:

Lambda = -6*l^2
if not keep_Delta:
    # print(Ric == 2/3*Lambda*G)
    pass

Check of Eq. (2.10)

One must have $a=b$ and keep_Delta == False for the test to pass:

In [27]:

if a == b and not keep_Delta:
    G1 = - (1 + rho2*l^2 - 2*m/rho2) * dt*dt + rho2/Delta_r * dr*dr \
         + rho2/Delta_th * dth*dth \
         + sinth2/Xi_a^2*(rho2*Xi_a + 2*a^2*m/rho2*sinth2) * dph * dph \
         + costh2/Xi_a^2*(rho2*Xi_a + 2*a^2*m/rho2*costh2) * dps * dps \
         + a*sinth2/Xi_a*(rho2*l^2 - 2*m/rho2) * (dt*dph + dph*dt) \
         + a*costh2/Xi_a*(rho2*l^2 - 2*m/rho2) * (dt*dps + dps*dt) \
         + 2*m*a^2*sinth2*costh2/Xi_a^2/rho2 * (dph*dps + dps*dph)
    print(G1 == G)

True

Global AdS coordinates

In [28]:

ADS.<T,y,mu,Ph,Ps> = M.chart(r't y:(a/sqrt(1-a^2*l^2),+oo) mu:(0,1):\mu Ph:(0,2*pi):\Phi Ps:(0,2*pi):\Psi')
ADS

\renewcommand{\Bold}[1]{\mathbf{#1}}\left(\mathcal{M},(t, y, {\mu}, {\Phi}, {\Psi})\right)

In [29]:

ADS.coord_range()

\renewcommand{\Bold}[1]{\mathbf{#1}}t :\ \left( -\infty, +\infty \right) ;\quad y :\ \left( \frac{a}{\sqrt{-a^{2} {\ell}^{2} + 1}} , +\infty \right) ;\quad {\mu} :\ \left( 0 , 1 \right) ;\quad {\Phi} :\ \left( 0 , 2 \, \pi \right) ;\quad {\Psi} :\ \left( 0 , 2 \, \pi \right)

In [30]:

assumptions()

\renewcommand{\Bold}[1]{\mathbf{#1}}\left[\verb|t|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, \verb|r|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, r > 0, \verb|mu|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, {\mu} > 0, {\mu} < 1, \verb|ph|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, {\phi} > 0, {\phi} < 2 \, \pi, \verb|ps|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, {\psi} > 0, {\psi} < 2 \, \pi, \verb|m|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, \verb|a|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, \verb|b|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, \verb|l|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, a > 0, -a^{2} {\ell}^{2} + 1 > 0, \verb|y|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, y > \frac{a}{\sqrt{-a^{2} {\ell}^{2} + 1}}, \verb|Ph|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, {\Phi} > 0, {\Phi} < 2 \, \pi, \verb|Ps|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, {\Psi} > 0, {\Psi} < 2 \, \pi\right]

Transition from the Boyer-Lindquist coordinates to the AdS global coordinates, according to Eq. (5.24) of S.W. Hawking, C.J. Hunter & M.M. Taylor-Robinson, Phys. Rev. D 59, 064005 (1999):

In [31]:

BL_to_ADS = BL.transition_map(ADS, [t, sqrt(r^2 + a^2)/sqrt(Xi_a), mu, 
                                    ph + a*l^2*t, ps + a*l^2*t])
BL_to_ADS.display()

\renewcommand{\Bold}[1]{\mathbf{#1}}\left\{\begin{array}{lcl} t & = & t \\ y & = & \frac{\sqrt{a^{2} + r^{2}}}{\sqrt{-a^{2} {\ell}^{2} + 1}} \\ {\mu} & = & {\mu} \\ {\Phi} & = & a {\ell}^{2} t + {\phi} \\ {\Psi} & = & a {\ell}^{2} t + {\psi} \end{array}\right.

In [32]:

BL_to_ADS.set_inverse(t, sqrt(Xi_a*y^2 - a^2), mu, Ph - a*l^2*t, Ps - a*l^2*t, 
                      verbose=True)
BL_to_ADS.inverse().display()

Check of the inverse coordinate transformation:
  t == t  *passed*
  r == r  *passed*
  mu == mu  *passed*
  ph == ph  *passed*
  ps == ps  *passed*
  t == t  *passed*
  y == abs(y)  **failed**
  mu == mu  *passed*
  Ph == Ph  *passed*
  Ps == Ps  *passed*
NB: a failed report can reflect a mere lack of simplification.

\renewcommand{\Bold}[1]{\mathbf{#1}}\left\{\begin{array}{lcl} t & = & t \\ r & = & \sqrt{-{\left(a^{2} {\ell}^{2} - 1\right)} y^{2} - a^{2}} \\ {\mu} & = & {\mu} \\ {\phi} & = & -a {\ell}^{2} t + {\Phi} \\ {\psi} & = & -a {\ell}^{2} t + {\Psi} \end{array}\right.

Metric tensor is global AdS coordinates

In [33]:

G.display_comp(chart=ADS, only_nonredundant=True)

\renewcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{lcl} G_{ \, t \, t }^{ \phantom{\, t}\phantom{\, t} } & = & -\frac{{\left(a^{6} {\ell}^{8} - 3 \, a^{4} {\ell}^{6} + 3 \, a^{2} {\ell}^{4} - {\ell}^{2}\right)} y^{4} + {\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{2} + 2 \, m}{{\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{2}} \\ G_{ \, t \, {\Phi} }^{ \phantom{\, t}\phantom{\, {\Phi}} } & = & -\frac{2 \, {\left(a m {\mu}^{2} - a m\right)}}{{\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{2}} \\ G_{ \, t \, {\Psi} }^{ \phantom{\, t}\phantom{\, {\Psi}} } & = & \frac{2 \, a m {\mu}^{2}}{{\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{2}} \\ G_{ \, y \, y }^{ \phantom{\, y}\phantom{\, y} } & = & \frac{{\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{4}}{{\left(a^{6} {\ell}^{8} - 3 \, a^{4} {\ell}^{6} + 3 \, a^{2} {\ell}^{4} - {\ell}^{2}\right)} y^{6} + {\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{4} - 2 \, {\left(a^{2} {\ell}^{2} - 1\right)} m y^{2} - 2 \, a^{2} m} \\ G_{ \, {\mu} \, {\mu} }^{ \phantom{\, {\mu}}\phantom{\, {\mu}} } & = & -\frac{y^{2}}{{\mu}^{2} - 1} \\ G_{ \, {\Phi} \, {\Phi} }^{ \phantom{\, {\Phi}}\phantom{\, {\Phi}} } & = & -\frac{2 \, a^{2} m {\mu}^{4} - 4 \, a^{2} m {\mu}^{2} - {\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - {\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} {\mu}^{2} - 1\right)} y^{4} + 2 \, a^{2} m}{{\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{2}} \\ G_{ \, {\Phi} \, {\Psi} }^{ \phantom{\, {\Phi}}\phantom{\, {\Psi}} } & = & \frac{2 \, {\left(a^{2} m {\mu}^{4} - a^{2} m {\mu}^{2}\right)}}{{\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{2}} \\ G_{ \, {\Psi} \, {\Psi} }^{ \phantom{\, {\Psi}}\phantom{\, {\Psi}} } & = & -\frac{2 \, a^{2} m {\mu}^{4} - {\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} {\mu}^{2} y^{4}}{{\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{2}} \end{array}

From now on, we set the AdS coordinates as the default chart on $\mathcal{M}$ :

In [34]:

M.set_default_chart(ADS)
M.set_default_frame(ADS.frame())

Then

In [35]:

G.display_comp(only_nonredundant=True)

\renewcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{lcl} G_{ \, t \, t }^{ \phantom{\, t}\phantom{\, t} } & = & -\frac{{\left(a^{6} {\ell}^{8} - 3 \, a^{4} {\ell}^{6} + 3 \, a^{2} {\ell}^{4} - {\ell}^{2}\right)} y^{4} + {\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{2} + 2 \, m}{{\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{2}} \\ G_{ \, t \, {\Phi} }^{ \phantom{\, t}\phantom{\, {\Phi}} } & = & -\frac{2 \, {\left(a m {\mu}^{2} - a m\right)}}{{\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{2}} \\ G_{ \, t \, {\Psi} }^{ \phantom{\, t}\phantom{\, {\Psi}} } & = & \frac{2 \, a m {\mu}^{2}}{{\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{2}} \\ G_{ \, y \, y }^{ \phantom{\, y}\phantom{\, y} } & = & \frac{{\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{4}}{{\left(a^{6} {\ell}^{8} - 3 \, a^{4} {\ell}^{6} + 3 \, a^{2} {\ell}^{4} - {\ell}^{2}\right)} y^{6} + {\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{4} - 2 \, {\left(a^{2} {\ell}^{2} - 1\right)} m y^{2} - 2 \, a^{2} m} \\ G_{ \, {\mu} \, {\mu} }^{ \phantom{\, {\mu}}\phantom{\, {\mu}} } & = & -\frac{y^{2}}{{\mu}^{2} - 1} \\ G_{ \, {\Phi} \, {\Phi} }^{ \phantom{\, {\Phi}}\phantom{\, {\Phi}} } & = & -\frac{2 \, a^{2} m {\mu}^{4} - 4 \, a^{2} m {\mu}^{2} - {\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - {\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} {\mu}^{2} - 1\right)} y^{4} + 2 \, a^{2} m}{{\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{2}} \\ G_{ \, {\Phi} \, {\Psi} }^{ \phantom{\, {\Phi}}\phantom{\, {\Psi}} } & = & \frac{2 \, {\left(a^{2} m {\mu}^{4} - a^{2} m {\mu}^{2}\right)}}{{\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{2}} \\ G_{ \, {\Psi} \, {\Psi} }^{ \phantom{\, {\Psi}}\phantom{\, {\Psi}} } & = & -\frac{2 \, a^{2} m {\mu}^{4} - {\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} {\mu}^{2} y^{4}}{{\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{2}} \end{array}

Comparison with Eq. (5.32) of S.W. Hawking, C.J. Hunter & M.M. Taylor-Robinson, Phys. Rev. D 59, 064005 (1999) (or Eq. (2.18) of our paper):

In [36]:

dt, dy, dmu, dPh, dPs = (ADS.coframe()[i] for i in M.irange())
dt, dy, dmu, dPh, dPs

\renewcommand{\Bold}[1]{\mathbf{#1}}\left(\mathrm{d} t, \mathrm{d} y, \mathrm{d} {\mu}, \mathrm{d} {\Phi}, \mathrm{d} {\Psi}\right)

In [37]:

s = dt - a*sinth2*dPh - a*costh2*dPs
s.display()

\renewcommand{\Bold}[1]{\mathbf{#1}}\mathrm{d} t + \left( a {\mu}^{2} - a \right) \mathrm{d} {\Phi} -a {\mu}^{2} \mathrm{d} {\Psi}

In [38]:

dth.display()

\renewcommand{\Bold}[1]{\mathbf{#1}}\left( -\frac{1}{\sqrt{{\mu} + 1} \sqrt{-{\mu} + 1}} \right) \mathrm{d} {\mu}

In [39]:

G1 = - (1 + y^2*l^2)* dt*dt \
     + y^2*(dth*dth + sinth2* dPh*dPh + costh2* dPs*dPs) \
     + 2*m/(y^2*Xi_a^3)* s*s \
     + y^4/(y^4*(1 + y^2*l^2) - 2*m*y^2/Xi_a^2 + 2*m*a^2/Xi_a^3)* dy*dy
# NB: note the Xi_a^3 term in the factor of s*s differs from Eq. (5.32) of Hawking et al (1999)
G == G1

\renewcommand{\Bold}[1]{\mathbf{#1}}\mathrm{True}

String worldsheet

The string worldsheet as a 2-dimensional pseudo-Riemannian manifold (we don't assume Lorentzian signature here):

In [40]:

W = Manifold(2, 'W', structure='pseudo-Riemannian')
print(W)

2-dimensional Riemannian manifold W

Let us assume that the string worldsheet is parametrized by $(t,y)$ :

In [41]:

XW.<t,y> = W.chart(r't y:(a/sqrt(1-a^2*l^2),+oo)')
XW

\renewcommand{\Bold}[1]{\mathbf{#1}}\left(W,(t, y)\right)

The string embedding in Kerr-AdS spacetime, as an expansion about a straight string solution in AdS (Eqs. (4.30)-(4.32) of the paper)

In [42]:

Mu0 = var('Mu0', latex_name=r'\mu_0', domain='real')
Phi0 = var('Phi0', latex_name=r'\Phi_0', domain='real')
Psi0 = var('Psi0', latex_name=r'\Psi_0', domain='real')
beta1 = var('beta1', latex_name=r'\beta_1', domain='real')
beta2 = var('beta2', latex_name=r'\beta_2', domain='real')

cosTh0 = Mu0
sinTh0 = sqrt(1 - Mu0^2)

mu_s = Mu0 + a^2*function('mu_1')(y)
Ph_s = Phi0 + beta1*a*l^2*t + beta1*a*function('Phi_1')(y)
Ps_s = Psi0 + beta2*a*l^2*t + beta2*a*function('Psi_1')(y)

F = W.diff_map(M, {(XW, ADS): [t, y, mu_s, Ph_s, Ps_s]}, name='F') 
F.display()

\renewcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} F:& W & \longrightarrow & \mathcal{M} \\ & \left(t, y\right) & \longmapsto & \left(t, r, {\mu}, {\phi}, {\psi}\right) = \left(t, \sqrt{-{\left(a^{2} {\ell}^{2} - 1\right)} y^{2} - a^{2}}, a^{2} \mu_{1}\left(y\right) + {\mu_0}, {\left(a {\beta_1} - a\right)} {\ell}^{2} t + a {\beta_1} \Phi_{1}\left(y\right) + {\Phi_0}, {\left(a {\beta_2} - a\right)} {\ell}^{2} t + a {\beta_2} \Psi_{1}\left(y\right) + {\Psi_0}\right) \\ & \left(t, y\right) & \longmapsto & \left(t, y, {\mu}, {\Phi}, {\Psi}\right) = \left(t, y, a^{2} \mu_{1}\left(y\right) + {\mu_0}, a {\beta_1} {\ell}^{2} t + a {\beta_1} \Phi_{1}\left(y\right) + {\Phi_0}, a {\beta_2} {\ell}^{2} t + a {\beta_2} \Psi_{1}\left(y\right) + {\Psi_0}\right) \end{array}

In [43]:

F.jacobian_matrix()

\renewcommand{\Bold}[1]{\mathbf{#1}}\left(\begin{array}{rr} 1 & 0 \\ 0 & 1 \\ 0 & a^{2} \frac{\partial}{\partial y}\mu_{1}\left(y\right) \\ a {\beta_1} {\ell}^{2} & a {\beta_1} \frac{\partial}{\partial y}\Phi_{1}\left(y\right) \\ a {\beta_2} {\ell}^{2} & a {\beta_2} \frac{\partial}{\partial y}\Psi_{1}\left(y\right) \end{array}\right)

Induced metric on the string worldsheet

The string worldsheet metric is the metric $g$ induced by the spacetime metric $G$ , i.e. the pullback of $G$ by the embedding $F$ :

In [44]:

g = W.metric()
g.set(F.pullback(G))

In [45]:

g[0,0]

\renewcommand{\Bold}[1]{\mathbf{#1}}-\frac{2 \, {\left(a^{12} {\beta_1}^{2} - 2 \, a^{12} {\beta_1} {\beta_2} + a^{12} {\beta_2}^{2}\right)} {\ell}^{4} m \mu_{1}\left(y\right)^{4} + 8 \, {\left({\mu_0} a^{10} {\beta_1}^{2} - 2 \, {\mu_0} a^{10} {\beta_1} {\beta_2} + {\mu_0} a^{10} {\beta_2}^{2}\right)} {\ell}^{4} m \mu_{1}\left(y\right)^{3} - {\left({\left({\mu_0}^{2} a^{8} {\beta_2}^{2} - {\left({\mu_0}^{2} - 1\right)} a^{8} {\beta_1}^{2}\right)} {\ell}^{10} - {\left(3 \, {\mu_0}^{2} a^{6} {\beta_2}^{2} - 3 \, {\left({\mu_0}^{2} - 1\right)} a^{6} {\beta_1}^{2} + a^{6}\right)} {\ell}^{8} + 3 \, {\left({\mu_0}^{2} a^{4} {\beta_2}^{2} - {\left({\mu_0}^{2} - 1\right)} a^{4} {\beta_1}^{2} + a^{4}\right)} {\ell}^{6} - {\left({\mu_0}^{2} a^{2} {\beta_2}^{2} - {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} + 3 \, a^{2}\right)} {\ell}^{4} + {\ell}^{2}\right)} y^{4} + {\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{2} + {\left({\left({\left(a^{12} {\beta_1}^{2} - a^{12} {\beta_2}^{2}\right)} {\ell}^{10} - 3 \, {\left(a^{10} {\beta_1}^{2} - a^{10} {\beta_2}^{2}\right)} {\ell}^{8} + 3 \, {\left(a^{8} {\beta_1}^{2} - a^{8} {\beta_2}^{2}\right)} {\ell}^{6} - {\left(a^{6} {\beta_1}^{2} - a^{6} {\beta_2}^{2}\right)} {\ell}^{4}\right)} y^{4} + 4 \, {\left({\left(3 \, {\mu_0}^{2} a^{8} {\beta_2}^{2} + {\left(3 \, {\mu_0}^{2} - 1\right)} a^{8} {\beta_1}^{2} - {\left(6 \, {\mu_0}^{2} - 1\right)} a^{8} {\beta_1} {\beta_2}\right)} {\ell}^{4} + {\left(a^{6} {\beta_1} - a^{6} {\beta_2}\right)} {\ell}^{2}\right)} m\right)} \mu_{1}\left(y\right)^{2} + 2 \, {\left({\left({\mu_0}^{4} a^{4} {\beta_2}^{2} + {\left({\mu_0}^{4} - 2 \, {\mu_0}^{2} + 1\right)} a^{4} {\beta_1}^{2} - 2 \, {\left({\mu_0}^{4} - {\mu_0}^{2}\right)} a^{4} {\beta_1} {\beta_2}\right)} {\ell}^{4} - 2 \, {\left({\mu_0}^{2} a^{2} {\beta_2} - {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}\right)} {\ell}^{2} + 1\right)} m + 2 \, {\left({\left({\left({\mu_0} a^{10} {\beta_1}^{2} - {\mu_0} a^{10} {\beta_2}^{2}\right)} {\ell}^{10} - 3 \, {\left({\mu_0} a^{8} {\beta_1}^{2} - {\mu_0} a^{8} {\beta_2}^{2}\right)} {\ell}^{8} + 3 \, {\left({\mu_0} a^{6} {\beta_1}^{2} - {\mu_0} a^{6} {\beta_2}^{2}\right)} {\ell}^{6} - {\left({\mu_0} a^{4} {\beta_1}^{2} - {\mu_0} a^{4} {\beta_2}^{2}\right)} {\ell}^{4}\right)} y^{4} + 4 \, {\left({\left({\mu_0}^{3} a^{6} {\beta_2}^{2} + {\left({\mu_0}^{3} - {\mu_0}\right)} a^{6} {\beta_1}^{2} - {\left(2 \, {\mu_0}^{3} - {\mu_0}\right)} a^{6} {\beta_1} {\beta_2}\right)} {\ell}^{4} + {\left({\mu_0} a^{4} {\beta_1} - {\mu_0} a^{4} {\beta_2}\right)} {\ell}^{2}\right)} m\right)} \mu_{1}\left(y\right)}{{\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{2}}

In [46]:

g[0,0].expr().denominator().factor()

\renewcommand{\Bold}[1]{\mathbf{#1}}{\left(a {\ell} + 1\right)}^{3} {\left(a {\ell} - 1\right)}^{3} y^{2}

In [47]:

g[0,1]

\renewcommand{\Bold}[1]{\mathbf{#1}}-\frac{{\left(2 \, {\left(a^{12} {\beta_1}^{2} - a^{12} {\beta_1} {\beta_2}\right)} {\ell}^{2} m \mu_{1}\left(y\right)^{4} + 8 \, {\left({\mu_0} a^{10} {\beta_1}^{2} - {\mu_0} a^{10} {\beta_1} {\beta_2}\right)} {\ell}^{2} m \mu_{1}\left(y\right)^{3} + {\left({\left({\mu_0}^{2} - 1\right)} a^{8} {\beta_1}^{2} {\ell}^{8} - 3 \, {\left({\mu_0}^{2} - 1\right)} a^{6} {\beta_1}^{2} {\ell}^{6} + 3 \, {\left({\mu_0}^{2} - 1\right)} a^{4} {\beta_1}^{2} {\ell}^{4} - {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} {\ell}^{2}\right)} y^{4} + {\left({\left(a^{12} {\beta_1}^{2} {\ell}^{8} - 3 \, a^{10} {\beta_1}^{2} {\ell}^{6} + 3 \, a^{8} {\beta_1}^{2} {\ell}^{4} - a^{6} {\beta_1}^{2} {\ell}^{2}\right)} y^{4} + 2 \, {\left(a^{6} {\beta_1} + {\left(2 \, {\left(3 \, {\mu_0}^{2} - 1\right)} a^{8} {\beta_1}^{2} - {\left(6 \, {\mu_0}^{2} - 1\right)} a^{8} {\beta_1} {\beta_2}\right)} {\ell}^{2}\right)} m\right)} \mu_{1}\left(y\right)^{2} + 2 \, {\left({\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1} + {\left({\left({\mu_0}^{4} - 2 \, {\mu_0}^{2} + 1\right)} a^{4} {\beta_1}^{2} - {\left({\mu_0}^{4} - {\mu_0}^{2}\right)} a^{4} {\beta_1} {\beta_2}\right)} {\ell}^{2}\right)} m + 2 \, {\left({\left({\mu_0} a^{10} {\beta_1}^{2} {\ell}^{8} - 3 \, {\mu_0} a^{8} {\beta_1}^{2} {\ell}^{6} + 3 \, {\mu_0} a^{6} {\beta_1}^{2} {\ell}^{4} - {\mu_0} a^{4} {\beta_1}^{2} {\ell}^{2}\right)} y^{4} + 2 \, {\left({\mu_0} a^{4} {\beta_1} + {\left(2 \, {\left({\mu_0}^{3} - {\mu_0}\right)} a^{6} {\beta_1}^{2} - {\left(2 \, {\mu_0}^{3} - {\mu_0}\right)} a^{6} {\beta_1} {\beta_2}\right)} {\ell}^{2}\right)} m\right)} \mu_{1}\left(y\right)\right)} \frac{\partial\,\Phi_{1}}{\partial y} - {\left(2 \, {\left(a^{12} {\beta_1} {\beta_2} - a^{12} {\beta_2}^{2}\right)} {\ell}^{2} m \mu_{1}\left(y\right)^{4} + 8 \, {\left({\mu_0} a^{10} {\beta_1} {\beta_2} - {\mu_0} a^{10} {\beta_2}^{2}\right)} {\ell}^{2} m \mu_{1}\left(y\right)^{3} + {\left({\mu_0}^{2} a^{8} {\beta_2}^{2} {\ell}^{8} - 3 \, {\mu_0}^{2} a^{6} {\beta_2}^{2} {\ell}^{6} + 3 \, {\mu_0}^{2} a^{4} {\beta_2}^{2} {\ell}^{4} - {\mu_0}^{2} a^{2} {\beta_2}^{2} {\ell}^{2}\right)} y^{4} + {\left({\left(a^{12} {\beta_2}^{2} {\ell}^{8} - 3 \, a^{10} {\beta_2}^{2} {\ell}^{6} + 3 \, a^{8} {\beta_2}^{2} {\ell}^{4} - a^{6} {\beta_2}^{2} {\ell}^{2}\right)} y^{4} + 2 \, {\left(a^{6} {\beta_2} - {\left(6 \, {\mu_0}^{2} a^{8} {\beta_2}^{2} - {\left(6 \, {\mu_0}^{2} - 1\right)} a^{8} {\beta_1} {\beta_2}\right)} {\ell}^{2}\right)} m\right)} \mu_{1}\left(y\right)^{2} + 2 \, {\left({\mu_0}^{2} a^{2} {\beta_2} - {\left({\mu_0}^{4} a^{4} {\beta_2}^{2} - {\left({\mu_0}^{4} - {\mu_0}^{2}\right)} a^{4} {\beta_1} {\beta_2}\right)} {\ell}^{2}\right)} m + 2 \, {\left({\left({\mu_0} a^{10} {\beta_2}^{2} {\ell}^{8} - 3 \, {\mu_0} a^{8} {\beta_2}^{2} {\ell}^{6} + 3 \, {\mu_0} a^{6} {\beta_2}^{2} {\ell}^{4} - {\mu_0} a^{4} {\beta_2}^{2} {\ell}^{2}\right)} y^{4} + 2 \, {\left({\mu_0} a^{4} {\beta_2} - {\left(2 \, {\mu_0}^{3} a^{6} {\beta_2}^{2} - {\left(2 \, {\mu_0}^{3} - {\mu_0}\right)} a^{6} {\beta_1} {\beta_2}\right)} {\ell}^{2}\right)} m\right)} \mu_{1}\left(y\right)\right)} \frac{\partial\,\Psi_{1}}{\partial y}}{{\left(a^{6} {\ell}^{6} - 3 \, a^{4} {\ell}^{4} + 3 \, a^{2} {\ell}^{2} - 1\right)} y^{2}}

Nambu-Goto action

In [48]:

detg = g.determinant().expr()

Expanding at second order in $a$ :

In [49]:

detg_a2 = detg.series(a, 3).truncate().simplify_full()
detg_a2

\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{{\left({\left({\mu_0}^{2} a^{2} {\beta_2}^{2} - {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2}\right)} {\ell}^{4} - {\ell}^{2}\right)} y^{6} - 2 \, {\left({\left(2 \, {\mu_0}^{2} a^{2} {\beta_2} - 2 \, {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1} - a^{2}\right)} {\ell}^{2} - 1\right)} m y^{2} - y^{4} + 2 \, a^{2} m + {\left({\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} {\ell}^{4} y^{10} + 2 \, {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} {\ell}^{2} y^{8} - 4 \, {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} m y^{4} + 4 \, {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} m^{2} y^{2} - {\left(4 \, {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} {\ell}^{2} m - {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2}\right)} y^{6}\right)} \frac{\partial}{\partial y}\Phi_{1}\left(y\right)^{2} - {\left({\mu_0}^{2} a^{2} {\beta_2}^{2} {\ell}^{4} y^{10} + 2 \, {\mu_0}^{2} a^{2} {\beta_2}^{2} {\ell}^{2} y^{8} - 4 \, {\mu_0}^{2} a^{2} {\beta_2}^{2} m y^{4} + 4 \, {\mu_0}^{2} a^{2} {\beta_2}^{2} m^{2} y^{2} - {\left(4 \, {\mu_0}^{2} a^{2} {\beta_2}^{2} {\ell}^{2} m - {\mu_0}^{2} a^{2} {\beta_2}^{2}\right)} y^{6}\right)} \frac{\partial}{\partial y}\Psi_{1}\left(y\right)^{2}}{{\ell}^{2} y^{6} + y^{4} - 2 \, m y^{2}}

The Nambu-Goto Lagrangian at second order in $a$ :

In [50]:

L_a2 = (sqrt(-detg_a2)).series(a, 3).truncate().simplify_full()
L_a2

\renewcommand{\Bold}[1]{\mathbf{#1}}-\frac{{\left({\left({\mu_0}^{2} a^{2} {\beta_2}^{2} - {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2}\right)} {\ell}^{4} - 2 \, {\ell}^{2}\right)} y^{6} - 2 \, {\left({\left(2 \, {\mu_0}^{2} a^{2} {\beta_2} - 2 \, {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1} - a^{2}\right)} {\ell}^{2} - 2\right)} m y^{2} - 2 \, y^{4} + 2 \, a^{2} m + {\left({\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} {\ell}^{4} y^{10} + 2 \, {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} {\ell}^{2} y^{8} - 4 \, {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} m y^{4} + 4 \, {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} m^{2} y^{2} - {\left(4 \, {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} {\ell}^{2} m - {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2}\right)} y^{6}\right)} \frac{\partial}{\partial y}\Phi_{1}\left(y\right)^{2} - {\left({\mu_0}^{2} a^{2} {\beta_2}^{2} {\ell}^{4} y^{10} + 2 \, {\mu_0}^{2} a^{2} {\beta_2}^{2} {\ell}^{2} y^{8} - 4 \, {\mu_0}^{2} a^{2} {\beta_2}^{2} m y^{4} + 4 \, {\mu_0}^{2} a^{2} {\beta_2}^{2} m^{2} y^{2} - {\left(4 \, {\mu_0}^{2} a^{2} {\beta_2}^{2} {\ell}^{2} m - {\mu_0}^{2} a^{2} {\beta_2}^{2}\right)} y^{6}\right)} \frac{\partial}{\partial y}\Psi_{1}\left(y\right)^{2}}{2 \, {\left({\ell}^{2} y^{6} + y^{4} - 2 \, m y^{2}\right)}}

In [51]:

L_a2.numerator()

\renewcommand{\Bold}[1]{\mathbf{#1}}-{\mu_0}^{2} a^{2} {\beta_1}^{2} {\ell}^{4} y^{10} \frac{\partial}{\partial y}\Phi_{1}\left(y\right)^{2} + {\mu_0}^{2} a^{2} {\beta_2}^{2} {\ell}^{4} y^{10} \frac{\partial}{\partial y}\Psi_{1}\left(y\right)^{2} + a^{2} {\beta_1}^{2} {\ell}^{4} y^{10} \frac{\partial}{\partial y}\Phi_{1}\left(y\right)^{2} - 2 \, {\mu_0}^{2} a^{2} {\beta_1}^{2} {\ell}^{2} y^{8} \frac{\partial}{\partial y}\Phi_{1}\left(y\right)^{2} + 2 \, {\mu_0}^{2} a^{2} {\beta_2}^{2} {\ell}^{2} y^{8} \frac{\partial}{\partial y}\Psi_{1}\left(y\right)^{2} + 4 \, {\mu_0}^{2} a^{2} {\beta_1}^{2} {\ell}^{2} m y^{6} \frac{\partial}{\partial y}\Phi_{1}\left(y\right)^{2} - 4 \, {\mu_0}^{2} a^{2} {\beta_2}^{2} {\ell}^{2} m y^{6} \frac{\partial}{\partial y}\Psi_{1}\left(y\right)^{2} + {\mu_0}^{2} a^{2} {\beta_1}^{2} {\ell}^{4} y^{6} - {\mu_0}^{2} a^{2} {\beta_2}^{2} {\ell}^{4} y^{6} + 2 \, a^{2} {\beta_1}^{2} {\ell}^{2} y^{8} \frac{\partial}{\partial y}\Phi_{1}\left(y\right)^{2} - 4 \, a^{2} {\beta_1}^{2} {\ell}^{2} m y^{6} \frac{\partial}{\partial y}\Phi_{1}\left(y\right)^{2} - a^{2} {\beta_1}^{2} {\ell}^{4} y^{6} - {\mu_0}^{2} a^{2} {\beta_1}^{2} y^{6} \frac{\partial}{\partial y}\Phi_{1}\left(y\right)^{2} + {\mu_0}^{2} a^{2} {\beta_2}^{2} y^{6} \frac{\partial}{\partial y}\Psi_{1}\left(y\right)^{2} + 4 \, {\mu_0}^{2} a^{2} {\beta_1}^{2} m y^{4} \frac{\partial}{\partial y}\Phi_{1}\left(y\right)^{2} - 4 \, {\mu_0}^{2} a^{2} {\beta_2}^{2} m y^{4} \frac{\partial}{\partial y}\Psi_{1}\left(y\right)^{2} - 4 \, {\mu_0}^{2} a^{2} {\beta_1}^{2} m^{2} y^{2} \frac{\partial}{\partial y}\Phi_{1}\left(y\right)^{2} + a^{2} {\beta_1}^{2} y^{6} \frac{\partial}{\partial y}\Phi_{1}\left(y\right)^{2} + 4 \, {\mu_0}^{2} a^{2} {\beta_2}^{2} m^{2} y^{2} \frac{\partial}{\partial y}\Psi_{1}\left(y\right)^{2} - 4 \, a^{2} {\beta_1}^{2} m y^{4} \frac{\partial}{\partial y}\Phi_{1}\left(y\right)^{2} - 4 \, {\mu_0}^{2} a^{2} {\beta_1} {\ell}^{2} m y^{2} + 4 \, {\mu_0}^{2} a^{2} {\beta_2} {\ell}^{2} m y^{2} + 4 \, a^{2} {\beta_1}^{2} m^{2} y^{2} \frac{\partial}{\partial y}\Phi_{1}\left(y\right)^{2} + 4 \, a^{2} {\beta_1} {\ell}^{2} m y^{2} + 2 \, {\ell}^{2} y^{6} - 2 \, a^{2} {\ell}^{2} m y^{2} + 2 \, y^{4} - 2 \, a^{2} m - 4 \, m y^{2}

In [52]:

L_a2.denominator()

\renewcommand{\Bold}[1]{\mathbf{#1}}2 \, {\ell}^{2} y^{6} + 2 \, y^{4} - 4 \, m y^{2}

Euler-Lagrange equations

In [53]:

def euler_lagrange(lagr, qs, var):
    r"""
    Derive the Euler-Lagrange equations from a given Lagrangian.

    INPUT:

    - ``lagr`` -- symbolic expression representing the Lagrangian density
    - ``qs`` -- either a single symbolic function or a list/tuple of
      symbolic functions, representing the `q`'s; these functions must
      appear in ``lagr`` up to at most their first derivatives
    - ``var`` -- either a single variable, typically `t` (1-dimensional
      problem) or a list/tuple of symbolic variables

    OUTPUT:

    - list of Euler-Lagrange equations; if only one function is involved, the
      single Euler-Lagrannge equation is returned instead.

    """
    if not isinstance(qs, (list, tuple)):
        qs = [qs]
    if not isinstance(var, (list, tuple)):
        var = [var]
    n = len(qs)
    d = len(var)
    qv = [SR.var('qxxxx{}'.format(q)) for q in qs]
    dqv = [[SR.var('qxxxx{}_{}'.format(q, v)) for v in var] for q in qs]
    subs = {qs[i](*var): qv[i] for i in range(n)}
    subs_inv = {qv[i]: qs[i](*var) for i in range(n)}
    for i in range(n):
        subs.update({diff(qs[i](*var), var[j]): dqv[i][j]
                     for j in range(d)})
        subs_inv.update({dqv[i][j]: diff(qs[i](*var), var[j])
                         for j in range(d)})
    lg = lagr.substitute(subs)
    eqs = []
    for i in range(n):
        dLdq = diff(lg, qv[i]).simplify_full()
        dLdq = dLdq.substitute(subs_inv)
        ddL = 0
        for j in range(d):
            h =  diff(lg, dqv[i][j]).simplify_full()
            h = h.substitute(subs_inv)
            ddL += diff(h, var[j])
        eqs.append((dLdq - ddL).simplify_full() == 0)
    if n == 1:
        return eqs[0]
    return eqs

We compute the Euler-Lagrange equations at order $a^2$ for $\phi_1$ and $\psi_1$ :

In [54]:

eqs = euler_lagrange(L_a2, [Phi_1, Psi_1], y)
eqs

\renewcommand{\Bold}[1]{\mathbf{#1}}\left[2 \, {\left(2 \, {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} {\ell}^{2} y^{3} + {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} y\right)} \frac{\partial}{\partial y}\Phi_{1}\left(y\right) + {\left({\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} {\ell}^{2} y^{4} + {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} y^{2} - 2 \, {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} m\right)} \frac{\partial^{2}}{(\partial y)^{2}}\Phi_{1}\left(y\right) = 0, -2 \, {\left(2 \, {\mu_0}^{2} a^{2} {\beta_2}^{2} {\ell}^{2} y^{3} + {\mu_0}^{2} a^{2} {\beta_2}^{2} y\right)} \frac{\partial}{\partial y}\Psi_{1}\left(y\right) - {\left({\mu_0}^{2} a^{2} {\beta_2}^{2} {\ell}^{2} y^{4} + {\mu_0}^{2} a^{2} {\beta_2}^{2} y^{2} - 2 \, {\mu_0}^{2} a^{2} {\beta_2}^{2} m\right)} \frac{\partial^{2}}{(\partial y)^{2}}\Psi_{1}\left(y\right) = 0\right]

Solving the equation for $\phi_1$ (check of Eq. (4.34))

In [55]:

eq_phi1 = eqs[0]
eq_phi1

\renewcommand{\Bold}[1]{\mathbf{#1}}2 \, {\left(2 \, {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} {\ell}^{2} y^{3} + {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} y\right)} \frac{\partial}{\partial y}\Phi_{1}\left(y\right) + {\left({\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} {\ell}^{2} y^{4} + {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} y^{2} - 2 \, {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} m\right)} \frac{\partial^{2}}{(\partial y)^{2}}\Phi_{1}\left(y\right) = 0

In [56]:

eq_phi1 = (eq_phi1/(a^2*(Mu0^2-1)*beta1^2)).simplify_full()
eq_phi1

\renewcommand{\Bold}[1]{\mathbf{#1}}2 \, {\left(2 \, {\ell}^{2} y^{3} + y\right)} \frac{\partial}{\partial y}\Phi_{1}\left(y\right) + {\left({\ell}^{2} y^{4} + y^{2} - 2 \, m\right)} \frac{\partial^{2}}{(\partial y)^{2}}\Phi_{1}\left(y\right) = 0

In [57]:

Phi1_sol(y) = desolve(eq_phi1, Phi_1(y), ivar=y)
Phi1_sol(y)

\renewcommand{\Bold}[1]{\mathbf{#1}}K_{1} \int \frac{1}{{\ell}^{2} y^{4} + y^{2} - 2 \, m}\,{d y} + K_{2}

The symbolic constants $K_1$ and $K_2$ are actually denoted _K1 and _K2 by SageMath, as the print reveals:

In [58]:

print(Phi1_sol(y))

_K1*integrate(1/(l^2*y^4 + y^2 - 2*m), y) + _K2

Hence we perform the substitutions with SR.var('_K1') and SR.var('_K2'):

In [59]:

P = var("P", latex_name=r"\mathcal{P}'")
Phi1_sol(y) = Phi1_sol(y).subs({SR.var('_K1'): P, SR.var('_K2'): 0})
print(Phi1_sol(y))

P*integrate(1/(l^2*y^4 + y^2 - 2*m), y)

Solving the equation for $\psi_1$ (check of Eq. (4.34))

In [60]:

eq_psi1 = eqs[1]
eq_psi1

\renewcommand{\Bold}[1]{\mathbf{#1}}-2 \, {\left(2 \, {\mu_0}^{2} a^{2} {\beta_2}^{2} {\ell}^{2} y^{3} + {\mu_0}^{2} a^{2} {\beta_2}^{2} y\right)} \frac{\partial}{\partial y}\Psi_{1}\left(y\right) - {\left({\mu_0}^{2} a^{2} {\beta_2}^{2} {\ell}^{2} y^{4} + {\mu_0}^{2} a^{2} {\beta_2}^{2} y^{2} - 2 \, {\mu_0}^{2} a^{2} {\beta_2}^{2} m\right)} \frac{\partial^{2}}{(\partial y)^{2}}\Psi_{1}\left(y\right) = 0

In [61]:

eq_psi1 = (eq_psi1/(a^2*Mu0^2*beta2^2)).simplify_full()
eq_psi1

\renewcommand{\Bold}[1]{\mathbf{#1}}-2 \, {\left(2 \, {\ell}^{2} y^{3} + y\right)} \frac{\partial}{\partial y}\Psi_{1}\left(y\right) - {\left({\ell}^{2} y^{4} + y^{2} - 2 \, m\right)} \frac{\partial^{2}}{(\partial y)^{2}}\Psi_{1}\left(y\right) = 0

In [62]:

Psi1_sol(y) = desolve(eq_psi1, Psi_1(y), ivar=y)
Psi1_sol(y)

\renewcommand{\Bold}[1]{\mathbf{#1}}K_{1} \int \frac{1}{{\ell}^{2} y^{4} + y^{2} - 2 \, m}\,{d y} + K_{2}

In [63]:

Q = var('Q', latex_name=r"\mathcal{Q}'")
Psi1_sol(y) = Psi1_sol(y).subs({SR.var('_K1'): Q, SR.var('_K2'): 0})
print(Psi1_sol(y))

Q*integrate(1/(l^2*y^4 + y^2 - 2*m), y)

Nambu-Goto Lagrangian at fourth order in $a$

In [64]:

detg_a4 = detg.series(a, 5).truncate().simplify_full()

In [65]:

L_a4 = (sqrt(-detg_a4)).series(a, 5).truncate().simplify_full()

In [66]:

eqs = euler_lagrange(L_a4, [Phi_1, Psi_1, mu_1], y)

The equation for $\mu_1$ (check of Eq. (4.35))

In [67]:

eq_mu1 = eqs[2]
eq_mu1

\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{{\left({\left({\mu_0}^{3} - {\mu_0}\right)} a^{4} {\beta_1}^{2} - {\left({\mu_0}^{3} - {\mu_0}\right)} a^{4} {\beta_2}^{2}\right)} {\ell}^{4} y^{4} - 4 \, {\left({\left({\mu_0}^{3} - {\mu_0}\right)} a^{4} {\beta_1} - {\left({\mu_0}^{3} - {\mu_0}\right)} a^{4} {\beta_2}\right)} {\ell}^{2} m - {\left({\left({\mu_0}^{3} - {\mu_0}\right)} a^{4} {\beta_1}^{2} {\ell}^{4} y^{8} + 2 \, {\left({\mu_0}^{3} - {\mu_0}\right)} a^{4} {\beta_1}^{2} {\ell}^{2} y^{6} - 4 \, {\left({\mu_0}^{3} - {\mu_0}\right)} a^{4} {\beta_1}^{2} m y^{2} + 4 \, {\left({\mu_0}^{3} - {\mu_0}\right)} a^{4} {\beta_1}^{2} m^{2} - {\left(4 \, {\left({\mu_0}^{3} - {\mu_0}\right)} a^{4} {\beta_1}^{2} {\ell}^{2} m - {\left({\mu_0}^{3} - {\mu_0}\right)} a^{4} {\beta_1}^{2}\right)} y^{4}\right)} \frac{\partial}{\partial y}\Phi_{1}\left(y\right)^{2} + {\left({\left({\mu_0}^{3} - {\mu_0}\right)} a^{4} {\beta_2}^{2} {\ell}^{4} y^{8} + 2 \, {\left({\mu_0}^{3} - {\mu_0}\right)} a^{4} {\beta_2}^{2} {\ell}^{2} y^{6} - 4 \, {\left({\mu_0}^{3} - {\mu_0}\right)} a^{4} {\beta_2}^{2} m y^{2} + 4 \, {\left({\mu_0}^{3} - {\mu_0}\right)} a^{4} {\beta_2}^{2} m^{2} - {\left(4 \, {\left({\mu_0}^{3} - {\mu_0}\right)} a^{4} {\beta_2}^{2} {\ell}^{2} m - {\left({\mu_0}^{3} - {\mu_0}\right)} a^{4} {\beta_2}^{2}\right)} y^{4}\right)} \frac{\partial}{\partial y}\Psi_{1}\left(y\right)^{2} + 2 \, {\left(2 \, a^{4} {\ell}^{4} y^{7} + 3 \, a^{4} {\ell}^{2} y^{5} - 2 \, a^{4} m y - {\left(4 \, a^{4} {\ell}^{2} m - a^{4}\right)} y^{3}\right)} \frac{\partial}{\partial y}\mu_{1}\left(y\right) + {\left(a^{4} {\ell}^{4} y^{8} + 2 \, a^{4} {\ell}^{2} y^{6} - 4 \, a^{4} m y^{2} + 4 \, a^{4} m^{2} - {\left(4 \, a^{4} {\ell}^{2} m - a^{4}\right)} y^{4}\right)} \frac{\partial^{2}}{(\partial y)^{2}}\mu_{1}\left(y\right)}{{\left({\mu_0}^{2} - 1\right)} {\ell}^{2} y^{4} + {\left({\mu_0}^{2} - 1\right)} y^{2} - 2 \, {\left({\mu_0}^{2} - 1\right)} m} = 0

In [68]:

# eq_mu1.lhs().numerator().simplify_full()

In [69]:

# eq_mu1.lhs().denominator().simplify_full()

In [70]:

eq_mu1 = eq_mu1.lhs().numerator().simplify_full() == 0

In [71]:

eq_mu1 = (eq_mu1/a^4).simplify_full()
eq_mu1

\renewcommand{\Bold}[1]{\mathbf{#1}}{\left({\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_1}^{2} - {\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_2}^{2}\right)} {\ell}^{4} y^{4} - 4 \, {\left({\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_1} - {\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_2}\right)} {\ell}^{2} m - {\left({\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_1}^{2} {\ell}^{4} y^{8} + 2 \, {\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_1}^{2} {\ell}^{2} y^{6} - 4 \, {\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_1}^{2} m y^{2} + 4 \, {\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_1}^{2} m^{2} - {\left(4 \, {\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_1}^{2} {\ell}^{2} m - {\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_1}^{2}\right)} y^{4}\right)} \frac{\partial}{\partial y}\Phi_{1}\left(y\right)^{2} + {\left({\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_2}^{2} {\ell}^{4} y^{8} + 2 \, {\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_2}^{2} {\ell}^{2} y^{6} - 4 \, {\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_2}^{2} m y^{2} + 4 \, {\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_2}^{2} m^{2} - {\left(4 \, {\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_2}^{2} {\ell}^{2} m - {\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_2}^{2}\right)} y^{4}\right)} \frac{\partial}{\partial y}\Psi_{1}\left(y\right)^{2} + 2 \, {\left(2 \, {\ell}^{4} y^{7} + 3 \, {\ell}^{2} y^{5} - {\left(4 \, {\ell}^{2} m - 1\right)} y^{3} - 2 \, m y\right)} \frac{\partial}{\partial y}\mu_{1}\left(y\right) + {\left({\ell}^{4} y^{8} + 2 \, {\ell}^{2} y^{6} - {\left(4 \, {\ell}^{2} m - 1\right)} y^{4} - 4 \, m y^{2} + 4 \, m^{2}\right)} \frac{\partial^{2}}{(\partial y)^{2}}\mu_{1}\left(y\right) = 0

We plug the solutions obtained previously for $\phi_1(r)$ and $\psi_1(r)$ in this equation:

In [72]:

eq_mu1 = eq_mu1.substitute_function(Phi_1, Phi1_sol).substitute_function(Psi_1, Psi1_sol)
eq_mu1 = eq_mu1.simplify_full()
eq_mu1

\renewcommand{\Bold}[1]{\mathbf{#1}}{\left({\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_1}^{2} - {\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_2}^{2}\right)} {\ell}^{4} y^{4} - {\left({\mu_0}^{3} - {\mu_0}\right)} {\mathcal{P}'}^{2} {\beta_1}^{2} + {\left({\mu_0}^{3} - {\mu_0}\right)} {\mathcal{Q}'}^{2} {\beta_2}^{2} - 4 \, {\left({\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_1} - {\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_2}\right)} {\ell}^{2} m + 2 \, {\left(2 \, {\ell}^{4} y^{7} + 3 \, {\ell}^{2} y^{5} - {\left(4 \, {\ell}^{2} m - 1\right)} y^{3} - 2 \, m y\right)} \frac{\partial}{\partial y}\mu_{1}\left(y\right) + {\left({\ell}^{4} y^{8} + 2 \, {\ell}^{2} y^{6} - {\left(4 \, {\ell}^{2} m - 1\right)} y^{4} - 4 \, m y^{2} + 4 \, m^{2}\right)} \frac{\partial^{2}}{(\partial y)^{2}}\mu_{1}\left(y\right) = 0

In [73]:

lhs = eq_mu1.lhs()
lhs = lhs.simplify_full()
lhs

\renewcommand{\Bold}[1]{\mathbf{#1}}{\left({\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_1}^{2} - {\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_2}^{2}\right)} {\ell}^{4} y^{4} - {\left({\mu_0}^{3} - {\mu_0}\right)} {\mathcal{P}'}^{2} {\beta_1}^{2} + {\left({\mu_0}^{3} - {\mu_0}\right)} {\mathcal{Q}'}^{2} {\beta_2}^{2} - 4 \, {\left({\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_1} - {\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_2}\right)} {\ell}^{2} m + 2 \, {\left(2 \, {\ell}^{4} y^{7} + 3 \, {\ell}^{2} y^{5} - {\left(4 \, {\ell}^{2} m - 1\right)} y^{3} - 2 \, m y\right)} \frac{\partial}{\partial y}\mu_{1}\left(y\right) + {\left({\ell}^{4} y^{8} + 2 \, {\ell}^{2} y^{6} - {\left(4 \, {\ell}^{2} m - 1\right)} y^{4} - 4 \, m y^{2} + 4 \, m^{2}\right)} \frac{\partial^{2}}{(\partial y)^{2}}\mu_{1}\left(y\right)

In [74]:

s = lhs.coefficient(diff(mu_1(y), y, 2))  # coefficient of mu_1''
s.factor()

\renewcommand{\Bold}[1]{\mathbf{#1}}{\left({\ell}^{2} y^{4} + y^{2} - 2 \, m\right)}^{2}

In [75]:

s1 = (lhs/s - diff(mu_1(y), y, 2)).simplify_full()
s1

\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{{\left({\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_1}^{2} - {\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_2}^{2}\right)} {\ell}^{4} y^{4} - {\left({\mu_0}^{3} - {\mu_0}\right)} {\mathcal{P}'}^{2} {\beta_1}^{2} + {\left({\mu_0}^{3} - {\mu_0}\right)} {\mathcal{Q}'}^{2} {\beta_2}^{2} - 4 \, {\left({\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_1} - {\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_2}\right)} {\ell}^{2} m + 2 \, {\left(2 \, {\ell}^{4} y^{7} + 3 \, {\ell}^{2} y^{5} - {\left(4 \, {\ell}^{2} m - 1\right)} y^{3} - 2 \, m y\right)} \frac{\partial}{\partial y}\mu_{1}\left(y\right)}{{\ell}^{4} y^{8} + 2 \, {\ell}^{2} y^{6} - {\left(4 \, {\ell}^{2} m - 1\right)} y^{4} - 4 \, m y^{2} + 4 \, m^{2}}

In [76]:

b1 = s1.coefficient(diff(mu_1(y), y)).factor()
b1

\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{2 \, {\left(2 \, {\ell}^{2} y^{2} + 1\right)} y}{{\ell}^{2} y^{4} + y^{2} - 2 \, m}

In [77]:

s2 = (s1 - b1*diff(mu_1(y), y)).simplify_full()
s2

\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{{\left({\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_1}^{2} - {\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_2}^{2}\right)} {\ell}^{4} y^{4} - {\left({\mu_0}^{3} - {\mu_0}\right)} {\mathcal{P}'}^{2} {\beta_1}^{2} + {\left({\mu_0}^{3} - {\mu_0}\right)} {\mathcal{Q}'}^{2} {\beta_2}^{2} - 4 \, {\left({\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_1} - {\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_2}\right)} {\ell}^{2} m}{{\ell}^{4} y^{8} + 2 \, {\ell}^{2} y^{6} - {\left(4 \, {\ell}^{2} m - 1\right)} y^{4} - 4 \, m y^{2} + 4 \, m^{2}}

In [78]:

s2.factor()

\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{{\left({\beta_1}^{2} {\ell}^{4} y^{4} - {\beta_2}^{2} {\ell}^{4} y^{4} - {\mathcal{P}'}^{2} {\beta_1}^{2} + {\mathcal{Q}'}^{2} {\beta_2}^{2} - 4 \, {\beta_1} {\ell}^{2} m + 4 \, {\beta_2} {\ell}^{2} m\right)} {\left({\mu_0} + 1\right)} {\left({\mu_0} - 1\right)} {\mu_0}}{{\left({\ell}^{2} y^{4} + y^{2} - 2 \, m\right)}^{2}}

The equation for $\mu_1$ is thus:

In [79]:

eq_mu1 = diff(mu_1(y), y, 2) + b1*diff(mu_1(y), y) + s2.factor() == 0
eq_mu1

\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{{\left({\beta_1}^{2} {\ell}^{4} y^{4} - {\beta_2}^{2} {\ell}^{4} y^{4} - {\mathcal{P}'}^{2} {\beta_1}^{2} + {\mathcal{Q}'}^{2} {\beta_2}^{2} - 4 \, {\beta_1} {\ell}^{2} m + 4 \, {\beta_2} {\ell}^{2} m\right)} {\left({\mu_0} + 1\right)} {\left({\mu_0} - 1\right)} {\mu_0}}{{\left({\ell}^{2} y^{4} + y^{2} - 2 \, m\right)}^{2}} + \frac{2 \, {\left(2 \, {\ell}^{2} y^{2} + 1\right)} y \frac{\partial}{\partial y}\mu_{1}\left(y\right)}{{\ell}^{2} y^{4} + y^{2} - 2 \, m} + \frac{\partial^{2}}{(\partial y)^{2}}\mu_{1}\left(y\right) = 0

Given that $\mu_1(y) = - \sin\Theta_0 \; \theta_1(y) = - \sqrt{1-\mu_0^2} \; \theta_1(y), \qquad \sin2\Theta_0 = 2\mu_0\sqrt{1-\mu_0^2}$ and $\mathcal{P}' = \mathcal{P}/\beta_1^2 \qquad\mbox{and}\qquad \mathcal{Q}' = \mathcal{Q}/\beta_1^2,$ we get for the equation for $\theta_1$ : $\theta_1'' + \frac{2y(2\ell^2 y^2 + 1)}{\ell^2 y^4 + y^2 - 2m} \, \theta_1' + \frac{\beta_2^{-2}\mathcal{Q}^2 - \beta_1^{-2}\mathcal{P}^2 - 4 (\beta_1 - \beta_2) \ell^2 m + (\beta_1^2 - \beta_2^2) \ell^4 y^4}{2(\ell^2 y^4 + y^2 - 2m)^2}\sin(2\Theta_0) = 0$ This agrees with Eq. (4.35) of the paper.

Solving the equation for $\mu_1$

In [80]:

mu1_sol(y) = desolve(eq_mu1, mu_1(y), ivar=y)
mu1_sol(y)

\renewcommand{\Bold}[1]{\mathbf{#1}}K_{2} - \int \frac{{\left({\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_1}^{2} - {\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_2}^{2}\right)} {\ell}^{2} y - {\left({\mu_0}^{3} - {\mu_0}\right)} \int \frac{{\left({\beta_1}^{2} - {\beta_2}^{2}\right)} {\ell}^{2} y^{2} + {\mathcal{P}'}^{2} {\beta_1}^{2} - {\mathcal{Q}'}^{2} {\beta_2}^{2} - 2 \, {\left({\beta_1}^{2} - {\beta_2}^{2} - 2 \, {\beta_1} + 2 \, {\beta_2}\right)} {\ell}^{2} m}{{\ell}^{2} y^{4} + y^{2} - 2 \, m}\,{d y} - K_{1}}{{\ell}^{2} y^{4} + y^{2} - 2 \, m}\,{d y}

Let us check that mu1_sol is indeed a solution of the equation for $\mu_1$ :

In [81]:

eq_mu1.substitute_function(mu_1, mu1_sol).simplify_full()

\renewcommand{\Bold}[1]{\mathbf{#1}}0 = 0

In [82]:

mu1_sol(y)

\renewcommand{\Bold}[1]{\mathbf{#1}}K_{2} - \int \frac{{\left({\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_1}^{2} - {\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_2}^{2}\right)} {\ell}^{2} y - {\left({\mu_0}^{3} - {\mu_0}\right)} \int \frac{{\left({\beta_1}^{2} - {\beta_2}^{2}\right)} {\ell}^{2} y^{2} + {\mathcal{P}'}^{2} {\beta_1}^{2} - {\mathcal{Q}'}^{2} {\beta_2}^{2} - 2 \, {\left({\beta_1}^{2} - {\beta_2}^{2} - 2 \, {\beta_1} + 2 \, {\beta_2}\right)} {\ell}^{2} m}{{\ell}^{2} y^{4} + y^{2} - 2 \, m}\,{d y} - K_{1}}{{\ell}^{2} y^{4} + y^{2} - 2 \, m}\,{d y}

The innermost integral can be written $(\beta_1^2 - \beta_2^2) \ell^2 \; s_1(y) + \left({\mathcal{P}'}^2 \beta_1^2 - {\mathcal{Q}'}\beta_2^2 - 2 (\beta_1^2-\beta_2^2 - 2 (\beta_1-\beta_2))\ell^2 m \right) \; s_2(y)$ with $s_1(y) := \int^y \frac{\bar{y}^2}{\ell^2 \bar{y}^4 + \bar{y}^2 - 2m} \, \mathrm{d}\bar{y} \qquad \mbox{and}\qquad s_2(y) := \int^y \frac{\mathrm{d}\bar{y}}{\ell^2 \bar{y}^4 + \bar{y}^2 - 2m} .$

Let us evaluate $s_1$ by means of FriCAS:

In [83]:

s1 = integrate(y^2/(l^2*y^4 + y^2 - 2*m), y, algorithm='fricas')
s1

\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{2} \, \sqrt{\frac{1}{2}} \sqrt{-\frac{\frac{8 \, {\ell}^{4} m + {\ell}^{2}}{\sqrt{8 \, {\ell}^{6} m + {\ell}^{4}}} + 1}{8 \, {\ell}^{4} m + {\ell}^{2}}} \log\left(\frac{\sqrt{\frac{1}{2}} {\left(8 \, {\ell}^{4} m + {\ell}^{2}\right)} \sqrt{-\frac{\frac{8 \, {\ell}^{4} m + {\ell}^{2}}{\sqrt{8 \, {\ell}^{6} m + {\ell}^{4}}} + 1}{8 \, {\ell}^{4} m + {\ell}^{2}}}}{\sqrt{8 \, {\ell}^{6} m + {\ell}^{4}}} + y\right) - \frac{1}{2} \, \sqrt{\frac{1}{2}} \sqrt{-\frac{\frac{8 \, {\ell}^{4} m + {\ell}^{2}}{\sqrt{8 \, {\ell}^{6} m + {\ell}^{4}}} + 1}{8 \, {\ell}^{4} m + {\ell}^{2}}} \log\left(-\frac{\sqrt{\frac{1}{2}} {\left(8 \, {\ell}^{4} m + {\ell}^{2}\right)} \sqrt{-\frac{\frac{8 \, {\ell}^{4} m + {\ell}^{2}}{\sqrt{8 \, {\ell}^{6} m + {\ell}^{4}}} + 1}{8 \, {\ell}^{4} m + {\ell}^{2}}}}{\sqrt{8 \, {\ell}^{6} m + {\ell}^{4}}} + y\right) - \frac{1}{2} \, \sqrt{\frac{1}{2}} \sqrt{\frac{\frac{8 \, {\ell}^{4} m + {\ell}^{2}}{\sqrt{8 \, {\ell}^{6} m + {\ell}^{4}}} - 1}{8 \, {\ell}^{4} m + {\ell}^{2}}} \log\left(\frac{\sqrt{\frac{1}{2}} {\left(8 \, {\ell}^{4} m + {\ell}^{2}\right)} \sqrt{\frac{\frac{8 \, {\ell}^{4} m + {\ell}^{2}}{\sqrt{8 \, {\ell}^{6} m + {\ell}^{4}}} - 1}{8 \, {\ell}^{4} m + {\ell}^{2}}}}{\sqrt{8 \, {\ell}^{6} m + {\ell}^{4}}} + y\right) + \frac{1}{2} \, \sqrt{\frac{1}{2}} \sqrt{\frac{\frac{8 \, {\ell}^{4} m + {\ell}^{2}}{\sqrt{8 \, {\ell}^{6} m + {\ell}^{4}}} - 1}{8 \, {\ell}^{4} m + {\ell}^{2}}} \log\left(-\frac{\sqrt{\frac{1}{2}} {\left(8 \, {\ell}^{4} m + {\ell}^{2}\right)} \sqrt{\frac{\frac{8 \, {\ell}^{4} m + {\ell}^{2}}{\sqrt{8 \, {\ell}^{6} m + {\ell}^{4}}} - 1}{8 \, {\ell}^{4} m + {\ell}^{2}}}}{\sqrt{8 \, {\ell}^{6} m + {\ell}^{4}}} + y\right)

In [84]:

s1 = s1.canonicalize_radical().simplify_log()
s1

\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{\sqrt{2} \sqrt{8 \, {\ell}^{2} m - \sqrt{8 \, {\ell}^{2} m + 1} + 1} \log\left(\frac{\sqrt{2} {\left(8 \, {\ell}^{2} m + 1\right)}^{\frac{1}{4}} {\ell} y - \sqrt{8 \, {\ell}^{2} m - \sqrt{8 \, {\ell}^{2} m + 1} + 1}}{\sqrt{2} {\left(8 \, {\ell}^{2} m + 1\right)}^{\frac{1}{4}} {\ell} y + \sqrt{8 \, {\ell}^{2} m - \sqrt{8 \, {\ell}^{2} m + 1} + 1}}\right) + \sqrt{2} \sqrt{-8 \, {\ell}^{2} m - \sqrt{8 \, {\ell}^{2} m + 1} - 1} \log\left(\frac{\sqrt{2} {\left(8 \, {\ell}^{2} m + 1\right)}^{\frac{1}{4}} {\ell} y + \sqrt{-8 \, {\ell}^{2} m - \sqrt{8 \, {\ell}^{2} m + 1} - 1}}{\sqrt{2} {\left(8 \, {\ell}^{2} m + 1\right)}^{\frac{1}{4}} {\ell} y - \sqrt{-8 \, {\ell}^{2} m - \sqrt{8 \, {\ell}^{2} m + 1} - 1}}\right)}{4 \, {\left(8 \, {\ell}^{2} m + 1\right)}^{\frac{3}{4}} {\ell}}

Check:

In [85]:

diff(s1, y).simplify_full()

\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{y^{2}}{{\ell}^{2} y^{4} + y^{2} - 2 \, m}

Similarly, we evaluate $s_2$ by means of FriCAS:

In [86]:

s2 = integrate(1/(l^2*y^4 + y^2 - 2*m), y, algorithm='fricas')
s2

\renewcommand{\Bold}[1]{\mathbf{#1}}-\frac{1}{4} \, \sqrt{\frac{\frac{8 \, {\ell}^{2} m^{2} + m}{\sqrt{8 \, {\ell}^{2} m^{3} + m^{2}}} + 1}{8 \, {\ell}^{2} m^{2} + m}} \log\left(2 \, {\ell}^{2} y + \frac{1}{2} \, {\left(8 \, {\ell}^{2} m - \frac{8 \, {\ell}^{2} m^{2} + m}{\sqrt{8 \, {\ell}^{2} m^{3} + m^{2}}} + 1\right)} \sqrt{\frac{\frac{8 \, {\ell}^{2} m^{2} + m}{\sqrt{8 \, {\ell}^{2} m^{3} + m^{2}}} + 1}{8 \, {\ell}^{2} m^{2} + m}}\right) + \frac{1}{4} \, \sqrt{\frac{\frac{8 \, {\ell}^{2} m^{2} + m}{\sqrt{8 \, {\ell}^{2} m^{3} + m^{2}}} + 1}{8 \, {\ell}^{2} m^{2} + m}} \log\left(2 \, {\ell}^{2} y - \frac{1}{2} \, {\left(8 \, {\ell}^{2} m - \frac{8 \, {\ell}^{2} m^{2} + m}{\sqrt{8 \, {\ell}^{2} m^{3} + m^{2}}} + 1\right)} \sqrt{\frac{\frac{8 \, {\ell}^{2} m^{2} + m}{\sqrt{8 \, {\ell}^{2} m^{3} + m^{2}}} + 1}{8 \, {\ell}^{2} m^{2} + m}}\right) - \frac{1}{4} \, \sqrt{-\frac{\frac{8 \, {\ell}^{2} m^{2} + m}{\sqrt{8 \, {\ell}^{2} m^{3} + m^{2}}} - 1}{8 \, {\ell}^{2} m^{2} + m}} \log\left(2 \, {\ell}^{2} y + \frac{1}{2} \, {\left(8 \, {\ell}^{2} m + \frac{8 \, {\ell}^{2} m^{2} + m}{\sqrt{8 \, {\ell}^{2} m^{3} + m^{2}}} + 1\right)} \sqrt{-\frac{\frac{8 \, {\ell}^{2} m^{2} + m}{\sqrt{8 \, {\ell}^{2} m^{3} + m^{2}}} - 1}{8 \, {\ell}^{2} m^{2} + m}}\right) + \frac{1}{4} \, \sqrt{-\frac{\frac{8 \, {\ell}^{2} m^{2} + m}{\sqrt{8 \, {\ell}^{2} m^{3} + m^{2}}} - 1}{8 \, {\ell}^{2} m^{2} + m}} \log\left(2 \, {\ell}^{2} y - \frac{1}{2} \, {\left(8 \, {\ell}^{2} m + \frac{8 \, {\ell}^{2} m^{2} + m}{\sqrt{8 \, {\ell}^{2} m^{3} + m^{2}}} + 1\right)} \sqrt{-\frac{\frac{8 \, {\ell}^{2} m^{2} + m}{\sqrt{8 \, {\ell}^{2} m^{3} + m^{2}}} - 1}{8 \, {\ell}^{2} m^{2} + m}}\right)

In [87]:

s2 = s2.canonicalize_radical().simplify_log()
s2

\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{\sqrt{-8 \, {\ell}^{2} m + \sqrt{8 \, {\ell}^{2} m + 1} - 1} \log\left(\frac{4 \, {\left(8 \, {\ell}^{2} m + 1\right)}^{\frac{1}{4}} {\ell}^{2} \sqrt{m} y - \sqrt{-8 \, {\ell}^{2} m + \sqrt{8 \, {\ell}^{2} m + 1} - 1} {\left(\sqrt{8 \, {\ell}^{2} m + 1} + 1\right)}}{4 \, {\left(8 \, {\ell}^{2} m + 1\right)}^{\frac{1}{4}} {\ell}^{2} \sqrt{m} y + \sqrt{-8 \, {\ell}^{2} m + \sqrt{8 \, {\ell}^{2} m + 1} - 1} {\left(\sqrt{8 \, {\ell}^{2} m + 1} + 1\right)}}\right) + \sqrt{8 \, {\ell}^{2} m + \sqrt{8 \, {\ell}^{2} m + 1} + 1} \log\left(\frac{4 \, {\left(8 \, {\ell}^{2} m + 1\right)}^{\frac{1}{4}} {\ell}^{2} \sqrt{m} y - \sqrt{8 \, {\ell}^{2} m + \sqrt{8 \, {\ell}^{2} m + 1} + 1} {\left(\sqrt{8 \, {\ell}^{2} m + 1} - 1\right)}}{4 \, {\left(8 \, {\ell}^{2} m + 1\right)}^{\frac{1}{4}} {\ell}^{2} \sqrt{m} y + \sqrt{8 \, {\ell}^{2} m + \sqrt{8 \, {\ell}^{2} m + 1} + 1} {\left(\sqrt{8 \, {\ell}^{2} m + 1} - 1\right)}}\right)}{4 \, {\left(8 \, {\ell}^{2} m + 1\right)}^{\frac{3}{4}} \sqrt{m}}

Check:

In [88]:

diff(s2, y).simplify_full()

\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{{\ell}^{2} y^{4} + y^{2} - 2 \, m}

In the above expressions for $s_1(y)$ and $s_2(y)$ there appears the factor $\mathfrak{P} = \sqrt{1 + 8\ell^2 m},$ which we represent by the symbolic variable B

In [89]:

B = var('B')
assume(B > 1)

Let us make $B$ appear in $s_1$ :

In [90]:

s1 = s1.subs({l^2: (B^2 - 1)/(8*m)}).simplify_full()
s1

\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{\sqrt{2} \sqrt{B^{2} - B} \log\left(\frac{\sqrt{2} \sqrt{B} {\ell} y - \sqrt{B^{2} - B}}{\sqrt{2} \sqrt{B} {\ell} y + \sqrt{B^{2} - B}}\right) + \sqrt{2} \sqrt{-B^{2} - B} \log\left(\frac{\sqrt{2} \sqrt{B} {\ell} y + \sqrt{-B^{2} - B}}{\sqrt{2} \sqrt{B} {\ell} y - \sqrt{-B^{2} - B}}\right)}{4 \, B^{\frac{3}{2}} {\ell}}

In this expression, there appears the term $\sqrt{-B^2-B}$ which is imaginary since $B>1$ . We there rewrite it as $i\sqrt{B}\sqrt{B+1}$ :

In [91]:

s1 = s1.subs({sqrt(-B^2 - B): I*sqrt(B)*sqrt(B + 1), 
              sqrt(B^2 - B): sqrt(B)*sqrt(B - 1)})
s1

\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{i \, \sqrt{2} \sqrt{B + 1} \sqrt{B} \log\left(\frac{\sqrt{2} \sqrt{B} {\ell} y + i \, \sqrt{B + 1} \sqrt{B}}{\sqrt{2} \sqrt{B} {\ell} y - i \, \sqrt{B + 1} \sqrt{B}}\right) + \sqrt{2} \sqrt{B - 1} \sqrt{B} \log\left(\frac{\sqrt{2} \sqrt{B} {\ell} y - \sqrt{B - 1} \sqrt{B}}{\sqrt{2} \sqrt{B} {\ell} y + \sqrt{B - 1} \sqrt{B}}\right)}{4 \, B^{\frac{3}{2}} {\ell}}

In [92]:

s1 = s1.simplify_log()
s1

\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{i \, \sqrt{2} \sqrt{B + 1} \log\left(\frac{\sqrt{2} {\ell} y + i \, \sqrt{B + 1}}{\sqrt{2} {\ell} y - i \, \sqrt{B + 1}}\right) + \sqrt{2} \sqrt{B - 1} \log\left(\frac{\sqrt{2} {\ell} y - \sqrt{B - 1}}{\sqrt{2} {\ell} y + \sqrt{B - 1}}\right)}{4 \, B {\ell}}

In the first $\log$ , we recognize the $\mathrm{arctan}$ function, via the identity $\mathrm{arctan}\, x = \frac{i}{2} \ln\left( \frac{i + x}{i - x} \right),$ which we use in the form $i \ln\left( \frac{x + i}{x - i} \right) = 2 \mathrm{arctan}(x) - \pi$ as we can check:

In [93]:

taylor(I*ln((x+I)/(x-I)) - 2*atan(x) + pi, x, 0, 10)

\renewcommand{\Bold}[1]{\mathbf{#1}}0

Thus, we set, disregarding the additive constant $-\pi$ ,

In [94]:

s1 = sqrt(2)/(4*B*l)*(2*sqrt(B+1)*atan(sqrt(2)*l/sqrt(B+1)*y)
                      + sqrt(B-1)*ln((sqrt(2)*l/sqrt(B-1)*y - 1)/(sqrt(2)*l/sqrt(B-1)*y + 1)))
s1

\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{\sqrt{2} {\left(2 \, \sqrt{B + 1} \arctan\left(\frac{\sqrt{2} {\ell} y}{\sqrt{B + 1}}\right) + \sqrt{B - 1} \log\left(\frac{\frac{\sqrt{2} {\ell} y}{\sqrt{B - 1}} - 1}{\frac{\sqrt{2} {\ell} y}{\sqrt{B - 1}} + 1}\right)\right)}}{4 \, B {\ell}}

Let us check that we have indeed a primitive of $y\mapsto \frac{y^2}{\ell^2 y^4 + y^2 - 2m}$ :

In [95]:

Ds1 = diff(s1, y).simplify_full()
Ds1

\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{4 \, {\ell}^{2} y^{2}}{4 \, {\ell}^{4} y^{4} + 4 \, {\ell}^{2} y^{2} - B^{2} + 1}

In [96]:

Ds1.subs({B: sqrt(1 + 8*l^2*m)}).simplify_full()

\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{y^{2}}{{\ell}^{2} y^{4} + y^{2} - 2 \, m}

Similarly, we can express $s_2$ in terms of $B$ :

In [97]:

s2 = s2.subs({l^2: (B^2 - 1)/(8*m)}).simplify_full()
s2

\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{\sqrt{B^{2} + B} \log\left(\frac{{\left(B + 1\right)} \sqrt{B} \sqrt{m} y - 2 \, \sqrt{B^{2} + B} m}{{\left(B + 1\right)} \sqrt{B} \sqrt{m} y + 2 \, \sqrt{B^{2} + B} m}\right) + \sqrt{-B^{2} + B} \log\left(\frac{{\left(B - 1\right)} \sqrt{B} \sqrt{m} y - 2 \, \sqrt{-B^{2} + B} m}{{\left(B - 1\right)} \sqrt{B} \sqrt{m} y + 2 \, \sqrt{-B^{2} + B} m}\right)}{4 \, B^{\frac{3}{2}} \sqrt{m}}

Since $B>1$ , we replace $\sqrt{-B^2 + B}$ by $i\sqrt{B}\sqrt{B-1}$ :

In [98]:

s2 = s2.subs({sqrt(-B^2 + B): I*sqrt(B)*sqrt(B - 1), 
              sqrt(B^2 + B): sqrt(B)*sqrt(B + 1)})
s2

\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{\sqrt{B + 1} \sqrt{B} \log\left(\frac{{\left(B + 1\right)} \sqrt{B} \sqrt{m} y - 2 \, \sqrt{B + 1} \sqrt{B} m}{{\left(B + 1\right)} \sqrt{B} \sqrt{m} y + 2 \, \sqrt{B + 1} \sqrt{B} m}\right) + i \, \sqrt{B - 1} \sqrt{B} \log\left(\frac{{\left(B - 1\right)} \sqrt{B} \sqrt{m} y - 2 i \, \sqrt{B - 1} \sqrt{B} m}{{\left(B - 1\right)} \sqrt{B} \sqrt{m} y + 2 i \, \sqrt{B - 1} \sqrt{B} m}\right)}{4 \, B^{\frac{3}{2}} \sqrt{m}}

In [99]:

s2 = s2.simplify_log()
s2

\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{\sqrt{B + 1} \log\left(\frac{{\left(B + 1\right)} \sqrt{m} y - 2 \, \sqrt{B + 1} m}{{\left(B + 1\right)} \sqrt{m} y + 2 \, \sqrt{B + 1} m}\right) + i \, \sqrt{B - 1} \log\left(\frac{{\left(B - 1\right)} \sqrt{m} y - 2 i \, \sqrt{B - 1} m}{{\left(B - 1\right)} \sqrt{m} y + 2 i \, \sqrt{B - 1} m}\right)}{4 \, B \sqrt{m}}

Again, we use the identity $i \ln\left( \frac{x + i}{x - i} \right) = 2 \mathrm{arctan}(x) - \pi$ to rewrite $s_2$ as

In [100]:

s2 = 1/(4*B*sqrt(m))*(sqrt(B+1)*ln( (sqrt(B+1)/(2*sqrt(m))*y - 1)
                                   /(sqrt(B+1)/(2*sqrt(m))*y + 1) )
                      - 2*sqrt(B-1)*atan(sqrt(B-1)/(2*sqrt(m))*y))
s2

\renewcommand{\Bold}[1]{\mathbf{#1}}-\frac{2 \, \sqrt{B - 1} \arctan\left(\frac{\sqrt{B - 1} y}{2 \, \sqrt{m}}\right) - \sqrt{B + 1} \log\left(\frac{\frac{\sqrt{B + 1} y}{\sqrt{m}} - 2}{\frac{\sqrt{B + 1} y}{\sqrt{m}} + 2}\right)}{4 \, B \sqrt{m}}

Let us check that we have indeed a primitive of $y\mapsto \frac{1}{\ell^2 y^4 + y^2 - 2m}$ :

In [101]:

Ds2 = diff(s2, y).simplify_full()
Ds2

\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{8 \, m}{{\left(B^{2} - 1\right)} y^{4} + 8 \, m y^{2} - 16 \, m^{2}}

In [102]:

Ds2.subs({B: sqrt(1 + 8*l^2*m)}).simplify_full()

\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{{\ell}^{2} y^{4} + y^{2} - 2 \, m}

Given the above expressions for $s_1(y)$ and $s_2(y)$ we rewrite the solution

In [103]:

mu1_sol(y)

\renewcommand{\Bold}[1]{\mathbf{#1}}K_{2} - \int \frac{{\left({\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_1}^{2} - {\left({\mu_0}^{3} - {\mu_0}\right)} {\beta_2}^{2}\right)} {\ell}^{2} y - {\left({\mu_0}^{3} - {\mu_0}\right)} \int \frac{{\left({\beta_1}^{2} - {\beta_2}^{2}\right)} {\ell}^{2} y^{2} + {\mathcal{P}'}^{2} {\beta_1}^{2} - {\mathcal{Q}'}^{2} {\beta_2}^{2} - 2 \, {\left({\beta_1}^{2} - {\beta_2}^{2} - 2 \, {\beta_1} + 2 \, {\beta_2}\right)} {\ell}^{2} m}{{\ell}^{2} y^{4} + y^{2} - 2 \, m}\,{d y} - K_{1}}{{\ell}^{2} y^{4} + y^{2} - 2 \, m}\,{d y}

In [104]:

C1, C2 = var('C_1', 'C_2') 
# mu1 / mu0(1-mu0^2) : 
mu1s0 = - C2/(Mu0*sqrt(1-Mu0^2)) - C1/(Mu0*sqrt(1-Mu0^2))*s2 \
        + integrate(((beta1^2 - beta2^2)*l^2*y 
                     - (beta1^2 - beta2^2)*l^2 * s1
              - (P^2*beta1^2 - Q^2*beta2^2 - 2*(beta1^2 - beta2^2 - 2*(beta1-beta2))*l^2*m) * s2)
                     / (l^2*y^4 + y^2 - 2*m), 
                    y, hold=True)
mu1s0

\renewcommand{\Bold}[1]{\mathbf{#1}}-\frac{C_{2}}{\sqrt{-{\mu_0}^{2} + 1} {\mu_0}} + \frac{{\left(2 \, \sqrt{B - 1} \arctan\left(\frac{\sqrt{B - 1} y}{2 \, \sqrt{m}}\right) - \sqrt{B + 1} \log\left(\frac{\frac{\sqrt{B + 1} y}{\sqrt{m}} - 2}{\frac{\sqrt{B + 1} y}{\sqrt{m}} + 2}\right)\right)} C_{1}}{4 \, \sqrt{-{\mu_0}^{2} + 1} B {\mu_0} \sqrt{m}} + \int \frac{4 \, {\left({\beta_1}^{2} - {\beta_2}^{2}\right)} {\ell}^{2} y - \frac{\sqrt{2} {\left({\beta_1}^{2} - {\beta_2}^{2}\right)} {\left(2 \, \sqrt{B + 1} \arctan\left(\frac{\sqrt{2} {\ell} y}{\sqrt{B + 1}}\right) + \sqrt{B - 1} \log\left(\frac{\frac{\sqrt{2} {\ell} y}{\sqrt{B - 1}} - 1}{\frac{\sqrt{2} {\ell} y}{\sqrt{B - 1}} + 1}\right)\right)} {\ell}}{B} + \frac{{\left({\mathcal{P}'}^{2} {\beta_1}^{2} - {\mathcal{Q}'}^{2} {\beta_2}^{2} - 2 \, {\left({\beta_1}^{2} - {\beta_2}^{2} - 2 \, {\beta_1} + 2 \, {\beta_2}\right)} {\ell}^{2} m\right)} {\left(2 \, \sqrt{B - 1} \arctan\left(\frac{\sqrt{B - 1} y}{2 \, \sqrt{m}}\right) - \sqrt{B + 1} \log\left(\frac{\frac{\sqrt{B + 1} y}{\sqrt{m}} - 2}{\frac{\sqrt{B + 1} y}{\sqrt{m}} + 2}\right)\right)}}{B \sqrt{m}}}{4 \, {\left({\ell}^{2} y^{4} + y^{2} - 2 \, m\right)}}\,{d y}

In [105]:

mu1_sol(y) = mu1s0 * Mu0*(1-Mu0^2)
mu1_sol(y)

\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{4} \, {\left({\mu_0}^{2} - 1\right)} {\mu_0} {\left(\frac{4 \, C_{2}}{\sqrt{-{\mu_0}^{2} + 1} {\mu_0}} - \frac{{\left(2 \, \sqrt{B - 1} \arctan\left(\frac{\sqrt{B - 1} y}{2 \, \sqrt{m}}\right) - \sqrt{B + 1} \log\left(\frac{\frac{\sqrt{B + 1} y}{\sqrt{m}} - 2}{\frac{\sqrt{B + 1} y}{\sqrt{m}} + 2}\right)\right)} C_{1}}{\sqrt{-{\mu_0}^{2} + 1} B {\mu_0} \sqrt{m}} - 4 \, \int \frac{4 \, {\left({\beta_1}^{2} - {\beta_2}^{2}\right)} {\ell}^{2} y - \frac{\sqrt{2} {\left({\beta_1}^{2} - {\beta_2}^{2}\right)} {\left(2 \, \sqrt{B + 1} \arctan\left(\frac{\sqrt{2} {\ell} y}{\sqrt{B + 1}}\right) + \sqrt{B - 1} \log\left(\frac{\frac{\sqrt{2} {\ell} y}{\sqrt{B - 1}} - 1}{\frac{\sqrt{2} {\ell} y}{\sqrt{B - 1}} + 1}\right)\right)} {\ell}}{B} + \frac{{\left({\mathcal{P}'}^{2} {\beta_1}^{2} - {\mathcal{Q}'}^{2} {\beta_2}^{2} - 2 \, {\left({\beta_1}^{2} - {\beta_2}^{2} - 2 \, {\beta_1} + 2 \, {\beta_2}\right)} {\ell}^{2} m\right)} {\left(2 \, \sqrt{B - 1} \arctan\left(\frac{\sqrt{B - 1} y}{2 \, \sqrt{m}}\right) - \sqrt{B + 1} \log\left(\frac{\frac{\sqrt{B + 1} y}{\sqrt{m}} - 2}{\frac{\sqrt{B + 1} y}{\sqrt{m}} + 2}\right)\right)}}{B \sqrt{m}}}{4 \, {\left({\ell}^{2} y^{4} + y^{2} - 2 \, m\right)}}\,{d y}\right)}

Let us check that we do have a solution of the equation for $\mu_1$ :

In [106]:

eq_mu1.substitute_function(mu_1, mu1_sol).simplify_full().subs({B: sqrt(1 + 8*l^2*m)}).simplify_full()

\renewcommand{\Bold}[1]{\mathbf{#1}}0 = 0

Conjugate momenta

In [107]:

def conjugate_momenta(lagr, qs, var):
    r"""
    Compute the conjugate momenta from a given Lagrangian.

    INPUT:

    - ``lagr`` -- symbolic expression representing the Lagrangian density
    - ``qs`` -- either a single symbolic function or a list/tuple of
      symbolic functions, representing the `q`'s; these functions must
      appear in ``lagr`` up to at most their first derivatives
    - ``var`` -- either a single variable, typically `t` (1-dimensional
      problem) or a list/tuple of symbolic variables; in the latter case the
      time coordinate must the first one

    OUTPUT:

    - list of conjugate momenta; if only one function is involved, the
      single conjugate momentum is returned instead.

    """
    if not isinstance(qs, (list, tuple)):
        qs = [qs]
    if not isinstance(var, (list, tuple)):
        var = [var]
    n = len(qs)
    d = len(var)
    dqvt = [SR.var('qxxxx{}_t'.format(q)) for q in qs]
    subs = {diff(qs[i](*var), var[0]): dqvt[i] for i in range(n)}
    subs_inv = {dqvt[i]: diff(qs[i](*var), var[0]) for i in range(n)}
    lg = lagr.substitute(subs)
    ps = [diff(lg, dotq).simplify_full().substitute(subs_inv) for dotq in dqvt]
    if n == 1:
        return ps[0]
    return ps

In [108]:

pis = conjugate_momenta(L_a2, [Phi_1, Psi_1], y)
pis

\renewcommand{\Bold}[1]{\mathbf{#1}}\left[-{\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} {\ell}^{2} y^{4} \frac{\partial}{\partial y}\Phi_{1}\left(y\right) - {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} y^{2} \frac{\partial}{\partial y}\Phi_{1}\left(y\right) + 2 \, {\left({\mu_0}^{2} - 1\right)} a^{2} {\beta_1}^{2} m \frac{\partial}{\partial y}\Phi_{1}\left(y\right), {\mu_0}^{2} a^{2} {\beta_2}^{2} {\ell}^{2} y^{4} \frac{\partial}{\partial y}\Psi_{1}\left(y\right) + {\mu_0}^{2} a^{2} {\beta_2}^{2} y^{2} \frac{\partial}{\partial y}\Psi_{1}\left(y\right) - 2 \, {\mu_0}^{2} a^{2} {\beta_2}^{2} m \frac{\partial}{\partial y}\Psi_{1}\left(y\right)\right]

In [109]:

pi_phi_y = (pis[0]/(a*beta1)).substitute_function(Phi_1, Phi1_sol).simplify_full()
pi_phi_y

\renewcommand{\Bold}[1]{\mathbf{#1}}-{\left({\mu_0}^{2} - 1\right)} {\mathcal{P}'} a {\beta_1}

In [110]:

pi_psi_y = (pis[1]/(a*beta2)).substitute_function(Psi_1, Psi1_sol).simplify_full()
pi_psi_y

\renewcommand{\Bold}[1]{\mathbf{#1}}{\mu_0}^{2} {\mathcal{Q}'} a {\beta_2}

In [111]:

pis4 = conjugate_momenta(L_a4, [Phi_1, Psi_1, mu_1], y)

In [112]:

pis4[2]

\renewcommand{\Bold}[1]{\mathbf{#1}}-\frac{a^{4} {\ell}^{2} y^{4} \frac{\partial}{\partial y}\mu_{1}\left(y\right) + a^{4} y^{2} \frac{\partial}{\partial y}\mu_{1}\left(y\right) - 2 \, a^{4} m \frac{\partial}{\partial y}\mu_{1}\left(y\right)}{{\mu_0}^{2} - 1}

The quantity $\pi_\theta^y / (a^2 \sin\Theta_0\cos\Theta_0)$ :

In [113]:

pi_theta_y_a2sT0 = (- pis4[2] / (a^4*Mu0)).substitute_function(mu_1, mu1_sol).simplify_full()
pi_theta_y_a2sT0 = pi_theta_y_a2sT0.subs({B: sqrt(1 + 8*l^2*m)}).simplify_full()
pi_theta_y_a2sT0

\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{{\left(2 \, {\left(\sqrt{2} {\mu_0} {\beta_1}^{2} - \sqrt{2} {\mu_0} {\beta_2}^{2}\right)} {\ell} \sqrt{m} \arctan\left(\frac{\sqrt{2} {\ell} y}{\sqrt{\sqrt{8 \, {\ell}^{2} m + 1} + 1}}\right) + {\left({\mu_0} {\mathcal{P}'}^{2} {\beta_1}^{2} - {\mu_0} {\mathcal{Q}'}^{2} {\beta_2}^{2} - 2 \, {\left({\mu_0} {\beta_1}^{2} - {\mu_0} {\beta_2}^{2} - 2 \, {\mu_0} {\beta_1} + 2 \, {\mu_0} {\beta_2}\right)} {\ell}^{2} m\right)} \log\left(\frac{\sqrt{m} y \sqrt{\sqrt{8 \, {\ell}^{2} m + 1} + 1} - 2 \, m}{\sqrt{m} y \sqrt{\sqrt{8 \, {\ell}^{2} m + 1} + 1} + 2 \, m}\right)\right)} \sqrt{-{\mu_0}^{2} + 1} \sqrt{\sqrt{8 \, {\ell}^{2} m + 1} + 1} + {\left({\left(\sqrt{2} {\mu_0} {\beta_1}^{2} - \sqrt{2} {\mu_0} {\beta_2}^{2}\right)} {\ell} \sqrt{m} \log\left(\frac{\sqrt{2} {\ell} y \sqrt{\sqrt{8 \, {\ell}^{2} m + 1} - 1} - \sqrt{8 \, {\ell}^{2} m + 1} + 1}{\sqrt{2} {\ell} y \sqrt{\sqrt{8 \, {\ell}^{2} m + 1} - 1} + \sqrt{8 \, {\ell}^{2} m + 1} - 1}\right) - 2 \, {\left({\mu_0} {\mathcal{P}'}^{2} {\beta_1}^{2} - {\mu_0} {\mathcal{Q}'}^{2} {\beta_2}^{2} - 2 \, {\left({\mu_0} {\beta_1}^{2} - {\mu_0} {\beta_2}^{2} - 2 \, {\mu_0} {\beta_1} + 2 \, {\mu_0} {\beta_2}\right)} {\ell}^{2} m\right)} \arctan\left(\frac{y \sqrt{\sqrt{8 \, {\ell}^{2} m + 1} - 1}}{2 \, \sqrt{m}}\right)\right)} \sqrt{-{\mu_0}^{2} + 1} \sqrt{\sqrt{8 \, {\ell}^{2} m + 1} - 1} - 4 \, {\left({\left({\mu_0} {\beta_1}^{2} - {\mu_0} {\beta_2}^{2}\right)} \sqrt{-{\mu_0}^{2} + 1} {\ell}^{2} \sqrt{m} y - C_{1} \sqrt{m}\right)} \sqrt{8 \, {\ell}^{2} m + 1}}{4 \, \sqrt{8 \, {\ell}^{2} m + 1} \sqrt{-{\mu_0}^{2} + 1} {\mu_0} \sqrt{m}}

In [114]:

pi_theta_y_a2sT0.numerator().subs({l^2: (B^2 - 1)/(8*m)}).simplify_full()

\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{16 \, B C_{1} m^{\frac{3}{2}} - {\left(2 \, {\left(2 \, {\left(B^{2} - 1\right)} {\mu_0} {\beta_1} + {\left(4 \, {\mu_0} {\mathcal{P}'}^{2} - {\left(B^{2} - 1\right)} {\mu_0}\right)} {\beta_1}^{2} - 2 \, {\left(B^{2} - 1\right)} {\mu_0} {\beta_2} - {\left(4 \, {\mu_0} {\mathcal{Q}'}^{2} - {\left(B^{2} - 1\right)} {\mu_0}\right)} {\beta_2}^{2}\right)} \sqrt{B - 1} m \arctan\left(\frac{\sqrt{B - 1} y}{2 \, \sqrt{m}}\right) - {\left(2 \, {\left(B^{2} - 1\right)} {\mu_0} {\beta_1} + {\left(4 \, {\mu_0} {\mathcal{P}'}^{2} - {\left(B^{2} - 1\right)} {\mu_0}\right)} {\beta_1}^{2} - 2 \, {\left(B^{2} - 1\right)} {\mu_0} {\beta_2} - {\left(4 \, {\mu_0} {\mathcal{Q}'}^{2} - {\left(B^{2} - 1\right)} {\mu_0}\right)} {\beta_2}^{2}\right)} \sqrt{B + 1} m \log\left(\frac{\sqrt{B + 1} \sqrt{m} y - 2 \, m}{\sqrt{B + 1} \sqrt{m} y + 2 \, m}\right) - 2 \, {\left(4 \, {\left(\sqrt{2} {\mu_0} {\beta_1}^{2} - \sqrt{2} {\mu_0} {\beta_2}^{2}\right)} \sqrt{B + 1} {\ell} m \arctan\left(\frac{\sqrt{2} {\ell} y}{\sqrt{B + 1}}\right) + 2 \, {\left(\sqrt{2} {\mu_0} {\beta_1}^{2} - \sqrt{2} {\mu_0} {\beta_2}^{2}\right)} \sqrt{B - 1} {\ell} m \log\left(\frac{\sqrt{2} \sqrt{B - 1} {\ell} y - B + 1}{\sqrt{2} \sqrt{B - 1} {\ell} y + B - 1}\right) - {\left({\left(B^{3} - B\right)} {\mu_0} {\beta_1}^{2} - {\left(B^{3} - B\right)} {\mu_0} {\beta_2}^{2}\right)} y\right)} \sqrt{m}\right)} \sqrt{-{\mu_0}^{2} + 1}}{4 \, m}

In [115]:

pi_theta_y_a2sT0.denominator()

\renewcommand{\Bold}[1]{\mathbf{#1}}4 \, \sqrt{8 \, {\ell}^{2} m + 1} \sqrt{-{\mu_0}^{2} + 1} {\mu_0} \sqrt{m}

The quantity $\frac{\pi_\theta^y}{(a^2/2) \sin 2\Theta_0} + (\beta_1^2 - \beta_2^2)\ell^2 y - \frac{C_1}{\sin\Theta_0\cos\Theta_0}$

In [116]:

part1 = - (beta1^2 - beta2^2)*l^2*y + C1/(Mu0*sqrt(1-Mu0^2))
s = (pi_theta_y_a2sT0  - part1).simplify_full()
s

\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{{\left(2 \, {\left(\sqrt{2} {\beta_1}^{2} - \sqrt{2} {\beta_2}^{2}\right)} {\ell} \sqrt{m} \arctan\left(\frac{\sqrt{2} {\ell} y}{\sqrt{\sqrt{8 \, {\ell}^{2} m + 1} + 1}}\right) + {\left({\mathcal{P}'}^{2} {\beta_1}^{2} - {\mathcal{Q}'}^{2} {\beta_2}^{2} - 2 \, {\left({\beta_1}^{2} - {\beta_2}^{2} - 2 \, {\beta_1} + 2 \, {\beta_2}\right)} {\ell}^{2} m\right)} \log\left(\frac{\sqrt{m} y \sqrt{\sqrt{8 \, {\ell}^{2} m + 1} + 1} - 2 \, m}{\sqrt{m} y \sqrt{\sqrt{8 \, {\ell}^{2} m + 1} + 1} + 2 \, m}\right)\right)} \sqrt{\sqrt{8 \, {\ell}^{2} m + 1} + 1} + {\left({\left(\sqrt{2} {\beta_1}^{2} - \sqrt{2} {\beta_2}^{2}\right)} {\ell} \sqrt{m} \log\left(\frac{\sqrt{2} {\ell} y \sqrt{\sqrt{8 \, {\ell}^{2} m + 1} - 1} - \sqrt{8 \, {\ell}^{2} m + 1} + 1}{\sqrt{2} {\ell} y \sqrt{\sqrt{8 \, {\ell}^{2} m + 1} - 1} + \sqrt{8 \, {\ell}^{2} m + 1} - 1}\right) - 2 \, {\left({\mathcal{P}'}^{2} {\beta_1}^{2} - {\mathcal{Q}'}^{2} {\beta_2}^{2} - 2 \, {\left({\beta_1}^{2} - {\beta_2}^{2} - 2 \, {\beta_1} + 2 \, {\beta_2}\right)} {\ell}^{2} m\right)} \arctan\left(\frac{y \sqrt{\sqrt{8 \, {\ell}^{2} m + 1} - 1}}{2 \, \sqrt{m}}\right)\right)} \sqrt{\sqrt{8 \, {\ell}^{2} m + 1} - 1}}{4 \, \sqrt{8 \, {\ell}^{2} m + 1} \sqrt{m}}

Let us perform an expansion in $1/y$ for $y\rightarrow +\infty$ :

In [117]:

u = var('u')
assume(u > 0)
s = s.subs({y: 1/u}).simplify_log()
assume(l>0)
s = s.taylor(u, 0, 2)
s = s.subs({u: 1/y})
s

\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{{\left(\sqrt{2} \pi {\beta_1}^{2} - \sqrt{2} \pi {\beta_2}^{2}\right)} {\ell} \sqrt{m} \sqrt{\sqrt{8 \, {\ell}^{2} m + 1} + 1} - {\left(\pi {\mathcal{P}'}^{2} {\beta_1}^{2} - \pi {\mathcal{Q}'}^{2} {\beta_2}^{2} - 2 \, {\left(\pi {\beta_1}^{2} - \pi {\beta_2}^{2} - 2 \, \pi {\beta_1} + 2 \, \pi {\beta_2}\right)} {\ell}^{2} m\right)} \sqrt{\sqrt{8 \, {\ell}^{2} m + 1} - 1}}{4 \, \sqrt{8 \, {\ell}^{2} m + 1} \sqrt{m}} - \frac{{\beta_1}^{2} - {\beta_2}^{2}}{y}

In [118]:

\renewcommand{\Bold}[1]{\mathbf{#1}}\frac{{\left(\sqrt{2} \pi {\beta_1}^{2} - \sqrt{2} \pi {\beta_2}^{2}\right)} {\ell} \sqrt{m} \sqrt{\sqrt{8 \, {\ell}^{2} m + 1} + 1} - {\left(\pi {\mathcal{P}'}^{2} {\beta_1}^{2} - \pi {\mathcal{Q}'}^{2} {\beta_2}^{2} - 2 \, {\left(\pi {\beta_1}^{2} - \pi {\beta_2}^{2} - 2 \, \pi {\beta_1} + 2 \, \pi {\beta_2}\right)} {\ell}^{2} m\right)} \sqrt{\sqrt{8 \, {\ell}^{2} m + 1} - 1}}{4 \, \sqrt{8 \, {\ell}^{2} m + 1} \sqrt{m}} - \frac{{\beta_1}^{2} - {\beta_2}^{2}}{y}

Final result for $\frac{\pi_\theta^y}{(a^2/2) \sin 2\Theta_0}$ :

In [119]:

part1 + s

\renewcommand{\Bold}[1]{\mathbf{#1}}-{\left({\beta_1}^{2} - {\beta_2}^{2}\right)} {\ell}^{2} y + \frac{{\left(\sqrt{2} \pi {\beta_1}^{2} - \sqrt{2} \pi {\beta_2}^{2}\right)} {\ell} \sqrt{m} \sqrt{\sqrt{8 \, {\ell}^{2} m + 1} + 1} - {\left(\pi {\mathcal{P}'}^{2} {\beta_1}^{2} - \pi {\mathcal{Q}'}^{2} {\beta_2}^{2} - 2 \, {\left(\pi {\beta_1}^{2} - \pi {\beta_2}^{2} - 2 \, \pi {\beta_1} + 2 \, \pi {\beta_2}\right)} {\ell}^{2} m\right)} \sqrt{\sqrt{8 \, {\ell}^{2} m + 1} - 1}}{4 \, \sqrt{8 \, {\ell}^{2} m + 1} \sqrt{m}} - \frac{{\beta_1}^{2} - {\beta_2}^{2}}{y} + \frac{C_{1}}{\sqrt{-{\mu_0}^{2} + 1} {\mu_0}}

The terms in $C_1$ , $y$ and $y^{-1}$ agree with Eq. (4.37) of the paper.

In [0]: